configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.11.0-rc1],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24 AC_PROG_CXX
  25 rw_PROG_CXX_WORKS
  26 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  27
  28 ax_CHECK_SDT_WORKS
  29 AM_CONDITIONAL([SDT_WORKS], [test "x$ax_check_sdt_works" = "xyes"])
  30
  31 # Checks for programs.
  32 AC_PROG_GREP
  33 AC_PROG_MAKE_SET
  34 AC_PROG_SED
  35 AC_PATH_PROG([report_fold], [fold])
  36 LT_INIT
  37
  38 # Check for objcopy, required by the base address statedump and dynamic linker tests
  39 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
  40 AS_IF([test "x$OBJCOPY" = "xno"],
  41         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  42 )
  43 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  44
  45 # check for pgrep
  46 AC_PATH_PROG([PGREP], [pgrep], [no])
  47 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
  48
  49 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
  50 # is not distributed in tarballs
  51 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
  52 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
  53
  54 # check for bison
  55 AC_PROG_YACC
  56 BISON=$YACC
  57 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  58
  59 AS_IF([test "x$have_bison" != "xyes"], [
  60   AS_IF([test "x$in_git_repo" = "xyes"], [
  61     AC_MSG_FAILURE([
  62 Bison >= 2.4 is required when building from the Git repository. You can
  63 set the YACC variable to override automatic detection.
  64     ])
  65   ], [
  66     AC_MSG_WARN([
  67 Missing Bison >= 2.4. Note that the parser files are already built in
  68 this distribution tarball, so Bison is only needed if you intend to
  69 modify their sources. You can set the YACC variable to override automatic
  70 detection.
  71     ])
  72   ])
  73 ])
  74 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
  75
  76 # check for flex
  77 AC_PROG_LEX
  78 FLEX=$LEX
  79 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
  80
  81 AS_IF([test "x$have_flex" != "xyes"], [
  82   AS_IF([test "x$in_git_repo" = "xyes"], [
  83     AC_MSG_FAILURE([
  84 Flex >= 2.5.35 is required when building from the Git repository. You can
  85 set the LEX variable to override automatic detection.
  86     ])
  87   ], [
  88     AC_MSG_WARN([
  89 Missing Flex >= 2.5.35. Note that the lexer files are already built in
  90 this distribution tarball, so Flex is only needed if you intend to
  91 modify their sources. You can set the LEX variable to override automatic
  92 detection.
  93     ])
  94   ])
  95 ])
  96 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
  97
  98
  99 # Checks for typedefs, structures, and compiler characteristics.
 100 AC_C_INLINE
 101 AC_TYPE_INT32_T
 102 AC_TYPE_INT64_T
 103 AC_TYPE_MODE_T
 104 AC_TYPE_OFF_T
 105 AC_TYPE_PID_T
 106 AC_TYPE_SIZE_T
 107 AC_TYPE_SSIZE_T
 108 AC_TYPE_UID_T
 109 AC_TYPE_UINT16_T
 110 AC_TYPE_UINT32_T
 111 AC_TYPE_UINT64_T
 112 AC_TYPE_UINT8_T
 113
 114 AX_C___ATTRIBUTE__
 115 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 116         [:],
 117         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 118
 119 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 120
 121 # Check if linker has the -no-pie option.
 122 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 123 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 124
 125 AX_LIB_SOCKET_NSL
 126
 127 LT_NO_UNDEFINED=""
 128 AS_CASE([$host_os],
 129   [cygwin*],
 130     [
 131       LT_NO_UNDEFINED="-no-undefined"
 132     ],
 133   [cygwin*|darwin*|mingw*|solaris*],
 134     [
 135       # On platforms where we only support the relayd, disable the other binaries by default
 136       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 137       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 138       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 139       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 140       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 141       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 142     ]
 143 )
 144
 145 AC_SUBST(LT_NO_UNDEFINED)
 146
 147 # Compute minor/major/patchlevel version numbers
 148 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 149 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 150 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 151
 152 AC_SUBST([MAJOR_VERSION], [$major_version])
 153 AC_SUBST([MINOR_VERSION], [$minor_version])
 154 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 155 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 156 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 157 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 158
 159 version_name="Lafontaine"
 160 version_description="A modern Saison beer from Montréal's Oshlag microbrewery, Lafontaine is a refreshing, zesty, rice beer with hints of fruit and spices."
 161 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 162
 163 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 164 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 165
 166 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 167 AC_ARG_ENABLE(libtool-linkdep-fixup,
 168         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 169                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 170         libtool_fixup=$enableval,
 171         libtool_fixup=yes)
 172
 173 AS_IF([test "x$libtool_fixup" = "xyes"],
 174             [
 175             libtool_m4="$srcdir/m4/libtool.m4"
 176             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 177             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 178             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 179             AS_IF([test $libtool_flag_pattern_count -ne 0],
 180             [
 181                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 182                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 183                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 184                   ],
 185                   [
 186                   AC_MSG_RESULT([none])
 187                   ])
 188             ])
 189
 190 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 191
 192 AC_CHECK_HEADERS([ \
 193         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 194         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 195         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 196         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 197         sys/mount.h sys/param.h sys/time.h elf.h
 198 ])
 199
 200 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 201
 202 # Basic functions check
 203 AC_CHECK_FUNCS([ \
 204         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 205         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 206         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 207         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 208         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 209         sched_getcpu sysconf sync_file_range
 210 ])
 211
 212 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 213 # add -lrt to LIBS
 214 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 215
 216 # Checks for dl.
 217 AC_CHECK_LIB([dl], [dlopen], [
 218         have_libdl=yes
 219         libdl_name=dl
 220         DL_LIBS="-ldl"
 221 ], [
 222         # libdl not found, check for dlopen in libc.
 223         AC_CHECK_LIB([c], [dlopen], [
 224                 have_libc_dl=yes
 225                 libdl_name=c
 226                 DL_LIBS="-lc"
 227         ], [
 228                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 229         ])
 230 ])
 231 AC_SUBST(DL_LIBS)
 232
 233 # Check if libdl has dlmopen support.
 234 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 235 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 236         AC_DEFINE([HAVE_DLMOPEN], [1])
 237         HAVE_DLMOPEN=1
 238 ], [
 239         HAVE_DLMOPEN=0
 240 ])
 241 AC_SUBST(HAVE_DLMOPEN)
 242
 243 # Babeltrace viewer check
 244 AC_ARG_WITH([babeltrace-bin],
 245         AS_HELP_STRING([--with-babeltrace-bin],
 246         [Location of the babeltrace viewer executable (including the filename)]),
 247         [BABELTRACE_BIN="$withval"],
 248         [BABELTRACE_BIN=''])
 249 AC_SUBST([BABELTRACE_BIN])
 250
 251 # lttv-gui
 252 AC_ARG_WITH([lttv-gui-bin],
 253         AS_HELP_STRING([--with-lttv-gui-bin],
 254    [Location of the lttv GUI viewer executable (including the filename)]),
 255    [LTTV_GUI_BIN="$withval"],
 256    [LTTV_GUI_BIN=''])
 257 AC_SUBST([LTTV_GUI_BIN])
 258
 259 AC_ARG_WITH([consumerd32-bin],
 260         AS_HELP_STRING([--with-consumerd32-bin],
 261         [Location of the 32-bit consumerd executable (including the filename)]),
 262         [CONSUMERD32_BIN="$withval"],
 263         [CONSUMERD32_BIN=''])
 264 AC_SUBST([CONSUMERD32_BIN])
 265
 266 AC_ARG_WITH([consumerd64-bin],
 267         AS_HELP_STRING([--with-consumerd64-bin],
 268         [Location of the 64-bit consumerd executable (including the filename)]),
 269         [CONSUMERD64_BIN="$withval"],
 270         [CONSUMERD64_BIN=''])
 271 AC_SUBST([CONSUMERD64_BIN])
 272
 273 AC_ARG_WITH([consumerd32-libdir],
 274         AS_HELP_STRING([--with-consumerd32-libdir],
 275         [Directory containing the 32-bit consumerd libraries]),
 276         [CONSUMERD32_LIBDIR="$withval"],
 277         [CONSUMERD32_LIBDIR=''])
 278 AC_SUBST([CONSUMERD32_LIBDIR])
 279
 280 AC_ARG_WITH([consumerd64-libdir],
 281         AS_HELP_STRING([--with-consumerd64-libdir],
 282         [Directory containing the 64-bit consumerd libraries]),
 283         [CONSUMERD64_LIBDIR="$withval"],
 284         [CONSUMERD64_LIBDIR=''])
 285 AC_SUBST([CONSUMERD64_LIBDIR])
 286
 287 AC_ARG_WITH([sessiond-bin],
 288         AS_HELP_STRING([--with-sessiond-bin],
 289         [Location of the sessiond executable (including the filename)]),
 290         [SESSIOND_BIN="$withval"],
 291         [SESSIOND_BIN=''])
 292 AC_SUBST([SESSIOND_BIN])
 293
 294 AC_ARG_WITH([lttng-system-rundir],
 295         AS_HELP_STRING([--with-lttng-system-rundir],
 296         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 297         [LTTNG_SYSTEM_RUNDIR="$withval"],
 298         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 299 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 300
 301 AC_ARG_ENABLE([test-java-agent-jul],
 302         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 303         [test_java_agent_jul=$enableval],
 304         [test_java_agent_jul=no]
 305 )
 306
 307 AC_ARG_ENABLE([test-java-agent-log4j],
 308         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 309         [test_java_agent_log4j=$enableval],
 310         [test_java_agent_log4j=no]
 311 )
 312
 313 AC_ARG_ENABLE([test-java-agent-all],
 314         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 315         [test_java_agent_jul=$enableval
 316          test_java_agent_log4j=$enableval],
 317         [:]
 318 )
 319
 320 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 321 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 322 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 323 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 324 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 325 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 326 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 327 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 328
 329 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 330         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 331         $1="$2"
 332         AC_SUBST([$1])
 333 ])
 334
 335 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 336         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 337         $1="$2"
 338         AC_SUBST([$1])
 339 ])
 340
 341 # Default values
 342 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 343 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 344 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 345 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 346 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 347 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 348 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 349 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 350 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 351 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 352 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 353 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 354 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 355 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 356 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 357 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 358 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 359 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 360 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 361 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 362 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 363 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 364 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 365 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 366 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 367 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 368 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 369 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 370 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 371 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 372 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 373 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 374 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 375 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 376 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 377 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 378 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 379 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 380 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 381 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 382 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 383 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 384 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 385 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 386 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 387 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 388 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 389 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 390 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 391
 392 # Command short descriptions
 393 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 394 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 395 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 396 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 397 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 398 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
 399 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 400 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 401 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
 402 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 403 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 404 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 405 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 406 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk])
 407 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 408 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 409 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 410 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 411 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 412 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 413 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 414 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 415 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 416 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 417
 418 if test "x$prefix" = "xNONE"; then
 419         prefix=$ac_default_prefix
 420 fi
 421 CONFDIR=`eval echo $sysconfdir`
 422 AC_SUBST(CONFDIR)
 423 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 424
 425 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 426
 427 # Check libpopt
 428 PKG_CHECK_MODULES([POPT], [popt],
 429   [
 430     dnl PKG_CHECK_MODULES defines POPT_LIBS
 431   ],
 432   [
 433     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 434     AC_MSG_WARN([Finding libpopt without pkg-config.])
 435     AC_CHECK_LIB([popt],
 436       [poptGetContext],
 437       [POPT_LIBS="-lpopt"],
 438       [
 439         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 440       ]
 441     )
 442   ]
 443 )
 444 AC_SUBST(POPT_LIBS)
 445
 446 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 447
 448 # First, check for uuid in system libs
 449 AH_TEMPLATE([LTTNG_HAVE_LIBUUID], [Define if you have libuuid support])
 450 AC_CHECK_FUNCS([uuid_generate],
 451   [
 452     AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 453     UUID_LIBS=""
 454   ],
 455   [
 456     # Then, check if the pkg-config module is available, otherwise explicitly check
 457     # for libuuid, or uuid support in the C-library.
 458     PKG_CHECK_MODULES([UUID], [uuid],
 459       [
 460         AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 461         dnl PKG_CHECK_MODULES defines UUID_LIBS
 462       ],
 463       [
 464         AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 465         AC_MSG_WARN([Finding libuuid without pkg-config.])
 466         AC_CHECK_LIB([uuid], [uuid_generate],
 467           [
 468             AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 469             UUID_LIBS="-luuid"
 470           ],
 471           [
 472             # libuuid not found, check for uuid_create in libc.
 473             AC_CHECK_LIB([c], [uuid_create],
 474               [
 475                 AC_DEFINE([LTTNG_HAVE_LIBUUID], [1])
 476                 UUID_LIBS="-lc"
 477               ],
 478               [
 479                 AC_MSG_FAILURE([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 480               ]
 481             )
 482           ]
 483         )
 484       ]
 485     )
 486   ]
 487 )
 488 AC_SUBST(UUID_LIBS)
 489
 490 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 491
 492 # URCU library version needed or newer
 493 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed])
 494
 495 # Check liburcu needed function calls
 496 AC_CHECK_DECL([cds_list_add], [],
 497         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 498 AC_CHECK_DECL([cds_wfcq_init], [],
 499         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 500 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 501         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 502 AC_CHECK_DECL([futex_async], [],
 503         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 504 AC_CHECK_DECL([rcu_thread_offline], [],
 505         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 506 AC_CHECK_DECL([rcu_thread_online], [],
 507         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 508 AC_CHECK_DECL([caa_likely], [],
 509         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 510 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 511         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 512
 513 #Function added in urcu 0.7.0
 514 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 515         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 516 )
 517
 518 #Function added in urcu 0.9.0
 519 AC_CHECK_DECL([urcu_ref_get_unless_zero], [],
 520         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]]
 521 )
 522
 523 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 524 # it can be explicitly disabled with --without-kmod
 525 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 526 AC_ARG_WITH([kmod],
 527   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 528   [],
 529   [with_kmod=check]
 530 )
 531
 532 AS_IF([test "x$with_kmod" != "xno"],
 533   [
 534     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 535       [
 536         AC_DEFINE([HAVE_KMOD], [1])
 537         KMOD_LIBS="-lkmod"
 538       ],
 539       [
 540         if test "x$with_kmod" != xcheck; then
 541           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 542         else
 543           with_kmod=no
 544         fi
 545       ]
 546     )
 547   ]
 548 )
 549 AC_SUBST(KMOD_LIBS)
 550
 551 # Check for liblttng-ust-ctl, fail if it's not found,
 552 # it can be explicitly disabled with --without-lttng-ust
 553 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 554 AC_ARG_WITH([lttng-ust],
 555   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 556   [],
 557   [with_lttng_ust=yes]
 558 )
 559
 560 AS_IF([test "x$with_lttng_ust" = "xyes"],
 561   [
 562     AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 563       [
 564         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 565       ],
 566       [
 567         AC_MSG_FAILURE([Cannot find LTTng-UST >= 2.2.x. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])
 568       ],
 569       [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 570     )
 571   ]
 572 )
 573 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 574
 575
 576 # Check for fmemopen
 577 AC_CHECK_LIB([c], [fmemopen],
 578 [
 579         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 580 ]
 581 )
 582
 583 # check for libpfm
 584 AC_CHECK_LIB([pfm], [pfm_initialize],
 585              [
 586               have_libpfm=yes
 587               ])
 588 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 589
 590 # For Python
 591 # SWIG version needed or newer:
 592 swig_version=2.0.0
 593
 594 AC_ARG_ENABLE([python-bindings],
 595               [AC_HELP_STRING([--enable-python-bindings],
 596                               [compile Python bindings])],
 597               [enable_python_binding=$enableval], [enable_python_binding=no])
 598
 599 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 600
 601 if test "x$enable_python_binding" = xyes; then
 602   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 603   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 604   AM_PATH_PYTHON([3.0])
 605
 606   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 607   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 608   AS_IF([test -z "$PYTHON_INCLUDE"], [
 609     AS_IF([test -z "$PYTHON_CONFIG"], [
 610       AC_PATH_PROGS([PYTHON_CONFIG],
 611                     [python$PYTHON_VERSION-config python-config],
 612                     [no],
 613                     [`dirname $PYTHON`])
 614       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 615     ])
 616     AC_MSG_CHECKING([python include flags])
 617     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 618     AC_MSG_RESULT([$PYTHON_INCLUDE])
 619   ])
 620
 621 else
 622     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 623 [if you want Python bindings.])
 624
 625 fi
 626
 627 # Epoll check. If not present, the build will fallback on poll() API
 628 AX_HAVE_EPOLL(
 629         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 630         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 631 )
 632 AX_CONFIG_FEATURE(
 633         [epoll], [This platform supports epoll(7)],
 634         [HAVE_EPOLL], [This platform supports epoll(7).],
 635         [enable_epoll="yes"], [enable_epoll="no"]
 636 )
 637 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 638
 639 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 640 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 641
 642 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 643         AX_JAVA_OPTIONS
 644         AX_PROG_JAVAC
 645         AX_PROG_JAVA
 646         AX_PROG_JAR
 647
 648         AX_CHECK_CLASSPATH
 649
 650         # Check for Java UST agent common class first
 651         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 652         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 653                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 654         fi
 655
 656         if test "x$test_java_agent_jul" = "xyes"; then
 657                 # Check for JUL agent class
 658                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 659                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 660                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 661                 fi
 662         fi
 663
 664         if test "x$test_java_agent_log4j" = "xyes"; then
 665                 # Check for Log4j agent class
 666                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 667                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 668                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 669                 fi
 670
 671                 # Check for Log4j class
 672                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 673                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 674                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 675                 fi
 676         fi
 677 fi
 678
 679 # enable building man pages (user's intention)
 680 AC_ARG_ENABLE(
 681         man-pages,
 682         AS_HELP_STRING(
 683                 [--disable-man-pages],
 684                 [Do not build and install man pages (already built in a distributed tarball)]
 685         ),
 686         [man_pages_opt=$enableval],
 687         [man_pages_opt=yes]
 688 )
 689
 690 # check for asciidoc and xmlto if we enabled building the man pages
 691 have_asciidoc_xmlto=no
 692 warn_prebuilt_man_pages=no
 693
 694 AS_IF([test "x$man_pages_opt" = "xyes"], [
 695         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 696         AC_PATH_PROG([XMLTO], [xmlto], [no])
 697
 698         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 699                 AS_IF([test "x$in_git_repo" = "xyes"], [
 700                         # this is an error because we're in the Git repo, which
 701                         # means the man pages are not already generated for us,
 702                         # thus asciidoc/xmlto are required because we were asked
 703                         # to build the man pages
 704                         AC_MSG_ERROR([
 705 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 706 --disable-man-pages to disable building the man pages, in which case
 707 they will not be installed.
 708                         ])
 709                 ], [
 710                         # only warn here: since we're in the tarball, the man
 711                         # pages should already be generated at this point, thus
 712                         # asciidoc/xmlto are not strictly required
 713                         warn_prebuilt_man_pages=yes
 714                 ])
 715         ], [
 716                 have_asciidoc_xmlto=yes
 717         ])
 718 ])
 719
 720 # export man page build condition: build the man pages if the user
 721 # asked for it, and if the tools are available
 722 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 723 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 724
 725 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 726
 727 # embedded --help message
 728 AC_ARG_ENABLE(
 729         [embedded-help],
 730         AS_HELP_STRING(
 731                 [--enable-embedded-help],
 732                 [Embed the --help messages in the executable files]
 733         ),
 734         [embedded_help=$enableval],
 735         [embedded_help=no]
 736 )
 737 AS_IF([test "x$embedded_help" = "xyes"], [
 738         AS_IF([test "x$man_pages_opt" = "xno"], [
 739                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 740         ])
 741         AC_PATH_PROG([man_prog_path], [man], [no])
 742         AS_IF([test "x$man_prog_path" = "xno"], [
 743                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 744         ])
 745         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 746         AC_SUBST([MANPROG], [$man_prog_path])
 747 ])
 748 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 749
 750 # Python agent test
 751 UST_PYTHON_AGENT="lttngust"
 752
 753 AC_ARG_ENABLE(test-python2-agent,
 754         AS_HELP_STRING([--enable-test-python2-agent],
 755                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 756         ),[:],[test_python2_agent_autodetect=yes]
 757 )
 758
 759 AC_ARG_ENABLE(test-python3-agent,
 760         AS_HELP_STRING([--enable-test-python3-agent],
 761                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 762         ),[:],[test_python3_agent_autodetect=yes]
 763 )
 764
 765 AC_ARG_ENABLE(test-python-agent-all,
 766         AS_HELP_STRING([--enable-test-python-agent-all],
 767                 [enable test for all python{2/3} agent.]
 768         ),
 769 )
 770
 771 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 772        unset test_python2_agent_autodetect
 773        unset test_python3_agent_autodetect
 774 ])
 775
 776 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 777        enable_test_python2_agent=yes
 778        enable_test_python3_agent=yes
 779 ])
 780
 781 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 782        enable_test_python2_agent=no
 783        enable_test_python3_agent=no
 784 ])
 785
 786
 787 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 788         AS_IF([test -z "$PYTHON2"], [
 789                         PYTHON2=python2
 790                 ], [
 791                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 792         ])
 793
 794         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 795         AS_IF([test -z "$PYTHON2_BIN"], [
 796                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 797                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 798                 ])
 799         ], [
 800                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 801                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 802                         PYTHON2_AGENT=$PYTHON2_BIN
 803                         AC_MSG_RESULT([yes])
 804                         RUN_PYTHON_AGENT_TEST=yes
 805                 ], [
 806                         AC_MSG_RESULT([no])
 807                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 808                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 809                         ])
 810                 ])
 811
 812         ])
 813
 814 ])
 815
 816 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 817         AS_IF([test -z "$PYTHON3"], [
 818                 PYTHON3=python3
 819         ], [
 820                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 821         ])
 822
 823         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 824         AS_IF([test -z "$PYTHON3_BIN"], [
 825                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 826                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 827                 ])
 828         ], [
 829                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 830                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 831                         PYTHON3_AGENT=$PYTHON3_BIN
 832                         AC_MSG_RESULT([yes])
 833                         RUN_PYTHON_AGENT_TEST=yes
 834                 ], [
 835                         AC_MSG_RESULT([no])
 836                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 837                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 838                         ])
 839                 ])
 840
 841         ])
 842 ])
 843 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 844 AC_SUBST([PYTHON2_AGENT])
 845 AC_SUBST([PYTHON3_AGENT])
 846
 847 # Arguments for binaries build exclusion
 848 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 849 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 850               [Disable the build of lttng-consumerd binaries]))
 851 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 852 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 853               [Disable the build of lttng-relayd binaries]))
 854 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 855               [Disable the build of lttng-sessiond binaries]))
 856 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 857               [Disable the build of the extra components]))
 858
 859
 860 # Always build libconfig since it a dependency of libcommon
 861 build_lib_config=yes
 862
 863 build_lib_compat=no
 864 build_lib_consumer=no
 865 build_lib_hashtable=no
 866 build_lib_health=no
 867 build_lib_index=no
 868 build_lib_kernel_consumer=no
 869 build_lib_kernel_ctl=no
 870 build_lib_lttng_ctl=no
 871 build_lib_relayd=no
 872 build_lib_sessiond_comm=no
 873 build_lib_testpoint=no
 874 build_lib_ust_consumer=no
 875
 876 # There is an overlap for enabled dependencies, but this makes everything
 877 # simpler. libcommon and libconfig are always compiled so they are not repeated
 878 # here.
 879
 880 # Enable binary dependencies.
 881 AS_IF([test x$enable_bin_lttng != xno],
 882       [
 883        build_lib_lttng_ctl=yes
 884       ]
 885 )
 886
 887 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 888       [
 889        build_lib_consumer=yes
 890        build_lib_sessiond_comm=yes
 891        build_lib_index=yes
 892        build_lib_health=yes
 893        build_lib_testpoint=yes
 894       ]
 895 )
 896
 897 AS_IF([test x$enable_bin_lttng_crash != xno],
 898       # Do nothing since libconfig and libcommon are built by default.
 899       []
 900 )
 901
 902 AS_IF([test x$enable_bin_lttng_relayd != xno],
 903       [
 904        build_lib_lttng_ctl=yes
 905        build_lib_sessiond_comm=yes
 906        build_lib_hashtable=yes
 907        build_lib_compat=yes
 908        build_lib_index=yes
 909        build_lib_health=yes
 910        build_lib_testpoint=yes
 911       ]
 912 )
 913 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 914       [
 915        build_lib_lttng_ctl=yes
 916        build_lib_sessiond_comm=yes
 917        build_lib_kernel_ctl=yes
 918        build_lib_hashtable=yes
 919        build_lib_compat=yes
 920        build_lib_relayd=yes
 921        build_lib_testpoint=yes
 922        build_lib_health=yes
 923       ]
 924 )
 925
 926 # Libraries dependencies enabling
 927 AS_IF([test x$build_lib_lttng_ctl = xyes],
 928       [
 929        build_lib_sessiond_comm=yes
 930        build_lib_hashtable=yes
 931       ]
 932 )
 933
 934 AS_IF([test x$build_lib_consumer = xyes],
 935       [
 936        build_lib_sessiond_comm=yes
 937        build_lib_kernel_consumer=yes
 938        build_lib_hashtable=yes
 939        build_lib_compat=yes
 940        build_lib_relayd=yes
 941        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 942       ]
 943 )
 944
 945 AS_IF([test x$build_lib_kernel_consumer = xyes],
 946       [
 947        build_lib_kernel_ctl=yes
 948        build_lib_relayd=yes
 949       ]
 950 )
 951
 952 AS_IF([test x$build_lib_relayd = xyes],
 953       [
 954        build_lib_sessiond_comm=yes
 955       ]
 956 )
 957
 958 # Find arch type
 959 AS_CASE([$host_cpu],
 960         [k1om], [ARCHTYPE="x86"],
 961         [i386], [ARCHTYPE="x86"],
 962         [i486], [ARCHTYPE="x86"],
 963         [i586], [ARCHTYPE="x86"],
 964         [i686], [ARCHTYPE="x86"],
 965         [amd64], [ARCHTYPE="x86"],
 966         [x86_64], [ARCHTYPE="x86"],
 967         [powerpc], [ARCHTYPE="ppc"],
 968         [ppc64], [ARCHTYPE="ppc"],
 969         [powerpc64], [ARCHTYPE="ppc"],
 970         [powerpc64le], [ARCHTYPE="ppc"],
 971         [ppc], [ARCHTYPE="ppc"],
 972         [s390], [ARCHTYPE="s390"],
 973         [s390x], [ARCHTYPE="s390"],
 974         [sparc], [ARCHTYPE="sparc64"],
 975         [sparc64], [ARCHTYPE="sparc64"],
 976         [alpha*], [ARCHTYPE="alpha"],
 977         [ia64], [ARCHTYPE="ia64"],
 978         [arm*], [ARCHTYPE="arm"],
 979         [aarch64*], [ARCHTYPE="aarch64"],
 980         [mips*], [ARCHTYPE="mips"],
 981         [nios2*], [ARCHTYPE="nios2"],
 982         [tile*], [ARCHTYPE="tile"],
 983         [hppa*], [ARCHTYPE="hppa"],
 984         [m68k], [ARCHTYPE="m68k"],
 985         [riscv*], [ARCHTYPE="riscv"],
 986         [ARCHTYPE="unknown"]
 987 )
 988
 989 AC_SUBST(ARCHTYPE)
 990
 991 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
 992 AC_MSG_CHECKING([for architecture support of userspace callstack tracing from the kernel])
 993 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 994         # Userspace callstack capture is only supported by the Linux kernel on x86.
 995         AC_MSG_RESULT([yes])
 996         have_modules_userspace_callstack_context=yes
 997         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
 998 ], [
 999         AC_MSG_RESULT([no])
1000         have_modules_userspace_callstack_context=no
1001 ])
1002 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context != xno])
1003
1004 # Export binaries build conditions.
1005 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1006 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1007 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1008 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1009 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1010
1011 # Export the tests and extras build conditions.
1012 AS_IF([\
1013 test "x$enable_bin_lttng" != "xno" && \
1014 test "x$enable_bin_lttng_consumerd" != "xno" && \
1015 test "x$enable_bin_lttng_crash" != "xno" && \
1016 test "x$enable_bin_lttng_relayd" != "xno" && \
1017 test "x$enable_bin_lttng_sessiond" != "xno"],
1018 [build_tests=yes],
1019 [build_tests=no]
1020 )
1021
1022 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1023 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1024
1025 # Export libraries build conditions.
1026 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
1027 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
1028 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1029 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
1030 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1031 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1032 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1033 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1034 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1035 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1036 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1037 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1038 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1039
1040 AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
1041 AC_SUBST(AM_CFLAGS)
1042
1043 AM_CPPFLAGS="-I\$(top_srcdir)/include -I\$(top_builddir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1044 AC_SUBST(AM_CPPFLAGS)
1045
1046 lttngincludedir="${includedir}/lttng"
1047 AC_SUBST(lttngincludedir)
1048
1049 lttngactionincludedir="${includedir}/lttng/action"
1050 AC_SUBST(lttngactionincludedir)
1051
1052 lttngconditionincludedir="${includedir}/lttng/condition"
1053 AC_SUBST(lttngconditionincludedir)
1054
1055 lttngnotificationincludedir="${includedir}/lttng/notification"
1056 AC_SUBST(lttngnotificationincludedir)
1057
1058 lttngtriggerincludedir="${includedir}/lttng/trigger"
1059 AC_SUBST(lttngtriggerincludedir)
1060
1061 lttnglibexecdir="${libdir}/lttng/libexec"
1062 AC_SUBST(lttnglibexecdir)
1063
1064 AC_CONFIG_FILES([
1065         Makefile
1066         doc/Makefile
1067         doc/man/Makefile
1068         doc/man/asciidoc-attrs.conf
1069         include/Makefile
1070         extras/Makefile
1071         extras/bindings/Makefile
1072         extras/bindings/swig/Makefile
1073         extras/bindings/swig/python/Makefile
1074         extras/core-handler/Makefile
1075         src/Makefile
1076         src/common/Makefile
1077         src/common/kernel-ctl/Makefile
1078         src/common/kernel-consumer/Makefile
1079         src/common/consumer/Makefile
1080         src/common/ust-consumer/Makefile
1081         src/common/hashtable/Makefile
1082         src/common/sessiond-comm/Makefile
1083         src/common/compat/Makefile
1084         src/common/relayd/Makefile
1085         src/common/testpoint/Makefile
1086         src/common/index/Makefile
1087         src/common/health/Makefile
1088         src/common/config/Makefile
1089         src/common/string-utils/Makefile
1090         src/lib/Makefile
1091         src/lib/lttng-ctl/Makefile
1092         src/lib/lttng-ctl/filter/Makefile
1093         src/lib/lttng-ctl/lttng-ctl.pc
1094         src/bin/Makefile
1095         src/bin/lttng-consumerd/Makefile
1096         src/bin/lttng-sessiond/Makefile
1097         src/bin/lttng-relayd/Makefile
1098         src/bin/lttng/Makefile
1099         src/bin/lttng-crash/Makefile
1100         tests/Makefile
1101         tests/destructive/Makefile
1102         tests/regression/Makefile
1103         tests/regression/kernel/Makefile
1104         tests/regression/tools/Makefile
1105         tests/regression/tools/streaming/Makefile
1106         tests/regression/tools/filtering/Makefile
1107         tests/regression/tools/health/Makefile
1108         tests/regression/tools/tracefile-limits/Makefile
1109         tests/regression/tools/snapshots/Makefile
1110         tests/regression/tools/live/Makefile
1111         tests/regression/tools/exclusion/Makefile
1112         tests/regression/tools/save-load/Makefile
1113         tests/regression/tools/save-load/configuration/Makefile
1114         tests/regression/tools/mi/Makefile
1115         tests/regression/tools/wildcard/Makefile
1116         tests/regression/tools/crash/Makefile
1117         tests/regression/tools/regen-metadata/Makefile
1118         tests/regression/tools/regen-statedump/Makefile
1119         tests/regression/tools/notification/Makefile
1120         tests/regression/tools/rotation/Makefile
1121         tests/regression/ust/Makefile
1122         tests/regression/ust/nprocesses/Makefile
1123         tests/regression/ust/high-throughput/Makefile
1124         tests/regression/ust/low-throughput/Makefile
1125         tests/regression/ust/before-after/Makefile
1126         tests/regression/ust/buffers-pid/Makefile
1127         tests/regression/ust/periodical-metadata-flush/Makefile
1128         tests/regression/ust/multi-session/Makefile
1129         tests/regression/ust/multi-lib/Makefile
1130         tests/regression/ust/overlap/Makefile
1131         tests/regression/ust/overlap/demo/Makefile
1132         tests/regression/ust/linking/Makefile
1133         tests/regression/ust/daemon/Makefile
1134         tests/regression/ust/exit-fast/Makefile
1135         tests/regression/ust/fork/Makefile
1136         tests/regression/ust/libc-wrapper/Makefile
1137         tests/regression/ust/baddr-statedump/Makefile
1138         tests/regression/ust/ust-dl/Makefile
1139         tests/regression/ust/java-jul/Makefile
1140         tests/regression/ust/java-log4j/Makefile
1141         tests/regression/ust/python-logging/Makefile
1142         tests/regression/ust/getcpu-override/Makefile
1143         tests/regression/ust/clock-override/Makefile
1144         tests/regression/ust/type-declarations/Makefile
1145         tests/regression/ust/rotation-destroy-flush/Makefile
1146         tests/regression/ust/blocking/Makefile
1147         tests/stress/Makefile
1148         tests/unit/Makefile
1149         tests/unit/ini_config/Makefile
1150         tests/perf/Makefile
1151         tests/utils/Makefile
1152         tests/utils/tap/Makefile
1153         tests/utils/testapp/Makefile
1154         tests/utils/testapp/gen-ust-events/Makefile
1155         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1156         tests/utils/testapp/gen-ust-nevents/Makefile
1157         tests/utils/testapp/gen-ust-nevents-str/Makefile
1158         tests/utils/testapp/gen-syscall-events/Makefile
1159         tests/utils/testapp/gen-ust-tracef/Makefile
1160         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1161         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1162         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1163 ])
1164
1165 # Inject variable into python test script.
1166 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1167 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1168 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1169 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1170
1171 AC_OUTPUT
1172
1173 #
1174 # Mini-report on what will be built.
1175 #
1176
1177 PPRINT_INIT
1178 PPRINT_SET_INDENT(1)
1179 PPRINT_SET_TS(38)
1180
1181 AS_ECHO
1182 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1183 AS_ECHO
1184
1185 AS_IF([test -n "$report_fold"], [
1186         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1187 ], [
1188         AS_ECHO("$version_description")
1189 ])
1190
1191 AS_ECHO
1192 PPRINT_SUBTITLE([Features])
1193
1194 # Target architecture we're building for.
1195 target_arch=$host_cpu
1196 [
1197 for f in $CFLAGS; do
1198         if test $f = "-m32"; then
1199                         target_arch="32-bit"
1200         elif test $f = "-m64"; then
1201                         target_arch="64-bit"
1202         fi
1203 done
1204 ]
1205 PPRINT_PROP_STRING([Target architecture], $target_arch)
1206
1207 # kmod enabled/disabled
1208 test "x$with_kmod" != "xno" && value=1 || value=0
1209 PPRINT_PROP_BOOL([libkmod support], $value)
1210
1211 # LTTng-UST enabled/disabled
1212 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1213 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1214
1215 AS_ECHO
1216 PPRINT_SUBTITLE([Binaries])
1217
1218 # List binaries to be built
1219 test x$enable_bin_lttng != xno && value=1 || value=0
1220 PPRINT_PROP_BOOL([lttng], $value)
1221
1222 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1223 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1224
1225 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1226 PPRINT_PROP_BOOL([lttng-crash], $value)
1227
1228 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1229 PPRINT_PROP_BOOL([lttng-relayd], $value)
1230
1231 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1232 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1233
1234 # Extras
1235 test x$enable_extras != xno && value=1 || value=0
1236 AS_ECHO
1237 PPRINT_SET_INDENT(0)
1238 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1239 PPRINT_SET_INDENT(1)
1240
1241 AS_ECHO
1242 PPRINT_SUBTITLE([Tests])
1243
1244 # Print clear message that tests won't be built
1245 AS_IF([test "x$build_tests" = "xno"],[
1246         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1247 ])
1248
1249 # LTTng UST Java agent JUL tests enabled/disabled
1250 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1251 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1252
1253 # LTTng UST Java agent Log4j tests enabled/disabled
1254 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1255 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1256
1257 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1258 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1259
1260 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1261 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1262
1263 #Python binding enabled/disabled
1264 test "x$enable_python_binding" = xyes && value=1 || value=0
1265 AS_ECHO
1266 PPRINT_SET_INDENT(0)
1267 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1268
1269 # man pages build enabled/disabled
1270 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1271
1272 AS_IF([test "x$man_pages_opt" != "xno"], [
1273         AS_IF([test "x$in_git_repo" = "xyes"], [
1274                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1275         ], [
1276                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1277                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1278                 ], [
1279                         PPRINT_PROP_STRING([build_man_pages_msg],
1280                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1281                                 $PPRINT_COLOR_SUBTITLE)
1282                 ])
1283         ])
1284 ], [
1285         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1286 ])
1287
1288 m4_popdef([build_man_pages_msg])
1289
1290 test "x$embedded_help" = xyes && value=1 || value=0
1291 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1292
1293 PPRINT_SET_INDENT(1)
1294
1295 report_bindir="`eval eval echo $bindir`"
1296 report_libdir="`eval eval echo $libdir`"
1297
1298 # Print the bindir and libdir this `make install' will install into.
1299 AS_ECHO
1300 PPRINT_SUBTITLE([Install directories])
1301 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1302 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1303
1304 AS_ECHO
1305 PPRINT_SUBTITLE([Search directories])
1306
1307 # If we build the sessiond, print the paths it will use
1308 AS_IF([test "$SESSIOND_BIN" = ""],[
1309         path="$report_bindir/lttng-sessiond"
1310 ],[
1311         path="$SESSIOND_BIN"
1312 ])
1313 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1314
1315 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1316         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1317 ],[
1318         path="$CONSUMERD32_BIN"
1319 ])
1320 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1321
1322 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1323         path="`eval eval echo $libdir`"
1324 ],[
1325         path="$CONSUMERD32_LIBDIR"
1326 ])
1327 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1328
1329 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1330         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1331 ],[
1332         path="$CONSUMERD64_BIN"
1333 ])
1334 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1335
1336 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1337         path="`eval eval echo $libdir`"
1338 ],[
1339         path="$CONSUMERD64_LIBDIR"
1340 ])
1341 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1342 PPRINT_SET_INDENT(0)
1343
1344 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1345         AS_ECHO
1346         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1347
1348 Note that the man pages are already built in this distribution tarball,
1349 therefore asciidoc and xmlto are only needed if you intend to modify
1350 their sources.
1351
1352 Also note that the installed man pages will contain the project's
1353 default command-line option and environment variable values.
1354
1355 Use --disable-man-pages to completely disable building and installing
1356 the man pages.])
1357 ])