m4/ax_pthread.m4

   1 # SPDX-License-Identifier: GPL-2.0-or-later WITH LicenseRef-Autoconf-exception-macro
   2 # ===========================================================================
   3 #        https://www.gnu.org/software/autoconf-archive/ax_pthread.html
   4 # ===========================================================================
   5 #
   6 # SYNOPSIS
   7 #
   8 #   AX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
   9 #
  10 # DESCRIPTION
  11 #
  12 #   This macro figures out how to build C programs using POSIX threads. It
  13 #   sets the PTHREAD_LIBS output variable to the threads library and linker
  14 #   flags, and the PTHREAD_CFLAGS output variable to any special C compiler
  15 #   flags that are needed. (The user can also force certain compiler
  16 #   flags/libs to be tested by setting these environment variables.)
  17 #
  18 #   Also sets PTHREAD_CC and PTHREAD_CXX to any special C compiler that is
  19 #   needed for multi-threaded programs (defaults to the value of CC
  20 #   respectively CXX otherwise). (This is necessary on e.g. AIX to use the
  21 #   special cc_r/CC_r compiler alias.)
  22 #
  23 #   NOTE: You are assumed to not only compile your program with these flags,
  24 #   but also to link with them as well. For example, you might link with
  25 #   $PTHREAD_CC $CFLAGS $PTHREAD_CFLAGS $LDFLAGS ... $PTHREAD_LIBS $LIBS
  26 #   $PTHREAD_CXX $CXXFLAGS $PTHREAD_CFLAGS $LDFLAGS ... $PTHREAD_LIBS $LIBS
  27 #
  28 #   If you are only building threaded programs, you may wish to use these
  29 #   variables in your default LIBS, CFLAGS, and CC:
  30 #
  31 #     LIBS="$PTHREAD_LIBS $LIBS"
  32 #     CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  33 #     CXXFLAGS="$CXXFLAGS $PTHREAD_CFLAGS"
  34 #     CC="$PTHREAD_CC"
  35 #     CXX="$PTHREAD_CXX"
  36 #
  37 #   In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute constant
  38 #   has a nonstandard name, this macro defines PTHREAD_CREATE_JOINABLE to
  39 #   that name (e.g. PTHREAD_CREATE_UNDETACHED on AIX).
  40 #
  41 #   Also HAVE_PTHREAD_PRIO_INHERIT is defined if pthread is found and the
  42 #   PTHREAD_PRIO_INHERIT symbol is defined when compiling with
  43 #   PTHREAD_CFLAGS.
  44 #
  45 #   ACTION-IF-FOUND is a list of shell commands to run if a threads library
  46 #   is found, and ACTION-IF-NOT-FOUND is a list of commands to run it if it
  47 #   is not found. If ACTION-IF-FOUND is not specified, the default action
  48 #   will define HAVE_PTHREAD.
  49 #
  50 #   Please let the authors know if this macro fails on any platform, or if
  51 #   you have any other suggestions or comments. This macro was based on work
  52 #   by SGJ on autoconf scripts for FFTW (http://www.fftw.org/) (with help
  53 #   from M. Frigo), as well as ac_pthread and hb_pthread macros posted by
  54 #   Alejandro Forero Cuervo to the autoconf macro repository. We are also
  55 #   grateful for the helpful feedback of numerous users.
  56 #
  57 #   Updated for Autoconf 2.68 by Daniel Richard G.
  58 #
  59 # LICENSE
  60 #
  61 #   Copyright (c) 2008 Steven G. Johnson <stevenj@alum.mit.edu>
  62 #   Copyright (c) 2011 Daniel Richard G. <skunk@iSKUNK.ORG>
  63 #   Copyright (c) 2019 Marc Stevens <marc.stevens@cwi.nl>
  64 #
  65 #   This program is free software: you can redistribute it and/or modify it
  66 #   under the terms of the GNU General Public License as published by the
  67 #   Free Software Foundation, either version 3 of the License, or (at your
  68 #   option) any later version.
  69 #
  70 #   This program is distributed in the hope that it will be useful, but
  71 #   WITHOUT ANY WARRANTY; without even the implied warranty of
  72 #   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
  73 #   Public License for more details.
  74 #
  75 #   You should have received a copy of the GNU General Public License along
  76 #   with this program. If not, see <https://www.gnu.org/licenses/>.
  77 #
  78 #   As a special exception, the respective Autoconf Macro's copyright owner
  79 #   gives unlimited permission to copy, distribute and modify the configure
  80 #   scripts that are the output of Autoconf when processing the Macro. You
  81 #   need not follow the terms of the GNU General Public License when using
  82 #   or distributing such scripts, even though portions of the text of the
  83 #   Macro appear in them. The GNU General Public License (GPL) does govern
  84 #   all other use of the material that constitutes the Autoconf Macro.
  85 #
  86 #   This special exception to the GPL applies to versions of the Autoconf
  87 #   Macro released by the Autoconf Archive. When you make and distribute a
  88 #   modified version of the Autoconf Macro, you may extend this special
  89 #   exception to the GPL to apply to your modified version as well.
  90
  91 #serial 31
  92
  93 AU_ALIAS([ACX_PTHREAD], [AX_PTHREAD])
  94 AC_DEFUN([AX_PTHREAD], [
  95 AC_REQUIRE([AC_CANONICAL_HOST])
  96 AC_REQUIRE([AC_PROG_CC])
  97 AC_REQUIRE([AC_PROG_SED])
  98 AC_LANG_PUSH([C])
  99 ax_pthread_ok=no
 100
 101 # We used to check for pthread.h first, but this fails if pthread.h
 102 # requires special compiler flags (e.g. on Tru64 or Sequent).
 103 # It gets checked for in the link test anyway.
 104
 105 # First of all, check if the user has set any of the PTHREAD_LIBS,
 106 # etcetera environment variables, and if threads linking works using
 107 # them:
 108 if test "x$PTHREAD_CFLAGS$PTHREAD_LIBS" != "x"; then
 109         ax_pthread_save_CC="$CC"
 110         ax_pthread_save_CFLAGS="$CFLAGS"
 111         ax_pthread_save_LIBS="$LIBS"
 112         AS_IF([test "x$PTHREAD_CC" != "x"], [CC="$PTHREAD_CC"])
 113         AS_IF([test "x$PTHREAD_CXX" != "x"], [CXX="$PTHREAD_CXX"])
 114         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 115         LIBS="$PTHREAD_LIBS $LIBS"
 116         AC_MSG_CHECKING([for pthread_join using $CC $PTHREAD_CFLAGS $PTHREAD_LIBS])
 117         AC_LINK_IFELSE([AC_LANG_CALL([], [pthread_join])], [ax_pthread_ok=yes])
 118         AC_MSG_RESULT([$ax_pthread_ok])
 119         if test "x$ax_pthread_ok" = "xno"; then
 120                 PTHREAD_LIBS=""
 121                 PTHREAD_CFLAGS=""
 122         fi
 123         CC="$ax_pthread_save_CC"
 124         CFLAGS="$ax_pthread_save_CFLAGS"
 125         LIBS="$ax_pthread_save_LIBS"
 126 fi
 127
 128 # We must check for the threads library under a number of different
 129 # names; the ordering is very important because some systems
 130 # (e.g. DEC) have both -lpthread and -lpthreads, where one of the
 131 # libraries is broken (non-POSIX).
 132
 133 # Create a list of thread flags to try. Items with a "," contain both
 134 # C compiler flags (before ",") and linker flags (after ","). Other items
 135 # starting with a "-" are C compiler flags, and remaining items are
 136 # library names, except for "none" which indicates that we try without
 137 # any flags at all, and "pthread-config" which is a program returning
 138 # the flags for the Pth emulation library.
 139
 140 ax_pthread_flags="pthreads none -Kthread -pthread -pthreads -mthreads pthread --thread-safe -mt pthread-config"
 141
 142 # The ordering *is* (sometimes) important.  Some notes on the
 143 # individual items follow:
 144
 145 # pthreads: AIX (must check this before -lpthread)
 146 # none: in case threads are in libc; should be tried before -Kthread and
 147 #       other compiler flags to prevent continual compiler warnings
 148 # -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h)
 149 # -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads), Tru64
 150 #           (Note: HP C rejects this with "bad form for `-t' option")
 151 # -pthreads: Solaris/gcc (Note: HP C also rejects)
 152 # -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it
 153 #      doesn't hurt to check since this sometimes defines pthreads and
 154 #      -D_REENTRANT too), HP C (must be checked before -lpthread, which
 155 #      is present but should not be used directly; and before -mthreads,
 156 #      because the compiler interprets this as "-mt" + "-hreads")
 157 # -mthreads: Mingw32/gcc, Lynx/gcc
 158 # pthread: Linux, etcetera
 159 # --thread-safe: KAI C++
 160 # pthread-config: use pthread-config program (for GNU Pth library)
 161
 162 case $host_os in
 163
 164         freebsd*)
 165
 166         # -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able)
 167         # lthread: LinuxThreads port on FreeBSD (also preferred to -pthread)
 168
 169         ax_pthread_flags="-kthread lthread $ax_pthread_flags"
 170         ;;
 171
 172         hpux*)
 173
 174         # From the cc(1) man page: "[-mt] Sets various -D flags to enable
 175         # multi-threading and also sets -lpthread."
 176
 177         ax_pthread_flags="-mt -pthread pthread $ax_pthread_flags"
 178         ;;
 179
 180         openedition*)
 181
 182         # IBM z/OS requires a feature-test macro to be defined in order to
 183         # enable POSIX threads at all, so give the user a hint if this is
 184         # not set. (We don't define these ourselves, as they can affect
 185         # other portions of the system API in unpredictable ways.)
 186
 187         AC_EGREP_CPP([AX_PTHREAD_ZOS_MISSING],
 188             [
 189 #            if !defined(_OPEN_THREADS) && !defined(_UNIX03_THREADS)
 190              AX_PTHREAD_ZOS_MISSING
 191 #            endif
 192             ],
 193             [AC_MSG_WARN([IBM z/OS requires -D_OPEN_THREADS or -D_UNIX03_THREADS to enable pthreads support.])])
 194         ;;
 195
 196         solaris*)
 197
 198         # On Solaris (at least, for some versions), libc contains stubbed
 199         # (non-functional) versions of the pthreads routines, so link-based
 200         # tests will erroneously succeed. (N.B.: The stubs are missing
 201         # pthread_cleanup_push, or rather a function called by this macro,
 202         # so we could check for that, but who knows whether they'll stub
 203         # that too in a future libc.)  So we'll check first for the
 204         # standard Solaris way of linking pthreads (-mt -lpthread).
 205
 206         ax_pthread_flags="-mt,-lpthread pthread $ax_pthread_flags"
 207         ;;
 208 esac
 209
 210 # Are we compiling with Clang?
 211
 212 AC_CACHE_CHECK([whether $CC is Clang],
 213     [ax_cv_PTHREAD_CLANG],
 214     [ax_cv_PTHREAD_CLANG=no
 215      # Note that Autoconf sets GCC=yes for Clang as well as GCC
 216      if test "x$GCC" = "xyes"; then
 217         AC_EGREP_CPP([AX_PTHREAD_CC_IS_CLANG],
 218             [/* Note: Clang 2.7 lacks __clang_[a-z]+__ */
 219 #            if defined(__clang__) && defined(__llvm__)
 220              AX_PTHREAD_CC_IS_CLANG
 221 #            endif
 222             ],
 223             [ax_cv_PTHREAD_CLANG=yes])
 224      fi
 225     ])
 226 ax_pthread_clang="$ax_cv_PTHREAD_CLANG"
 227
 228
 229 # GCC generally uses -pthread, or -pthreads on some platforms (e.g. SPARC)
 230
 231 # Note that for GCC and Clang -pthread generally implies -lpthread,
 232 # except when -nostdlib is passed.
 233 # This is problematic using libtool to build C++ shared libraries with pthread:
 234 # [1] https://gcc.gnu.org/bugzilla/show_bug.cgi?id=25460
 235 # [2] https://bugzilla.redhat.com/show_bug.cgi?id=661333
 236 # [3] https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=468555
 237 # To solve this, first try -pthread together with -lpthread for GCC
 238
 239 AS_IF([test "x$GCC" = "xyes"],
 240       [ax_pthread_flags="-pthread,-lpthread -pthread -pthreads $ax_pthread_flags"])
 241
 242 # Clang takes -pthread (never supported any other flag), but we'll try with -lpthread first
 243
 244 AS_IF([test "x$ax_pthread_clang" = "xyes"],
 245       [ax_pthread_flags="-pthread,-lpthread -pthread"])
 246
 247
 248 # The presence of a feature test macro requesting re-entrant function
 249 # definitions is, on some systems, a strong hint that pthreads support is
 250 # correctly enabled
 251
 252 case $host_os in
 253         darwin* | hpux* | linux* | osf* | solaris*)
 254         ax_pthread_check_macro="_REENTRANT"
 255         ;;
 256
 257         aix*)
 258         ax_pthread_check_macro="_THREAD_SAFE"
 259         ;;
 260
 261         *)
 262         ax_pthread_check_macro="--"
 263         ;;
 264 esac
 265 AS_IF([test "x$ax_pthread_check_macro" = "x--"],
 266       [ax_pthread_check_cond=0],
 267       [ax_pthread_check_cond="!defined($ax_pthread_check_macro)"])
 268
 269
 270 if test "x$ax_pthread_ok" = "xno"; then
 271 for ax_pthread_try_flag in $ax_pthread_flags; do
 272
 273         case $ax_pthread_try_flag in
 274                 none)
 275                 AC_MSG_CHECKING([whether pthreads work without any flags])
 276                 ;;
 277
 278                 *,*)
 279                 PTHREAD_CFLAGS=`echo $ax_pthread_try_flag | sed "s/^\(.*\),\(.*\)$/\1/"`
 280                 PTHREAD_LIBS=`echo $ax_pthread_try_flag | sed "s/^\(.*\),\(.*\)$/\2/"`
 281                 AC_MSG_CHECKING([whether pthreads work with "$PTHREAD_CFLAGS" and "$PTHREAD_LIBS"])
 282                 ;;
 283
 284                 -*)
 285                 AC_MSG_CHECKING([whether pthreads work with $ax_pthread_try_flag])
 286                 PTHREAD_CFLAGS="$ax_pthread_try_flag"
 287                 ;;
 288
 289                 pthread-config)
 290                 AC_CHECK_PROG([ax_pthread_config], [pthread-config], [yes], [no])
 291                 AS_IF([test "x$ax_pthread_config" = "xno"], [continue])
 292                 PTHREAD_CFLAGS="`pthread-config --cflags`"
 293                 PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`"
 294                 ;;
 295
 296                 *)
 297                 AC_MSG_CHECKING([for the pthreads library -l$ax_pthread_try_flag])
 298                 PTHREAD_LIBS="-l$ax_pthread_try_flag"
 299                 ;;
 300         esac
 301
 302         ax_pthread_save_CFLAGS="$CFLAGS"
 303         ax_pthread_save_LIBS="$LIBS"
 304         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 305         LIBS="$PTHREAD_LIBS $LIBS"
 306
 307         # Check for various functions.  We must include pthread.h,
 308         # since some functions may be macros.  (On the Sequent, we
 309         # need a special flag -Kthread to make this header compile.)
 310         # We check for pthread_join because it is in -lpthread on IRIX
 311         # while pthread_create is in libc.  We check for pthread_attr_init
 312         # due to DEC craziness with -lpthreads.  We check for
 313         # pthread_cleanup_push because it is one of the few pthread
 314         # functions on Solaris that doesn't have a non-functional libc stub.
 315         # We try pthread_create on general principles.
 316
 317         AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <pthread.h>
 318 #                       if $ax_pthread_check_cond
 319 #                        error "$ax_pthread_check_macro must be defined"
 320 #                       endif
 321                         static void *some_global = NULL;
 322                         static void routine(void *a)
 323                           {
 324                              /* To avoid any unused-parameter or
 325                                 unused-but-set-parameter warning.  */
 326                              some_global = a;
 327                           }
 328                         static void *start_routine(void *a) { return a; }],
 329                        [pthread_t th; pthread_attr_t attr;
 330                         pthread_create(&th, 0, start_routine, 0);
 331                         pthread_join(th, 0);
 332                         pthread_attr_init(&attr);
 333                         pthread_cleanup_push(routine, 0);
 334                         pthread_cleanup_pop(0) /* ; */])],
 335             [ax_pthread_ok=yes],
 336             [])
 337
 338         CFLAGS="$ax_pthread_save_CFLAGS"
 339         LIBS="$ax_pthread_save_LIBS"
 340
 341         AC_MSG_RESULT([$ax_pthread_ok])
 342         AS_IF([test "x$ax_pthread_ok" = "xyes"], [break])
 343
 344         PTHREAD_LIBS=""
 345         PTHREAD_CFLAGS=""
 346 done
 347 fi
 348
 349
 350 # Clang needs special handling, because older versions handle the -pthread
 351 # option in a rather... idiosyncratic way
 352
 353 if test "x$ax_pthread_clang" = "xyes"; then
 354
 355         # Clang takes -pthread; it has never supported any other flag
 356
 357         # (Note 1: This will need to be revisited if a system that Clang
 358         # supports has POSIX threads in a separate library.  This tends not
 359         # to be the way of modern systems, but it's conceivable.)
 360
 361         # (Note 2: On some systems, notably Darwin, -pthread is not needed
 362         # to get POSIX threads support; the API is always present and
 363         # active.  We could reasonably leave PTHREAD_CFLAGS empty.  But
 364         # -pthread does define _REENTRANT, and while the Darwin headers
 365         # ignore this macro, third-party headers might not.)
 366
 367         # However, older versions of Clang make a point of warning the user
 368         # that, in an invocation where only linking and no compilation is
 369         # taking place, the -pthread option has no effect ("argument unused
 370         # during compilation").  They expect -pthread to be passed in only
 371         # when source code is being compiled.
 372         #
 373         # Problem is, this is at odds with the way Automake and most other
 374         # C build frameworks function, which is that the same flags used in
 375         # compilation (CFLAGS) are also used in linking.  Many systems
 376         # supported by AX_PTHREAD require exactly this for POSIX threads
 377         # support, and in fact it is often not straightforward to specify a
 378         # flag that is used only in the compilation phase and not in
 379         # linking.  Such a scenario is extremely rare in practice.
 380         #
 381         # Even though use of the -pthread flag in linking would only print
 382         # a warning, this can be a nuisance for well-run software projects
 383         # that build with -Werror.  So if the active version of Clang has
 384         # this misfeature, we search for an option to squash it.
 385
 386         AC_CACHE_CHECK([whether Clang needs flag to prevent "argument unused" warning when linking with -pthread],
 387             [ax_cv_PTHREAD_CLANG_NO_WARN_FLAG],
 388             [ax_cv_PTHREAD_CLANG_NO_WARN_FLAG=unknown
 389              # Create an alternate version of $ac_link that compiles and
 390              # links in two steps (.c -> .o, .o -> exe) instead of one
 391              # (.c -> exe), because the warning occurs only in the second
 392              # step
 393              ax_pthread_save_ac_link="$ac_link"
 394              ax_pthread_sed='s/conftest\.\$ac_ext/conftest.$ac_objext/g'
 395              ax_pthread_link_step=`AS_ECHO(["$ac_link"]) | sed "$ax_pthread_sed"`
 396              ax_pthread_2step_ac_link="($ac_compile) && (echo ==== >&5) && ($ax_pthread_link_step)"
 397              ax_pthread_save_CFLAGS="$CFLAGS"
 398              for ax_pthread_try in '' -Qunused-arguments -Wno-unused-command-line-argument unknown; do
 399                 AS_IF([test "x$ax_pthread_try" = "xunknown"], [break])
 400                 CFLAGS="-Werror -Wunknown-warning-option $ax_pthread_try -pthread $ax_pthread_save_CFLAGS"
 401                 ac_link="$ax_pthread_save_ac_link"
 402                 AC_LINK_IFELSE([AC_LANG_SOURCE([[int main(void){return 0;}]])],
 403                     [ac_link="$ax_pthread_2step_ac_link"
 404                      AC_LINK_IFELSE([AC_LANG_SOURCE([[int main(void){return 0;}]])],
 405                          [break])
 406                     ])
 407              done
 408              ac_link="$ax_pthread_save_ac_link"
 409              CFLAGS="$ax_pthread_save_CFLAGS"
 410              AS_IF([test "x$ax_pthread_try" = "x"], [ax_pthread_try=no])
 411              ax_cv_PTHREAD_CLANG_NO_WARN_FLAG="$ax_pthread_try"
 412             ])
 413
 414         case "$ax_cv_PTHREAD_CLANG_NO_WARN_FLAG" in
 415                 no | unknown) ;;
 416                 *) PTHREAD_CFLAGS="$ax_cv_PTHREAD_CLANG_NO_WARN_FLAG $PTHREAD_CFLAGS" ;;
 417         esac
 418
 419 fi # $ax_pthread_clang = yes
 420
 421
 422
 423 # Various other checks:
 424 if test "x$ax_pthread_ok" = "xyes"; then
 425         ax_pthread_save_CFLAGS="$CFLAGS"
 426         ax_pthread_save_LIBS="$LIBS"
 427         CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 428         LIBS="$PTHREAD_LIBS $LIBS"
 429
 430         # Detect AIX lossage: JOINABLE attribute is called UNDETACHED.
 431         AC_CACHE_CHECK([for joinable pthread attribute],
 432             [ax_cv_PTHREAD_JOINABLE_ATTR],
 433             [ax_cv_PTHREAD_JOINABLE_ATTR=unknown
 434              for ax_pthread_attr in PTHREAD_CREATE_JOINABLE PTHREAD_CREATE_UNDETACHED; do
 435                  AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <pthread.h>],
 436                                                  [int attr = $ax_pthread_attr; return attr /* ; */])],
 437                                 [ax_cv_PTHREAD_JOINABLE_ATTR=$ax_pthread_attr; break],
 438                                 [])
 439              done
 440             ])
 441         AS_IF([test "x$ax_cv_PTHREAD_JOINABLE_ATTR" != "xunknown" && \
 442                test "x$ax_cv_PTHREAD_JOINABLE_ATTR" != "xPTHREAD_CREATE_JOINABLE" && \
 443                test "x$ax_pthread_joinable_attr_defined" != "xyes"],
 444               [AC_DEFINE_UNQUOTED([PTHREAD_CREATE_JOINABLE],
 445                                   [$ax_cv_PTHREAD_JOINABLE_ATTR],
 446                                   [Define to necessary symbol if this constant
 447                                    uses a non-standard name on your system.])
 448                ax_pthread_joinable_attr_defined=yes
 449               ])
 450
 451         AC_CACHE_CHECK([whether more special flags are required for pthreads],
 452             [ax_cv_PTHREAD_SPECIAL_FLAGS],
 453             [ax_cv_PTHREAD_SPECIAL_FLAGS=no
 454              case $host_os in
 455              solaris*)
 456              ax_cv_PTHREAD_SPECIAL_FLAGS="-D_POSIX_PTHREAD_SEMANTICS"
 457              ;;
 458              esac
 459             ])
 460         AS_IF([test "x$ax_cv_PTHREAD_SPECIAL_FLAGS" != "xno" && \
 461                test "x$ax_pthread_special_flags_added" != "xyes"],
 462               [PTHREAD_CFLAGS="$ax_cv_PTHREAD_SPECIAL_FLAGS $PTHREAD_CFLAGS"
 463                ax_pthread_special_flags_added=yes])
 464
 465         AC_CACHE_CHECK([for PTHREAD_PRIO_INHERIT],
 466             [ax_cv_PTHREAD_PRIO_INHERIT],
 467             [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]],
 468                                              [[int i = PTHREAD_PRIO_INHERIT;
 469                                                return i;]])],
 470                             [ax_cv_PTHREAD_PRIO_INHERIT=yes],
 471                             [ax_cv_PTHREAD_PRIO_INHERIT=no])
 472             ])
 473         AS_IF([test "x$ax_cv_PTHREAD_PRIO_INHERIT" = "xyes" && \
 474                test "x$ax_pthread_prio_inherit_defined" != "xyes"],
 475               [AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], [1], [Have PTHREAD_PRIO_INHERIT.])
 476                ax_pthread_prio_inherit_defined=yes
 477               ])
 478
 479         CFLAGS="$ax_pthread_save_CFLAGS"
 480         LIBS="$ax_pthread_save_LIBS"
 481
 482         # More AIX lossage: compile with *_r variant
 483         if test "x$GCC" != "xyes"; then
 484             case $host_os in
 485                 aix*)
 486                 AS_CASE(["x/$CC"],
 487                     [x*/c89|x*/c89_128|x*/c99|x*/c99_128|x*/cc|x*/cc128|x*/xlc|x*/xlc_v6|x*/xlc128|x*/xlc128_v6],
 488                     [#handle absolute path differently from PATH based program lookup
 489                      AS_CASE(["x$CC"],
 490                          [x/*],
 491                          [
 492                            AS_IF([AS_EXECUTABLE_P([${CC}_r])],[PTHREAD_CC="${CC}_r"])
 493                            AS_IF([test "x${CXX}" != "x"], [AS_IF([AS_EXECUTABLE_P([${CXX}_r])],[PTHREAD_CXX="${CXX}_r"])])
 494                          ],
 495                          [
 496                            AC_CHECK_PROGS([PTHREAD_CC],[${CC}_r],[$CC])
 497                            AS_IF([test "x${CXX}" != "x"], [AC_CHECK_PROGS([PTHREAD_CXX],[${CXX}_r],[$CXX])])
 498                          ]
 499                      )
 500                     ])
 501                 ;;
 502             esac
 503         fi
 504 fi
 505
 506 test -n "$PTHREAD_CC" || PTHREAD_CC="$CC"
 507 test -n "$PTHREAD_CXX" || PTHREAD_CXX="$CXX"
 508
 509 AC_SUBST([PTHREAD_LIBS])
 510 AC_SUBST([PTHREAD_CFLAGS])
 511 AC_SUBST([PTHREAD_CC])
 512 AC_SUBST([PTHREAD_CXX])
 513
 514 # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
 515 if test "x$ax_pthread_ok" = "xyes"; then
 516         ifelse([$1],,[AC_DEFINE([HAVE_PTHREAD],[1],[Define if you have POSIX threads libraries and header files.])],[$1])
 517         :
 518 else
 519         ax_pthread_ok=no
 520         $2
 521 fi
 522 AC_LANG_POP
 523 ])dnl AX_PTHREAD