+AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
+
+CFLAGS="-Wall $CFLAGS"
+
+# URCU
+
+# urcu - check if we just find the headers it out of the box.
+AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
+This error can also occur when the liburcu package's configure script has not been run.])])
+
+# urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
+# Part of Userspace RCU library 0.7.2 or better.
+AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
+liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
+
+AC_MSG_CHECKING([caa_likely()])
+AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
+#include <urcu/compiler.h>
+void fct(void)
+{
+ if (caa_likely(1)) {
+ }
+}
+]])],[
+ AC_MSG_RESULT([yes])
+],[
+ AC_MSG_RESULT([no])
+ AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
+
+])
+
+# urcu - check that URCU lib is available to compilation
+AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
+
+# urcu - check that URCU lib is at least version 0.6
+AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
+
+AC_MSG_CHECKING([host system alignment requirements])
+case $host_cpu in
+changequote(,)dnl
+ i[3456]86)
+changequote([,])dnl
+ ;;
+ x86_64) ;;
+ amd64) ;;
+ powerpc) ;;
+ ppc64) ;;
+ powerpc64) ;;
+ s390) NO_UNALIGNED_ACCESS=1 ;;
+ s390x) NO_UNALIGNED_ACCESS=1 ;;
+ arm*) NO_UNALIGNED_ACCESS=1 ;;
+ mips*) NO_UNALIGNED_ACCESS=1 ;;
+ tile*) NO_UNALIGNED_ACCESS=1 ;;
+ *) AC_MSG_ERROR([unable to detect alignment requirements (unsupported architecture ($host_cpu)?)]) ;;
+esac
+
+if test x$NO_UNALIGNED_ACCESS = x ; then
+AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
+fi
+
+# Set compile flags to java include files if given
+AC_ARG_WITH([java-jdk],
+ [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
+ [JAVA_JDK=$withval],
+ [JAVA_JDK=""]
+)
+AS_IF([test $JAVA_JDK],[
+ AS_IF([test -d $JAVA_JDK],[
+ AC_MSG_RESULT([using Java includes in $JAVA_SDK])
+ SUBDIRS=`find $JAVA_JDK/include -type d`
+ CPPFLAGS+=" "
+ CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
+ CPPFLAGS+=" "
+ ],[
+ AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
+ ])
+])
+
+# Check for JNI header files if requested
+AC_ARG_WITH([jni-interface],
+ [AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
+ [jni_interface=$withval],
+ [jni_interface=no]
+)
+
+AS_IF([test "x$jni_interface" = "xyes"],[
+ AC_CHECK_HEADERS([jni.h],[],[
+ AC_MSG_ERROR([missing jni.h
+Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
+Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
+ ])
+])
+AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
+
+# sdt.h integration
+AC_ARG_WITH([sdt],
+ [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
+ [with_sdt=$withval],
+ [with_sdt="no"]
+)
+
+AS_IF([test "x$with_sdt" = "xyes"],[
+ AC_MSG_CHECKING([STAP_PROBEV()])
+ AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
+ #define SDT_USE_VARIADIC
+ #include <sys/sdt.h>
+ void fct(void)
+ {
+ STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
+ }
+ ]])],[
+ AC_MSG_RESULT([yes])
+ AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
+ ],[
+ AC_MSG_RESULT([no])
+ AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
+ ])
+])
+
+AC_ARG_WITH([lttng-system-rundir],
+ AS_HELP_STRING([--with-lttng-system-rundir],
+ [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
+ [lttng_system_rundir="$withval"],
+ [lttng_system_rundir="/var/run/lttng"])
+AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
+ [LTTng system runtime directory])
+
+AC_CONFIG_FILES([
+ Makefile
+ doc/Makefile
+ doc/examples/Makefile
+ include/Makefile
+ include/lttng/ust-version.h
+ snprintf/Makefile
+ libringbuffer/Makefile
+ liblttng-ust-comm/Makefile
+ liblttng-ust/Makefile
+ liblttng-ust-ctl/Makefile
+ liblttng-ust-fork/Makefile
+ liblttng-ust-java/Makefile
+ liblttng-ust-libc-wrapper/Makefile
+ liblttng-ust-cyg-profile/Makefile
+ tools/Makefile
+ tests/Makefile
+ tests/hello/Makefile
+ tests/hello.cxx/Makefile
+ tests/same_line_tracepoint/Makefile
+ tests/snprintf/Makefile
+ tests/benchmark/Makefile
+ tests/utils/Makefile
+ lttng-ust.pc
+])
+