configure.ac

   1 AC_INIT([lttng-tools],[2.0.0],[dgoulet@efficios.com],[],[http://lttng.org])
   2 AC_CONFIG_AUX_DIR([config])
   3 AC_CANONICAL_TARGET
   4 AC_CANONICAL_HOST
   5 AC_CONFIG_MACRO_DIR([config])
   6 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
   7 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
   8
   9 version_name="Annedd'ale"
  10 version_description="New type of beer, 100% from Quebec, flavored with sapin beaumier needles, with a touch of hops."
  11
  12 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  13 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], "")
  14
  15 AC_CONFIG_HEADERS([include/config.h])
  16
  17 AC_CHECK_HEADERS([ \
  18         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
  19         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
  20         getopt.h sys/ipc.h sys/shm.h popt.h grp.h \
  21 ])
  22
  23 # Babeltrace viewer check
  24 AC_ARG_WITH([babeltrace-bin],
  25         AS_HELP_STRING([--with-babeltrace-bin],
  26         [Location of the babeltrace viewer executable (including the filename)]),
  27         [BABELTRACE_BIN="$withval"],
  28         [BABELTRACE_BIN=''])
  29 AC_SUBST([BABELTRACE_BIN])
  30
  31 # lttv-gui
  32 AC_ARG_WITH([lttv-gui-bin],
  33         AS_HELP_STRING([--with-lttv-gui-bin],
  34    [Location of the lttv GUI viewer executable (including the filename)]),
  35    [LTTV_GUI_BIN="$withval"],
  36    [LTTV_GUI_BIN=''])
  37 AC_SUBST([LTTV_GUI_BIN])
  38
  39 AC_ARG_WITH([consumerd32-bin],
  40         AS_HELP_STRING([--with-consumerd32-bin],
  41         [Location of the 32-bit consumerd executable (including the filename)]),
  42         [CONSUMERD32_BIN="$withval"],
  43         [CONSUMERD32_BIN=''])
  44 AC_SUBST([CONSUMERD32_BIN])
  45
  46 AC_ARG_WITH([consumerd64-bin],
  47         AS_HELP_STRING([--with-consumerd64-bin],
  48         [Location of the 64-bit consumerd executable (including the filename)]),
  49         [CONSUMERD64_BIN="$withval"],
  50         [CONSUMERD64_BIN=''])
  51 AC_SUBST([CONSUMERD64_BIN])
  52
  53 AC_ARG_WITH([consumerd32-libdir],
  54         AS_HELP_STRING([--with-consumerd32-libdir],
  55         [Directory containing the 32-bit consumerd libraries]),
  56         [CONSUMERD32_LIBDIR="$withval"],
  57         [CONSUMERD32_LIBDIR=''])
  58 AC_SUBST([CONSUMERD32_LIBDIR])
  59
  60 AC_ARG_WITH([consumerd64-libdir],
  61         AS_HELP_STRING([--with-consumerd64-libdir],
  62         [Directory containing the 64-bit consumerd libraries]),
  63         [CONSUMERD64_LIBDIR="$withval"],
  64         [CONSUMERD64_LIBDIR=''])
  65 AC_SUBST([CONSUMERD64_LIBDIR])
  66
  67 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
  68 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
  69 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
  70 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
  71 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
  72 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
  73
  74 # Check for pthread
  75 AC_CHECK_LIB([pthread], [pthread_create], [],
  76         [AC_MSG_ERROR([Cannot find libpthread. Use [LDFLAGS]=-Ldir to specify its location.])]
  77 )
  78
  79 # Check libpopt
  80 AC_CHECK_LIB([popt], [poptGetContext], [],
  81         [AC_MSG_ERROR([Cannot find libpopt. Use [LDFLAGS]=-Ldir to specify its location.])]
  82 )
  83
  84 # Needed for benchmark time
  85 AC_CHECK_DECL([caa_get_cycles], [],
  86         [AC_MSG_ERROR([liburcu liburcu_version or newer is needed])], [[#include <urcu/arch.h>]]
  87 )
  88
  89 # URCU library version needed or newer
  90 liburcu_version=">= 0.6.7"
  91
  92 # Check liburcu needed function calls
  93 AC_CHECK_DECL([cds_list_add], [],
  94         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/list.h>]]
  95 )
  96 AC_CHECK_DECL([cds_wfq_init], [],
  97         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfqueue.h>]]
  98 )
  99 AC_CHECK_DECL([cds_wfq_dequeue_blocking], [],
 100     [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/wfqueue.h>]]
 101 )
 102 AC_CHECK_DECL([futex_async], [],
 103         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu/futex.h>]]
 104 )
 105 AC_CHECK_DECL([rcu_thread_offline], [],
 106         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 107 )
 108 AC_CHECK_DECL([rcu_thread_online], [],
 109         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 110 )
 111 AC_CHECK_DECL([caa_likely], [],
 112         [AC_MSG_ERROR([liburcu $liburcu_version or newer is needed])], [[#include <urcu.h>]]
 113 )
 114
 115 # Check liblttng-ust-ctl library
 116 AC_ARG_ENABLE(lttng-ust,
 117         AS_HELP_STRING([--disable-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 118         lttng_ust_support=$enableval, lttng_ust_support=yes)
 119
 120 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 121         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_create_session], [],
 122                 [AC_MSG_ERROR([Cannot find LTTng-UST. Use [LDFLAGS]=-Ldir to specify its location, or specify --disable-lttng-ust to build lttng-tools without LTTng-UST support.])]
 123         )
 124 ])
 125
 126 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [ test "x$ac_cv_lib_lttng_ust_ctl_ustctl_create_session" = "xyes" ])
 127
 128 AC_CHECK_FUNCS([sched_getcpu sysconf])
 129
 130 # check for dlopen
 131 AC_CHECK_LIB([dl], [dlopen],
 132 [
 133         have_libdl=yes
 134 ],
 135 [
 136         #libdl not found, check for dlopen in libc.
 137         AC_CHECK_LIB([c], [dlopen],
 138         [
 139                 have_libc_dl=yes
 140         ],
 141         [
 142                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 143         ])
 144 ])
 145 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 146 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 147
 148 # Option to only build the consumer daemon and its libraries
 149 AC_ARG_WITH([consumerd-only],
 150         AS_HELP_STRING([--with-consumerd-only],[Only build the consumer daemon [default=no]]),
 151         [consumerd_only=$withval],
 152         [consumerd_only=no])
 153 AM_CONDITIONAL([BUILD_CONSUMERD_ONLY], [test "x$consumerd_only" = "xyes"])
 154
 155 # Epoll check. If not present, the build will fallback on poll() API
 156 AX_HAVE_EPOLL(
 157         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 158         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 159 )
 160 AX_CONFIG_FEATURE(
 161         [epoll], [This platform supports epoll(7)],
 162         [HAVE_EPOLL], [This platform supports epoll(7).],
 163         [enable_epoll="yes"], [enable_epoll="no"]
 164 )
 165 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 166
 167 AC_PROG_CC
 168 LT_INIT
 169
 170 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 171
 172 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include"
 173
 174 lttngincludedir="${includedir}/lttng"
 175
 176 AC_SUBST(lttngincludedir)
 177 AC_SUBST(DEFAULT_INCLUDES)
 178
 179 lttnglibexecdir="${libdir}/lttng/libexec"
 180 AC_SUBST(lttnglibexecdir)
 181
 182 AC_CONFIG_FILES([
 183         Makefile
 184         doc/Makefile
 185         doc/man/Makefile
 186         include/Makefile
 187         benchmark/Makefile
 188         src/Makefile
 189         src/common/Makefile
 190         src/common/kernel-ctl/Makefile
 191         src/common/kernel-consumer/Makefile
 192         src/common/ust-consumer/Makefile
 193         src/common/hashtable/Makefile
 194         src/common/sessiond-comm/Makefile
 195         src/common/compat/Makefile
 196         src/lib/Makefile
 197         src/lib/lttng-ctl/Makefile
 198         src/bin/Makefile
 199         src/bin/lttng-consumerd/Makefile
 200         src/bin/lttng-sessiond/Makefile
 201         src/bin/lttng/Makefile
 202         tests/Makefile
 203         tests/ust-nevents/Makefile
 204         tests/ust-nprocesses/Makefile
 205 ])
 206
 207 AC_OUTPUT
 208
 209 #
 210 # Mini-report on what will be built
 211 #
 212 AS_ECHO()
 213
 214 AS_ECHO("Version name: $version_name")
 215 AS_ECHO("$version_description")
 216
 217 AS_ECHO()
 218
 219 # Target architecture we're building for
 220 target_arch=$host_cpu
 221 [
 222 for f in $CFLAGS; do
 223         if test $f = "-m32"; then
 224                         target_arch="32-bit"
 225         elif test $f = "-m64"; then
 226                         target_arch="64-bit"
 227         fi
 228 done
 229 ]
 230 AS_ECHO_N("Target architecture: ")
 231 AS_ECHO($target_arch)
 232
 233 # LTTng-UST enabled/disabled
 234 AS_ECHO_N("Lttng-UST support: ")
 235 AS_IF([test "x$lttng_ust_support" = "xyes"],[
 236         AS_ECHO("Enabled")
 237 ],[
 238         AS_ECHO("Disabled")
 239 ])
 240
 241 # Do we build only the consumerd, or everything
 242 AS_IF([test "x$consumerd_only" = "xyes"],[
 243         AS_ECHO("Only the consumerd daemon will be built.")
 244 ],[
 245         AS_ECHO("All binaries will be built.")
 246 ])
 247
 248 # Print the bindir and libdir this `make install' will install into.
 249 AS_ECHO()
 250 AS_ECHO_N("Binaries will be installed in:  ")
 251 AS_ECHO("`eval eval echo $bindir`")
 252 AS_ECHO_N("Libraries will be installed in: ")
 253 AS_ECHO("`eval eval echo $libdir`")
 254
 255 # If we build the sessiond, print the paths it will use
 256 AS_IF([test "x$consumerd_only" = "xno"],[
 257         AS_ECHO()
 258         AS_ECHO("The sessiond daemon will look in the following directories: ")
 259         AS_ECHO_N("32-bit consumerd executable at: ")
 260         AS_IF([test "$CONSUMERD32_BIN" = ""],[
 261                 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 262                 AS_ECHO("/lttng-consumerd")
 263         ],[
 264                 AS_ECHO("$CONSUMERD32_BIN")
 265         ])
 266
 267         AS_ECHO_N("32-bit consumer libraries in:   ")
 268         AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
 269                 AS_ECHO("`eval eval echo $libdir`")
 270         ],[
 271                 AS_ECHO("$CONSUMERD32_LIBDIR")
 272         ])
 273
 274         AS_ECHO_N("64-bit consumerd executable at: ")
 275         AS_IF([test "$CONSUMERD64_BIN" = ""],[
 276                 AS_ECHO_N("`eval eval echo $lttnglibexecdir`")
 277                 AS_ECHO("/lttng-consumerd")
 278         ],[
 279                 AS_ECHO("$CONSUMERD64_BIN")
 280         ])
 281
 282         AS_ECHO_N("64-bit consumer libraries in:   ")
 283         AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
 284                 AS_ECHO("`eval eval echo $libdir`")
 285         ],[
 286                 AS_ECHO("$CONSUMERD64_LIBDIR")
 287         ])
 288 ])
 289
 290 AS_ECHO()
 291