configure.ac

   1 dnl Version infos
   2 m4_define([V_MAJOR], [2])
   3 m4_define([V_MINOR], [11])
   4 m4_define([V_PATCH], [1])
   5 dnl m4_define([V_EXTRA], [])
   6 m4_define([V_NAME], [[Lafontaine]])
   7 m4_define([V_DESC], [[A modern Saison beer from Montréal's Oshlag microbrewery, Lafontaine is a refreshing, zesty, rice beer with hints of fruit and spices.]])
   8
   9 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
  10 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
  11
  12 AC_PREREQ(2.59)
  13 AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com], [], [https://lttng.org])
  14
  15 dnl Substitute minor/major/patchlevel version numbers
  16 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
  17 AC_SUBST([MINOR_VERSION], [V_MINOR])
  18 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
  19
  20 # Following the numbering scheme proposed by libtool for the library version
  21 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  22 # This is the library version of liblttng-ust.
  23 m4_define([UST_LIB_V_MAJOR], [0])
  24 m4_define([UST_LIB_V_MINOR], [0])
  25 m4_define([UST_LIB_V_PATCH], [0])
  26
  27 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [UST_LIB_V_MAJOR:UST_LIB_V_MINOR:UST_LIB_V_PATCH])
  28 AC_SUBST([LTTNG_UST_LIBRARY_VERSION_MAJOR], [UST_LIB_V_MAJOR])
  29 # note: remember to update tracepoint.h dlopen() to match this version
  30 # number. TODO: eventually automate by exporting the major number.
  31
  32 # This is the library version of liblttng-ust-ctl, used internally by
  33 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  34 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [4:0:0])
  35
  36 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  37 AC_CONFIG_AUX_DIR([config])
  38 AC_CONFIG_MACRO_DIR([m4])
  39 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  40
  41 AC_CANONICAL_TARGET
  42 AC_CANONICAL_HOST
  43
  44 AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
  45 AM_MAINTAINER_MODE([enable])
  46
  47 # Enable silent rules if available (Introduced in AM 1.11)
  48 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  49
  50 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  51
  52 # Checks for C compiler
  53 AC_USE_SYSTEM_EXTENSIONS
  54 AC_SYS_LARGEFILE
  55 AC_PROG_CC
  56 AC_PROG_CC_STDC
  57 AC_PROG_CXX
  58 rw_PROG_CXX_WORKS
  59 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  60
  61 # Check if the compiler support weak symbols
  62 AX_SYS_WEAK_ALIAS
  63
  64 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
  65         AC_MSG_ERROR([Your platform doesn't support weak symbols.])
  66 ])
  67
  68 # Checks for programs.
  69 AC_PROG_SED
  70 AC_PROG_GREP
  71 AC_PROG_LN_S
  72 AC_PROG_MKDIR_P
  73 AC_PROG_MAKE_SET
  74 AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"])
  75 AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"])
  76
  77 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  78 AC_ARG_ENABLE([libtool-linkdep-fixup], [
  79 AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
  80 ], [
  81         libtool_fixup=$enableval
  82 ], [
  83         libtool_fixup=yes
  84 ])
  85
  86 AS_IF([test "x$libtool_fixup" = "xyes"], [
  87         libtool_m4="$srcdir/m4/libtool.m4"
  88         libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  89         AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  90         libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  91
  92         AS_IF([test $libtool_flag_pattern_count -ne 0], [
  93         AC_MSG_RESULT([$libtool_flag_pattern_count])
  94         AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  95                 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  96         ], [
  97                 AC_MSG_RESULT([none])
  98         ])
  99 ])
 100 LT_INIT([disable-static])
 101
 102 AC_MSG_CHECKING([whether shared libraries are enabled])
 103 AS_IF([test "x$enable_shared" = "xyes"], [
 104         AC_MSG_RESULT([yes])
 105 ], [
 106         AC_MSG_RESULT([no])
 107         AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 108 ])
 109
 110 # Checks for typedefs, structures, and compiler characteristics.
 111 AC_C_INLINE
 112 AC_TYPE_INT8_T
 113 AC_TYPE_INT16_T
 114 AC_TYPE_INT32_T
 115 AC_TYPE_INT64_T
 116 AC_TYPE_MODE_T
 117 AC_TYPE_OFF_T
 118 AC_TYPE_PID_T
 119 AC_TYPE_SIZE_T
 120 AC_TYPE_SSIZE_T
 121 AC_TYPE_UID_T
 122 AC_TYPE_UINT8_T
 123 AC_TYPE_UINT16_T
 124 AC_TYPE_UINT32_T
 125 AC_TYPE_UINT64_T
 126 AC_CHECK_TYPES([ptrdiff_t])
 127
 128 AX_C___ATTRIBUTE__
 129 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 130         [:],
 131         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 132
 133 # Checks for library functions.
 134 AC_FUNC_CHOWN
 135 AC_FUNC_FORK
 136 AC_FUNC_MMAP
 137 AC_FUNC_REALLOC
 138 AC_FUNC_STRERROR_R
 139 AC_FUNC_STRNLEN
 140 AC_CHECK_FUNCS([ \
 141         atexit \
 142         clock_gettime \
 143         ftruncate \
 144         getpagesize \
 145         gettimeofday \
 146         localeconv \
 147         memchr \
 148         memmove \
 149         memset \
 150         mkdir \
 151         munmap \
 152         realpath \
 153         sched_getcpu \
 154         socket \
 155         strchr \
 156         strdup \
 157         strerror \
 158         strtol \
 159         sysconf \
 160 ])
 161
 162 # AC_FUNC_MALLOC causes problems when cross-compiling.
 163 #AC_FUNC_MALLOC
 164
 165 # Checks for header files.
 166 AC_HEADER_STDBOOL
 167 AC_CHECK_HEADERS([ \
 168         arpa/inet.h \
 169         fcntl.h \
 170         float.h \
 171         limits.h \
 172         locale.h \
 173         stddef.h \
 174         sys/socket.h \
 175         sys/time.h \
 176         wchar.h \
 177 ])
 178
 179 # Set architecture specific options
 180 AS_CASE([$host_cpu],
 181         [i[[3456]]86], [],
 182         [x86_64], [],
 183         [amd64], [],
 184         [powerpc], [],
 185         [ppc64], [],
 186         [ppc64le], [],
 187         [powerpc64], [],
 188         [powerpc64le], [],
 189         [s390], [NO_UNALIGNED_ACCESS=1],
 190         [s390x], [NO_UNALIGNED_ACCESS=1],
 191         [arm*], [
 192                 NO_UNALIGNED_ACCESS=1
 193                 NO_NUMA=1
 194                 ],
 195         [aarch64*], [NO_UNALIGNED_ACCESS=1],
 196         [mips*], [NO_UNALIGNED_ACCESS=1],
 197         [tile*], [NO_UNALIGNED_ACCESS=1],
 198         [
 199                 UNSUPPORTED_ARCH=1
 200                 NO_UNALIGNED_ACCESS=1
 201         ])
 202
 203 # Configuration options, which will be installed in the config.h
 204 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
 205 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
 206 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
 207
 208 # Checks for libraries.
 209 AC_CHECK_LIB([dl], [dlopen], [
 210         have_libdl=yes
 211         libdl_name=dl
 212 ], [
 213         #libdl not found, check for dlopen in libc.
 214         AC_CHECK_LIB([c], [dlopen], [
 215                 have_libc_dl=yes
 216                 libdl_name=c
 217         ], [
 218                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 219         ])
 220 ])
 221
 222 # Check if libdl has dlmopen support.
 223 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 224 AC_CHECK_LIB([$libdl_name], [dlmopen],
 225         [AC_DEFINE([HAVE_DLMOPEN], [1])]
 226 )
 227
 228 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 229 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 230
 231 AC_CHECK_LIB([pthread], [pthread_create])
 232 AC_CHECK_LIB([pthread], [pthread_setname_np],
 233         AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1], [Define to 1 if pthread_setname_np is available.]),
 234         AC_CHECK_LIB([pthread], [pthread_set_name_np],
 235                 AC_DEFINE([HAVE_PTHREAD_SET_NAME_NP], [1], [Define to 1 if pthread_set_name_np is available.]),
 236                 AC_MSG_RESULT([pthread setname/set_name not found.])))
 237
 238 # Check for dlfcn.h
 239 AC_CHECK_HEADER([dlfcn.h])
 240 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
 241         AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
 242                 #define _GNU_SOURCE /* Required on Linux to get GNU extensions */
 243                 #include <dlfcn.h>
 244         ])
 245 ], [
 246         ac_cv_have_decl_RTLD_DI_LINKMAP="no"
 247 ])
 248
 249 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 250
 251 # URCU
 252
 253 # urcu - check if we just find the headers it out of the box.
 254 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 255 This error can also occur when the liburcu package's configure script has not been run.])])
 256
 257 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 258 # Part of Userspace RCU library 0.7.2 or better.
 259 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 260 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 261
 262 AC_MSG_CHECKING([caa_likely()])
 263 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 264         #include <urcu/compiler.h>
 265         void fct(void)
 266         {
 267                 if (caa_likely(1)) {
 268                 }
 269         }
 270 ]])], [
 271         AC_MSG_RESULT([yes])
 272 ], [
 273         AC_MSG_RESULT([no])
 274         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 275 ])
 276
 277 # urcu - check that URCU lib is available to compilation
 278 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 279
 280 # urcu - check that URCU lib is at least version 0.6
 281 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 282
 283 # numa.h integration
 284 AS_IF([test "x$NO_NUMA" = "x1"],[
 285       AS_IF([test "x$enable_numa" = "x" ], [enable_numa=no])
 286 ])
 287
 288 AC_ARG_ENABLE([numa], [
 289 AS_HELP_STRING([--disable-numa], [disable NUMA support])
 290 ], [
 291         enable_numa=$enableval
 292 ], [
 293         enable_numa=yes
 294 ])
 295
 296 AS_IF([test "x$enable_numa" = "xyes"], [
 297         # numa - check that numa lib is available
 298         AC_CHECK_LIB([numa], [numa_available], [],
 299 [AC_MSG_ERROR([libnuma is not available. Please either install it (e.g. libnuma-dev) or use [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure argument to disable NUMA support.])])
 300         have_libnuma=yes
 301 ])
 302 AM_CONDITIONAL([HAVE_LIBNUMA], [test "x$have_libnuma" = "xyes"])
 303
 304 # optional linux/perf_event.h
 305 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 306
 307 # Perf event counters are supported on all architectures supported by
 308 # perf, using the read system call as fallback.
 309 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
 310
 311 AS_IF([test "x$have_perf_event" = "xyes"], [
 312         AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 313 ])
 314
 315 AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
 316         AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 317 ])
 318
 319 # Check for JNI header files if requested
 320 AC_ARG_ENABLE([jni-interface], [
 321 AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
 322 ], [
 323         jni_interface=$enableval
 324 ], [
 325         jni_interface=no
 326 ])
 327
 328 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 329
 330
 331 AC_ARG_ENABLE([java-agent-jul], [
 332 AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
 333 ], [
 334         java_agent_jul=$enableval
 335 ], [
 336         java_agent_jul=no
 337 ])
 338
 339 AC_ARG_ENABLE([java-agent-log4j], [
 340 AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
 341 ], [
 342         java_agent_log4j=$enableval
 343 ], [
 344         java_agent_log4j=no
 345 ])
 346
 347 AC_ARG_ENABLE([java-agent-all], [
 348 AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
 349 ], [
 350         java_agent_jul=$enableval
 351         java_agent_log4j=$enableval
 352 ], [:])
 353
 354 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 355 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 356 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 357
 358 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
 359         AX_JAVA_OPTIONS
 360         AX_PROG_JAVAC
 361         AX_PROG_JAVA
 362         AX_PROG_JAR
 363
 364         AX_JNI_INCLUDE_DIR
 365         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 366         do
 367                 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
 368         done
 369
 370         saved_CPPFLAGS="$CPPFLAGS"
 371         CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 372         AX_PROG_JAVAH
 373         CPPFLAGS="$saved_CPPFLAGS"
 374 ])
 375
 376 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
 377
 378 AS_IF([test "x$java_agent_log4j" = "xyes"], [
 379         AX_CHECK_CLASSPATH
 380         AX_CHECK_CLASS([org.apache.log4j.Logger])
 381         AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 382                 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 383         ])
 384 ])
 385
 386 # Option to build the python agent
 387 AC_ARG_ENABLE([python-agent], [
 388 AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
 389 ], [
 390         python_agent=$enableval
 391 ], [:])
 392 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 393 AS_IF([test "x$python_agent" = "xyes"], [
 394         AM_PATH_PYTHON([2.7])
 395 ])
 396
 397 # sdt.h integration
 398 AC_ARG_WITH([sdt], [
 399 AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
 400 ], [
 401         with_sdt=$withval
 402 ], [
 403         with_sdt="no"
 404 ])
 405
 406 AS_IF([test "x$with_sdt" = "xyes"], [
 407         AC_MSG_CHECKING([STAP_PROBEV()])
 408         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 409                 #define SDT_USE_VARIADIC
 410                 #include <sys/sdt.h>
 411                 void fct(void)
 412                 {
 413                         STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 414                 }
 415         ]])], [
 416                 AC_MSG_RESULT([yes])
 417                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 418         ], [
 419                 AC_MSG_RESULT([no])
 420                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 421         ])
 422 ])
 423
 424 AC_ARG_WITH([lttng-system-rundir], [
 425 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 426 ], [
 427         lttng_system_rundir="$withval"
 428 ], [
 429         lttng_system_rundir="/var/run/lttng"
 430 ])
 431 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 432                 [LTTng system runtime directory])
 433
 434 AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
 435 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
 436
 437 # Enable building examples
 438 AC_ARG_ENABLE(
 439         examples,
 440         AS_HELP_STRING(
 441                 [--disable-examples],
 442                 [Do not build and install examples]
 443         ),
 444         [enable_examples=$enableval],
 445         [enable_examples=yes]
 446 )
 447
 448 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" != "xno"])
 449
 450 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 451 # is not distributed in tarballs.
 452 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 453 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 454
 455 # Enable building man pages (user's intention).
 456 AC_ARG_ENABLE(
 457         man-pages,
 458         AS_HELP_STRING(
 459                 [--disable-man-pages],
 460                 [Do not build and install man pages (already built in a distributed tarball)]
 461         ),
 462         [man_pages_opt=$enableval],
 463         [man_pages_opt=yes]
 464 )
 465
 466 # Check for asciidoc and xmlto if we enabled building the man pages.
 467 have_asciidoc_xmlto=no
 468 warn_prebuilt_man_pages=no
 469
 470 AS_IF([test "x$man_pages_opt" = "xyes"], [
 471         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 472         AC_PATH_PROG([XMLTO], [xmlto], [no])
 473
 474         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 475                 AS_IF([test "x$in_git_repo" = "xyes"], [
 476                         # This is an error because we're in the Git repo, which
 477                         # means the man pages are not already generated for us,
 478                         # thus asciidoc/xmlto are required because we were asked
 479                         # to build the man pages.
 480                         AC_MSG_ERROR([
 481 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 482 --disable-man-pages to disable building the man pages, in which case
 483 they will not be installed.
 484                         ])
 485                 ], [
 486                         # Only warn here: since we're in the tarball, the man
 487                         # pages should already be generated at this point, thus
 488                         # asciidoc/xmlto are not strictly required.
 489                         warn_prebuilt_man_pages=yes
 490                 ])
 491         ], [
 492                 have_asciidoc_xmlto=yes
 493         ])
 494 ])
 495
 496 # Export man page build condition: build the man pages if the user
 497 # asked for it, and if the tools are available.
 498 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 499 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 500
 501 # Default values
 502 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 503         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 504         $1="$2"
 505         AC_SUBST([$1])
 506 ])
 507
 508 _AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
 509
 510 AM_CFLAGS="-Wall"
 511 AC_SUBST(AM_CFLAGS)
 512 AC_SUBST(JNI_CPPFLAGS)
 513
 514 AC_CONFIG_FILES([
 515         Makefile
 516         doc/Makefile
 517         doc/examples/Makefile
 518         doc/man/Makefile
 519         include/Makefile
 520         include/lttng/ust-version.h
 521         snprintf/Makefile
 522         libringbuffer/Makefile
 523         liblttng-ust-comm/Makefile
 524         liblttng-ust/Makefile
 525         liblttng-ust-ctl/Makefile
 526         liblttng-ust-fork/Makefile
 527         liblttng-ust-dl/Makefile
 528         liblttng-ust-fd/Makefile
 529         liblttng-ust-java/Makefile
 530         liblttng-ust-java-agent/Makefile
 531         liblttng-ust-java-agent/java/Makefile
 532         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 533         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 534         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 535         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 536         liblttng-ust-java-agent/jni/Makefile
 537         liblttng-ust-java-agent/jni/common/Makefile
 538         liblttng-ust-java-agent/jni/jul/Makefile
 539         liblttng-ust-java-agent/jni/log4j/Makefile
 540         liblttng-ust-libc-wrapper/Makefile
 541         liblttng-ust-cyg-profile/Makefile
 542         liblttng-ust-python-agent/Makefile
 543         python-lttngust/Makefile
 544         python-lttngust/setup.py
 545         python-lttngust/lttngust/__init__.py
 546         tools/Makefile
 547         tests/Makefile
 548         tests/ctf-types/Makefile
 549         tests/hello/Makefile
 550         tests/hello.cxx/Makefile
 551         tests/same_line_tracepoint/Makefile
 552         tests/snprintf/Makefile
 553         tests/ust-elf/Makefile
 554         tests/benchmark/Makefile
 555         tests/utils/Makefile
 556         tests/test-app-ctx/Makefile
 557         tests/gcc-weak-hidden/Makefile
 558         lttng-ust.pc
 559 ])
 560
 561 # Create link for python agent for the VPATH guru.
 562 AC_CONFIG_LINKS([
 563         python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
 564         python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
 565         python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
 566         python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
 567 ])
 568
 569 AC_OUTPUT
 570
 571
 572 #
 573 # Mini-report on what will be built.
 574 #
 575
 576 PPRINT_INIT
 577 PPRINT_SET_INDENT(1)
 578 PPRINT_SET_TS(38)
 579
 580 AS_ECHO
 581 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"V_NAME\"$PPRINT_COLOR_RST")
 582 AS_ECHO
 583
 584 AS_ECHO("V_DESC")
 585
 586 AS_ECHO
 587 PPRINT_SUBTITLE([System])
 588
 589 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 590
 591 test "x$NO_UNALIGNED_ACCESS" != "x1" && value=1 || value=0
 592 PPRINT_PROP_BOOL([Efficient unaligned memory access], $value)
 593
 594 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
 595        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 596 ])
 597
 598 AS_ECHO
 599 PPRINT_SUBTITLE([Features])
 600 PPRINT_SET_INDENT(1)
 601
 602 test "x$with_sdt" = "xyes" && value=1 || value=0
 603 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 604
 605 test "x$java_agent_jul" = xyes && value=1 || value=0
 606 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 607
 608 test "x$java_agent_log4j" = xyes && value=1 || value=0
 609 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
 610
 611 test "x$jni_interface" = xyes && value=1 || value=0
 612 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 613
 614 test "x$python_agent" = xyes && value=1 || value=0
 615 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 616
 617 test "x$enable_numa" = xyes && value=1 || value=0
 618 PPRINT_PROP_BOOL([NUMA], $value)
 619
 620 AS_ECHO
 621 PPRINT_SET_INDENT(0)
 622
 623 test "x$enable_examples" = xyes && value=1 || value=0
 624 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 625
 626 # man pages build enabled/disabled
 627 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 628
 629 AS_IF([test "x$man_pages_opt" != "xno"], [
 630         AS_IF([test "x$in_git_repo" = "xyes"], [
 631                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 632         ], [
 633                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 634                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 635                 ], [
 636                         PPRINT_PROP_STRING([build_man_pages_msg],
 637                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
 638                                 $PPRINT_COLOR_SUBTITLE)
 639                 ])
 640         ])
 641 ], [
 642         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 643 ])
 644
 645 m4_popdef([build_man_pages_msg])
 646
 647 PPRINT_SET_INDENT(1)
 648
 649 report_bindir="`eval eval echo $bindir`"
 650 report_libdir="`eval eval echo $libdir`"
 651
 652 # Print the bindir and libdir this `make install' will install into.
 653 AS_ECHO
 654 PPRINT_SUBTITLE([Install directories])
 655 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 656 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 657
 658 AS_ECHO
 659 PPRINT_SUBTITLE([System directories])
 660
 661 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 662
 663 PPRINT_SET_INDENT(0)
 664
 665 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 666         AS_ECHO
 667         PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 668
 669 Note that the man pages are already built in this distribution tarball,
 670 therefore asciidoc and xmlto are only needed if you intend to modify
 671 their sources.
 672
 673 Use --disable-man-pages to completely disable building and installing
 674 the man pages.])
 675 ])