scripts/lttng-modules/master.groovy

   1 /**
   2  * Copyright (C) 2016-2018 - Michael Jeanson <mjeanson@efficios.com>
   3  *
   4  * This program is free software: you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation, either version 3 of the License, or
   7  * (at your option) any later version.
   8  *
   9  * This program is distributed in the hope that it will be useful,
  10  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12  * GNU General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU General Public License
  15  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16  */
  17
  18 import hudson.model.*
  19 import hudson.AbortException
  20 import hudson.console.HyperlinkNote
  21 import java.util.concurrent.CancellationException
  22 import org.eclipse.jgit.api.Git
  23 import org.eclipse.jgit.lib.Ref
  24
  25
  26 class InvalidKVersionException extends Exception {
  27   public InvalidKVersionException(String message) {
  28     super(message)
  29   }
  30 }
  31
  32 class EmptyKVersionException extends Exception {
  33   public EmptyKVersionException(String message) {
  34     super(message)
  35   }
  36 }
  37
  38 class VanillaKVersion implements Comparable<VanillaKVersion> {
  39
  40   Integer major = 0
  41   Integer majorB = 0
  42   Integer minor = 0
  43   Integer patch = 0
  44   Integer rc = Integer.MAX_VALUE
  45
  46   VanillaKVersion() {}
  47
  48   VanillaKVersion(version) {
  49     this.parse(version)
  50   }
  51
  52   static VanillaKVersion minKVersion() {
  53     return new VanillaKVersion("v0.0.0")
  54   }
  55
  56   static VanillaKVersion maxKVersion() {
  57     return new VanillaKVersion("v" + Integer.MAX_VALUE + ".0.0")
  58   }
  59
  60   static VanillaKVersion factory(version) {
  61     return new VanillaKVersion(version)
  62   }
  63
  64   def parse(version) {
  65     this.major = 0
  66     this.majorB = 0
  67     this.minor = 0
  68     this.patch = 0
  69     this.rc = Integer.MAX_VALUE
  70
  71     if (!version) {
  72       throw new EmptyKVersionException("Empty kernel version")
  73     }
  74
  75     def match = version =~ /^v(\d+)\.(\d+)(\.(\d+))?(\.(\d+))?(-rc(\d+))?$/
  76     if (!match) {
  77       throw new InvalidKVersionException("Invalid kernel version: ${version}")
  78     }
  79
  80     Integer offset = 0;
  81
  82     // Major
  83     this.major = Integer.parseInt(match.group(1))
  84     if (this.major <= 2) {
  85       offset = 2
  86       this.majorB = Integer.parseInt(match.group(2))
  87     }
  88
  89     // Minor
  90     if (match.group(2 + offset) != null) {
  91       this.minor = Integer.parseInt(match.group(2 + offset))
  92     }
  93
  94     // Patch level
  95     if (match.group(4 + offset) != null) {
  96       this.patch = Integer.parseInt(match.group(4 + offset))
  97     }
  98
  99     // RC
 100     if (match.group(8) != null) {
 101       this.rc = Integer.parseInt(match.group(8))
 102     }
 103   }
 104
 105   // Return true if this version is a release candidate
 106   Boolean isRC() {
 107     return this.rc != Integer.MAX_VALUE
 108   }
 109
 110   // Return true if both version are of the same stable branch
 111   Boolean isSameStable(VanillaKVersion o) {
 112     if (this.major != o.major) {
 113       return false
 114     }
 115     if (this.majorB != o.majorB) {
 116       return false
 117     }
 118     if (this.minor != o.minor) {
 119       return false
 120     }
 121
 122     return true
 123   }
 124
 125   @Override int compareTo(VanillaKVersion o) {
 126     if (this.major != o.major) {
 127       return Integer.compare(this.major, o.major)
 128     }
 129     if (this.majorB != o.majorB) {
 130       return Integer.compare(this.majorB, o.majorB)
 131     }
 132     if (this.minor != o.minor) {
 133       return Integer.compare(this.minor, o.minor)
 134     }
 135     if (this.patch != o.patch) {
 136       return Integer.compare(this.patch, o.patch)
 137     }
 138     if (this.rc != o.rc) {
 139       return Integer.compare(this.rc, o.rc)
 140     }
 141
 142     // Same version
 143     return 0;
 144   }
 145
 146   String toString() {
 147     String vString = "v${this.major}"
 148
 149     if (this.majorB > 0) {
 150       vString = vString.concat(".${this.majorB}")
 151     }
 152
 153     vString = vString.concat(".${this.minor}")
 154
 155     if (this.patch > 0) {
 156       vString = vString.concat(".${this.patch}")
 157     }
 158
 159     if (this.rc > 0 && this.rc < Integer.MAX_VALUE) {
 160       vString = vString.concat("-rc${this.rc}")
 161     }
 162     return vString
 163   }
 164 }
 165
 166 class UbuntuKVersion implements Comparable<UbuntuKVersion> {
 167
 168   Integer major = 0
 169   Integer minor = 0
 170   Integer patch = 0
 171   Integer umajor = 0
 172   Integer uminor = 0
 173   String suffix = ""
 174   Boolean isLTS = false
 175
 176   UbuntuKVersion() {}
 177
 178   UbuntuKVersion(version) {
 179     this.parse(version)
 180   }
 181
 182   static UbuntuKVersion minKVersion() {
 183     return new UbuntuKVersion("Ubuntu-lts-0.0.0-0.0")
 184   }
 185
 186   static UbuntuKVersion maxKVersion() {
 187     return new UbuntuKVersion("Ubuntu-" + Integer.MAX_VALUE + ".0.0-0.0")
 188   }
 189
 190   static UbuntuKVersion factory(version) {
 191     return new UbuntuKVersion(version)
 192   }
 193
 194   def parse(version) {
 195     this.major = 0
 196     this.minor = 0
 197     this.patch = 0
 198     this.umajor = 0
 199     this.uminor = 0
 200     this.suffix = "";
 201     this.isLTS = false
 202
 203     if (!version) {
 204       throw new EmptyKVersionException("Empty kernel version")
 205     }
 206
 207     //'Ubuntu-lts-4.8.0-27.29_16.04.1',
 208     //'Ubuntu-4.4.0-70.91',
 209     def match = version =~ /^Ubuntu-(lts-)??(\d+)\.(\d+)\.(\d+)-(\d+)\.(\d+)(.*)??$/
 210     if (!match) {
 211       throw new InvalidKVersionException("Invalid kernel version: ${version}")
 212     }
 213
 214     this.isLTS = match.group(1) != null
 215
 216     // Major
 217     this.major = Integer.parseInt(match.group(2))
 218
 219     // Minor
 220     this.minor = Integer.parseInt(match.group(3))
 221
 222     // Patch level
 223     this.patch = Integer.parseInt(match.group(4))
 224
 225     // Ubuntu major
 226     this.umajor = Integer.parseInt(match.group(5))
 227
 228     // Ubuntu minor
 229     this.uminor = Integer.parseInt(match.group(6))
 230
 231     if (match.group(7) != null) {
 232       this.suffix = match.group(7)
 233     }
 234   }
 235
 236   // Return true if this version is a release candidate
 237   Boolean isRC() {
 238     return false
 239   }
 240
 241   // Return true if both version are of the same stable branch
 242   Boolean isSameStable(UbuntuKVersion o) {
 243     if (this.isLTS != o.isLTS) {
 244       return false
 245     }
 246     if (this.major != o.major) {
 247       return false
 248     }
 249     if (this.minor != o.minor) {
 250       return false
 251     }
 252     if (this.patch != o.patch) {
 253       return false
 254     }
 255
 256     return true
 257   }
 258
 259   @Override int compareTo(UbuntuKVersion o) {
 260     if (this.major != o.major) {
 261       return Integer.compare(this.major, o.major)
 262     }
 263     if (this.minor != o.minor) {
 264       return Integer.compare(this.minor, o.minor)
 265     }
 266     if (this.patch != o.patch) {
 267       return Integer.compare(this.patch, o.patch)
 268     }
 269     if (this.umajor != o.umajor) {
 270       return Integer.compare(this.umajor, o.umajor)
 271     }
 272     if (this.uminor != o.uminor) {
 273       return Integer.compare(this.uminor, o.uminor)
 274     }
 275     if (this.isLTS != o.isLTS) {
 276       if (o.isLTS) {
 277         return 1
 278       } else {
 279         return -1
 280       }
 281     }
 282
 283     // Same version
 284     return 0;
 285   }
 286
 287   String toString() {
 288     String vString = "Ubuntu-"
 289
 290     if (this.isLTS) {
 291       vString = vString.concat("lts-")
 292     }
 293
 294     vString = vString.concat("${this.major}.${this.minor}.${this.patch}-${this.umajor}.${this.uminor}${this.suffix}")
 295
 296     return vString
 297   }
 298 }
 299
 300
 301 // Retrieve parameters of the current build
 302 def mversion = build.buildVariableResolver.resolve('mversion')
 303 def maxConcurrentBuild = build.buildVariableResolver.resolve('maxConcurrentBuild')
 304 def kgitrepo = build.buildVariableResolver.resolve('kgitrepo')
 305 def kverfloor_raw = build.buildVariableResolver.resolve('kverfloor')
 306 def kverceil_raw = build.buildVariableResolver.resolve('kverceil')
 307 def kverfilter = build.buildVariableResolver.resolve('kverfilter')
 308 def uversion = build.buildVariableResolver.resolve('uversion')
 309 def job = Hudson.instance.getJob(build.buildVariableResolver.resolve('kbuildjob'))
 310 def currentJobName = build.project.getFullDisplayName()
 311 def gitmodpath = build.getEnvironment(listener).get('WORKSPACE') + "/src/lttng-modules"
 312
 313 // Get the out variable
 314 def config = new HashMap()
 315 def bindings = getBinding()
 316 config.putAll(bindings.getVariables())
 317 def out = config['out']
 318
 319
 320 // Get the lttng-modules git url
 321 def gitmodrepo = Git.open(new File(gitmodpath))
 322 def mgitrepo = gitmodrepo.getRepository().getConfig().getString("remote", "origin", "url")
 323
 324 // Get tags from git repository
 325 def refs = Git.lsRemoteRepository().setTags(true).setRemote(kgitrepo).call()
 326
 327 // Get kernel versions to build
 328 def kversions = []
 329 def kversionsRC = []
 330 def matchStrs = []
 331 def blacklist = []
 332 def kversionFactory = ""
 333
 334 if (uversion != null) {
 335   kversionFactory = new UbuntuKVersion()
 336   switch (uversion) {
 337     case 'bionic':
 338       matchStrs = [
 339         ~/^refs\/tags\/(Ubuntu-4\.15\.0-\d{1,3}?\.[\d]+)$/,
 340       ]
 341       break
 342
 343     case 'xenial':
 344       matchStrs = [
 345         ~/^refs\/tags\/(Ubuntu-4\.4\.0-\d{1,3}?\.[\d]+)$/,
 346         ~/^refs\/tags\/(Ubuntu-lts-4\.8\.0-.*_16\.04\.\d+)$/,
 347         ~/^refs\/tags\/(Ubuntu-lts-4\.10\.0-.*_16\.04\.\d+)$/,
 348         ~/^refs\/tags\/(Ubuntu-lts-4\.15\.0-.*_16\.04\.\d+)$/,
 349       ]
 350
 351       blacklist = [
 352         'Ubuntu-lts-4.10.0-7.9_16.04.1',
 353       ]
 354       break
 355
 356     case 'trusty':
 357       matchStrs = [
 358         ~/^refs\/tags\/(Ubuntu-3\.13\.0-[\d\.]+)$/,
 359         ~/^refs\/tags\/(Ubuntu-lts-.*_14\.04\.\d+)$/,
 360       ]
 361       break
 362
 363     default:
 364       println "Unsupported Ubuntu version: ${uversion}"
 365       throw new InterruptedException()
 366       break
 367   }
 368 } else {
 369   // Vanilla
 370   kversionFactory = new VanillaKVersion()
 371   matchStrs = [
 372     ~/^refs\/tags\/(v[\d\.]+(-rc(\d+))?)$/,
 373   ]
 374 }
 375
 376 // Parse kernel versions
 377 def kverfloor = ""
 378 try {
 379     kverfloor = kversionFactory.factory(kverfloor_raw)
 380 } catch (EmptyKVersionException e) {
 381     kverfloor = kversionFactory.minKVersion()
 382 }
 383
 384 def kverceil = ""
 385 try {
 386     kverceil = kversionFactory.factory(kverceil_raw)
 387 } catch (EmptyKVersionException e) {
 388     kverceil = kversionFactory.maxKVersion()
 389 }
 390
 391 // Build a sorted list of versions to build
 392 for (ref in refs) {
 393   for (matchStr in matchStrs) {
 394     def match = ref.getName() =~ matchStr
 395     if (match && !blacklist.contains(match.group(1))) {
 396       def v = kversionFactory.factory(match.group(1))
 397
 398       if ((v >= kverfloor) && (v < kverceil)) {
 399         if (v.isRC()) {
 400           kversionsRC.add(v)
 401         } else {
 402           kversions.add(v)
 403         }
 404       }
 405     }
 406   }
 407 }
 408
 409 kversions.sort()
 410 kversionsRC.sort()
 411
 412 switch (kverfilter) {
 413   case 'stable-head':
 414     // Keep only the head of each stable branch
 415     println('Filter kernel versions to keep only the latest point release of each stable branch.')
 416
 417     for (i = 0; i < kversions.size(); i++) {
 418       def curr = kversions[i]
 419       def next = i < kversions.size() - 1 ? kversions[i + 1] : null
 420
 421       if (next != null) {
 422         if (curr.isSameStable(next)) {
 423           kversions.remove(i)
 424           i--
 425         }
 426       }
 427     }
 428     break
 429
 430   default:
 431     // No filtering of kernel versions
 432     println('No kernel versions filtering selected.')
 433     break
 434 }
 435
 436 // If the last RC version is newer than the last stable, add it to the build list
 437 if (kversionsRC.size() > 0 && kversionsRC.last() > kversions.last()) {
 438   kversions.add(kversionsRC.last())
 439 }
 440
 441 println "Building the following kernel versions:"
 442 for (k in kversions) {
 443   println k
 444 }
 445
 446 // Debug: Stop build here
 447 //throw new InterruptedException()
 448
 449 def joburl = HyperlinkNote.encodeTo('/' + job.url, job.fullDisplayName)
 450
 451 def allBuilds = []
 452 def ongoingBuild = []
 453 def failedRuns = []
 454 def isFailed = false
 455 def similarJobQueued = 0;
 456
 457 // Loop while we have kernel versions remaining or jobs running
 458 while ( kversions.size() != 0 || ongoingBuild.size() != 0 ) {
 459
 460   if(ongoingBuild.size() < maxConcurrentBuild.toInteger() && kversions.size() != 0) {
 461     def kversion = kversions.pop()
 462     def job_params = [
 463       new StringParameterValue('mversion', mversion),
 464       new StringParameterValue('mgitrepo', mgitrepo),
 465       new StringParameterValue('ktag', kversion.toString()),
 466       new StringParameterValue('kgitrepo', kgitrepo),
 467     ]
 468
 469     // Launch the parametrized build
 470     def param_build = job.scheduleBuild2(0, new Cause.UpstreamCause(build), new ParametersAction(job_params))
 471     println "triggering ${joburl} for the ${mversion} branch on kernel ${kversion}"
 472
 473     // Add it to the ongoing build queue
 474     ongoingBuild.push(param_build)
 475
 476   } else {
 477
 478     println "Waiting... Queued: " + kversions.size() + " Running: " + ongoingBuild.size()
 479     try {
 480       Thread.sleep(10000)
 481     } catch(e) {
 482       if (e in InterruptedException) {
 483         build.setResult(hudson.model.Result.ABORTED)
 484         throw new InterruptedException()
 485       } else {
 486         throw(e)
 487       }
 488     }
 489
 490     // Abort job if a newer instance is queued
 491     similarJobQueued = Hudson.instance.queue.items.count{it.task.getFullDisplayName() == currentJobName}
 492     if ( similarJobQueued > 0 ) {
 493         build.setResult(hudson.model.Result.ABORTED)
 494         throw new InterruptedException()
 495     }
 496
 497     def i = ongoingBuild.iterator()
 498     while ( i.hasNext() ) {
 499       currentBuild = i.next()
 500       if ( currentBuild.isCancelled() || currentBuild.isDone() ) {
 501         // Remove from queue
 502         i.remove()
 503
 504         // Print results
 505         def matrixParent = currentBuild.get()
 506         allBuilds.add(matrixParent)
 507         def kernelStr = matrixParent.buildVariableResolver.resolve("ktag")
 508         println "${matrixParent.fullDisplayName} (${kernelStr}) completed with status ${matrixParent.result}"
 509
 510         // Process child runs of matrixBuild
 511         def childRuns = matrixParent.getRuns()
 512         for ( childRun in childRuns ) {
 513           println "\t${childRun.fullDisplayName} (${kernelStr}) completed with status ${childRun.result}"
 514           if (childRun.result != Result.SUCCESS) {
 515             failedRuns.add(childRun)
 516             isFailed = true
 517           }
 518         }
 519       }
 520     }
 521   }
 522 }
 523
 524 // Get log of failed runs
 525 for (failedRun in failedRuns) {
 526   println "---START---"
 527   failedRun.writeWholeLogTo(out)
 528   println "---END---"
 529 }
 530
 531 println "---Build report---"
 532 for (b in allBuilds) {
 533   def kernelStr = b.buildVariableResolver.resolve("ktag")
 534   println "${b.fullDisplayName} (${kernelStr}) completed with status ${b.result}"
 535   // Cleanup builds
 536   try {
 537     b.delete()
 538   } catch (all) {}
 539 }
 540
 541 // Mark this build failed if any child build has failed
 542 if (isFailed) {
 543   build.setResult(hudson.model.Result.FAILURE)
 544 }
 545
 546 // EOF