+AC_C_TYPEOF
+AC_TYPE_INT16_T
+AC_TYPE_INT32_T
+AC_TYPE_INT64_T
+AC_TYPE_INT8_T
+AC_TYPE_MODE_T
+AC_TYPE_OFF_T
+AC_TYPE_PID_T
+AC_TYPE_SIZE_T
+AC_TYPE_SSIZE_T
+AC_TYPE_UID_T
+AC_TYPE_UINT16_T
+AC_TYPE_UINT32_T
+AC_TYPE_UINT64_T
+AC_TYPE_UINT8_T
+AC_CHECK_TYPES([ptrdiff_t])
+
+
+## ##
+## C++ compiler checks ##
+## ##
+
+# Find an optional C++11 compiler without GNU extensions (-std=c++11)
+AX_CXX_COMPILE_STDCXX([11], [noext], [optional])
+
+
+## ##
+## Header checks ##
+## ##
+
+AC_HEADER_STDBOOL
+AC_CHECK_HEADERS([ \
+ arpa/inet.h \
+ dlfcn.h \
+ fcntl.h \
+ float.h \
+ limits.h \
+ linux/perf_event.h \
+ locale.h \
+ stddef.h \
+ sys/socket.h \
+ sys/time.h \
+ wchar.h \
+])
+
+# Check for dlinfo() by testing for RTLD_DI_LINKMAP in dlfcn.h
+AS_IF([test "x$ac_cv_header_dlfcn_h" = "xyes"], [
+ AC_CHECK_DECL([RTLD_DI_LINKMAP], [], [], [[#include <dlfcn.h>]])
+])
+
+
+## ##
+## Programs checks ##
+## ##
+
+AM_PROG_AR
+AC_PROG_SED
+AC_PROG_GREP
+AC_PROG_LN_S
+AC_PROG_MKDIR_P
+AC_PROG_MAKE_SET
+AC_CHECK_PROGS([ASCIIDOC], [asciidoc])
+AC_CHECK_PROGS([CMAKE], [cmake])
+AC_CHECK_PROGS([FOLD], [fold])
+AC_CHECK_PROGS([XMLTO], [xmlto])
+
+AM_PATH_PYTHON([2.7], [], [PYTHON=""])
+
+# Initialize and configure libtool
+LT_INIT([disable-static])
+
+
+## ##
+## Library checks ##
+## ##
+
+AC_FUNC_CHOWN
+AC_FUNC_FORK
+AC_FUNC_MMAP
+AC_FUNC_STRERROR_R
+AC_FUNC_STRNLEN
+AC_CHECK_FUNCS([ \
+ atexit \
+ clock_gettime \
+ ftruncate \
+ getpagesize \
+ gettimeofday \
+ localeconv \
+ memchr \
+ memmove \
+ memset \
+ mkdir \
+ munmap \
+ realpath \
+ sched_getcpu \
+ socket \
+ strchr \
+ strdup \
+ strerror \
+ strtol \
+ strtoul \
+ sysconf \
+])
+
+# AC_FUNC_MALLOC causes problems when cross-compiling.
+#AC_FUNC_MALLOC
+#AC_FUNC_REALLOC
+
+# Check for pthread_setname_np and its signature
+LTTNG_PTHREAD_SETNAME_NP
+LTTNG_PTHREAD_GETNAME_NP
+
+# Check dor dlopen() in -ldl or -lc
+AC_CHECK_LIB([dl], [dlopen], [
+ libdl_name=dl
+ DL_LIBS="-ldl"
+], [
+ # dlopen not found in libdl, check in libc
+ AC_CHECK_LIB([c], [dlopen], [
+ libdl_name=c
+ DL_LIBS="-lc"
+ ], [
+ AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
+ ])
+])
+AC_SUBST(DL_LIBS)
+
+# Check if libdl has dlmopen()
+AC_CHECK_LIB([$libdl_name], [dlmopen], [
+ AC_DEFINE([HAVE_DLMOPEN], [1], [Define to 1 if dlmopen is available.])
+])
+
+# Require URCU >= 0.12 for DEFINE_URCU_TLS_INIT
+PKG_CHECK_MODULES([URCU], [liburcu >= 0.12])
+
+
+## ##
+## User variables ##
+## ##
+
+# Additional variables captured during ./configure
+
+AC_ARG_VAR([CLASSPATH], [Java class path])
+
+
+## ##
+## Optionnal features selection ##
+## ##
+
+# numa integration
+# Enabled by default, except on some platforms
+AE_FEATURE_DEFAULT_ENABLE
+AE_FEATURE([numa],[disable NUMA support])
+
+# Java JNI interface library
+# Disabled by default
+AE_FEATURE_DEFAULT_DISABLE
+AE_FEATURE([jni-interface], [build JNI interface between C and Java])
+
+# Build the Java Logging API agent
+# Disabled by default
+AE_FEATURE_DEFAULT_DISABLE
+AE_FEATURE([java-agent-jul],[build the LTTng UST Java agent with JUL support])
+
+# Build the Java Log4j agent
+# Disabled by default
+AE_FEATURE_DEFAULT_DISABLE
+AE_FEATURE([java-agent-log4j],[build the LTTng UST Java agent with Log4j support])
+
+# Build both Java agents
+# Disabled by default
+AE_FEATURE_DEFAULT_DISABLE
+AE_FEATURE([java-agent-all],[build the LTTng UST Java agent with all supported backends])
+
+# Build the Python agent
+# Disabled by default
+AE_FEATURE_DEFAULT_DISABLE
+AE_FEATURE([python-agent],[build the LTTng UST Python agent])
+
+# Build the examples
+# Disabled by default
+AE_FEATURE_DEFAULT_ENABLE
+AE_FEATURE([examples],[Do not build and install examples])
+
+# Man pages
+# Enabled by default
+AE_FEATURE_DEFAULT_ENABLE
+AE_FEATURE([man-pages],[Do not build and install man pages (already built in a distributed tarball)])
+
+# Systemtap sdt.h integration
+# Disabled by default
+AC_ARG_WITH([sdt],
+ [AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])]
+)
+
+# Override the default runtime directory
+AC_ARG_WITH([lttng-system-rundir], [
+AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
+], [
+ lttng_system_rundir="$withval"
+], [
+ lttng_system_rundir="/var/run/lttng"
+])
+
+# Add the java command line arguments like '--wit-java-prefix'
+AX_JAVA_OPTIONS
+
+
+## ##
+## Check for conflicting features selection ##
+## ##
+
+AE_IF_FEATURE_DISABLED([shared], [
+ AC_MSG_ERROR(LTTng-UST requires shared libraries to be enabled)
+])
+
+AE_IF_FEATURE_ENABLED([java-agent-all], [
+ AE_FEATURE_ENABLE([java-agent-jul])
+ AE_FEATURE_ENABLE([java-agent-log4j])
+])
+
+
+## ##
+## Check for optional features dependencies ##
+## ##
+
+# The numa integration requires libnuma
+AE_IF_FEATURE_ENABLED([numa], [
+ AC_CHECK_LIB([numa], [numa_available], [], [
+ AC_MSG_ERROR([dnl
+libnuma is not available. Please either install it (e.g. libnuma-dev) or use
+[LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure
+argument to disable NUMA support.
+ ])
+ ])
+])
+
+# The JNI interface and Java Agents require a working Java JDK
+AS_IF([AE_IS_FEATURE_ENABLED([jni-interface]) || AE_IS_FEATURE_ENABLED([java-agent-jul]) || AE_IS_FEATURE_ENABLED([java-agent-log4j])], [
+ AX_PROG_JAVAC
+ AX_PROG_JAVA
+ AX_PROG_JAR
+
+ # Get the CPPFLAGS required to build jni libaries
+ AX_JNI_INCLUDE_DIR
+ for jni_include_dir in $JNI_INCLUDE_DIRS; do
+ JNI_CPPFLAGS="$JNI_CPPFLAGS -I$jni_include_dir"
+ done
+
+ # Check for javah and jni.h
+ saved_CPPFLAGS="$CPPFLAGS"
+ CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
+ AX_PROG_JAVAH
+ CPPFLAGS="$saved_CPPFLAGS"
+])
+
+# The log4j agent requires the log4j jar in the classpath
+AE_IF_FEATURE_ENABLED([java-agent-log4j], [
+ AX_CHECK_CLASS([org.apache.log4j.Logger])
+ AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
+ AC_MSG_ERROR([dnl
+The UST Java agent support for log4j was requested but the Log4j classes were
+not found. Please specify the location of the Log4j jar via the Java CLASSPATH
+environment variable, e.g. ./configure CLASSPATH="/path/to/log4j.jar"
+
+Current CLASSPATH: "$CLASSPATH"
+ ])
+ ])
+])
+
+# The python agent requires a python interpreter
+AE_IF_FEATURE_ENABLED([python-agent], [
+ AS_IF([test "x$PYTHON" = "x"], [
+ AC_MSG_ERROR([dnl
+Cannot find a suitable python interpreter. You can override it with the PYTHON
+environment variable.
+ ])
+ ])
+])
+
+# Check for asciidoc and xmlto if we enabled building the man pages.
+AE_IF_FEATURE_ENABLED([man-pages], [
+ AS_IF([test "x$ASCIIDOC" = "x" || test "x$XMLTO" = "x"], [
+ AE_IF_IN_GIT_REPO([
+ # This is an error because we're in the Git repo, which
+ # means the man pages are not already generated for us,
+ # thus asciidoc/xmlto are required because we were asked
+ # to build the man pages.
+ AC_MSG_ERROR([dnl
+Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
+--disable-man-pages to disable building the man pages, in which case
+they will not be installed.
+ ])
+ ], [
+ # Only warn here: since we're in the tarball, the man
+ # pages should already be generated at this point, thus
+ # asciidoc/xmlto are not strictly required.
+ warn_prebuilt_man_pages=yes
+ ])
+ ], [
+ have_asciidoc_xmlto=yes
+ ])
+])
+
+AS_IF([test "x$with_sdt" = "xyes"], [
+ AC_MSG_CHECKING([STAP_PROBEV()])
+ AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
+ #define SDT_USE_VARIADIC
+ #include <sys/sdt.h>
+ void fct(void)
+ {
+ STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
+ }
+ ]])], [
+ AC_MSG_RESULT([yes])
+ AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1], [SystemTap integration via sdt.h])
+ ], [
+ AC_MSG_RESULT([no])
+ AC_MSG_ERROR([dnl
+The sdt.h integration was requested but the STAP_PROBEV define cannot be used.
+Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify
+a non-standard path to sys/sdt.h
+ ])
+ ])
+])
+
+
+## ##
+## Set defines for optional features conditionnals in the source code ##
+## ##
+
+AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"], [LTTng system runtime directory])
+
+# Defined in include/lttng/ust-version.h
+AC_DEFINE([LTTNG_UST_MAJOR_VERSION], ust_version_major, [LTTng UST major version])
+AC_DEFINE([LTTNG_UST_MINOR_VERSION], ust_version_minor, [LTTng UST minor version])
+AC_DEFINE([LTTNG_UST_PATCHLEVEL_VERSION], ust_version_patch, [LTTng UST patch version])
+AC_DEFINE([LTTNG_UST_VERSION], ["]ust_version["], [LTTng UST version string])
+AC_DEFINE([LTTNG_UST_LIB_SONAME_MAJOR], [ust_lib_version_current], [Major SONAME number of liblttng-ust])
+AC_DEFINE([LTTNG_UST_CTL_LIB_SONAME_MAJOR], [ust_ctl_lib_version_current], [Major SONAME number of liblttng-ust-ctl])
+
+
+## ##
+## Set automake variables for optional feature conditionnals in Makefile.am ##
+## ##
+
+AM_CONDITIONAL([ENABLE_EXAMPLES], AE_IS_FEATURE_ENABLED([examples]))
+AM_CONDITIONAL([ENABLE_GEN_TP_EXAMPLES], [test "x$PYTHON" != "x"])
+AM_CONDITIONAL([ENABLE_JAVA_AGENT], AE_IS_FEATURE_ENABLED([java-agent-jul]) || AE_IS_FEATURE_ENABLED([java-agent-log4j]))
+AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_JUL], AE_IS_FEATURE_ENABLED([java-agent-jul]))
+AM_CONDITIONAL([ENABLE_JAVA_AGENT_WITH_LOG4J], AE_IS_FEATURE_ENABLED([java-agent-log4j]))
+AM_CONDITIONAL([ENABLE_JNI_INTERFACE], AE_IS_FEATURE_ENABLED([jni-interface]))
+AM_CONDITIONAL([ENABLE_MAN_PAGES], AE_IS_FEATURE_ENABLED([man-pages]))
+AM_CONDITIONAL([ENABLE_NUMA], AE_IS_FEATURE_ENABLED([numa]))
+AM_CONDITIONAL([ENABLE_PYTHON_AGENT], AE_IS_FEATURE_ENABLED([python-agent]))
+AM_CONDITIONAL([ENABLE_UST_DL], [test "x$ac_cv_have_decl_RTLD_DI_LINKMAP" = "xyes"])
+AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
+AM_CONDITIONAL([HAVE_CMAKE], [test "x$CMAKE" != "x"])
+AM_CONDITIONAL([HAVE_CXX], [test "$HAVE_CXX11" = "1"])
+AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
+AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$ac_cv_header_linux_perf_event_h" = "xyes"])
+
+
+## ##
+## Substitute variables for use in Makefile.am ##
+## ##
+
+# Library versions for libtool
+AC_SUBST([LTTNG_UST_LIBRARY_VERSION], ust_lib_version)
+AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], ust_ctl_lib_version)
+
+# Major soname for python-lttngust
+AC_SUBST([LTTNG_UST_LIB_SONAME_MAJOR], [ust_lib_version_current])
+
+AM_CFLAGS="-Wall $URCU_CFLAGS $PTHREAD_CFLAGS"
+AC_SUBST(AM_CFLAGS)
+
+AM_CXXFLAGS="$AM_CFLAGS"
+AC_SUBST(AM_CXXFLAGS)
+
+# The order in which the include folders are searched is important.
+# The top_builddir should always be searched first in the event that a build
+# time generated file is included.
+AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h"
+AC_SUBST(AM_CPPFLAGS)
+
+AC_SUBST(JNI_CPPFLAGS)
+
+
+## ##
+## Output files generated by configure ##
+## ##
+
+# List of files to be generated from '.in' templates by AC_OUTPUT
+AC_CONFIG_FILES([
+ Makefile
+ doc/Makefile
+ doc/examples/Makefile
+ doc/man/Makefile
+ include/Makefile
+ snprintf/Makefile
+ libcounter/Makefile
+ libmsgpack/Makefile
+ libringbuffer/Makefile
+ liblttng-ust-comm/Makefile
+ liblttng-ust/Makefile
+ liblttng-ust-ctl/Makefile
+ liblttng-ust-fork/Makefile
+ liblttng-ust-dl/Makefile
+ liblttng-ust-fd/Makefile
+ liblttng-ust-java/Makefile
+ liblttng-ust-java-agent/Makefile
+ liblttng-ust-java-agent/java/Makefile
+ liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
+ liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
+ liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
+ liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
+ liblttng-ust-java-agent/jni/Makefile
+ liblttng-ust-java-agent/jni/common/Makefile
+ liblttng-ust-java-agent/jni/jul/Makefile
+ liblttng-ust-java-agent/jni/log4j/Makefile
+ liblttng-ust-libc-wrapper/Makefile
+ liblttng-ust-cyg-profile/Makefile
+ liblttng-ust-python-agent/Makefile
+ python-lttngust/Makefile
+ python-lttngust/setup.py
+ python-lttngust/lttngust/version.py
+ tools/Makefile
+ tests/Makefile
+ tests/compile/Makefile
+ tests/compile/ctf-types/Makefile
+ tests/compile/hello.cxx/Makefile
+ tests/compile/hello/Makefile
+ tests/compile/hello-many/Makefile
+ tests/compile/same_line_tracepoint/Makefile
+ tests/compile/test-app-ctx/Makefile
+ tests/benchmark/Makefile
+ tests/unit/gcc-weak-hidden/Makefile
+ tests/unit/libmsgpack/Makefile
+ tests/unit/Makefile
+ tests/unit/libringbuffer/Makefile
+ tests/unit/pthread_name/Makefile
+ tests/unit/snprintf/Makefile
+ tests/unit/ust-elf/Makefile
+ tests/unit/ust-error/Makefile
+ tests/unit/ust-utils/Makefile
+ tests/utils/Makefile
+ lttng-ust.pc
+ lttng-ust-ctl.pc
+])
+