configure.ac

   1 AC_INIT([lttng-tools],[2.4.0],[dgoulet@efficios.com],[],[http://lttng.org])
   2 AC_CONFIG_AUX_DIR([config])
   3 AC_CANONICAL_TARGET
   4 AC_CANONICAL_HOST
   5 AC_CONFIG_MACRO_DIR([config])
   6 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   7 AM_MAINTAINER_MODE([enable])
   8 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
   9
  10 # Compute minor/major/patchlevel version numbers
  11 AC_PROG_SED
  12 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  13 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  14 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  15 AC_SUBST([MAJOR_VERSION], [$major_version])
  16 AC_SUBST([MINOR_VERSION], [$minor_version])
  17 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  18 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  19 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  20 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  21
  22 version_name="Époque Opaque"
  23 version_description="The Époque Opaque is a black IPA from Trou du Diable brewery. The nose is eerily reminiscent of the coffee crisp candy from of our childhood. These strong mocha accents are present on the palate, which are quickly subdued by Japanese and Australian hops leading to a final state of satisfaction enjoyable for any fan of bitter beer."
  24
  25 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  26 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], "")
  27
  28 AC_CONFIG_HEADERS([include/config.h])
  29
  30 AC_PROG_GREP
  31 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  32 AC_ARG_ENABLE(libtool-linkdep-fixup,
  33         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  34                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  35         libtool_fixup=$enableval,
  36         libtool_fixup=yes)
  37
  38 AS_IF([test "x$libtool_fixup" = "xyes"],
  39             [
  40             libtool_m4="$srcdir/config/libtool.m4"
  41             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  42             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  43             libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  44             AS_IF([test $libtool_flag_pattern_count -ne 0],
  45             [
  46                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  47                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  48                   sed -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  49                   ],
  50                   [
  51                   AC_MSG_RESULT([none])
  52                   ])
  53             ])
  54
  55 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
  56
  57 AC_CHECK_HEADERS([ \
  58         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
  59         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
  60         getopt.h sys/ipc.h sys/shm.h popt.h grp.h \
  61 ])
  62
  63 # Babeltrace viewer check
  64 AC_ARG_WITH([babeltrace-bin],
  65         AS_HELP_STRING([--with-babeltrace-bin],
  66         [Location of the babeltrace viewer executable (including the filename)]),
  67         [BABELTRACE_BIN="$withval"],
  68         [BABELTRACE_BIN=''])
  69 AC_SUBST([BABELTRACE_BIN])
  70
  71 # lttv-gui
  72 AC_ARG_WITH([lttv-gui-bin],
  73         AS_HELP_STRING([--with-lttv-gui-bin],
  74    [Location of the lttv GUI viewer executable (including the filename)]),
  75    [LTTV_GUI_BIN="$withval"],
  76    [LTTV_GUI_BIN=''])
  77 AC_SUBST([LTTV_GUI_BIN])
  78
  79 AC_ARG_WITH([consumerd32-bin],
  80         AS_HELP_STRING([--with-consumerd32-bin],
  81         [Location of the 32-bit consumerd executable (including the filename)]),
  82         [CONSUMERD32_BIN="$withval"],
  83         [CONSUMERD32_BIN=''])
  84 AC_SUBST([CONSUMERD32_BIN])
  85
  86 AC_ARG_WITH([consumerd64-bin],
  87         AS_HELP_STRING([--with-consumerd64-bin],
  88         [Location of the 64-bit consumerd executable (including the filename)]),
  89         [CONSUMERD64_BIN="$withval"],
  90         [CONSUMERD64_BIN=''])
  91 AC_SUBST([CONSUMERD64_BIN])
  92
  93 AC_ARG_WITH([consumerd32-libdir],
  94         AS_HELP_STRING([--with-consumerd32-libdir],
  95         [Directory containing the 32-bit consumerd libraries]),
  96         [CONSUMERD32_LIBDIR="$withval"],
  97         [CONSUMERD32_LIBDIR=''])
  98 AC_SUBST([CONSUMERD32_LIBDIR])
  99
 100 AC_ARG_WITH([consumerd64-libdir],
 101         AS_HELP_STRING([--with-consumerd64-libdir],
 102         [Directory containing the 64-bit consumerd libraries]),
 103         [CONSUMERD64_LIBDIR="$withval"],
 104         [CONSUMERD64_LIBDIR=''])
 105 AC_SUBST([CONSUMERD64_LIBDIR])
 106
 107 AC_ARG_WITH([sessiond-bin],
 108         AS_HELP_STRING([--with-sessiond-bin],
 109         [Location of the sessiond executable (including the filename)]),
 110         [SESSIOND_BIN="$withval"],
 111         [SESSIOND_BIN=''])
 112 AC_SUBST([SESSIOND_BIN])
 113
 114 AC_ARG_WITH([lttng-system-rundir],
 115         AS_HELP_STRING([--with-lttng-system-rundir],
 116         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 117         [LTTNG_SYSTEM_RUNDIR="$withval"],
 118         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 119 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 120
 121 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 122 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 123 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 124 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 125 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 126 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 127 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 128 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 129
 130 # Check for pthread
 131 AC_CHECK_LIB([pthread], [pthread_create], [],
 132         [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
 133 )
 134
 135 # Check libpopt
 136 AC_CHECK_LIB([popt], [poptGetContext], [],
 137         [AC_MSG_ERROR([Cannot find libpopt. Use [LDFLAGS]=-Ldir to specify its location.])]
 138 )
 139
 140 # Check for libuuid
 141 AC_CHECK_LIB([uuid], [uuid_generate],
 142 [
 143         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 144         have_libuuid=yes
 145 ],
 146 [
 147         # libuuid not found, check for uuid_create in libc.
 148         AC_CHECK_LIB([c], [uuid_create],
 149         [
 150                 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 151                 have_libc_uuid=yes
 152         ],
 153         [
 154                 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 155         ])
 156 ]
 157 )
 158 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 159 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 160
 161 # URCU library version needed or newer
 162 liburcu_version=">= 0.7.2"
 163
 164 # Check liburcu needed function calls
 165 AC_CHECK_DECL([cds_list_add], [],
 166         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/list.h>]]
 167 )
 168 AC_CHECK_DECL([cds_wfq_init], [],
 169         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfqueue.h>]]
 170 )
 171 AC_CHECK_DECL([cds_wfq_dequeue_blocking], [],
 172     [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfqueue.h>]]
 173 )
 174 AC_CHECK_DECL([futex_async], [],
 175         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/futex.h>]]
 176 )
 177 AC_CHECK_DECL([rcu_thread_offline], [],
 178         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 179 )
 180 AC_CHECK_DECL([rcu_thread_online], [],
 181         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 182 )
 183 AC_CHECK_DECL([caa_likely], [],
 184         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 185 )
 186 #Function added in urcu 0.7.0
 187 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 188         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 189 )
 190
 191 AC_ARG_WITH(lttng-ust-prefix,
 192   AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
 193                  [Specify the installation prefix of the lttng-ust library.
 194                   Headers must be in PATH/include; libraries in PATH/lib.]),
 195                   [
 196                     CPPFLAGS="$CPPFLAGS -I${withval}/include"
 197                     LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 198                   ])
 199
 200 # Check liblttng-ust-ctl library
 201 AC_ARG_ENABLE(lttng-ust,
 202         AS_HELP_STRING([--disable-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 203         lttng_ust_support=$enableval, lttng_ust_support=yes)
 204
 205 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 206         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 207                 [
 208                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 209                         lttng_ust_ctl_found=yes
 210                 ],
 211                 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --disable-lttng-ust to build lttng-tools without LTTng-UST support.])],
 212                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt]
 213         )
 214 ])
 215 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 216 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 217
 218 # check for dlopen
 219 AC_CHECK_LIB([dl], [dlopen],
 220 [
 221         have_libdl=yes
 222 ],
 223 [
 224         #libdl not found, check for dlopen in libc.
 225         AC_CHECK_LIB([c], [dlopen],
 226         [
 227                 have_libc_dl=yes
 228         ],
 229         [
 230                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 231         ])
 232 ])
 233 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 234 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 235
 236 # Check for fmemopen
 237 AC_CHECK_LIB([c], [fmemopen],
 238 [
 239         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 240 ]
 241 )
 242
 243 # Check for open_memstream
 244 AC_CHECK_LIB([c], [open_memstream],
 245 [
 246         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 247 ]
 248 )
 249
 250 # For Python
 251 # SWIG version needed or newer:
 252 swig_version=2.0.0
 253
 254 AC_ARG_ENABLE([python-bindings],
 255               [AC_HELP_STRING([--enable-python-bindings],
 256                               [compile Python bindings])],
 257               [enable_python=yes], [enable_python=no])
 258
 259 AM_CONDITIONAL([USE_PYTHON], [test "x${enable_python:-yes}" = xyes])
 260
 261 if test "x${enable_python:-yes}" = xyes; then
 262   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 263   AM_PATH_PYTHON
 264
 265   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 266   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 267   AS_IF([test -z "$PYTHON_INCLUDE"], [
 268     AS_IF([test -z "$PYTHON_CONFIG"], [
 269       AC_PATH_PROGS([PYTHON_CONFIG],
 270                     [python$PYTHON_VERSION-config python-config],
 271                     [no],
 272                     [`dirname $PYTHON`])
 273       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 274     ])
 275     AC_MSG_CHECKING([python include flags])
 276     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 277     AC_MSG_RESULT([$PYTHON_INCLUDE])
 278   ])
 279
 280 else
 281     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 282 [if you want Python bindings.])
 283
 284 fi
 285
 286 # Option to only build the consumer daemon and its libraries
 287 AC_ARG_WITH([consumerd-only],
 288         AS_HELP_STRING([--with-consumerd-only],[Only build the consumer daemon [default=no]]),
 289         [consumerd_only=$withval],
 290         [consumerd_only=no])
 291 AM_CONDITIONAL([BUILD_CONSUMERD_ONLY], [test "x$consumerd_only" = "xyes"])
 292
 293 # Epoll check. If not present, the build will fallback on poll() API
 294 AX_HAVE_EPOLL(
 295         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 296         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 297 )
 298 AX_CONFIG_FEATURE(
 299         [epoll], [This platform supports epoll(7)],
 300         [HAVE_EPOLL], [This platform supports epoll(7).],
 301         [enable_epoll="yes"], [enable_epoll="no"]
 302 )
 303 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 304
 305 # Set compile flags to java include files if given. This is only used to
 306 # compile JUL tests.
 307 AC_ARG_WITH([java-jdk],
 308         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 309         [JAVA_JDK=$withval],
 310         [JAVA_JDK=""]
 311 )
 312 AM_CONDITIONAL([HAVE_JAVA_JDK], [test $JAVA_JDK], [Java JDK path])
 313 AC_SUBST([JAVA_JDK])
 314
 315 AS_IF([test $JAVA_JDK],[
 316         AS_IF([test -d $JAVA_JDK],
 317                 [
 318                         AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 319                         SUBDIRS=`find $JAVA_JDK/include -type d`
 320                         CPPFLAGS+=" "
 321                         CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 322                         CPPFLAGS+=" "
 323         ],[AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)]
 324         )
 325 ])
 326
 327 # Check for the UST JUL jar file in the system. Hardcoded path is added here
 328 # since we have *no* idea where this could be installed. Note that this is only
 329 # used for JUL testing.
 330 AC_MSG_CHECKING(Java JUL UST jar file)
 331 java_jul_jar_path="/usr/local/lib/lttng/java/liblttng-ust-jul.jar"
 332 if test -f $java_jul_jar_path; then
 333         build_java_jul=yes
 334         AC_MSG_RESULT(found)
 335 else
 336         build_java_jul=no
 337         AC_MSG_RESULT(not found)
 338 fi
 339 AM_CONDITIONAL([BUILD_JAVA_JUL], [test "x$build_java_jul" = "xyes"])
 340 AC_SUBST([java_jul_jar_path])
 341
 342 AC_SYS_LARGEFILE
 343 AC_PROG_CC
 344 LT_INIT
 345 AC_PROG_YACC
 346 AC_PROG_LEX
 347
 348 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-parser.h"; then
 349         if test x"$YACC" != "xbison -y"; then
 350                 AC_MSG_ERROR([[bison not found and is required when building from git.
 351                 Please install bison]])
 352         fi
 353 fi
 354
 355 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-lexer.c"; then
 356         if test x"$LEX" != "xflex"; then
 357                 AC_MSG_ERROR([[flex not found and is required when building from git.
 358                 Please install flex]])
 359         fi
 360 fi
 361
 362 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 363
 364 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 365
 366 lttngincludedir="${includedir}/lttng"
 367
 368 AC_SUBST(lttngincludedir)
 369 AC_SUBST(DEFAULT_INCLUDES)
 370
 371 lttnglibexecdir="${libdir}/lttng/libexec"
 372 AC_SUBST(lttnglibexecdir)
 373
 374 AC_CONFIG_FILES([
 375         Makefile
 376         doc/Makefile
 377         doc/man/Makefile
 378         include/Makefile
 379         extras/Makefile
 380         extras/bindings/Makefile
 381         extras/bindings/swig/Makefile
 382         extras/bindings/swig/python/Makefile
 383         extras/core-handler/Makefile
 384         src/Makefile
 385         src/common/Makefile
 386         src/common/kernel-ctl/Makefile
 387         src/common/kernel-consumer/Makefile
 388         src/common/ust-consumer/Makefile
 389         src/common/hashtable/Makefile
 390         src/common/sessiond-comm/Makefile
 391         src/common/compat/Makefile
 392         src/common/relayd/Makefile
 393         src/common/testpoint/Makefile
 394         src/common/index/Makefile
 395         src/common/health/Makefile
 396         src/lib/Makefile
 397         src/lib/lttng-ctl/Makefile
 398         src/lib/lttng-ctl/filter/Makefile
 399         src/lib/lttng-ctl/lttng-ctl.pc
 400         src/bin/Makefile
 401         src/bin/lttng-consumerd/Makefile
 402         src/bin/lttng-sessiond/Makefile
 403         src/bin/lttng-relayd/Makefile
 404         src/bin/lttng/Makefile
 405         tests/Makefile
 406         tests/regression/Makefile
 407         tests/regression/kernel/Makefile
 408         tests/regression/tools/Makefile
 409         tests/regression/tools/streaming/Makefile
 410         tests/regression/tools/filtering/Makefile
 411         tests/regression/tools/health/Makefile
 412         tests/regression/tools/tracefile-limits/Makefile
 413         tests/regression/tools/snapshots/Makefile
 414         tests/regression/tools/live/Makefile
 415         tests/regression/tools/exclusion/Makefile
 416         tests/regression/ust/Makefile
 417         tests/regression/ust/nprocesses/Makefile
 418         tests/regression/ust/high-throughput/Makefile
 419         tests/regression/ust/low-throughput/Makefile
 420         tests/regression/ust/before-after/Makefile
 421         tests/regression/ust/buffers-pid/Makefile
 422         tests/regression/ust/periodical-metadata-flush/Makefile
 423         tests/regression/ust/multi-session/Makefile
 424         tests/regression/ust/overlap/Makefile
 425         tests/regression/ust/overlap/demo/Makefile
 426         tests/regression/ust/linking/Makefile
 427         tests/regression/ust/daemon/Makefile
 428         tests/regression/ust/exit-fast/Makefile
 429         tests/regression/ust/fork/Makefile
 430         tests/regression/ust/libc-wrapper/Makefile
 431         tests/regression/ust/java-jul/Makefile
 432         tests/stress/Makefile
 433         tests/unit/Makefile
 434         tests/utils/Makefile
 435         tests/utils/tap/Makefile
 436         tests/utils/testapp/Makefile
 437         tests/utils/testapp/gen-ust-events/Makefile
 438         tests/utils/testapp/gen-ust-nevents/Makefile
 439 ])
 440
 441 AC_OUTPUT
 442
 443 #
 444 # Mini-report on what will be built
 445 #
 446 AS_ECHO()
 447
 448 AS_ECHO("Version name: $version_name")
 449 AS_ECHO("$version_description")
 450
 451 AS_ECHO()
 452
 453 # Target architecture we're building for
 454 target_arch=$host_cpu
 455 [
 456 for f in $CFLAGS; do
 457         if test $f = "-m32"; then
 458                         target_arch="32-bit"
 459         elif test $f = "-m64"; then
 460                         target_arch="64-bit"
 461         fi
 462 done
 463 ]
 464 AS_ECHO_N("Target architecture: ")
 465 AS_ECHO($target_arch)
 466
 467 # LTTng-UST enabled/disabled
 468 AS_ECHO_N("Lttng-UST support: ")
 469 AS_IF([test "x$lttng_ust_support" = "xyes"],[
 470         AS_ECHO("Enabled")
 471 ],[
 472         AS_ECHO("Disabled")
 473 ])
 474
 475 #Python binding enabled/disabled
 476 AS_ECHO_N("Python binding: ")
 477 AS_IF([test "x${enable_python:-yes}" = xyes], [
 478         AS_ECHO("Enabled")
 479 ],[
 480         AS_ECHO("Disabled")
 481 ])
 482
 483 # Do we build only the consumerd, or everything
 484 AS_IF([test "x$consumerd_only" = "xyes"],[
 485         AS_ECHO("Only the consumerd daemon will be built.")
 486 ],[
 487         AS_ECHO("All binaries will be built.")
 488 ])
 489
 490 # Print the bindir and libdir this `make install' will install into.
 491 AS_ECHO()
 492 AS_ECHO_N("Binaries will be installed in:  ")
 493 AS_ECHO("`eval eval echo $bindir`")
 494 AS_ECHO_N("Libraries will be installed in: ")
 495 AS_ECHO("`eval eval echo $libdir`")
 496
 497 # If we build the sessiond, print the paths it will use
 498 AS_IF([test "x$consumerd_only" = "xno"],[
 499         AS_ECHO()
 500         AS_ECHO_N("The lttng command will look for the lttng-sessiond executable at: ")
 501         AS_IF([test "$SESSIOND_BIN" = ""],[
 502                 AS_ECHO_N("`eval eval echo $bindir`")
 503                 AS_ECHO("/lttng-sessiond")
 504         ],[
 505                 AS_ECHO("$SESSIOND_BIN")
 506         ])
 507
 508         AS_ECHO()
 509         AS_ECHO("The sessiond daemon will look in the following directories: ")
 510         AS_ECHO_N("32-bit consumerd executable at: ")
 511         AS_IF([test "$CONSUMERD32_BIN" = ""],[
 512                 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 513                 AS_ECHO("/lttng-consumerd")
 514         ],[
 515                 AS_ECHO("$CONSUMERD32_BIN")
 516         ])
 517
 518         AS_ECHO_N("32-bit consumer libraries in:   ")
 519         AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
 520                 AS_ECHO("`eval eval echo $libdir`")
 521         ],[
 522                 AS_ECHO("$CONSUMERD32_LIBDIR")
 523         ])
 524
 525         AS_ECHO_N("64-bit consumerd executable at: ")
 526         AS_IF([test "$CONSUMERD64_BIN" = ""],[
 527                 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 528                 AS_ECHO("/lttng-consumerd")
 529         ],[
 530                 AS_ECHO("$CONSUMERD64_BIN")
 531         ])
 532
 533         AS_ECHO_N("64-bit consumer libraries in:   ")
 534         AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
 535                 AS_ECHO("`eval eval echo $libdir`")
 536         ],[
 537                 AS_ECHO("$CONSUMERD64_LIBDIR")
 538         ])
 539 ])
 540
 541 AS_ECHO()
 542