m4/ax_append_flag.m4

   1 # SPDX-License-Identifier: FSFAP
   2 # ===========================================================================
   3 #      https://www.gnu.org/software/autoconf-archive/ax_append_flag.html
   4 # ===========================================================================
   5 #
   6 # SYNOPSIS
   7 #
   8 #   AX_APPEND_FLAG(FLAG, [FLAGS-VARIABLE])
   9 #
  10 # DESCRIPTION
  11 #
  12 #   FLAG is appended to the FLAGS-VARIABLE shell variable, with a space
  13 #   added in between.
  14 #
  15 #   If FLAGS-VARIABLE is not specified, the current language's flags (e.g.
  16 #   CFLAGS) is used.  FLAGS-VARIABLE is not changed if it already contains
  17 #   FLAG.  If FLAGS-VARIABLE is unset in the shell, it is set to exactly
  18 #   FLAG.
  19 #
  20 #   NOTE: Implementation based on AX_CFLAGS_GCC_OPTION.
  21 #
  22 # LICENSE
  23 #
  24 #   Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
  25 #   Copyright (c) 2011 Maarten Bosmans <mkbosmans@gmail.com>
  26 #
  27 #   Copying and distribution of this file, with or without modification, are
  28 #   permitted in any medium without royalty provided the copyright notice
  29 #   and this notice are preserved.  This file is offered as-is, without any
  30 #   warranty.
  31
  32 #serial 8
  33
  34 AC_DEFUN([AX_APPEND_FLAG],
  35 [dnl
  36 AC_PREREQ(2.64)dnl for _AC_LANG_PREFIX and AS_VAR_SET_IF
  37 AS_VAR_PUSHDEF([FLAGS], [m4_default($2,_AC_LANG_PREFIX[FLAGS])])
  38 AS_VAR_SET_IF(FLAGS,[
  39   AS_CASE([" AS_VAR_GET(FLAGS) "],
  40     [*" $1 "*], [AC_RUN_LOG([: FLAGS already contains $1])],
  41     [
  42      AS_VAR_APPEND(FLAGS,[" $1"])
  43      AC_RUN_LOG([: FLAGS="$FLAGS"])
  44     ])
  45   ],
  46   [
  47   AS_VAR_SET(FLAGS,[$1])
  48   AC_RUN_LOG([: FLAGS="$FLAGS"])
  49   ])
  50 AS_VAR_POPDEF([FLAGS])dnl
  51 ])dnl AX_APPEND_FLAG