+AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
+
+CFLAGS="-Wall $CFLAGS"
+
+# URCU
+
+# urcu - check if we just find the headers it out of the box.
+AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
+This error can also occur when the liburcu package's configure script has not been run.])])
+
+# urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
+# Part of Userspace RCU library 0.7.2 or better.
+AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
+liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
+
+AC_MSG_CHECKING([caa_likely()])
+AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
+#include <urcu/compiler.h>
+void fct(void)
+{
+ if (caa_likely(1)) {
+ }
+}
+]])],[
+ AC_MSG_RESULT([yes])
+],[
+ AC_MSG_RESULT([no])
+ AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
+
+])
+
+# urcu - check that URCU lib is available to compilation
+AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
+
+# urcu - check that URCU lib is at least version 0.6
+AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
+
+# optional linux/perf_event.h
+AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
+
+# Perf event counters are only supported on x86 so far.
+AC_MSG_CHECKING([UST support for architecture perf event counters])
+case $host_cpu in
+changequote(,)dnl
+ i[3456]86)
+changequote([,])dnl
+ UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes;;
+ x86_64) UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes;;
+ amd64) UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=yes;;
+ *) UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS=no;;
+esac
+AC_MSG_RESULT([$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS])
+
+AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes" -a "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"])
+
+if test "x$have_perf_event" = "xyes" -a "x$UST_SUPPORT_FOR_ARCH_PERF_EVENT_COUNTERS" = "xyes"; then
+AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
+fi
+
+AC_MSG_CHECKING([host system alignment requirements])
+case $host_cpu in
+changequote(,)dnl
+ i[3456]86)
+changequote([,])dnl
+ ;;
+ x86_64) ;;
+ amd64) ;;
+ powerpc) ;;
+ ppc64) ;;
+ ppc64le) ;;
+ powerpc64) ;;
+ powerpc64le) ;;
+ s390) NO_UNALIGNED_ACCESS=1 ;;
+ s390x) NO_UNALIGNED_ACCESS=1 ;;
+ arm*) NO_UNALIGNED_ACCESS=1 ;;
+ aarch64) NO_UNALIGNED_ACCESS=1 ;;
+ mips*) NO_UNALIGNED_ACCESS=1 ;;
+ tile*) NO_UNALIGNED_ACCESS=1 ;;
+ *)
+ UNSUPPORTED_ARCH=1
+ NO_UNALIGNED_ACCESS=1
+ ;;
+esac
+AC_MSG_RESULT([$host_cpu])
+
+if test x$NO_UNALIGNED_ACCESS = x ; then
+AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
+fi
+
+# Check for JNI header files if requested
+AC_ARG_ENABLE([jni-interface],
+ [AS_HELP_STRING([--enable-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
+ [jni_interface=$enableval],
+ [jni_interface=no]
+)
+
+AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
+
+
+AC_ARG_ENABLE([java-agent-jul],
+ [AS_HELP_STRING([--enable-java-agent-jul],[build the LTTng UST Java agent with JUL support [default=no]])],
+ [java_agent_jul=$enableval],
+ [java_agent_jul=no]
+)
+
+AC_ARG_ENABLE([java-agent-log4j],
+ [AS_HELP_STRING([--enable-java-agent-log4j],[build the LTTng UST Java agent with Log4j support [default=no]])],
+ [java_agent_log4j=$enableval],
+ [java_agent_log4j=no]
+)
+
+AC_ARG_ENABLE([java-agent-all],
+ [AS_HELP_STRING([--enable-java-agent-all],[build the LTTng UST Java agent with all supported backends [default=no]])],
+ [java_agent_jul=$enableval
+ java_agent_log4j=$enableval],
+ [:]
+)
+
+
+AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
+AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
+AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
+
+if test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"; then
+ AX_JAVA_OPTIONS
+ AX_PROG_JAVAC
+ AX_PROG_JAVA
+ AX_PROG_JAR
+
+ AX_JNI_INCLUDE_DIR
+ for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
+ do
+ CPPFLAGS="$CPPFLAGS -I$JNI_INCLUDE_DIR"
+ done
+
+ AX_PROG_JAVAH
+fi
+
+if test "x$java_agent_log4j" = "xyes"; then
+ AX_CHECK_CLASSPATH
+
+ AX_CHECK_CLASS(org.apache.log4j.Logger)
+
+ if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
+ AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
+ fi
+fi
+
+# Option to build the python agent
+AC_ARG_ENABLE([python-agent],
+ [AS_HELP_STRING([--enable-python-agent],[build the LTTng UST Python agent [default=no]])],
+ [python_agent=$enableval],
+ [:]
+)
+AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
+if test "x$python_agent" = "xyes"; then
+ AM_PATH_PYTHON([2.7])
+fi
+
+# sdt.h integration
+AC_ARG_WITH([sdt],
+ [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
+ [with_sdt=$withval],
+ [with_sdt="no"]
+)
+
+AS_IF([test "x$with_sdt" = "xyes"],[
+ AC_MSG_CHECKING([STAP_PROBEV()])
+ AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
+ #define SDT_USE_VARIADIC
+ #include <sys/sdt.h>
+ void fct(void)
+ {
+ STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
+ }
+ ]])],[
+ AC_MSG_RESULT([yes])
+ AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
+ ],[
+ AC_MSG_RESULT([no])
+ AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
+ ])
+])
+
+AC_MSG_CHECKING([whether shared libraries are enabled])
+AS_IF([test "x$enable_shared" = "xyes"],
+ [
+ AC_MSG_RESULT([yes])
+ ],
+ [
+ AC_MSG_RESULT([no])
+ AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
+ ])
+
+AC_ARG_WITH([lttng-system-rundir],
+ AS_HELP_STRING([--with-lttng-system-rundir],
+ [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
+ [lttng_system_rundir="$withval"],
+ [lttng_system_rundir="/var/run/lttng"])
+AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
+ [LTTng system runtime directory])
+
+AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES],[python],["yes"])
+AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test $BUILD_GEN_TP_EXAMPLES], [Build examples requiring lttng-gen-tp])
+
+AC_CONFIG_FILES([
+ Makefile
+ doc/Makefile
+ doc/examples/Makefile
+ include/Makefile
+ include/lttng/ust-version.h
+ snprintf/Makefile
+ libringbuffer/Makefile
+ liblttng-ust-comm/Makefile
+ liblttng-ust/Makefile
+ liblttng-ust-ctl/Makefile
+ liblttng-ust-fork/Makefile
+ liblttng-ust-dl/Makefile
+ liblttng-ust-java/Makefile
+ liblttng-ust-java-agent/Makefile
+ liblttng-ust-java-agent/java/Makefile
+ liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
+ liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
+ liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
+ liblttng-ust-java-agent/jni/Makefile
+ liblttng-ust-java-agent/jni/jul/Makefile
+ liblttng-ust-java-agent/jni/log4j/Makefile
+ liblttng-ust-libc-wrapper/Makefile
+ liblttng-ust-cyg-profile/Makefile
+ liblttng-ust-python-agent/Makefile
+ liblttng-ust-python-agent/setup.py
+ liblttng-ust-python-agent/lttngust/__init__.py
+ tools/Makefile
+ tests/Makefile
+ tests/hello/Makefile
+ tests/hello.cxx/Makefile
+ tests/same_line_tracepoint/Makefile
+ tests/snprintf/Makefile
+ tests/ust-elf/Makefile
+ tests/benchmark/Makefile
+ tests/utils/Makefile
+ lttng-ust.pc
+])
+
+# Create link for python agent for the VPATH guru.
+AC_CONFIG_LINKS([
+ liblttng-ust-python-agent/lttngust/agent.py:liblttng-ust-python-agent/lttngust/agent.py
+ liblttng-ust-python-agent/lttngust/cmd.py:liblttng-ust-python-agent/lttngust/cmd.py
+ liblttng-ust-python-agent/lttngust/debug.py:liblttng-ust-python-agent/lttngust/debug.py
+ liblttng-ust-python-agent/lttngust/loghandler.py:liblttng-ust-python-agent/lttngust/loghandler.py
+])
+