configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.8.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 # Checks for C compiler
  18 AC_USE_SYSTEM_EXTENSIONS
  19 AC_SYS_LARGEFILE
  20 AC_PROG_CC
  21 AC_PROG_CC_STDC
  22
  23 # Checks for programs.
  24 AC_PROG_GREP
  25 AC_PROG_LEX
  26 AC_PROG_MAKE_SET
  27 AC_PROG_SED
  28 AC_PROG_YACC
  29 LT_INIT
  30
  31 # Checks for typedefs, structures, and compiler characteristics.
  32 AC_C_INLINE
  33 AC_TYPE_INT32_T
  34 AC_TYPE_INT64_T
  35 AC_TYPE_MODE_T
  36 AC_TYPE_OFF_T
  37 AC_TYPE_PID_T
  38 AC_TYPE_SIZE_T
  39 AC_TYPE_SSIZE_T
  40 AC_TYPE_UID_T
  41 AC_TYPE_UINT16_T
  42 AC_TYPE_UINT32_T
  43 AC_TYPE_UINT64_T
  44 AC_TYPE_UINT8_T
  45
  46 AX_C___ATTRIBUTE__
  47 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  48         [:],
  49         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  50
  51 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  52 LIBS="$PTHREAD_LIBS $LIBS"
  53 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  54 CC="$PTHREAD_CC"
  55
  56 AX_LIB_SOCKET_NSL
  57
  58 # Compute minor/major/patchlevel version numbers
  59 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  60 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  61 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  62 AC_SUBST([MAJOR_VERSION], [$major_version])
  63 AC_SUBST([MINOR_VERSION], [$minor_version])
  64 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  65 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  66 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  67 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  68
  69 version_name="Herbe à Détourne"
  70 version_description='Brewed with unrestrained amounts of Citra hop, the Herbe à Détourne is a fantastic New World Tripel brewed by "Dieu du Ciel!". Aromas of mango, cantaloupe melon and passion fruit, combined with a controlled bitter finish, unite in making this smooth golden-orange beer stand apart.'
  71 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
  72
  73 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  74 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
  75
  76 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  77 AC_ARG_ENABLE(libtool-linkdep-fixup,
  78         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  79                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  80         libtool_fixup=$enableval,
  81         libtool_fixup=yes)
  82
  83 AS_IF([test "x$libtool_fixup" = "xyes"],
  84             [
  85             libtool_m4="$srcdir/m4/libtool.m4"
  86             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  87             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  88             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  89             AS_IF([test $libtool_flag_pattern_count -ne 0],
  90             [
  91                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  92                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  93                   SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  94                   ],
  95                   [
  96                   AC_MSG_RESULT([none])
  97                   ])
  98             ])
  99
 100 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 101
 102 AC_CHECK_HEADERS([ \
 103         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 104         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 105         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 106         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 107         sys/mount.h sys/param.h sys/time.h
 108 ])
 109
 110 # Basic functions check
 111 AC_CHECK_FUNCS([ \
 112         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 113         gethostbyname gethostname getpagesize localtime_r memchr memset \
 114         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 115         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 116         strtoull dirfd gethostbyname2 getipnodebyname \
 117 ])
 118
 119 # Babeltrace viewer check
 120 AC_ARG_WITH([babeltrace-bin],
 121         AS_HELP_STRING([--with-babeltrace-bin],
 122         [Location of the babeltrace viewer executable (including the filename)]),
 123         [BABELTRACE_BIN="$withval"],
 124         [BABELTRACE_BIN=''])
 125 AC_SUBST([BABELTRACE_BIN])
 126
 127 # lttv-gui
 128 AC_ARG_WITH([lttv-gui-bin],
 129         AS_HELP_STRING([--with-lttv-gui-bin],
 130    [Location of the lttv GUI viewer executable (including the filename)]),
 131    [LTTV_GUI_BIN="$withval"],
 132    [LTTV_GUI_BIN=''])
 133 AC_SUBST([LTTV_GUI_BIN])
 134
 135 AC_ARG_WITH([consumerd32-bin],
 136         AS_HELP_STRING([--with-consumerd32-bin],
 137         [Location of the 32-bit consumerd executable (including the filename)]),
 138         [CONSUMERD32_BIN="$withval"],
 139         [CONSUMERD32_BIN=''])
 140 AC_SUBST([CONSUMERD32_BIN])
 141
 142 AC_ARG_WITH([consumerd64-bin],
 143         AS_HELP_STRING([--with-consumerd64-bin],
 144         [Location of the 64-bit consumerd executable (including the filename)]),
 145         [CONSUMERD64_BIN="$withval"],
 146         [CONSUMERD64_BIN=''])
 147 AC_SUBST([CONSUMERD64_BIN])
 148
 149 AC_ARG_WITH([consumerd32-libdir],
 150         AS_HELP_STRING([--with-consumerd32-libdir],
 151         [Directory containing the 32-bit consumerd libraries]),
 152         [CONSUMERD32_LIBDIR="$withval"],
 153         [CONSUMERD32_LIBDIR=''])
 154 AC_SUBST([CONSUMERD32_LIBDIR])
 155
 156 AC_ARG_WITH([consumerd64-libdir],
 157         AS_HELP_STRING([--with-consumerd64-libdir],
 158         [Directory containing the 64-bit consumerd libraries]),
 159         [CONSUMERD64_LIBDIR="$withval"],
 160         [CONSUMERD64_LIBDIR=''])
 161 AC_SUBST([CONSUMERD64_LIBDIR])
 162
 163 AC_ARG_WITH([sessiond-bin],
 164         AS_HELP_STRING([--with-sessiond-bin],
 165         [Location of the sessiond executable (including the filename)]),
 166         [SESSIOND_BIN="$withval"],
 167         [SESSIOND_BIN=''])
 168 AC_SUBST([SESSIOND_BIN])
 169
 170 AC_ARG_WITH([lttng-system-rundir],
 171         AS_HELP_STRING([--with-lttng-system-rundir],
 172         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 173         [LTTNG_SYSTEM_RUNDIR="$withval"],
 174         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 175 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 176
 177 AC_ARG_ENABLE([test-java-agent-jul],
 178         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 179         [test_java_agent_jul=$enableval],
 180         [test_java_agent_jul=no]
 181 )
 182
 183 AC_ARG_ENABLE([test-java-agent-log4j],
 184         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 185         [test_java_agent_log4j=$enableval],
 186         [test_java_agent_log4j=no]
 187 )
 188
 189 AC_ARG_ENABLE([test-java-agent-all],
 190         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 191         [test_java_agent_jul=$enableval
 192          test_java_agent_log4j=$enableval],
 193         [:]
 194 )
 195
 196 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 197 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 198 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 199 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 200 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 201 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 202 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 203 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 204
 205 if test "x$prefix" = "xNONE"; then
 206         prefix=$ac_default_prefix
 207 fi
 208 CONFDIR=`eval echo $sysconfdir`
 209 AC_SUBST(CONFDIR)
 210 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 211
 212 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 213
 214 #
 215 # Check for pthread
 216 AC_CHECK_LIB([pthread], [pthread_create], [],
 217         [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
 218 )
 219
 220 # Check libpopt
 221 PKG_CHECK_MODULES([POPT], [popt],
 222         [LIBS="$LIBS $POPT_LIBS"],
 223         [AC_MSG_ERROR([Cannot find libpopt. Use [LDFLAGS]=-Ldir to specify its location.])]
 224 )
 225
 226 AM_PATH_XML2(2.7.6, true, AC_MSG_ERROR(No supported version of libxml2 found.))
 227
 228 # Check for libuuid
 229 PKG_CHECK_MODULES([UUID], [uuid],
 230 [
 231         LIBS="$LIBS $UUID_LIBS"
 232         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 233         have_libuuid=yes
 234 ],
 235 [
 236         # libuuid not found, check for uuid_create in libc.
 237         AC_CHECK_LIB([c], [uuid_create],
 238         [
 239                 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 240                 have_libc_uuid=yes
 241         ],
 242         [
 243                 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 244         ])
 245 ]
 246 )
 247 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 248 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 249
 250 # URCU library version needed or newer
 251 liburcu_version=">= 0.8.0"
 252
 253 # Check liburcu needed function calls
 254 AC_CHECK_DECL([cds_list_add], [],
 255         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/list.h>]]
 256 )
 257 AC_CHECK_DECL([cds_wfcq_init], [],
 258         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
 259 )
 260 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 261     [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
 262 )
 263 AC_CHECK_DECL([futex_async], [],
 264         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/futex.h>]]
 265 )
 266 AC_CHECK_DECL([rcu_thread_offline], [],
 267         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 268 )
 269 AC_CHECK_DECL([rcu_thread_online], [],
 270         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 271 )
 272 AC_CHECK_DECL([caa_likely], [],
 273         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 274 )
 275 #Function added in urcu 0.7.0
 276 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 277         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 278 )
 279
 280 # Check kmod library
 281 AC_ARG_WITH(kmod-prefix,
 282   AS_HELP_STRING([--with-kmod-prefix=PATH],
 283                 [Specify the installation prefix of the kmod library.
 284                 Headers must be in PATH/include; libraries in PATH/lib.]),
 285                 [
 286                         CPPFLAGS="$CPPFLAGS -I${withval}/include"
 287                         LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 288                 ])
 289
 290 AC_ARG_ENABLE(kmod,
 291         AS_HELP_STRING([--disable-kmod],[build without kmod support]),
 292         kmod_support=zz$enableval, kmod_support=yes)
 293
 294 AS_IF([test "x$kmod_support" = "xyes"], [
 295         AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 296                 [
 297                         AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
 298                         LIBS="$LIBS -lkmod"
 299                         kmod_found=yes
 300                 ],
 301                 kmod_found=no
 302         )
 303 ])
 304 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
 305
 306 AC_ARG_WITH(lttng-ust-prefix,
 307   AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
 308                  [Specify the installation prefix of the lttng-ust library.
 309                   Headers must be in PATH/include; libraries in PATH/lib.]),
 310                   [
 311                     CPPFLAGS="$CPPFLAGS -I${withval}/include"
 312                     LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 313                   ])
 314
 315 # Check liblttng-ust-ctl library
 316 AC_ARG_WITH(lttng-ust,
 317         AS_HELP_STRING([--without-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 318         lttng_ust_support=$withval, lttng_ust_support=yes)
 319
 320 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 321         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 322                 [
 323                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 324                         lttng_ust_ctl_found=yes
 325                 ],
 326                 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])],
 327                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 328         )
 329 ])
 330 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 331 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 332
 333 # check for dlopen
 334 AC_CHECK_LIB([dl], [dlopen],
 335 [
 336         have_libdl=yes
 337 ],
 338 [
 339         #libdl not found, check for dlopen in libc.
 340         AC_CHECK_LIB([c], [dlopen],
 341         [
 342                 have_libc_dl=yes
 343         ],
 344         [
 345                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 346         ])
 347 ])
 348 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 349 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 350
 351 # Check for fmemopen
 352 AC_CHECK_LIB([c], [fmemopen],
 353 [
 354         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 355 ]
 356 )
 357
 358 # Check for open_memstream
 359 AC_CHECK_LIB([c], [open_memstream],
 360 [
 361         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 362 ]
 363 )
 364
 365 AC_ARG_ENABLE([git-version],
 366               [AC_HELP_STRING([--disable-git-version],
 367                               [Do not use the git version for the build])],
 368               [have_git_version=$enableval], [have_git_version=yes]
 369 )
 370
 371 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 372         [test "x${have_git_version}" = "xyes"])
 373
 374 # For Python
 375 # SWIG version needed or newer:
 376 swig_version=2.0.0
 377
 378 AC_ARG_ENABLE([python-bindings],
 379               [AC_HELP_STRING([--enable-python-bindings],
 380                               [compile Python bindings])],
 381               [enable_python_binding=yes], [enable_python_binding=no])
 382
 383 AM_CONDITIONAL([PYTHON_BINDING], [test "x${enable_python_binding:-yes}" = xyes])
 384
 385 if test "x${enable_python_binding:-yes}" = xyes; then
 386   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 387   AM_PATH_PYTHON([3.0])
 388
 389   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 390   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 391   AS_IF([test -z "$PYTHON_INCLUDE"], [
 392     AS_IF([test -z "$PYTHON_CONFIG"], [
 393       AC_PATH_PROGS([PYTHON_CONFIG],
 394                     [python$PYTHON_VERSION-config python-config],
 395                     [no],
 396                     [`dirname $PYTHON`])
 397       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 398     ])
 399     AC_MSG_CHECKING([python include flags])
 400     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 401     AC_MSG_RESULT([$PYTHON_INCLUDE])
 402   ])
 403
 404 else
 405     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 406 [if you want Python bindings.])
 407
 408 fi
 409
 410 # Epoll check. If not present, the build will fallback on poll() API
 411 AX_HAVE_EPOLL(
 412         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 413         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 414 )
 415 AX_CONFIG_FEATURE(
 416         [epoll], [This platform supports epoll(7)],
 417         [HAVE_EPOLL], [This platform supports epoll(7).],
 418         [enable_epoll="yes"], [enable_epoll="no"]
 419 )
 420 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 421
 422 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 423 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 424
 425 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 426         AX_JAVA_OPTIONS
 427         AX_PROG_JAVAC
 428         AX_PROG_JAVA
 429         AX_PROG_JAR
 430
 431         AX_CHECK_CLASSPATH
 432
 433         # Check for Java UST agent common class first
 434         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 435         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 436                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 437         fi
 438
 439         if test "x$test_java_agent_jul" = "xyes"; then
 440                 # Check for JUL agent class
 441                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 442                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 443                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 444                 fi
 445         fi
 446
 447         if test "x$test_java_agent_log4j" = "xyes"; then
 448                 # Check for Log4j agent class
 449                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 450                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 451                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 452                 fi
 453
 454                 # Check for Log4j class
 455                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 456                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 457                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 458                 fi
 459         fi
 460 fi
 461
 462 # Python agent test
 463 UST_PYTHON_AGENT="lttngust"
 464
 465 AC_ARG_ENABLE(test-python2-agent,
 466         AS_HELP_STRING([--enable-test-python2-agent],
 467                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 468         ),[:],[test_python2_agent_autodetect=yes]
 469 )
 470
 471 AC_ARG_ENABLE(test-python3-agent,
 472         AS_HELP_STRING([--enable-test-python3-agent],
 473                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 474         ),[:],[test_python3_agent_autodetect=yes]
 475 )
 476
 477 AC_ARG_ENABLE(test-python-agent-all,
 478         AS_HELP_STRING([--enable-test-python-agent-all],
 479                 [enable test for all python{2/3} agent.]
 480         ),
 481 )
 482
 483 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 484        unset test_python2_agent_autodetect
 485        unset test_python3_agent_autodetect
 486 ])
 487
 488 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 489        enable_test_python2_agent=yes
 490        enable_test_python3_agent=yes
 491 ])
 492
 493 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 494        enable_test_python2_agent=no
 495        enable_test_python3_agent=no
 496 ])
 497
 498
 499 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 500         AS_IF([test -z "$PYTHON2"], [
 501                         PYTHON2=python2
 502                 ], [
 503                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 504         ])
 505
 506         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 507         AS_IF([test -z "$PYTHON2_BIN"], [
 508                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 509                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 510                 ])
 511         ], [
 512                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 513                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 514                         PYTHON2_AGENT=$PYTHON2_BIN
 515                         AC_MSG_RESULT([yes])
 516                         RUN_PYTHON_AGENT_TEST=yes
 517                 ], [
 518                         AC_MSG_RESULT([no])
 519                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 520                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 521                         ])
 522                 ])
 523
 524         ])
 525
 526 ])
 527
 528 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 529         AS_IF([test -z "$PYTHON3"], [
 530                 PYTHON3=python3
 531         ], [
 532                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 533         ])
 534
 535         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 536         AS_IF([test -z "$PYTHON3_BIN"], [
 537                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 538                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 539                 ])
 540         ], [
 541                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 542                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 543                         PYTHON3_AGENT=$PYTHON3_BIN
 544                         AC_MSG_RESULT([yes])
 545                         RUN_PYTHON_AGENT_TEST=yes
 546                 ], [
 547                         AC_MSG_RESULT([no])
 548                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 549                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 550                         ])
 551                 ])
 552
 553         ])
 554 ])
 555 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 556 AC_SUBST([PYTHON2_AGENT])
 557 AC_SUBST([PYTHON3_AGENT])
 558
 559 # Arguments for binaries build exclusion
 560 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 561 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 562               [Disable the build of lttng-consumerd binaries]))
 563 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 564 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 565               [Disable the build of lttng-relayd binaries]))
 566 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 567               [Disable the build of lttng-sessiond binaries]))
 568 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 569               [Disable the build of the extra components]))
 570
 571
 572 # Always build libconfig since it a dependency of libcommon
 573 build_lib_config=yes
 574
 575 build_lib_compat=no
 576 build_lib_consumer=no
 577 build_lib_hashtable=no
 578 build_lib_health=no
 579 build_lib_index=no
 580 build_lib_kernel_consumer=no
 581 build_lib_kernel_ctl=no
 582 build_lib_lttng_ctl=no
 583 build_lib_relayd=no
 584 build_lib_sessiond_comm=no
 585 build_lib_testpoint=no
 586 build_lib_ust_consumer=no
 587
 588 # There is an overlap for enabled dependencies, but this makes everything
 589 # simpler. libcommon and libconfig are always compiled so they are not repeated
 590 # here.
 591
 592 # Enable binary dependencies.
 593 AS_IF([test x$enable_bin_lttng != xno],
 594       [
 595        build_lib_lttng_ctl=yes
 596       ]
 597 )
 598
 599 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 600       [
 601        build_lib_consumer=yes
 602        build_lib_sessiond_comm=yes
 603        build_lib_index=yes
 604        build_lib_health=yes
 605        build_lib_testpoint=yes
 606       ]
 607 )
 608
 609 AS_IF([test x$enable_bin_lttng_crash != xno],
 610       # Do nothing since libconfig and libcommon are built by default.
 611       []
 612 )
 613
 614 AS_IF([test x$enable_bin_lttng_relayd != xno],
 615       [
 616        build_lib_lttng_ctl=yes
 617        build_lib_sessiond_comm=yes
 618        build_lib_hashtable=yes
 619        build_lib_compat=yes
 620        build_lib_index=yes
 621        build_lib_health=yes
 622        build_lib_testpoint=yes
 623       ]
 624 )
 625 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 626       [
 627        build_lib_lttng_ctl=yes
 628        build_lib_sessiond_comm=yes
 629        build_lib_kernel_ctl=yes
 630        build_lib_hashtable=yes
 631        build_lib_compat=yes
 632        build_lib_relayd=yes
 633        build_lib_testpoint=yes
 634        build_lib_health=yes
 635        build_lib_health=yes
 636       ]
 637 )
 638
 639 # Libraries dependencies enabling
 640 AS_IF([test x$build_lib_lttng_ctl = xyes],
 641       [
 642        build_lib_sessiond_comm=yes
 643        build_lib_hashtable=yes
 644       ]
 645 )
 646
 647 AS_IF([test x$build_lib_consumer = xyes],
 648       [
 649        build_lib_sessiond_comm=yes
 650        build_lib_kernel_consumer=yes
 651        build_lib_hashtable=yes
 652        build_lib_compat=yes
 653        build_lib_relayd=yes
 654        AS_IF([test x$lttng_ust_ctl_found = xyes],[build_lib_ust_consumer=yes])
 655       ]
 656 )
 657
 658 AS_IF([test x$build_lib_kernel_consumer = xyes],
 659       [
 660        build_lib_kernel_ctl=yes
 661        build_lib_relayd=yes
 662       ]
 663 )
 664
 665 AS_IF([test x$build_lib_relayd = xyes],
 666       [
 667        build_lib_sessiond_comm=yes
 668       ]
 669 )
 670
 671
 672 # Export binaries build conditions.
 673 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 674 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 675 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 676 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 677 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 678
 679 # Export the tests and extras build conditions.
 680 AS_IF([\
 681 test "x$enable_bin_lttng" != "xno" && \
 682 test "x$enable_bin_lttng_consumerd" != "xno" && \
 683 test "x$enable_bin_lttng_crash" != "xno" && \
 684 test "x$enable_bin_lttng_relayd" != "xno" && \
 685 test "x$enable_bin_lttng_sessiond" != "xno"],
 686 [build_tests=yes],
 687 [build_tests=no]
 688 )
 689
 690 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 691 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 692
 693 # Export libraries build conditions.
 694 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 695 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 696 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 697 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
 698 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
 699 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
 700 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
 701 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
 702 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
 703 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
 704 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
 705 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
 706 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
 707
 708 # check for pgrep
 709 AC_PATH_PROG([PGREP], [pgrep], [no])
 710 AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"])
 711
 712 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-parser.h"; then
 713         if test x"$(basename "$YACC")" != "xbison -y"; then
 714                 AC_MSG_ERROR([[bison not found and is required when building from git.
 715                 Please install bison]])
 716         fi
 717         AC_PATH_PROG([BISON],[bison])
 718         AX_PROG_BISON_VERSION([2.4], [],[
 719                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
 720         ])
 721 fi
 722
 723 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-lexer.c"; then
 724         if test x"$LEX" != "xflex"; then
 725                 AC_MSG_ERROR([[flex not found and is required when building from git.
 726                 Please install flex]])
 727         fi
 728         AC_PATH_PROG([FLEX],[flex])
 729         AX_PROG_FLEX_VERSION([2.5.35], [],[
 730                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
 731         ])
 732 fi
 733
 734 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 735
 736 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 737
 738 lttngincludedir="${includedir}/lttng"
 739
 740 AC_SUBST(lttngincludedir)
 741 AC_SUBST(DEFAULT_INCLUDES)
 742
 743 lttnglibexecdir="${libdir}/lttng/libexec"
 744 AC_SUBST(lttnglibexecdir)
 745
 746 AC_CONFIG_FILES([
 747         Makefile
 748         doc/Makefile
 749         doc/man/Makefile
 750         include/Makefile
 751         extras/Makefile
 752         extras/bindings/Makefile
 753         extras/bindings/swig/Makefile
 754         extras/bindings/swig/python/Makefile
 755         extras/core-handler/Makefile
 756         src/Makefile
 757         src/common/Makefile
 758         src/common/kernel-ctl/Makefile
 759         src/common/kernel-consumer/Makefile
 760         src/common/consumer/Makefile
 761         src/common/ust-consumer/Makefile
 762         src/common/hashtable/Makefile
 763         src/common/sessiond-comm/Makefile
 764         src/common/compat/Makefile
 765         src/common/relayd/Makefile
 766         src/common/testpoint/Makefile
 767         src/common/index/Makefile
 768         src/common/health/Makefile
 769         src/common/config/Makefile
 770         src/lib/Makefile
 771         src/lib/lttng-ctl/Makefile
 772         src/lib/lttng-ctl/filter/Makefile
 773         src/lib/lttng-ctl/lttng-ctl.pc
 774         src/bin/Makefile
 775         src/bin/lttng-consumerd/Makefile
 776         src/bin/lttng-sessiond/Makefile
 777         src/bin/lttng-relayd/Makefile
 778         src/bin/lttng/Makefile
 779         src/bin/lttng-crash/Makefile
 780         tests/Makefile
 781         tests/regression/Makefile
 782         tests/regression/kernel/Makefile
 783         tests/regression/tools/Makefile
 784         tests/regression/tools/streaming/Makefile
 785         tests/regression/tools/filtering/Makefile
 786         tests/regression/tools/health/Makefile
 787         tests/regression/tools/tracefile-limits/Makefile
 788         tests/regression/tools/snapshots/Makefile
 789         tests/regression/tools/live/Makefile
 790         tests/regression/tools/exclusion/Makefile
 791         tests/regression/tools/save-load/Makefile
 792         tests/regression/tools/mi/Makefile
 793         tests/regression/tools/wildcard/Makefile
 794         tests/regression/tools/crash/Makefile
 795         tests/regression/ust/Makefile
 796         tests/regression/ust/nprocesses/Makefile
 797         tests/regression/ust/high-throughput/Makefile
 798         tests/regression/ust/low-throughput/Makefile
 799         tests/regression/ust/before-after/Makefile
 800         tests/regression/ust/buffers-pid/Makefile
 801         tests/regression/ust/periodical-metadata-flush/Makefile
 802         tests/regression/ust/multi-session/Makefile
 803         tests/regression/ust/overlap/Makefile
 804         tests/regression/ust/overlap/demo/Makefile
 805         tests/regression/ust/linking/Makefile
 806         tests/regression/ust/daemon/Makefile
 807         tests/regression/ust/exit-fast/Makefile
 808         tests/regression/ust/fork/Makefile
 809         tests/regression/ust/libc-wrapper/Makefile
 810         tests/regression/ust/baddr-statedump/Makefile
 811         tests/regression/ust/ust-dl/Makefile
 812         tests/regression/ust/java-jul/Makefile
 813         tests/regression/ust/java-log4j/Makefile
 814         tests/regression/ust/python-logging/Makefile
 815         tests/regression/ust/getcpu-override/Makefile
 816         tests/regression/ust/clock-override/Makefile
 817         tests/stress/Makefile
 818         tests/unit/Makefile
 819         tests/unit/ini_config/Makefile
 820         tests/utils/Makefile
 821         tests/utils/tap/Makefile
 822         tests/utils/testapp/Makefile
 823         tests/utils/testapp/gen-ust-events/Makefile
 824         tests/utils/testapp/gen-ust-nevents/Makefile
 825         tests/utils/testapp/gen-ust-tracef/Makefile
 826 ])
 827
 828 # Inject variable into python test script.
 829 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
 830
 831 AC_OUTPUT
 832
 833 #
 834 # Mini-report on what will be built.
 835 #
 836 AS_ECHO()
 837
 838 AS_ECHO("Version name: $version_name")
 839 AS_ECHO("$version_description")
 840
 841 AS_ECHO()
 842
 843 # Target architecture we're building for.
 844 target_arch=$host_cpu
 845 [
 846 for f in $CFLAGS; do
 847         if test $f = "-m32"; then
 848                         target_arch="32-bit"
 849         elif test $f = "-m64"; then
 850                         target_arch="64-bit"
 851         fi
 852 done
 853 ]
 854 AS_ECHO_N("Target architecture: ")
 855 AS_ECHO($target_arch)
 856
 857 # kmod enabled/disabled
 858 AS_ECHO_N("libkmod support: ")
 859 AS_IF([test "x$kmod_found" = "xyes"],[
 860         AS_ECHO("Enabled")
 861 ],[
 862         AS_ECHO("Disabled")
 863 ])
 864
 865 # LTTng-UST enabled/disabled
 866 AS_ECHO_N("Lttng-UST support: ")
 867 AS_IF([test "x$lttng_ust_support" = "xyes"],[
 868         AS_ECHO("Enabled")
 869 ],[
 870         AS_ECHO("Disabled")
 871 ])
 872
 873 AS_ECHO()
 874 AS_ECHO("Binaries:")
 875
 876 # List binaries to be built
 877 AS_ECHO_N("lttng: ")
 878 AS_IF([test x$enable_bin_lttng != xno],[
 879        AS_ECHO("Enabled")
 880 ],[
 881        AS_ECHO("Disabled")
 882 ])
 883
 884 AS_ECHO_N("lttng-consumerd: ")
 885 AS_IF([test x$enable_bin_lttng_consumerd != xno],[
 886        AS_ECHO("Enabled")
 887 ],[
 888        AS_ECHO("Disabled")
 889 ])
 890
 891 AS_ECHO_N("lttng-crash: ")
 892 AS_IF([test x$enable_bin_lttng_crash != xno],[
 893        AS_ECHO("Enabled")
 894 ],[
 895        AS_ECHO("Disabled")
 896 ])
 897
 898 AS_ECHO_N("lttng-relayd: ")
 899 AS_IF([test x$enable_bin_lttng_relayd != xno],[
 900        AS_ECHO("Enabled")
 901 ],[
 902        AS_ECHO("Disabled")
 903 ])
 904
 905 AS_ECHO_N("lttng-sessiond: ")
 906 AS_IF([test x$enable_bin_lttng_sessiond != xno],[
 907        AS_ECHO("Enabled")
 908 ],[
 909        AS_ECHO("Disabled")
 910 ])
 911
 912 AS_ECHO_N("Extras: ")
 913 AS_IF([test x$enable_extras != xno],[
 914        AS_ECHO("Enabled")
 915 ],[
 916        AS_ECHO("Disabled")
 917 ])
 918
 919 # Print the bindir and libdir this `make install' will install into.
 920 AS_ECHO()
 921 AS_ECHO_N("Binaries will be installed in:  ")
 922 AS_ECHO("`eval eval echo $bindir`")
 923 AS_ECHO_N("Libraries will be installed in: ")
 924 AS_ECHO("`eval eval echo $libdir`")
 925
 926
 927 AS_ECHO()
 928
 929 # Print clear message that tests won't be built
 930 AS_IF([test "x$build_tests" = "xno"],[
 931        AS_ECHO("WARNING: Tests won't be built since some binaries were disabled")
 932 ])
 933
 934 AS_ECHO("Tests:")
 935
 936 # LTTng UST Java agent JUL tests enabled/disabled
 937 AS_ECHO_N("LTTng-UST Java agent JUL tests: ")
 938 AS_IF([test "x$test_java_agent_jul" = "xyes"],[
 939         AS_ECHO("Enabled")
 940 ],[
 941         AS_ECHO("Disabled")
 942 ])
 943
 944 # LTTng UST Java agent Log4j tests enabled/disabled
 945 AS_ECHO_N("LTTng-UST Java agent Log4j tests: ")
 946 AS_IF([test "x$test_java_agent_log4j" = "xyes"],[
 947         AS_ECHO("Enabled")
 948 ],[
 949         AS_ECHO("Disabled")
 950 ])
 951
 952 AS_ECHO_N("LTTng-UST Python2 agent tests: ")
 953 AS_IF([test ! -z "$PYTHON2_AGENT"],[
 954         AS_ECHO("Enabled")
 955 ],[
 956         AS_ECHO("Disabled")
 957 ])
 958
 959 AS_ECHO_N("LTTng-UST Python3 agent tests: ")
 960 AS_IF([test ! -z "$PYTHON3_AGENT"],[
 961         AS_ECHO("Enabled")
 962 ],[
 963         AS_ECHO("Disabled")
 964 ])
 965
 966 #Python binding enabled/disabled
 967 AS_ECHO_N("Python binding: ")
 968 AS_IF([test "x${enable_python_binding:-yes}" = xyes], [
 969         AS_ECHO("Enabled")
 970 ],[
 971         AS_ECHO("Disabled")
 972 ])
 973
 974 # If we build the sessiond, print the paths it will use
 975 AS_ECHO()
 976 AS_ECHO_N("The lttng command will search for the lttng-sessiond executable at: ")
 977 AS_IF([test "$SESSIOND_BIN" = ""],[
 978         AS_ECHO_N("`eval eval echo $bindir`")
 979         AS_ECHO("/lttng-sessiond")
 980 ],[
 981         AS_ECHO("$SESSIOND_BIN")
 982 ])
 983
 984 AS_ECHO()
 985 AS_ECHO("The sessiond daemon will search the following directories: ")
 986 AS_ECHO_N("32-bit consumerd executable: ")
 987 AS_IF([test "$CONSUMERD32_BIN" = ""],[
 988         AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 989         AS_ECHO("/lttng-consumerd")
 990 ],[
 991         AS_ECHO("$CONSUMERD32_BIN")
 992 ])
 993
 994 AS_ECHO_N("32-bit consumer libraries:   ")
 995 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
 996         AS_ECHO("`eval eval echo $libdir`")
 997 ],[
 998         AS_ECHO("$CONSUMERD32_LIBDIR")
 999 ])
1000
1001 AS_ECHO_N("64-bit consumerd executable: ")
1002 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1003         AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
1004         AS_ECHO("/lttng-consumerd")
1005 ],[
1006         AS_ECHO("$CONSUMERD64_BIN")
1007 ])
1008
1009 AS_ECHO_N("64-bit consumer libraries:   ")
1010 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1011         AS_ECHO("`eval eval echo $libdir`")
1012 ],[
1013         AS_ECHO("$CONSUMERD64_LIBDIR")
1014 ])
1015
1016 AS_ECHO()
1017