scripts/lttng-modules/master.groovy

   1 /**
   2  * Copyright (C) 2016-2020 Michael Jeanson <mjeanson@efficios.com>
   3  *
   4  * This program is free software: you can redistribute it and/or modify
   5  * it under the terms of the GNU General Public License as published by
   6  * the Free Software Foundation, either version 3 of the License, or
   7  * (at your option) any later version.
   8  *
   9  * This program is distributed in the hope that it will be useful,
  10  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12  * GNU General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU General Public License
  15  * along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16  */
  17
  18 import hudson.model.*
  19 import hudson.AbortException
  20 import hudson.console.HyperlinkNote
  21 import java.util.concurrent.CancellationException
  22 import org.eclipse.jgit.api.Git
  23 import org.eclipse.jgit.lib.Ref
  24
  25
  26 class InvalidKVersionException extends Exception {
  27   public InvalidKVersionException(String message) {
  28     super(message)
  29   }
  30 }
  31
  32 class EmptyKVersionException extends Exception {
  33   public EmptyKVersionException(String message) {
  34     super(message)
  35   }
  36 }
  37
  38 class VanillaKVersion implements Comparable<VanillaKVersion> {
  39
  40   Integer major = 0
  41   Integer majorB = 0
  42   Integer minor = 0
  43   Integer patch = 0
  44   Integer rc = Integer.MAX_VALUE
  45
  46   VanillaKVersion() {}
  47
  48   VanillaKVersion(version) {
  49     this.parse(version)
  50   }
  51
  52   static VanillaKVersion minKVersion() {
  53     return new VanillaKVersion("v0.0.0")
  54   }
  55
  56   static VanillaKVersion maxKVersion() {
  57     return new VanillaKVersion("v" + Integer.MAX_VALUE + ".0.0")
  58   }
  59
  60   static VanillaKVersion factory(version) {
  61     return new VanillaKVersion(version)
  62   }
  63
  64   def parse(version) {
  65     this.major = 0
  66     this.majorB = 0
  67     this.minor = 0
  68     this.patch = 0
  69     this.rc = Integer.MAX_VALUE
  70
  71     if (!version) {
  72       throw new EmptyKVersionException("Empty kernel version")
  73     }
  74
  75     def match = version =~ /^v(\d+)\.(\d+)(\.(\d+))?(\.(\d+))?(-rc(\d+))?$/
  76     if (!match) {
  77       throw new InvalidKVersionException("Invalid kernel version: ${version}")
  78     }
  79
  80     Integer offset = 0;
  81
  82     // Major
  83     this.major = Integer.parseInt(match.group(1))
  84     if (this.major <= 2) {
  85       offset = 2
  86       this.majorB = Integer.parseInt(match.group(2))
  87     }
  88
  89     // Minor
  90     if (match.group(2 + offset) != null) {
  91       this.minor = Integer.parseInt(match.group(2 + offset))
  92     }
  93
  94     // Patch level
  95     if (match.group(4 + offset) != null) {
  96       this.patch = Integer.parseInt(match.group(4 + offset))
  97     }
  98
  99     // RC
 100     if (match.group(8) != null) {
 101       this.rc = Integer.parseInt(match.group(8))
 102     }
 103   }
 104
 105   // Return true if this version is a release candidate
 106   Boolean isRC() {
 107     return this.rc != Integer.MAX_VALUE
 108   }
 109
 110   // Return true if both version are of the same stable branch
 111   Boolean isSameStable(VanillaKVersion o) {
 112     if (this.major != o.major) {
 113       return false
 114     }
 115     if (this.majorB != o.majorB) {
 116       return false
 117     }
 118     if (this.minor != o.minor) {
 119       return false
 120     }
 121
 122     return true
 123   }
 124
 125   @Override int compareTo(VanillaKVersion o) {
 126     if (this.major != o.major) {
 127       return Integer.compare(this.major, o.major)
 128     }
 129     if (this.majorB != o.majorB) {
 130       return Integer.compare(this.majorB, o.majorB)
 131     }
 132     if (this.minor != o.minor) {
 133       return Integer.compare(this.minor, o.minor)
 134     }
 135     if (this.patch != o.patch) {
 136       return Integer.compare(this.patch, o.patch)
 137     }
 138     if (this.rc != o.rc) {
 139       return Integer.compare(this.rc, o.rc)
 140     }
 141
 142     // Same version
 143     return 0;
 144   }
 145
 146   String toString() {
 147     String vString = "v${this.major}"
 148
 149     if (this.majorB > 0) {
 150       vString = vString.concat(".${this.majorB}")
 151     }
 152
 153     vString = vString.concat(".${this.minor}")
 154
 155     if (this.patch > 0) {
 156       vString = vString.concat(".${this.patch}")
 157     }
 158
 159     if (this.rc > 0 && this.rc < Integer.MAX_VALUE) {
 160       vString = vString.concat("-rc${this.rc}")
 161     }
 162     return vString
 163   }
 164 }
 165
 166 class UbuntuKVersion implements Comparable<UbuntuKVersion> {
 167
 168   Integer major = 0
 169   Integer minor = 0
 170   Integer patch = 0
 171   Integer umajor = 0
 172   Integer uminor = 0
 173   String suffix = ""
 174   String strLTS = ""
 175   Boolean isLTS = false
 176
 177   UbuntuKVersion() {}
 178
 179   UbuntuKVersion(version) {
 180     this.parse(version)
 181   }
 182
 183   static UbuntuKVersion minKVersion() {
 184     return new UbuntuKVersion("Ubuntu-lts-0.0.0-0.0")
 185   }
 186
 187   static UbuntuKVersion maxKVersion() {
 188     return new UbuntuKVersion("Ubuntu-" + Integer.MAX_VALUE + ".0.0-0.0")
 189   }
 190
 191   static UbuntuKVersion factory(version) {
 192     return new UbuntuKVersion(version)
 193   }
 194
 195   def parse(version) {
 196     this.major = 0
 197     this.minor = 0
 198     this.patch = 0
 199     this.umajor = 0
 200     this.uminor = 0
 201     this.suffix = "";
 202     this.isLTS = false
 203
 204     if (!version) {
 205       throw new EmptyKVersionException("Empty kernel version")
 206     }
 207
 208     //'Ubuntu-hwe-5.8-5.8.0-19.20_20.04.3',
 209     //'Ubuntu-lts-4.8.0-27.29_16.04.1',
 210     //'Ubuntu-4.4.0-70.91',
 211     def match = version =~ /^Ubuntu-(lts-|hwe-)??(?:\d+\.\d+-)??(\d+)\.(\d+)\.(\d+)-(\d+)\.(\d+)(.*)??$/
 212     if (!match) {
 213       throw new InvalidKVersionException("Invalid kernel version: ${version}")
 214     }
 215
 216     if (match.group(1) != null) {
 217         this.isLTS = true
 218         this.strLTS = match.group(1)
 219     }
 220
 221     // Major
 222     this.major = Integer.parseInt(match.group(2))
 223
 224     // Minor
 225     this.minor = Integer.parseInt(match.group(3))
 226
 227     // Patch level
 228     this.patch = Integer.parseInt(match.group(4))
 229
 230     // Ubuntu major
 231     this.umajor = Integer.parseInt(match.group(5))
 232
 233     // Ubuntu minor
 234     this.uminor = Integer.parseInt(match.group(6))
 235
 236     if (match.group(7) != null) {
 237       this.suffix = match.group(7)
 238     }
 239   }
 240
 241   // Return true if this version is a release candidate
 242   Boolean isRC() {
 243     return false
 244   }
 245
 246   // Return true if both version are of the same stable branch
 247   Boolean isSameStable(UbuntuKVersion o) {
 248     if (this.isLTS != o.isLTS) {
 249       return false
 250     }
 251     if (this.major != o.major) {
 252       return false
 253     }
 254     if (this.minor != o.minor) {
 255       return false
 256     }
 257     if (this.patch != o.patch) {
 258       return false
 259     }
 260
 261     return true
 262   }
 263
 264   @Override int compareTo(UbuntuKVersion o) {
 265     if (this.major != o.major) {
 266       return Integer.compare(this.major, o.major)
 267     }
 268     if (this.minor != o.minor) {
 269       return Integer.compare(this.minor, o.minor)
 270     }
 271     if (this.patch != o.patch) {
 272       return Integer.compare(this.patch, o.patch)
 273     }
 274     if (this.umajor != o.umajor) {
 275       return Integer.compare(this.umajor, o.umajor)
 276     }
 277     if (this.uminor != o.uminor) {
 278       return Integer.compare(this.uminor, o.uminor)
 279     }
 280     if (this.isLTS != o.isLTS) {
 281       if (o.isLTS) {
 282         return 1
 283       } else {
 284         return -1
 285       }
 286     }
 287
 288     // Same version
 289     return 0;
 290   }
 291
 292   String toString() {
 293     String vString = "Ubuntu-"
 294
 295     if (this.isLTS) {
 296       vString = vString.concat("${this.strLTS}")
 297     }
 298
 299     // The tag pattern changed for HWE kernels >= 5.0
 300     if (this.isLTS && this.major >= 5) {
 301       vString = vString.concat("${this.major}.${this.minor}-${this.major}.${this.minor}.${this.patch}-${this.umajor}.${this.uminor}${this.suffix}")
 302     } else {
 303       vString = vString.concat("${this.major}.${this.minor}.${this.patch}-${this.umajor}.${this.uminor}${this.suffix}")
 304     }
 305
 306     return vString
 307   }
 308 }
 309
 310
 311 // Retrieve parameters of the current build
 312 def mbranch = build.getEnvironment(listener).get('GIT_BRANCH').minus('origin/')
 313 def maxConcurrentBuild = build.buildVariableResolver.resolve('maxConcurrentBuild')
 314 def kgitrepo = build.buildVariableResolver.resolve('kgitrepo')
 315 def kverfloor_raw = build.buildVariableResolver.resolve('kverfloor')
 316 def kverceil_raw = build.buildVariableResolver.resolve('kverceil')
 317 def kverfilter = build.buildVariableResolver.resolve('kverfilter')
 318 def kverrc = build.buildVariableResolver.resolve('kverrc')
 319 def uversion = build.buildVariableResolver.resolve('uversion')
 320 def job = Hudson.instance.getJob(build.buildVariableResolver.resolve('kbuildjob'))
 321 def currentJobName = build.project.getFullDisplayName()
 322 def gitmodpath = build.getEnvironment(listener).get('WORKSPACE') + "/src/lttng-modules"
 323
 324 // Get the out variable
 325 def config = new HashMap()
 326 def bindings = getBinding()
 327 config.putAll(bindings.getVariables())
 328 def out = config['out']
 329
 330
 331 // Get the lttng-modules git url
 332 def gitmodrepo = Git.open(new File(gitmodpath))
 333 def mgitrepo = gitmodrepo.getRepository().getConfig().getString("remote", "origin", "url")
 334
 335 // Get tags from git repository
 336 def refs = Git.lsRemoteRepository().setTags(true).setRemote(kgitrepo).call()
 337
 338 // Get kernel versions to build
 339 def kversions = []
 340 def kversionsRC = []
 341 def matchStrs = []
 342 def blacklist = []
 343 def kversionFactory = ""
 344
 345 if (uversion != null) {
 346   kversionFactory = new UbuntuKVersion()
 347   switch (uversion) {
 348     case 'jammy':
 349       matchStrs = [
 350         ~/^refs\/tags\/(Ubuntu-5\.15\.0-\d{1,3}?\.[\d]+)$/,
 351         ~/^refs\/tags\/(Ubuntu-hwe-6\.2-6\.2\.0-.*_22\.04\.\d+)$/,
 352       ]
 353       break
 354
 355     case 'focal':
 356       matchStrs = [
 357         ~/^refs\/tags\/(Ubuntu-5\.4\.0-\d{1,3}?\.[\d]+)$/,
 358         ~/^refs\/tags\/(Ubuntu-hwe-5\.13-5\.13\.0-.*_20\.04\.\d+)$/,
 359       ]
 360       break
 361
 362     default:
 363       println "Unsupported Ubuntu version: ${uversion}"
 364       throw new InterruptedException()
 365       break
 366   }
 367 } else {
 368   // Vanilla
 369   kversionFactory = new VanillaKVersion()
 370   matchStrs = [
 371     ~/^refs\/tags\/(v[\d\.]+(-rc(\d+))?)$/,
 372   ]
 373   blacklist = [
 374     'v3.2.3',
 375   ]
 376 }
 377
 378 // Parse kernel versions
 379 def kverfloor = ""
 380 try {
 381     kverfloor = kversionFactory.factory(kverfloor_raw)
 382 } catch (EmptyKVersionException e) {
 383     kverfloor = kversionFactory.minKVersion()
 384 }
 385
 386 def kverceil = ""
 387 try {
 388     kverceil = kversionFactory.factory(kverceil_raw)
 389 } catch (EmptyKVersionException e) {
 390     kverceil = kversionFactory.maxKVersion()
 391 }
 392
 393 // Build a sorted list of versions to build
 394 for (ref in refs) {
 395   for (matchStr in matchStrs) {
 396     def match = ref.getName() =~ matchStr
 397     if (match && !blacklist.contains(match.group(1))) {
 398       def v = kversionFactory.factory(match.group(1))
 399
 400       if ((v >= kverfloor) && (v < kverceil)) {
 401         if (v.isRC()) {
 402           kversionsRC.add(v)
 403         } else {
 404           kversions.add(v)
 405         }
 406       }
 407     }
 408   }
 409 }
 410
 411 // The filtering step assumes the version lists are sorted
 412 kversions.sort()
 413 kversionsRC.sort()
 414
 415 switch (kverfilter) {
 416   case 'stable-head':
 417     // Keep only the head of each stable branch
 418     println('Filter kernel versions to keep only the latest point release of each stable branch.')
 419
 420     for (i = 0; i < kversions.size(); i++) {
 421       def curr = kversions[i]
 422       def next = i < kversions.size() - 1 ? kversions[i + 1] : null
 423
 424       if (next != null) {
 425         if (curr.isSameStable(next)) {
 426           kversions.remove(i)
 427           i--
 428         }
 429       }
 430     }
 431     break
 432
 433   case 'lts-head':
 434     // Keep only the head of each LTS branch and the latest non-RC tag
 435     println('Filter kernel versions to keep only the latest point release of each lts branch and the current stable.')
 436
 437     def lts_kversions = []
 438     lts_kversions.add(kversionFactory.factory("v4.4"))  // SLTS until 2026
 439     lts_kversions.add(kversionFactory.factory("v4.9"))  // LTS until January 2023
 440     lts_kversions.add(kversionFactory.factory("v4.14")) // LTS until January 2024
 441     lts_kversions.add(kversionFactory.factory("v4.19")) // LTS until December 2024
 442     lts_kversions.add(kversionFactory.factory("v5.4"))  // LTS until December 2025
 443     lts_kversions.add(kversionFactory.factory("v5.10")) // LTS until December 2026
 444     lts_kversions.add(kversionFactory.factory("v5.15")) // LTS until October 2026
 445     lts_kversions.add(kversionFactory.factory("v6.1"))  // LTS until December 2026
 446
 447     // First filter the head of each branch
 448     for (i = 0; i < kversions.size(); i++) {
 449       def curr = kversions[i]
 450       def next = i < kversions.size() - 1 ? kversions[i + 1] : null
 451
 452       if (next != null) {
 453         if (curr.isSameStable(next)) {
 454           kversions.remove(i)
 455           i--
 456         }
 457       }
 458     }
 459
 460     for (i = 0; i < kversions.size(); i++) {
 461       def curr = kversions[i]
 462
 463       // Keep the newest tag
 464       if (i == kversions.size() - 1) {
 465         break
 466       }
 467
 468       // Prune non-LTS versions
 469       def keep = false
 470       for (j = 0; j < lts_kversions.size(); j++) {
 471         if (curr.isSameStable(lts_kversions[j])) {
 472           keep = true
 473           break
 474         }
 475       }
 476
 477       if (!keep) {
 478         kversions.remove(i)
 479         i--
 480       }
 481     }
 482     break
 483
 484   default:
 485     // No filtering of kernel versions
 486     println('No kernel versions filtering selected.')
 487     break
 488 }
 489
 490 if (kverrc == "true") {
 491   // If the last RC version is newer than the last stable, add it to the build list
 492   if (kversionsRC.size() > 0 && kversionsRC.last() > kversions.last()) {
 493     kversions.add(kversionsRC.last())
 494   }
 495 }
 496
 497 println "Building the following kernel versions:"
 498 for (k in kversions) {
 499   println k
 500 }
 501
 502 // Debug: Stop build here
 503 //throw new InterruptedException()
 504
 505 def joburl = HyperlinkNote.encodeTo('/' + job.url, job.fullDisplayName)
 506
 507 def allBuilds = []
 508 def ongoingBuild = []
 509 def failedRuns = []
 510 def isFailed = false
 511 def similarJobQueued = 0;
 512
 513 // Loop while we have kernel versions remaining or jobs running
 514 while ( kversions.size() != 0 || ongoingBuild.size() != 0 ) {
 515
 516   if(ongoingBuild.size() < maxConcurrentBuild.toInteger() && kversions.size() != 0) {
 517     def kversion = kversions.pop()
 518     def job_params = [
 519       new StringParameterValue('mversion', mbranch),
 520       new StringParameterValue('mgitrepo', mgitrepo),
 521       new StringParameterValue('ktag', kversion.toString()),
 522       new StringParameterValue('kgitrepo', kgitrepo),
 523     ]
 524
 525     // Launch the parametrized build
 526     def param_build = job.scheduleBuild2(0, new Cause.UpstreamCause(build), new ParametersAction(job_params))
 527     println "triggering ${joburl} for the ${mbranch} branch on kernel ${kversion}"
 528
 529     // Add it to the ongoing build queue
 530     ongoingBuild.push(param_build)
 531
 532   } else {
 533
 534     println "Waiting... Queued: " + kversions.size() + " Running: " + ongoingBuild.size()
 535     try {
 536       Thread.sleep(10000)
 537     } catch(e) {
 538       if (e in InterruptedException) {
 539         build.setResult(hudson.model.Result.ABORTED)
 540         throw new InterruptedException()
 541       } else {
 542         throw(e)
 543       }
 544     }
 545
 546     // Abort job if a newer instance is queued
 547     if (!currentJobName.contains("gerrit")) {
 548       similarJobQueued = Hudson.instance.queue.items.count{it.task.getFullDisplayName() == currentJobName}
 549       if (similarJobQueued > 0) {
 550         println "Abort, a newer instance of the job was queued"
 551         build.setResult(hudson.model.Result.ABORTED)
 552         throw new InterruptedException()
 553       }
 554     }
 555
 556     def i = ongoingBuild.iterator()
 557     while ( i.hasNext() ) {
 558       currentBuild = i.next()
 559       if ( currentBuild.isCancelled() || currentBuild.isDone() ) {
 560         // Remove from queue
 561         i.remove()
 562
 563         // Print results
 564         def matrixParent = currentBuild.get()
 565         allBuilds.add(matrixParent)
 566         def kernelStr = matrixParent.buildVariableResolver.resolve("ktag")
 567         println "${matrixParent.fullDisplayName} (${kernelStr}) completed with status ${matrixParent.result}"
 568
 569         // Process child runs of matrixBuild
 570         def childRuns = matrixParent.getRuns()
 571         for ( childRun in childRuns ) {
 572           println "\t${childRun.fullDisplayName} (${kernelStr}) completed with status ${childRun.result}"
 573           if (childRun.result != Result.SUCCESS) {
 574             failedRuns.add(childRun)
 575             isFailed = true
 576           }
 577         }
 578       }
 579     }
 580   }
 581 }
 582
 583 // Get log of failed runs
 584 for (failedRun in failedRuns) {
 585   println "---START---"
 586   failedRun.writeWholeLogTo(out)
 587   println "---END---"
 588 }
 589
 590 println "---Build report---"
 591 for (b in allBuilds) {
 592   def kernelStr = b.buildVariableResolver.resolve("ktag")
 593   println "${b.fullDisplayName} (${kernelStr}) completed with status ${b.result}"
 594   // Cleanup builds
 595   try {
 596     b.delete()
 597   } catch (all) {}
 598 }
 599
 600 // Mark this build failed if any child build has failed
 601 if (isFailed) {
 602   build.setResult(hudson.model.Result.FAILURE)
 603 }
 604
 605 // EOF