+ AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
+])
+
+AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
+
+
+# Check for fmemopen
+AC_CHECK_LIB([c], [fmemopen],
+[
+ AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
+]
+)
+
+# check for libpfm
+AC_CHECK_LIB([pfm], [pfm_initialize],
+ [
+ have_libpfm=yes
+ ])
+AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
+
+# For Python
+# SWIG version needed or newer:
+swig_version=2.0.0
+
+AC_ARG_ENABLE([python-bindings],
+ [AS_HELP_STRING([--enable-python-bindings],
+ [compile Python bindings])],
+ [enable_python_binding=$enableval], [enable_python_binding=no])
+
+AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
+
+if test "x$enable_python_binding" = xyes; then
+ AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
+ AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
+ AM_PATH_PYTHON([3.4])
+
+ AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
+ AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
+ AS_IF([test -z "$PYTHON_INCLUDE"], [
+ AS_IF([test -z "$PYTHON_CONFIG"], [
+ AC_PATH_PROGS([PYTHON_CONFIG],
+ [python$PYTHON_VERSION-config python-config],
+ [],
+ [`dirname $PYTHON`])
+ AS_IF([test "x$PYTHON_CONFIG" = "x"], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
+ ])
+ AC_MSG_CHECKING([python include flags])
+ PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
+ AC_MSG_RESULT([$PYTHON_INCLUDE])
+ ])
+
+else
+ AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
+[if you want Python bindings.])
+
+fi
+
+# Epoll check. If not present, the build will fallback on poll() API
+AX_HAVE_EPOLL(
+ [AX_CONFIG_FEATURE_ENABLE(epoll)],
+ [AX_CONFIG_FEATURE_DISABLE(epoll)]
+)
+AX_CONFIG_FEATURE(
+ [epoll], [This platform supports epoll(7)],
+ [HAVE_EPOLL], [This platform supports epoll(7).]
+)
+
+AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
+ [AX_CONFIG_FEATURE_ENABLE(dirfd)],
+ [AX_CONFIG_FEATURE_DISABLE(dirfd)]
+)
+AX_CONFIG_FEATURE(
+ [dirfd], [Use directory file descriptors],
+ [HAVE_DIRFD], [This platform supports directory file descriptors.]
+)
+
+AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
+AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
+AM_CONDITIONAL([TEST_JAVA_LOG4J2_AGENT], [test "x$test_java_agent_log4j2" = "xyes"])
+
+if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes" || test "x$test_java_agent_log4j2" = "xyes"; then
+ AX_JAVA_OPTIONS
+ AX_PROG_JAVAC
+ AX_PROG_JAVA
+ AX_PROG_JAR
+
+ AX_CHECK_CLASSPATH
+
+ # Check for Java UST agent common class first
+ AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
+ if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
+ AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
+ fi
+
+ if test "x$test_java_agent_jul" = "xyes"; then
+ # Check for JUL agent class
+ AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
+ if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
+ AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
+ fi
+ fi
+
+ if test "x$test_java_agent_log4j" = "xyes"; then
+ # Check for Log4j agent class
+ AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
+ if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
+ AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
+ fi
+
+ # Check for Log4j class
+ AX_CHECK_CLASS(org.apache.log4j.Logger)
+ if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
+ AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
+ fi
+ fi
+
+ if test "x$test_java_agent_log4j2" = "xyes"; then
+ # Check for Log4j2 agent class
+ AX_CHECK_CLASS(org.lttng.ust.agent.log4j2.LttngLogAppender)
+ if test "x$ac_cv_class_org_lttng_ust_agent_log4j2_LttngLogAppender" = "xno"; then
+ AC_MSG_ERROR([The UST Java agent Log4j 2.x class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j2.jar"])
+ fi
+
+ # Check for Log4j 2.x classes
+ AX_CHECK_CLASS([org.apache.logging.log4j.Logger])
+ AX_CHECK_CLASS([org.apache.logging.log4j.core.Core])
+ if test "x$ac_cv_class_org_apache_logging_log4j_Logger" = "xno" || test "x$ac_cv_class_org_apache_logging_log4j_core_Core" = "xno"; then
+ AC_MSG_ERROR([The Log4j 2.x API or core class was not found. Please specify the location of the jars via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j-core.jar:/path/to/log4j-api.jar"])
+ fi
+ fi
+fi
+
+# enable building man pages (user's intention)
+AC_ARG_ENABLE(
+ man-pages,
+ AS_HELP_STRING(
+ [--disable-man-pages],
+ [Do not build and install man pages (already built in a distributed tarball)]
+ ),
+ [man_pages_opt=$enableval],
+ [man_pages_opt=yes]
+)
+
+# check for asciidoc and xmlto if we enabled building the man pages
+have_asciidoc_xmlto=no
+warn_prebuilt_man_pages=no
+
+AS_IF([test "x$man_pages_opt" = "xyes"], [
+ AC_PATH_PROG([ASCIIDOC], [asciidoc])
+ AC_PATH_PROG([XMLTO], [xmlto])
+
+ AS_IF([test "x$ASCIIDOC" = "x" || test "x$XMLTO" = "x"], [
+ AS_IF([test "x$in_git_repo" = "xyes"], [
+ # this is an error because we're in the Git repo, which
+ # means the man pages are not already generated for us,
+ # thus asciidoc/xmlto are required because we were asked
+ # to build the man pages
+ AC_MSG_ERROR([
+You need asciidoc and xmlto to build the LTTng-tools man pages. Use
+--disable-man-pages to disable building the man pages, in which case
+they will not be installed.
+ ])
+ ], [
+ # only warn here: since we're in the tarball, the man
+ # pages should already be generated at this point, thus
+ # asciidoc/xmlto are not strictly required
+ warn_prebuilt_man_pages=yes
+ ])
+ ], [
+ have_asciidoc_xmlto=yes
+ ])
+])
+
+# export man page build condition: build the man pages if the user
+# asked for it, and if the tools are available
+AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
+AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
+
+AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
+
+# embedded --help message
+AC_ARG_ENABLE(
+ [embedded-help],
+ AS_HELP_STRING(
+ [--enable-embedded-help],
+ [Embed the --help messages in the executable files]
+ ),
+ [embedded_help=$enableval],
+ [embedded_help=no]
+)
+AS_IF([test "x$embedded_help" = "xyes"], [
+ AS_IF([test "x$man_pages_opt" = "xno"], [
+ AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
+ ])
+ AC_PATH_PROG([man_prog_path], [man])
+ AS_IF([test "x$man_prog_path" = "x"], [
+ AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
+ ])
+ AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
+ AC_SUBST([MANPROG], [$man_prog_path])
+])
+AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
+
+# Python agent test
+UST_PYTHON_AGENT="lttngust"
+
+AC_ARG_ENABLE(test-python2-agent,
+ AS_HELP_STRING([--enable-test-python2-agent],
+ [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
+ ),[:],[test_python2_agent_autodetect=yes]
+)
+
+AC_ARG_ENABLE(test-python3-agent,
+ AS_HELP_STRING([--enable-test-python3-agent],
+ [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
+ ),[:],[test_python3_agent_autodetect=yes]
+)
+
+AC_ARG_ENABLE(test-python-agent-all,
+ AS_HELP_STRING([--enable-test-python-agent-all],
+ [enable test for all python{2/3} agent.]
+ ),
+)
+
+AS_IF([test ! -z "$enable_test_python_agent_all"], [
+ unset test_python2_agent_autodetect
+ unset test_python3_agent_autodetect
+])
+
+AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
+ enable_test_python2_agent=yes
+ enable_test_python3_agent=yes
+])
+
+AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
+ enable_test_python2_agent=no
+ enable_test_python3_agent=no
+])
+
+
+AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
+ AS_IF([test -z "$PYTHON2"], [
+ PYTHON2=python2
+ ], [
+ AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
+ ])
+
+ AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
+ AS_IF([test -z "$PYTHON2_BIN"], [
+ AS_IF([test -z "$test_python2_agent_autodetect"],[
+ AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
+ ])
+ ], [
+ AC_MSG_CHECKING([for python2 lttng-ust agent])
+ AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
+ PYTHON2_AGENT=$PYTHON2_BIN
+ AC_MSG_RESULT([yes])
+ RUN_PYTHON_AGENT_TEST=yes
+ ], [
+ AC_MSG_RESULT([no])
+ AS_IF([test -z "$test_python2_agent_autodetect"],[
+ AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
+ ])
+ ])
+
+ ])
+
+])
+
+AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
+ AS_IF([test -z "$PYTHON3"], [
+ PYTHON3=python3
+ ], [
+ AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
+ ])
+
+ AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
+ AS_IF([test -z "$PYTHON3_BIN"], [
+ AS_IF([test -z "$test_python3_agent_autodetect"],[
+ AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
+ ])
+ ], [
+ AC_MSG_CHECKING([for python3 lttng-ust agent])
+ AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
+ PYTHON3_AGENT=$PYTHON3_BIN
+ AC_MSG_RESULT([yes])
+ RUN_PYTHON_AGENT_TEST=yes
+ ], [
+ AC_MSG_RESULT([no])
+ AS_IF([test -z "$test_python3_agent_autodetect"],[
+ AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
+ ])
+ ])
+
+ ])
+])
+AC_SUBST([RUN_PYTHON_AGENT_TEST])
+AC_SUBST([PYTHON2_AGENT])
+AC_SUBST([PYTHON3_AGENT])
+
+AC_ARG_ENABLE([test-sdt-uprobe],
+ [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
+ [test_sdt_uprobe="$enableval"],
+ [test_sdt_uprobe=autodetect]
+)
+
+AS_IF([test "$test_sdt_uprobe" != "no"], [
+ LTTNG_CHECK_SDT_WORKS
+ AC_PATH_PROG([DTRACE], [dtrace])
+])
+
+AS_IF([test "$test_sdt_uprobe" = "yes"], [
+ AS_IF([test "$lttng_cv_sdt_works" = "no"], [
+ AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
+ ])
+ AS_IF([test "x$DTRACE" = "x"], [
+ AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
+ ])
+])
+
+AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
+ AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
+ AS_IF([test "x$DTRACE" != "x"], [
+ test_sdt_uprobe=yes
+ ])
+ ])
+])
+
+AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
+
+# Arguments for binaries build exclusion
+AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
+AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
+ [Disable the build of lttng-consumerd binaries]))
+AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
+AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
+ [Disable the build of lttng-relayd binaries]))
+AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
+ [Disable the build of lttng-sessiond binaries]))
+AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
+ [Disable the build of the extra components]))
+
+
+build_lib_consumer=no
+build_lib_health=no
+build_lib_index=no
+build_lib_kernel_consumer=no
+build_lib_kernel_ctl=no
+build_lib_lttng_ctl=no
+build_lib_relayd=no
+build_lib_sessiond_comm=no
+build_lib_testpoint=no
+build_lib_ust_consumer=no
+
+# There is an overlap for enabled dependencies, but this makes everything
+# simpler. libcommon and libconfig are always compiled so they are not repeated
+# here.
+
+# Enable binary dependencies.
+AS_IF([test x$enable_bin_lttng != xno],
+ [
+ build_lib_lttng_ctl=yes
+ ]
+)
+
+AS_IF([test x$enable_bin_lttng_consumerd != xno],
+ [
+ build_lib_consumer=yes
+ build_lib_sessiond_comm=yes
+ build_lib_index=yes
+ build_lib_health=yes
+ build_lib_testpoint=yes
+ ]
+)
+
+AS_IF([test x$enable_bin_lttng_crash != xno],
+ # Do nothing since libconfig and libcommon are built by default.
+ []
+)
+
+AS_IF([test x$enable_bin_lttng_relayd != xno],
+ [
+ build_lib_sessiond_comm=yes
+ build_lib_index=yes
+ build_lib_health=yes
+ build_lib_testpoint=yes
+ ]
+)
+AS_IF([test x$enable_bin_lttng_sessiond != xno],
+ [
+ build_lib_lttng_ctl=yes
+ build_lib_sessiond_comm=yes
+ build_lib_kernel_ctl=yes
+ build_lib_relayd=yes
+ build_lib_testpoint=yes
+ build_lib_health=yes
+ ]
+)
+
+# Libraries dependencies enabling
+AS_IF([test x$build_lib_lttng_ctl = xyes],
+ [
+ build_lib_sessiond_comm=yes
+ ]
+)
+
+AS_IF([test x$build_lib_consumer = xyes],
+ [
+ build_lib_sessiond_comm=yes
+ build_lib_kernel_consumer=yes
+ build_lib_relayd=yes
+ AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
+ ]
+)
+
+AS_IF([test x$build_lib_kernel_consumer = xyes],
+ [
+ build_lib_kernel_ctl=yes
+ build_lib_relayd=yes
+ ]
+)
+
+AS_IF([test x$build_lib_relayd = xyes],
+ [
+ build_lib_sessiond_comm=yes
+ ]
+)
+
+# Find arch type
+AS_CASE([$host_cpu],
+ [k1om], [ARCHTYPE="x86"],
+ [i386], [ARCHTYPE="x86"],
+ [i486], [ARCHTYPE="x86"],
+ [i586], [ARCHTYPE="x86"],
+ [i686], [ARCHTYPE="x86"],
+ [amd64], [ARCHTYPE="x86"],
+ [x86_64], [ARCHTYPE="x86"],
+ [powerpc], [ARCHTYPE="ppc"],
+ [ppc64], [ARCHTYPE="ppc"],
+ [powerpc64], [ARCHTYPE="ppc"],
+ [powerpc64le], [ARCHTYPE="ppc"],
+ [ppc], [ARCHTYPE="ppc"],
+ [s390], [ARCHTYPE="s390"],
+ [s390x], [ARCHTYPE="s390"],
+ [sparc], [ARCHTYPE="sparc64"],
+ [sparc64], [ARCHTYPE="sparc64"],
+ [alpha*], [ARCHTYPE="alpha"],
+ [ia64], [ARCHTYPE="ia64"],
+ [arm*], [ARCHTYPE="arm"],
+ [aarch64*], [ARCHTYPE="aarch64"],
+ [mips*], [ARCHTYPE="mips"],
+ [nios2*], [ARCHTYPE="nios2"],
+ [tile*], [ARCHTYPE="tile"],
+ [hppa*], [ARCHTYPE="hppa"],
+ [m68k], [ARCHTYPE="m68k"],
+ [riscv*], [ARCHTYPE="riscv"],
+ [ARCHTYPE="unknown"]
+)
+
+AC_SUBST(ARCHTYPE)
+
+AS_CASE([$host_os],
+ [linux*], [OSTYPE="linux"],
+ [freebsd*], [OSTYPE="freebsd"],
+ [solaris*], [OSTYPE="solaris"],
+ [cygwin*], [OSTYPE="cygwin"],
+ [mingw*], [OSTYPE="mingw"],
+ [OSTYPE="unknown"]
+)
+AC_SUBST(OSTYPE)
+AM_CONDITIONAL([IS_LINUX], [test $OSTYPE = "linux"])
+
+
+
+# Userspace callstack capture is only supported by the Linux kernel on x86.
+AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
+AS_IF([test "x$ARCHTYPE" = "xx86" && test "x$OSTYPE" = "xlinux"],[
+ have_modules_userspace_callstack_context=yes
+ AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
+])
+AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context = xyes])
+
+# Export binaries build conditions.
+AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
+AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
+AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
+AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
+AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
+
+# Export the tests and extras build conditions.
+AS_IF([\
+test "x$enable_bin_lttng" != "xno" && \
+test "x$enable_bin_lttng_consumerd" != "xno" && \
+test "x$enable_bin_lttng_crash" != "xno" && \
+test "x$enable_bin_lttng_relayd" != "xno" && \
+test "x$enable_bin_lttng_sessiond" != "xno"],
+[build_tests=yes],
+[build_tests=no]
+)