configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.8.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 # Checks for C compiler
  18 AC_USE_SYSTEM_EXTENSIONS
  19 AC_SYS_LARGEFILE
  20 AC_PROG_CC
  21 AC_PROG_CC_STDC
  22
  23 # Checks for programs.
  24 AC_PROG_GREP
  25 AC_PROG_LEX
  26 AC_PROG_MAKE_SET
  27 AC_PROG_SED
  28 AC_PROG_YACC
  29 LT_INIT
  30
  31 # Checks for typedefs, structures, and compiler characteristics.
  32 AC_C_INLINE
  33 AC_TYPE_INT32_T
  34 AC_TYPE_INT64_T
  35 AC_TYPE_MODE_T
  36 AC_TYPE_OFF_T
  37 AC_TYPE_PID_T
  38 AC_TYPE_SIZE_T
  39 AC_TYPE_SSIZE_T
  40 AC_TYPE_UID_T
  41 AC_TYPE_UINT16_T
  42 AC_TYPE_UINT32_T
  43 AC_TYPE_UINT64_T
  44 AC_TYPE_UINT8_T
  45
  46 AX_C___ATTRIBUTE__
  47 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  48         [:],
  49         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  50
  51 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  52 LIBS="$PTHREAD_LIBS $LIBS"
  53 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  54 CC="$PTHREAD_CC"
  55
  56 AX_LIB_SOCKET_NSL
  57
  58 # Compute minor/major/patchlevel version numbers
  59 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  60 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  61 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  62 AC_SUBST([MAJOR_VERSION], [$major_version])
  63 AC_SUBST([MINOR_VERSION], [$minor_version])
  64 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  65 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  66 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  67 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  68
  69 version_name="Herbe à Détourne"
  70 version_description='Brewed with unrestrained amounts of Citra hop, the Herbe à Détourne is a fantastic New World Tripel brewed by "Dieu du Ciel!". Aromas of mango, cantaloupe melon and passion fruit, combined with a controlled bitter finish, unite in making this smooth golden-orange beer stand apart.'
  71 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
  72
  73 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  74 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
  75
  76 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  77 AC_ARG_ENABLE(libtool-linkdep-fixup,
  78         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
  79                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
  80         libtool_fixup=$enableval,
  81         libtool_fixup=yes)
  82
  83 AS_IF([test "x$libtool_fixup" = "xyes"],
  84             [
  85             libtool_m4="$srcdir/m4/libtool.m4"
  86             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  87             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  88             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  89             AS_IF([test $libtool_flag_pattern_count -ne 0],
  90             [
  91                   AC_MSG_RESULT([$libtool_flag_pattern_count])
  92                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  93                   SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  94                   ],
  95                   [
  96                   AC_MSG_RESULT([none])
  97                   ])
  98             ])
  99
 100 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 101
 102 AC_CHECK_HEADERS([ \
 103         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 104         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 105         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 106         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 107         sys/mount.h sys/param.h sys/time.h
 108 ])
 109
 110 # Basic functions check
 111 AC_CHECK_FUNCS([ \
 112         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 113         gethostbyname gethostname getpagesize localtime_r memchr memset \
 114         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 115         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 116         strtoull dirfd gethostbyname2 getipnodebyname \
 117 ])
 118
 119 # Babeltrace viewer check
 120 AC_ARG_WITH([babeltrace-bin],
 121         AS_HELP_STRING([--with-babeltrace-bin],
 122         [Location of the babeltrace viewer executable (including the filename)]),
 123         [BABELTRACE_BIN="$withval"],
 124         [BABELTRACE_BIN=''])
 125 AC_SUBST([BABELTRACE_BIN])
 126
 127 # lttv-gui
 128 AC_ARG_WITH([lttv-gui-bin],
 129         AS_HELP_STRING([--with-lttv-gui-bin],
 130    [Location of the lttv GUI viewer executable (including the filename)]),
 131    [LTTV_GUI_BIN="$withval"],
 132    [LTTV_GUI_BIN=''])
 133 AC_SUBST([LTTV_GUI_BIN])
 134
 135 AC_ARG_WITH([consumerd32-bin],
 136         AS_HELP_STRING([--with-consumerd32-bin],
 137         [Location of the 32-bit consumerd executable (including the filename)]),
 138         [CONSUMERD32_BIN="$withval"],
 139         [CONSUMERD32_BIN=''])
 140 AC_SUBST([CONSUMERD32_BIN])
 141
 142 AC_ARG_WITH([consumerd64-bin],
 143         AS_HELP_STRING([--with-consumerd64-bin],
 144         [Location of the 64-bit consumerd executable (including the filename)]),
 145         [CONSUMERD64_BIN="$withval"],
 146         [CONSUMERD64_BIN=''])
 147 AC_SUBST([CONSUMERD64_BIN])
 148
 149 AC_ARG_WITH([consumerd32-libdir],
 150         AS_HELP_STRING([--with-consumerd32-libdir],
 151         [Directory containing the 32-bit consumerd libraries]),
 152         [CONSUMERD32_LIBDIR="$withval"],
 153         [CONSUMERD32_LIBDIR=''])
 154 AC_SUBST([CONSUMERD32_LIBDIR])
 155
 156 AC_ARG_WITH([consumerd64-libdir],
 157         AS_HELP_STRING([--with-consumerd64-libdir],
 158         [Directory containing the 64-bit consumerd libraries]),
 159         [CONSUMERD64_LIBDIR="$withval"],
 160         [CONSUMERD64_LIBDIR=''])
 161 AC_SUBST([CONSUMERD64_LIBDIR])
 162
 163 AC_ARG_WITH([sessiond-bin],
 164         AS_HELP_STRING([--with-sessiond-bin],
 165         [Location of the sessiond executable (including the filename)]),
 166         [SESSIOND_BIN="$withval"],
 167         [SESSIOND_BIN=''])
 168 AC_SUBST([SESSIOND_BIN])
 169
 170 AC_ARG_WITH([lttng-system-rundir],
 171         AS_HELP_STRING([--with-lttng-system-rundir],
 172         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 173         [LTTNG_SYSTEM_RUNDIR="$withval"],
 174         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 175 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 176
 177 AC_ARG_ENABLE([test-java-agent-jul],
 178         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 179         [test_java_agent_jul=$enableval],
 180         [test_java_agent_jul=no]
 181 )
 182
 183 AC_ARG_ENABLE([test-java-agent-log4j],
 184         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 185         [test_java_agent_log4j=$enableval],
 186         [test_java_agent_log4j=no]
 187 )
 188
 189 AC_ARG_ENABLE([test-java-agent-all],
 190         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 191         [test_java_agent_jul=$enableval
 192          test_java_agent_log4j=$enableval],
 193         [:]
 194 )
 195
 196 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 197 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 198 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 199 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 200 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 201 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 202 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 203 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 204
 205 if test "x$prefix" = "xNONE"; then
 206         prefix=$ac_default_prefix
 207 fi
 208 CONFDIR=`eval echo $sysconfdir`
 209 AC_SUBST(CONFDIR)
 210 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 211
 212 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 213
 214 #
 215 # Check for pthread
 216 AC_CHECK_LIB([pthread], [pthread_create], [],
 217         [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
 218 )
 219
 220 # Check libpopt
 221 AC_CHECK_LIB([popt], [poptGetContext], [],
 222         [AC_MSG_ERROR([Cannot find libpopt. Use [LDFLAGS]=-Ldir to specify its location.])]
 223 )
 224
 225 AM_PATH_XML2(2.7.6, true, AC_MSG_ERROR(No supported version of libxml2 found.))
 226
 227 # Check for libuuid
 228 AC_CHECK_LIB([uuid], [uuid_generate],
 229 [
 230         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 231         have_libuuid=yes
 232 ],
 233 [
 234         # libuuid not found, check for uuid_create in libc.
 235         AC_CHECK_LIB([c], [uuid_create],
 236         [
 237                 AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 238                 have_libc_uuid=yes
 239         ],
 240         [
 241                 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
 242         ])
 243 ]
 244 )
 245 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
 246 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
 247
 248 # URCU library version needed or newer
 249 liburcu_version=">= 0.8.0"
 250
 251 # Check liburcu needed function calls
 252 AC_CHECK_DECL([cds_list_add], [],
 253         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/list.h>]]
 254 )
 255 AC_CHECK_DECL([cds_wfcq_init], [],
 256         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
 257 )
 258 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 259     [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfcqueue.h>]]
 260 )
 261 AC_CHECK_DECL([futex_async], [],
 262         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/futex.h>]]
 263 )
 264 AC_CHECK_DECL([rcu_thread_offline], [],
 265         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 266 )
 267 AC_CHECK_DECL([rcu_thread_online], [],
 268         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 269 )
 270 AC_CHECK_DECL([caa_likely], [],
 271         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 272 )
 273 #Function added in urcu 0.7.0
 274 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 275         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 276 )
 277
 278 # Check kmod library
 279 AC_ARG_WITH(kmod-prefix,
 280   AS_HELP_STRING([--with-kmod-prefix=PATH],
 281                 [Specify the installation prefix of the kmod library.
 282                 Headers must be in PATH/include; libraries in PATH/lib.]),
 283                 [
 284                         CPPFLAGS="$CPPFLAGS -I${withval}/include"
 285                         LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 286                 ])
 287
 288 AC_ARG_ENABLE(kmod,
 289         AS_HELP_STRING([--disable-kmod],[build without kmod support]),
 290         kmod_support=zz$enableval, kmod_support=yes)
 291
 292 AS_IF([test "x$kmod_support" = "xyes"], [
 293         AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 294                 [
 295                         AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
 296                         LIBS="$LIBS -lkmod"
 297                         kmod_found=yes
 298                 ],
 299                 kmod_found=no
 300         )
 301 ])
 302 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
 303
 304 AC_ARG_WITH(lttng-ust-prefix,
 305   AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
 306                  [Specify the installation prefix of the lttng-ust library.
 307                   Headers must be in PATH/include; libraries in PATH/lib.]),
 308                   [
 309                     CPPFLAGS="$CPPFLAGS -I${withval}/include"
 310                     LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 311                   ])
 312
 313 # Check liblttng-ust-ctl library
 314 AC_ARG_WITH(lttng-ust,
 315         AS_HELP_STRING([--without-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 316         lttng_ust_support=$enableval, lttng_ust_support=yes)
 317
 318 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 319         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 320                 [
 321                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 322                         lttng_ust_ctl_found=yes
 323                 ],
 324                 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])],
 325                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 326         )
 327 ])
 328 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 329 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 330
 331 # check for dlopen
 332 AC_CHECK_LIB([dl], [dlopen],
 333 [
 334         have_libdl=yes
 335 ],
 336 [
 337         #libdl not found, check for dlopen in libc.
 338         AC_CHECK_LIB([c], [dlopen],
 339         [
 340                 have_libc_dl=yes
 341         ],
 342         [
 343                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 344         ])
 345 ])
 346 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 347 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 348
 349 # Check for fmemopen
 350 AC_CHECK_LIB([c], [fmemopen],
 351 [
 352         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 353 ]
 354 )
 355
 356 # Check for open_memstream
 357 AC_CHECK_LIB([c], [open_memstream],
 358 [
 359         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 360 ]
 361 )
 362
 363 AC_ARG_ENABLE([git-version],
 364               [AC_HELP_STRING([--disable-git-version],
 365                               [Do not use the git version for the build])],
 366               [have_git_version=$enableval], [have_git_version=yes]
 367 )
 368
 369 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 370         [test "x${have_git_version}" = "xyes"])
 371
 372 # For Python
 373 # SWIG version needed or newer:
 374 swig_version=2.0.0
 375
 376 AC_ARG_ENABLE([python-bindings],
 377               [AC_HELP_STRING([--enable-python-bindings],
 378                               [compile Python bindings])],
 379               [enable_python_binding=yes], [enable_python_binding=no])
 380
 381 AM_CONDITIONAL([PYTHON_BINDING], [test "x${enable_python_binding:-yes}" = xyes])
 382
 383 if test "x${enable_python_binding:-yes}" = xyes; then
 384   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 385   AM_PATH_PYTHON([3.0])
 386
 387   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 388   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 389   AS_IF([test -z "$PYTHON_INCLUDE"], [
 390     AS_IF([test -z "$PYTHON_CONFIG"], [
 391       AC_PATH_PROGS([PYTHON_CONFIG],
 392                     [python$PYTHON_VERSION-config python-config],
 393                     [no],
 394                     [`dirname $PYTHON`])
 395       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 396     ])
 397     AC_MSG_CHECKING([python include flags])
 398     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 399     AC_MSG_RESULT([$PYTHON_INCLUDE])
 400   ])
 401
 402 else
 403     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 404 [if you want Python bindings.])
 405
 406 fi
 407
 408 # Epoll check. If not present, the build will fallback on poll() API
 409 AX_HAVE_EPOLL(
 410         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 411         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 412 )
 413 AX_CONFIG_FEATURE(
 414         [epoll], [This platform supports epoll(7)],
 415         [HAVE_EPOLL], [This platform supports epoll(7).],
 416         [enable_epoll="yes"], [enable_epoll="no"]
 417 )
 418 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 419
 420 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 421 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 422
 423 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 424         AX_JAVA_OPTIONS
 425         AX_PROG_JAVAC
 426         AX_PROG_JAVA
 427         AX_PROG_JAR
 428
 429         AX_CHECK_CLASSPATH
 430
 431         # Check for Java UST agent common class first
 432         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 433         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 434                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 435         fi
 436
 437         if test "x$test_java_agent_jul" = "xyes"; then
 438                 # Check for JUL agent class
 439                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 440                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 441                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 442                 fi
 443         fi
 444
 445         if test "x$test_java_agent_log4j" = "xyes"; then
 446                 # Check for Log4j agent class
 447                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 448                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 449                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 450                 fi
 451
 452                 # Check for Log4j class
 453                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 454                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 455                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 456                 fi
 457         fi
 458 fi
 459
 460 # Python agent test
 461 UST_PYTHON_AGENT="lttngust"
 462
 463 AC_ARG_ENABLE(test-python2-agent,
 464         AS_HELP_STRING([--enable-test-python2-agent],
 465                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 466         ),[:],[test_python2_agent_autodetect=yes]
 467 )
 468
 469 AC_ARG_ENABLE(test-python3-agent,
 470         AS_HELP_STRING([--enable-test-python3-agent],
 471                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 472         ),[:],[test_python3_agent_autodetect=yes]
 473 )
 474
 475 AC_ARG_ENABLE(test-python-agent-all,
 476         AS_HELP_STRING([--enable-test-python-agent-all],
 477                 [enable test for all python{2/3} agent.]
 478         ),
 479 )
 480
 481 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 482        unset test_python2_agent_autodetect
 483        unset test_python3_agent_autodetect
 484 ])
 485
 486 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 487        enable_test_python2_agent=yes
 488        enable_test_python3_agent=yes
 489 ])
 490
 491 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 492        enable_test_python2_agent=no
 493        enable_test_python3_agent=no
 494 ])
 495
 496
 497 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 498         AS_IF([test -z "$PYTHON2"], [
 499                         PYTHON2=python2
 500                 ], [
 501                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 502         ])
 503
 504         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 505         AS_IF([test -z "$PYTHON2_BIN"], [
 506                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 507                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 508                 ])
 509         ], [
 510                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 511                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 512                         PYTHON2_AGENT=$PYTHON2_BIN
 513                         AC_MSG_RESULT([yes])
 514                         RUN_PYTHON_AGENT_TEST=yes
 515                 ], [
 516                         AC_MSG_RESULT([no])
 517                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 518                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 519                         ])
 520                 ])
 521
 522         ])
 523
 524 ])
 525
 526 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 527         AS_IF([test -z "$PYTHON3"], [
 528                 PYTHON3=python3
 529         ], [
 530                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 531         ])
 532
 533         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 534         AS_IF([test -z "$PYTHON3_BIN"], [
 535                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 536                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 537                 ])
 538         ], [
 539                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 540                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 541                         PYTHON3_AGENT=$PYTHON3_BIN
 542                         AC_MSG_RESULT([yes])
 543                         RUN_PYTHON_AGENT_TEST=yes
 544                 ], [
 545                         AC_MSG_RESULT([no])
 546                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 547                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 548                         ])
 549                 ])
 550
 551         ])
 552 ])
 553 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 554 AC_SUBST([PYTHON2_AGENT])
 555 AC_SUBST([PYTHON3_AGENT])
 556
 557 # Arguments for binaries build exclusion
 558 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 559 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 560               [Disable the build of lttng-consumerd binaries]))
 561 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 562 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 563               [Disable the build of lttng-relayd binaries]))
 564 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 565               [Disable the build of lttng-sessiond binaries]))
 566 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 567               [Disable the build of the extra components]))
 568
 569
 570 # Always build libconfig since it a dependency of libcommon
 571 build_lib_config=yes
 572
 573 build_lib_compat=no
 574 build_lib_consumer=no
 575 build_lib_hashtable=no
 576 build_lib_health=no
 577 build_lib_index=no
 578 build_lib_kernel_consumer=no
 579 build_lib_kernel_ctl=no
 580 build_lib_lttng_ctl=no
 581 build_lib_relayd=no
 582 build_lib_sessiond_comm=no
 583 build_lib_testpoint=no
 584 build_lib_ust_consumer=no
 585
 586 # There is an overlap for enabled dependencies, but this makes everything
 587 # simpler. libcommon and libconfig are always compiled so they are not repeated
 588 # here.
 589
 590 # Enable binary dependencies.
 591 AS_IF([test x$enable_bin_lttng != xno],
 592       [
 593        build_lib_lttng_ctl=yes
 594       ]
 595 )
 596
 597 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 598       [
 599        build_lib_consumer=yes
 600        build_lib_sessiond_comm=yes
 601        build_lib_index=yes
 602        build_lib_health=yes
 603        build_lib_testpoint=yes
 604       ]
 605 )
 606
 607 AS_IF([test x$enable_bin_lttng_crash != xno],
 608       # Do nothing since libconfig and libcommon are built by default.
 609       []
 610 )
 611
 612 AS_IF([test x$enable_bin_lttng_relayd != xno],
 613       [
 614        build_lib_lttng_ctl=yes
 615        build_lib_sessiond_comm=yes
 616        build_lib_hashtable=yes
 617        build_lib_compat=yes
 618        build_lib_index=yes
 619        build_lib_health=yes
 620        build_lib_testpoint=yes
 621       ]
 622 )
 623 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 624       [
 625        build_lib_lttng_ctl=yes
 626        build_lib_sessiond_comm=yes
 627        build_lib_kernel_ctl=yes
 628        build_lib_hashtable=yes
 629        build_lib_compat=yes
 630        build_lib_relayd=yes
 631        build_lib_testpoint=yes
 632        build_lib_health=yes
 633        build_lib_health=yes
 634       ]
 635 )
 636
 637 # Libraries dependencies enabling
 638 AS_IF([test x$build_lib_lttng_ctl = xyes],
 639       [
 640        build_lib_sessiond_comm=yes
 641        build_lib_hashtable=yes
 642       ]
 643 )
 644
 645 AS_IF([test x$build_lib_consumer = xyes],
 646       [
 647        build_lib_sessiond_comm=yes
 648        build_lib_kernel_consumer=yes
 649        build_lib_hashtable=yes
 650        build_lib_compat=yes
 651        build_lib_relayd=yes
 652        AS_IF([test x$lttng_ust_ctl_found = xyes],[build_lib_ust_consumer=yes])
 653       ]
 654 )
 655
 656 AS_IF([test x$build_lib_kernel_consumer = xyes],
 657       [
 658        build_lib_kernel_ctl=yes
 659        build_lib_relayd=yes
 660       ]
 661 )
 662
 663 AS_IF([test x$build_lib_relayd = xyes],
 664       [
 665        build_lib_sessiond_comm=yes
 666       ]
 667 )
 668
 669
 670 # Export binaries build conditions.
 671 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 672 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 673 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 674 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 675 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 676
 677 # Export the tests and extras build conditions.
 678 AS_IF([\
 679 test "x$enable_bin_lttng" != "xno" && \
 680 test "x$enable_bin_lttng_consumerd" != "xno" && \
 681 test "x$enable_bin_lttng_crash" != "xno" && \
 682 test "x$enable_bin_lttng_relayd" != "xno" && \
 683 test "x$enable_bin_lttng_sessiond" != "xno"],
 684 [build_tests=yes],
 685 [build_tests=no]
 686 )
 687
 688 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 689 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 690
 691 # Export libraries build conditions.
 692 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 693 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 694 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 695 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
 696 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
 697 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
 698 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
 699 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
 700 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
 701 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
 702 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
 703 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
 704 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
 705
 706 # check for pgrep
 707 AC_PATH_PROG([PGREP], [pgrep], [no])
 708 AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"])
 709
 710 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-parser.h"; then
 711         if test x"$(basename "$YACC")" != "xbison -y"; then
 712                 AC_MSG_ERROR([[bison not found and is required when building from git.
 713                 Please install bison]])
 714         fi
 715         AC_PATH_PROG([BISON],[bison])
 716         AX_PROG_BISON_VERSION([2.4], [],[
 717                 AC_MSG_ERROR([[Bison >= 2.4 is required when building from git]])
 718         ])
 719 fi
 720
 721 if test ! -f "$srcdir/src/lib/lttng-ctl/filter/filter-lexer.c"; then
 722         if test x"$LEX" != "xflex"; then
 723                 AC_MSG_ERROR([[flex not found and is required when building from git.
 724                 Please install flex]])
 725         fi
 726         AC_PATH_PROG([FLEX],[flex])
 727         AX_PROG_FLEX_VERSION([2.5.35], [],[
 728                 AC_MSG_ERROR([[Flex >= 2.5.35 is required when building from git]])
 729         ])
 730 fi
 731
 732 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 733
 734 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 735
 736 lttngincludedir="${includedir}/lttng"
 737
 738 AC_SUBST(lttngincludedir)
 739 AC_SUBST(DEFAULT_INCLUDES)
 740
 741 lttnglibexecdir="${libdir}/lttng/libexec"
 742 AC_SUBST(lttnglibexecdir)
 743
 744 AC_CONFIG_FILES([
 745         Makefile
 746         doc/Makefile
 747         doc/man/Makefile
 748         include/Makefile
 749         extras/Makefile
 750         extras/bindings/Makefile
 751         extras/bindings/swig/Makefile
 752         extras/bindings/swig/python/Makefile
 753         extras/core-handler/Makefile
 754         src/Makefile
 755         src/common/Makefile
 756         src/common/kernel-ctl/Makefile
 757         src/common/kernel-consumer/Makefile
 758         src/common/consumer/Makefile
 759         src/common/ust-consumer/Makefile
 760         src/common/hashtable/Makefile
 761         src/common/sessiond-comm/Makefile
 762         src/common/compat/Makefile
 763         src/common/relayd/Makefile
 764         src/common/testpoint/Makefile
 765         src/common/index/Makefile
 766         src/common/health/Makefile
 767         src/common/config/Makefile
 768         src/lib/Makefile
 769         src/lib/lttng-ctl/Makefile
 770         src/lib/lttng-ctl/filter/Makefile
 771         src/lib/lttng-ctl/lttng-ctl.pc
 772         src/bin/Makefile
 773         src/bin/lttng-consumerd/Makefile
 774         src/bin/lttng-sessiond/Makefile
 775         src/bin/lttng-relayd/Makefile
 776         src/bin/lttng/Makefile
 777         src/bin/lttng-crash/Makefile
 778         tests/Makefile
 779         tests/regression/Makefile
 780         tests/regression/kernel/Makefile
 781         tests/regression/tools/Makefile
 782         tests/regression/tools/streaming/Makefile
 783         tests/regression/tools/filtering/Makefile
 784         tests/regression/tools/health/Makefile
 785         tests/regression/tools/tracefile-limits/Makefile
 786         tests/regression/tools/snapshots/Makefile
 787         tests/regression/tools/live/Makefile
 788         tests/regression/tools/exclusion/Makefile
 789         tests/regression/tools/save-load/Makefile
 790         tests/regression/tools/mi/Makefile
 791         tests/regression/tools/wildcard/Makefile
 792         tests/regression/tools/crash/Makefile
 793         tests/regression/ust/Makefile
 794         tests/regression/ust/nprocesses/Makefile
 795         tests/regression/ust/high-throughput/Makefile
 796         tests/regression/ust/low-throughput/Makefile
 797         tests/regression/ust/before-after/Makefile
 798         tests/regression/ust/buffers-pid/Makefile
 799         tests/regression/ust/periodical-metadata-flush/Makefile
 800         tests/regression/ust/multi-session/Makefile
 801         tests/regression/ust/overlap/Makefile
 802         tests/regression/ust/overlap/demo/Makefile
 803         tests/regression/ust/linking/Makefile
 804         tests/regression/ust/daemon/Makefile
 805         tests/regression/ust/exit-fast/Makefile
 806         tests/regression/ust/fork/Makefile
 807         tests/regression/ust/libc-wrapper/Makefile
 808         tests/regression/ust/baddr-statedump/Makefile
 809         tests/regression/ust/java-jul/Makefile
 810         tests/regression/ust/java-log4j/Makefile
 811         tests/regression/ust/python-logging/Makefile
 812         tests/regression/ust/getcpu-override/Makefile
 813         tests/regression/ust/clock-override/Makefile
 814         tests/stress/Makefile
 815         tests/unit/Makefile
 816         tests/unit/ini_config/Makefile
 817         tests/utils/Makefile
 818         tests/utils/tap/Makefile
 819         tests/utils/testapp/Makefile
 820         tests/utils/testapp/gen-ust-events/Makefile
 821         tests/utils/testapp/gen-ust-nevents/Makefile
 822         tests/utils/testapp/gen-ust-tracef/Makefile
 823 ])
 824
 825 # Inject variable into python test script.
 826 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
 827
 828 AC_OUTPUT
 829
 830 #
 831 # Mini-report on what will be built.
 832 #
 833 AS_ECHO()
 834
 835 AS_ECHO("Version name: $version_name")
 836 AS_ECHO("$version_description")
 837
 838 AS_ECHO()
 839
 840 # Target architecture we're building for.
 841 target_arch=$host_cpu
 842 [
 843 for f in $CFLAGS; do
 844         if test $f = "-m32"; then
 845                         target_arch="32-bit"
 846         elif test $f = "-m64"; then
 847                         target_arch="64-bit"
 848         fi
 849 done
 850 ]
 851 AS_ECHO_N("Target architecture: ")
 852 AS_ECHO($target_arch)
 853
 854 # kmod enabled/disabled
 855 AS_ECHO_N("libkmod support: ")
 856 AS_IF([test "x$kmod_found" = "xyes"],[
 857         AS_ECHO("Enabled")
 858 ],[
 859         AS_ECHO("Disabled")
 860 ])
 861
 862 # LTTng-UST enabled/disabled
 863 AS_ECHO_N("Lttng-UST support: ")
 864 AS_IF([test "x$lttng_ust_support" = "xyes"],[
 865         AS_ECHO("Enabled")
 866 ],[
 867         AS_ECHO("Disabled")
 868 ])
 869
 870 AS_ECHO()
 871 AS_ECHO("Binaries:")
 872
 873 # List binaries to be built
 874 AS_ECHO_N("lttng: ")
 875 AS_IF([test x$enable_bin_lttng != xno],[
 876        AS_ECHO("Enabled")
 877 ],[
 878        AS_ECHO("Disabled")
 879 ])
 880
 881 AS_ECHO_N("lttng-consumerd: ")
 882 AS_IF([test x$enable_bin_lttng_consumerd != xno],[
 883        AS_ECHO("Enabled")
 884 ],[
 885        AS_ECHO("Disabled")
 886 ])
 887
 888 AS_ECHO_N("lttng-crash: ")
 889 AS_IF([test x$enable_bin_lttng_crash != xno],[
 890        AS_ECHO("Enabled")
 891 ],[
 892        AS_ECHO("Disabled")
 893 ])
 894
 895 AS_ECHO_N("lttng-relayd: ")
 896 AS_IF([test x$enable_bin_lttng_relayd != xno],[
 897        AS_ECHO("Enabled")
 898 ],[
 899        AS_ECHO("Disabled")
 900 ])
 901
 902 AS_ECHO_N("lttng-sessiond: ")
 903 AS_IF([test x$enable_bin_lttng_sessiond != xno],[
 904        AS_ECHO("Enabled")
 905 ],[
 906        AS_ECHO("Disabled")
 907 ])
 908
 909 AS_ECHO_N("Extras: ")
 910 AS_IF([test x$enable_extras != xno],[
 911        AS_ECHO("Enabled")
 912 ],[
 913        AS_ECHO("Disabled")
 914 ])
 915
 916 # Print the bindir and libdir this `make install' will install into.
 917 AS_ECHO()
 918 AS_ECHO_N("Binaries will be installed in:  ")
 919 AS_ECHO("`eval eval echo $bindir`")
 920 AS_ECHO_N("Libraries will be installed in: ")
 921 AS_ECHO("`eval eval echo $libdir`")
 922
 923
 924 AS_ECHO()
 925
 926 # Print clear message that tests won't be built
 927 AS_IF([test "x$build_tests" = "xno"],[
 928        AS_ECHO("WARNING: Tests won't be built since some binaries were disabled")
 929 ])
 930
 931 AS_ECHO("Tests:")
 932
 933 # LTTng UST Java agent JUL tests enabled/disabled
 934 AS_ECHO_N("LTTng-UST Java agent JUL tests: ")
 935 AS_IF([test "x$test_java_agent_jul" = "xyes"],[
 936         AS_ECHO("Enabled")
 937 ],[
 938         AS_ECHO("Disabled")
 939 ])
 940
 941 # LTTng UST Java agent Log4j tests enabled/disabled
 942 AS_ECHO_N("LTTng-UST Java agent Log4j tests: ")
 943 AS_IF([test "x$test_java_agent_log4j" = "xyes"],[
 944         AS_ECHO("Enabled")
 945 ],[
 946         AS_ECHO("Disabled")
 947 ])
 948
 949 AS_ECHO_N("LTTng-UST Python2 agent tests: ")
 950 AS_IF([test ! -z "$PYTHON2_AGENT"],[
 951         AS_ECHO("Enabled")
 952 ],[
 953         AS_ECHO("Disabled")
 954 ])
 955
 956 AS_ECHO_N("LTTng-UST Python3 agent tests: ")
 957 AS_IF([test ! -z "$PYTHON3_AGENT"],[
 958         AS_ECHO("Enabled")
 959 ],[
 960         AS_ECHO("Disabled")
 961 ])
 962
 963 #Python binding enabled/disabled
 964 AS_ECHO_N("Python binding: ")
 965 AS_IF([test "x${enable_python_binding:-yes}" = xyes], [
 966         AS_ECHO("Enabled")
 967 ],[
 968         AS_ECHO("Disabled")
 969 ])
 970
 971 # If we build the sessiond, print the paths it will use
 972 AS_ECHO()
 973 AS_ECHO_N("The lttng command will search for the lttng-sessiond executable at: ")
 974 AS_IF([test "$SESSIOND_BIN" = ""],[
 975         AS_ECHO_N("`eval eval echo $bindir`")
 976         AS_ECHO("/lttng-sessiond")
 977 ],[
 978         AS_ECHO("$SESSIOND_BIN")
 979 ])
 980
 981 AS_ECHO()
 982 AS_ECHO("The sessiond daemon will search the following directories: ")
 983 AS_ECHO_N("32-bit consumerd executable: ")
 984 AS_IF([test "$CONSUMERD32_BIN" = ""],[
 985         AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 986         AS_ECHO("/lttng-consumerd")
 987 ],[
 988         AS_ECHO("$CONSUMERD32_BIN")
 989 ])
 990
 991 AS_ECHO_N("32-bit consumer libraries:   ")
 992 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
 993         AS_ECHO("`eval eval echo $libdir`")
 994 ],[
 995         AS_ECHO("$CONSUMERD32_LIBDIR")
 996 ])
 997
 998 AS_ECHO_N("64-bit consumerd executable: ")
 999 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1000         AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
1001         AS_ECHO("/lttng-consumerd")
1002 ],[
1003         AS_ECHO("$CONSUMERD64_BIN")
1004 ])
1005
1006 AS_ECHO_N("64-bit consumer libraries:   ")
1007 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1008         AS_ECHO("`eval eval echo $libdir`")
1009 ],[
1010         AS_ECHO("$CONSUMERD64_LIBDIR")
1011 ])
1012
1013 AS_ECHO()
1014