configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.12.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24 AC_PROG_CXX
  25 RW_PROG_CXX_WORKS
  26 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  27
  28 # Checks for programs.
  29 AC_PROG_GREP
  30 AC_PROG_MAKE_SET
  31 AC_PROG_SED
  32 AC_PATH_PROG([report_fold], [fold])
  33 LT_INIT
  34
  35 # Check for objcopy, required by the base address statedump and dynamic linker tests
  36 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
  37 AS_IF([test "x$OBJCOPY" = "xno"],
  38         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  39 )
  40 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  41
  42 # check for pgrep
  43 AC_PATH_PROG([PGREP], [pgrep], [no])
  44 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
  45
  46 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
  47 # is not distributed in tarballs
  48 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
  49 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
  50
  51 # check for bison
  52 AC_PROG_YACC
  53 BISON=$YACC
  54 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  55
  56 AS_IF([test "x$have_bison" != "xyes"], [
  57   AS_IF([test "x$in_git_repo" = "xyes"], [
  58     AC_MSG_FAILURE([
  59 Bison >= 2.4 is required when building from the Git repository. You can
  60 set the YACC variable to override automatic detection.
  61     ])
  62   ], [
  63     AC_MSG_WARN([
  64 Missing Bison >= 2.4. Note that the parser files are already built in
  65 this distribution tarball, so Bison is only needed if you intend to
  66 modify their sources. You can set the YACC variable to override automatic
  67 detection.
  68     ])
  69   ])
  70 ])
  71 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
  72
  73 # check for flex
  74 AC_PROG_LEX
  75 FLEX=$LEX
  76 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
  77
  78 AS_IF([test "x$have_flex" != "xyes"], [
  79   AS_IF([test "x$in_git_repo" = "xyes"], [
  80     AC_MSG_FAILURE([
  81 Flex >= 2.5.35 is required when building from the Git repository. You can
  82 set the LEX variable to override automatic detection.
  83     ])
  84   ], [
  85     AC_MSG_WARN([
  86 Missing Flex >= 2.5.35. Note that the lexer files are already built in
  87 this distribution tarball, so Flex is only needed if you intend to
  88 modify their sources. You can set the LEX variable to override automatic
  89 detection.
  90     ])
  91   ])
  92 ])
  93 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
  94
  95
  96 # Checks for typedefs, structures, and compiler characteristics.
  97 AC_C_INLINE
  98 AC_TYPE_INT32_T
  99 AC_TYPE_INT64_T
 100 AC_TYPE_MODE_T
 101 AC_TYPE_OFF_T
 102 AC_TYPE_PID_T
 103 AC_TYPE_SIZE_T
 104 AC_TYPE_SSIZE_T
 105 AC_TYPE_UID_T
 106 AC_TYPE_UINT16_T
 107 AC_TYPE_UINT32_T
 108 AC_TYPE_UINT64_T
 109 AC_TYPE_UINT8_T
 110
 111 AX_C___ATTRIBUTE__
 112 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 113         [:],
 114         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 115
 116 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 117
 118 # Check if linker has the -no-pie option.
 119 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 120 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 121
 122 AX_LIB_SOCKET_NSL
 123
 124 LT_NO_UNDEFINED=""
 125 AS_CASE([$host_os],
 126   [cygwin*],
 127     [
 128       LT_NO_UNDEFINED="-no-undefined"
 129     ],
 130   [cygwin*|darwin*|mingw*|solaris*],
 131     [
 132       # On platforms where we only support the relayd, disable the other binaries by default
 133       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 134       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 135       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 136       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 137       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 138       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 139     ]
 140 )
 141
 142 AC_SUBST(LT_NO_UNDEFINED)
 143
 144 # Compute minor/major/patchlevel version numbers
 145 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 146 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 147 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 148
 149 AC_SUBST([MAJOR_VERSION], [$major_version])
 150 AC_SUBST([MINOR_VERSION], [$minor_version])
 151 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 152 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 153 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 154 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 155
 156 version_name="Codename TBD"
 157 version_description="Description TBD"
 158 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 159
 160 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 161 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 162
 163 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 164 AC_ARG_ENABLE(libtool-linkdep-fixup,
 165         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 166                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 167         libtool_fixup=$enableval,
 168         libtool_fixup=yes)
 169
 170 AS_IF([test "x$libtool_fixup" = "xyes"],
 171             [
 172             libtool_m4="$srcdir/m4/libtool.m4"
 173             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 174             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 175             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 176             AS_IF([test $libtool_flag_pattern_count -ne 0],
 177             [
 178                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 179                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 180                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 181                   ],
 182                   [
 183                   AC_MSG_RESULT([none])
 184                   ])
 185             ])
 186
 187 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 188
 189 AC_CHECK_HEADERS([ \
 190         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 191         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 192         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 193         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 194         sys/mount.h sys/param.h sys/time.h elf.h
 195 ])
 196
 197 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 198
 199 # Basic functions check
 200 AC_CHECK_FUNCS([ \
 201         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 202         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 203         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 204         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 205         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 206         sched_getcpu sysconf sync_file_range
 207 ])
 208
 209 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 210 # add -lrt to LIBS
 211 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 212
 213 # Checks for dl.
 214 AC_CHECK_LIB([dl], [dlopen], [
 215         have_libdl=yes
 216         libdl_name=dl
 217         DL_LIBS="-ldl"
 218 ], [
 219         # libdl not found, check for dlopen in libc.
 220         AC_CHECK_LIB([c], [dlopen], [
 221                 have_libc_dl=yes
 222                 libdl_name=c
 223                 DL_LIBS="-lc"
 224         ], [
 225                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 226         ])
 227 ])
 228 AC_SUBST(DL_LIBS)
 229
 230 # Check if libdl has dlmopen support.
 231 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 232 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 233         AC_DEFINE([HAVE_DLMOPEN], [1])
 234         HAVE_DLMOPEN=1
 235 ], [
 236         HAVE_DLMOPEN=0
 237 ])
 238 AC_SUBST(HAVE_DLMOPEN)
 239
 240 # Babeltrace viewer check
 241 AC_ARG_WITH([babeltrace-bin],
 242         AS_HELP_STRING([--with-babeltrace-bin],
 243         [Location of the babeltrace viewer executable (including the filename)]),
 244         [BABELTRACE_BIN="$withval"],
 245         [BABELTRACE_BIN=''])
 246 AC_SUBST([BABELTRACE_BIN])
 247
 248 # lttv-gui
 249 AC_ARG_WITH([lttv-gui-bin],
 250         AS_HELP_STRING([--with-lttv-gui-bin],
 251    [Location of the lttv GUI viewer executable (including the filename)]),
 252    [LTTV_GUI_BIN="$withval"],
 253    [LTTV_GUI_BIN=''])
 254 AC_SUBST([LTTV_GUI_BIN])
 255
 256 AC_ARG_WITH([consumerd32-bin],
 257         AS_HELP_STRING([--with-consumerd32-bin],
 258         [Location of the 32-bit consumerd executable (including the filename)]),
 259         [CONSUMERD32_BIN="$withval"],
 260         [CONSUMERD32_BIN=''])
 261 AC_SUBST([CONSUMERD32_BIN])
 262
 263 AC_ARG_WITH([consumerd64-bin],
 264         AS_HELP_STRING([--with-consumerd64-bin],
 265         [Location of the 64-bit consumerd executable (including the filename)]),
 266         [CONSUMERD64_BIN="$withval"],
 267         [CONSUMERD64_BIN=''])
 268 AC_SUBST([CONSUMERD64_BIN])
 269
 270 AC_ARG_WITH([consumerd32-libdir],
 271         AS_HELP_STRING([--with-consumerd32-libdir],
 272         [Directory containing the 32-bit consumerd libraries]),
 273         [CONSUMERD32_LIBDIR="$withval"],
 274         [CONSUMERD32_LIBDIR=''])
 275 AC_SUBST([CONSUMERD32_LIBDIR])
 276
 277 AC_ARG_WITH([consumerd64-libdir],
 278         AS_HELP_STRING([--with-consumerd64-libdir],
 279         [Directory containing the 64-bit consumerd libraries]),
 280         [CONSUMERD64_LIBDIR="$withval"],
 281         [CONSUMERD64_LIBDIR=''])
 282 AC_SUBST([CONSUMERD64_LIBDIR])
 283
 284 AC_ARG_WITH([sessiond-bin],
 285         AS_HELP_STRING([--with-sessiond-bin],
 286         [Location of the sessiond executable (including the filename)]),
 287         [SESSIOND_BIN="$withval"],
 288         [SESSIOND_BIN=''])
 289 AC_SUBST([SESSIOND_BIN])
 290
 291 AC_ARG_WITH([lttng-system-rundir],
 292         AS_HELP_STRING([--with-lttng-system-rundir],
 293         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 294         [LTTNG_SYSTEM_RUNDIR="$withval"],
 295         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 296 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 297
 298 AC_ARG_ENABLE([test-java-agent-jul],
 299         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 300         [test_java_agent_jul=$enableval],
 301         [test_java_agent_jul=no]
 302 )
 303
 304 AC_ARG_ENABLE([test-java-agent-log4j],
 305         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 306         [test_java_agent_log4j=$enableval],
 307         [test_java_agent_log4j=no]
 308 )
 309
 310 AC_ARG_ENABLE([test-java-agent-all],
 311         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 312         [test_java_agent_jul=$enableval
 313          test_java_agent_log4j=$enableval],
 314         [:]
 315 )
 316
 317 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 318 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 319 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 320 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 321 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 322 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 323 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 324 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 325
 326 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 327         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 328         $1="$2"
 329         AC_SUBST([$1])
 330 ])
 331
 332 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 333         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 334         $1="$2"
 335         AC_SUBST([$1])
 336 ])
 337
 338 # Default values
 339 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 340 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 341 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 342 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 343 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 344 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 345 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 346 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 347 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 348 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 349 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 350 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 351 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 352 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 353 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 354 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 355 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 356 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 357 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 358 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 359 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 360 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 361 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 362 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 363 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 364 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 365 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 366 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 367 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 368 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 369 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 370 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 371 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 372 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 373 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 374 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 375 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 376 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 377 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 378 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 379 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 380 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 381 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 382 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 383 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 384 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 385 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 386 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 387 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 388
 389 # Command short descriptions
 390 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 391 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 392 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a tracing session])
 393 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 394 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 395 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 396 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
 397 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 398 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 399 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
 400 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 401 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 402 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 403 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 404 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk])
 405 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 406 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 407 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 408 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 409 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 410 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 411 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
 412 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
 413 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 414 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 415 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 416 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 417
 418 if test "x$prefix" = "xNONE"; then
 419         prefix=$ac_default_prefix
 420 fi
 421 CONFDIR=`eval echo $sysconfdir`
 422 AC_SUBST(CONFDIR)
 423 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 424
 425 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
 426
 427 # Check libpopt
 428 PKG_CHECK_MODULES([POPT], [popt],
 429   [
 430     dnl PKG_CHECK_MODULES defines POPT_LIBS
 431   ],
 432   [
 433     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 434     AC_MSG_WARN([Finding libpopt without pkg-config.])
 435     AC_CHECK_LIB([popt],
 436       [poptGetContext],
 437       [POPT_LIBS="-lpopt"],
 438       [
 439         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 440       ]
 441     )
 442   ]
 443 )
 444 AC_SUBST(POPT_LIBS)
 445
 446 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 447
 448 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 449
 450 # URCU library version needed or newer
 451 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.9.0 is needed])
 452
 453 # Check liburcu needed function calls
 454 AC_CHECK_DECL([cds_list_add], [],
 455         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 456 AC_CHECK_DECL([cds_wfcq_init], [],
 457         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 458 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 459         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 460 AC_CHECK_DECL([futex_async], [],
 461         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 462 AC_CHECK_DECL([rcu_thread_offline], [],
 463         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 464 AC_CHECK_DECL([rcu_thread_online], [],
 465         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 466 AC_CHECK_DECL([caa_likely], [],
 467         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 468 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 469         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 470
 471 #Function added in urcu 0.7.0
 472 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 473         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 474 )
 475
 476 #Function added in urcu 0.9.0
 477 AC_CHECK_DECL([urcu_ref_get_unless_zero], [],
 478         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/ref.h>]]
 479 )
 480
 481 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 482 # it can be explicitly disabled with --without-kmod
 483 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 484 AC_ARG_WITH([kmod],
 485   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 486   [],
 487   [with_kmod=check]
 488 )
 489
 490 AS_IF([test "x$with_kmod" != "xno"],
 491   [
 492     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 493       [
 494         AC_DEFINE([HAVE_KMOD], [1])
 495         KMOD_LIBS="-lkmod"
 496       ],
 497       [
 498         if test "x$with_kmod" != xcheck; then
 499           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 500         else
 501           with_kmod=no
 502         fi
 503       ]
 504     )
 505   ]
 506 )
 507 AC_SUBST(KMOD_LIBS)
 508
 509 # Check for liblttng-ust-ctl, fail if it's not found,
 510 # it can be explicitly disabled with --without-lttng-ust
 511 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 512 AC_ARG_WITH([lttng-ust],
 513   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 514   [],
 515   [with_lttng_ust=yes]
 516 )
 517
 518 AS_IF([test "x$with_lttng_ust" = "xyes"], [
 519   AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 520
 521   # Check for liblttng-ust
 522   PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
 523
 524   # Check for liblttng-ust-ctl
 525   PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
 526
 527   AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
 528 ])
 529
 530 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 531
 532
 533 # Check for fmemopen
 534 AC_CHECK_LIB([c], [fmemopen],
 535 [
 536         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 537 ]
 538 )
 539
 540 # check for libpfm
 541 AC_CHECK_LIB([pfm], [pfm_initialize],
 542              [
 543               have_libpfm=yes
 544               ])
 545 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 546
 547 # For Python
 548 # SWIG version needed or newer:
 549 swig_version=2.0.0
 550
 551 AC_ARG_ENABLE([python-bindings],
 552               [AC_HELP_STRING([--enable-python-bindings],
 553                               [compile Python bindings])],
 554               [enable_python_binding=$enableval], [enable_python_binding=no])
 555
 556 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 557
 558 if test "x$enable_python_binding" = xyes; then
 559   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 560   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 561   AM_PATH_PYTHON([3.0])
 562
 563   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 564   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 565   AS_IF([test -z "$PYTHON_INCLUDE"], [
 566     AS_IF([test -z "$PYTHON_CONFIG"], [
 567       AC_PATH_PROGS([PYTHON_CONFIG],
 568                     [python$PYTHON_VERSION-config python-config],
 569                     [no],
 570                     [`dirname $PYTHON`])
 571       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 572     ])
 573     AC_MSG_CHECKING([python include flags])
 574     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 575     AC_MSG_RESULT([$PYTHON_INCLUDE])
 576   ])
 577
 578 else
 579     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 580 [if you want Python bindings.])
 581
 582 fi
 583
 584 # Epoll check. If not present, the build will fallback on poll() API
 585 AX_HAVE_EPOLL(
 586         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 587         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 588 )
 589 AX_CONFIG_FEATURE(
 590         [epoll], [This platform supports epoll(7)],
 591         [HAVE_EPOLL], [This platform supports epoll(7).],
 592         [enable_epoll="yes"], [enable_epoll="no"]
 593 )
 594 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 595
 596 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
 597         [AX_CONFIG_FEATURE_ENABLE(dirfd)],
 598         [AX_CONFIG_FEATURE_DISABLE(dirfd)]
 599 )
 600 AX_CONFIG_FEATURE(
 601         [dirfd], [Use directory file descriptors],
 602         [COMPAT_DIRFD], [This platform supports directory file descriptors.],
 603         [enable_dirfd="yes"], [enable_dirfd="no"]
 604 )
 605 AM_CONDITIONAL([COMPAT_DIRFD], [ test "$enable_dirfd" = "yes" ])
 606
 607 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 608 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 609
 610 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 611         AX_JAVA_OPTIONS
 612         AX_PROG_JAVAC
 613         AX_PROG_JAVA
 614         AX_PROG_JAR
 615
 616         AX_CHECK_CLASSPATH
 617
 618         # Check for Java UST agent common class first
 619         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 620         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 621                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 622         fi
 623
 624         if test "x$test_java_agent_jul" = "xyes"; then
 625                 # Check for JUL agent class
 626                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 627                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 628                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 629                 fi
 630         fi
 631
 632         if test "x$test_java_agent_log4j" = "xyes"; then
 633                 # Check for Log4j agent class
 634                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 635                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 636                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 637                 fi
 638
 639                 # Check for Log4j class
 640                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 641                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 642                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 643                 fi
 644         fi
 645 fi
 646
 647 # enable building man pages (user's intention)
 648 AC_ARG_ENABLE(
 649         man-pages,
 650         AS_HELP_STRING(
 651                 [--disable-man-pages],
 652                 [Do not build and install man pages (already built in a distributed tarball)]
 653         ),
 654         [man_pages_opt=$enableval],
 655         [man_pages_opt=yes]
 656 )
 657
 658 # check for asciidoc and xmlto if we enabled building the man pages
 659 have_asciidoc_xmlto=no
 660 warn_prebuilt_man_pages=no
 661
 662 AS_IF([test "x$man_pages_opt" = "xyes"], [
 663         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 664         AC_PATH_PROG([XMLTO], [xmlto], [no])
 665
 666         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 667                 AS_IF([test "x$in_git_repo" = "xyes"], [
 668                         # this is an error because we're in the Git repo, which
 669                         # means the man pages are not already generated for us,
 670                         # thus asciidoc/xmlto are required because we were asked
 671                         # to build the man pages
 672                         AC_MSG_ERROR([
 673 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 674 --disable-man-pages to disable building the man pages, in which case
 675 they will not be installed.
 676                         ])
 677                 ], [
 678                         # only warn here: since we're in the tarball, the man
 679                         # pages should already be generated at this point, thus
 680                         # asciidoc/xmlto are not strictly required
 681                         warn_prebuilt_man_pages=yes
 682                 ])
 683         ], [
 684                 have_asciidoc_xmlto=yes
 685         ])
 686 ])
 687
 688 # export man page build condition: build the man pages if the user
 689 # asked for it, and if the tools are available
 690 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 691 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 692
 693 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 694
 695 # embedded --help message
 696 AC_ARG_ENABLE(
 697         [embedded-help],
 698         AS_HELP_STRING(
 699                 [--enable-embedded-help],
 700                 [Embed the --help messages in the executable files]
 701         ),
 702         [embedded_help=$enableval],
 703         [embedded_help=no]
 704 )
 705 AS_IF([test "x$embedded_help" = "xyes"], [
 706         AS_IF([test "x$man_pages_opt" = "xno"], [
 707                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 708         ])
 709         AC_PATH_PROG([man_prog_path], [man], [no])
 710         AS_IF([test "x$man_prog_path" = "xno"], [
 711                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 712         ])
 713         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 714         AC_SUBST([MANPROG], [$man_prog_path])
 715 ])
 716 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 717
 718 # Python agent test
 719 UST_PYTHON_AGENT="lttngust"
 720
 721 AC_ARG_ENABLE(test-python2-agent,
 722         AS_HELP_STRING([--enable-test-python2-agent],
 723                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 724         ),[:],[test_python2_agent_autodetect=yes]
 725 )
 726
 727 AC_ARG_ENABLE(test-python3-agent,
 728         AS_HELP_STRING([--enable-test-python3-agent],
 729                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 730         ),[:],[test_python3_agent_autodetect=yes]
 731 )
 732
 733 AC_ARG_ENABLE(test-python-agent-all,
 734         AS_HELP_STRING([--enable-test-python-agent-all],
 735                 [enable test for all python{2/3} agent.]
 736         ),
 737 )
 738
 739 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 740        unset test_python2_agent_autodetect
 741        unset test_python3_agent_autodetect
 742 ])
 743
 744 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 745        enable_test_python2_agent=yes
 746        enable_test_python3_agent=yes
 747 ])
 748
 749 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 750        enable_test_python2_agent=no
 751        enable_test_python3_agent=no
 752 ])
 753
 754
 755 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 756         AS_IF([test -z "$PYTHON2"], [
 757                         PYTHON2=python2
 758                 ], [
 759                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 760         ])
 761
 762         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 763         AS_IF([test -z "$PYTHON2_BIN"], [
 764                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 765                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 766                 ])
 767         ], [
 768                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 769                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 770                         PYTHON2_AGENT=$PYTHON2_BIN
 771                         AC_MSG_RESULT([yes])
 772                         RUN_PYTHON_AGENT_TEST=yes
 773                 ], [
 774                         AC_MSG_RESULT([no])
 775                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 776                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 777                         ])
 778                 ])
 779
 780         ])
 781
 782 ])
 783
 784 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 785         AS_IF([test -z "$PYTHON3"], [
 786                 PYTHON3=python3
 787         ], [
 788                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 789         ])
 790
 791         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 792         AS_IF([test -z "$PYTHON3_BIN"], [
 793                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 794                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 795                 ])
 796         ], [
 797                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 798                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 799                         PYTHON3_AGENT=$PYTHON3_BIN
 800                         AC_MSG_RESULT([yes])
 801                         RUN_PYTHON_AGENT_TEST=yes
 802                 ], [
 803                         AC_MSG_RESULT([no])
 804                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 805                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 806                         ])
 807                 ])
 808
 809         ])
 810 ])
 811 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 812 AC_SUBST([PYTHON2_AGENT])
 813 AC_SUBST([PYTHON3_AGENT])
 814
 815 AC_ARG_ENABLE([test-sdt-uprobe],
 816   [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
 817   [test_sdt_uprobe="$enableval"],
 818   [test_sdt_uprobe=autodetect]
 819 )
 820
 821 AS_IF([test "$test_sdt_uprobe" != "no"], [
 822   LTTNG_CHECK_SDT_WORKS
 823   AC_PATH_PROG([DTRACE], [dtrace])
 824 ])
 825
 826 AS_IF([test "$test_sdt_uprobe" = "yes"], [
 827   AS_IF([test "$lttng_cv_sdt_works" = "no"], [
 828     AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
 829   ])
 830   AS_IF([test "x$DTRACE" = "x"], [
 831     AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
 832   ])
 833 ])
 834
 835 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
 836   AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
 837     AS_IF([test "x$DTRACE" != "x"], [
 838       test_sdt_uprobe=yes
 839     ])
 840   ])
 841 ])
 842
 843 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
 844
 845 # Arguments for binaries build exclusion
 846 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 847 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 848               [Disable the build of lttng-consumerd binaries]))
 849 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 850 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 851               [Disable the build of lttng-relayd binaries]))
 852 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 853               [Disable the build of lttng-sessiond binaries]))
 854 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 855               [Disable the build of the extra components]))
 856
 857
 858 # Always build libconfig since it a dependency of libcommon
 859 build_lib_config=yes
 860
 861 build_lib_compat=no
 862 build_lib_consumer=no
 863 build_lib_hashtable=no
 864 build_lib_health=no
 865 build_lib_index=no
 866 build_lib_kernel_consumer=no
 867 build_lib_kernel_ctl=no
 868 build_lib_lttng_ctl=no
 869 build_lib_relayd=no
 870 build_lib_fd_tracker=no
 871 build_lib_sessiond_comm=no
 872 build_lib_testpoint=no
 873 build_lib_ust_consumer=no
 874
 875 # There is an overlap for enabled dependencies, but this makes everything
 876 # simpler. libcommon and libconfig are always compiled so they are not repeated
 877 # here.
 878
 879 # Enable binary dependencies.
 880 AS_IF([test x$enable_bin_lttng != xno],
 881       [
 882        build_lib_lttng_ctl=yes
 883       ]
 884 )
 885
 886 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 887       [
 888        build_lib_consumer=yes
 889        build_lib_sessiond_comm=yes
 890        build_lib_index=yes
 891        build_lib_health=yes
 892        build_lib_testpoint=yes
 893       ]
 894 )
 895
 896 AS_IF([test x$enable_bin_lttng_crash != xno],
 897       # Do nothing since libconfig and libcommon are built by default.
 898       []
 899 )
 900
 901 AS_IF([test x$enable_bin_lttng_relayd != xno],
 902       [
 903        build_lib_lttng_ctl=yes
 904        build_lib_sessiond_comm=yes
 905        build_lib_hashtable=yes
 906        build_lib_compat=yes
 907        build_lib_index=yes
 908        build_lib_health=yes
 909        build_lib_testpoint=yes
 910        build_lib_fd_tracker=yes
 911       ]
 912 )
 913 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 914       [
 915        build_lib_lttng_ctl=yes
 916        build_lib_sessiond_comm=yes
 917        build_lib_kernel_ctl=yes
 918        build_lib_hashtable=yes
 919        build_lib_compat=yes
 920        build_lib_relayd=yes
 921        build_lib_testpoint=yes
 922        build_lib_health=yes
 923       ]
 924 )
 925
 926 # Libraries dependencies enabling
 927 AS_IF([test x$build_lib_lttng_ctl = xyes],
 928       [
 929        build_lib_sessiond_comm=yes
 930        build_lib_hashtable=yes
 931       ]
 932 )
 933
 934 AS_IF([test x$build_lib_consumer = xyes],
 935       [
 936        build_lib_sessiond_comm=yes
 937        build_lib_kernel_consumer=yes
 938        build_lib_hashtable=yes
 939        build_lib_compat=yes
 940        build_lib_relayd=yes
 941        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 942       ]
 943 )
 944
 945 AS_IF([test x$build_lib_kernel_consumer = xyes],
 946       [
 947        build_lib_kernel_ctl=yes
 948        build_lib_relayd=yes
 949       ]
 950 )
 951
 952 AS_IF([test x$build_lib_relayd = xyes],
 953       [
 954        build_lib_sessiond_comm=yes
 955       ]
 956 )
 957
 958 # Find arch type
 959 AS_CASE([$host_cpu],
 960         [k1om], [ARCHTYPE="x86"],
 961         [i386], [ARCHTYPE="x86"],
 962         [i486], [ARCHTYPE="x86"],
 963         [i586], [ARCHTYPE="x86"],
 964         [i686], [ARCHTYPE="x86"],
 965         [amd64], [ARCHTYPE="x86"],
 966         [x86_64], [ARCHTYPE="x86"],
 967         [powerpc], [ARCHTYPE="ppc"],
 968         [ppc64], [ARCHTYPE="ppc"],
 969         [powerpc64], [ARCHTYPE="ppc"],
 970         [powerpc64le], [ARCHTYPE="ppc"],
 971         [ppc], [ARCHTYPE="ppc"],
 972         [s390], [ARCHTYPE="s390"],
 973         [s390x], [ARCHTYPE="s390"],
 974         [sparc], [ARCHTYPE="sparc64"],
 975         [sparc64], [ARCHTYPE="sparc64"],
 976         [alpha*], [ARCHTYPE="alpha"],
 977         [ia64], [ARCHTYPE="ia64"],
 978         [arm*], [ARCHTYPE="arm"],
 979         [aarch64*], [ARCHTYPE="aarch64"],
 980         [mips*], [ARCHTYPE="mips"],
 981         [nios2*], [ARCHTYPE="nios2"],
 982         [tile*], [ARCHTYPE="tile"],
 983         [hppa*], [ARCHTYPE="hppa"],
 984         [m68k], [ARCHTYPE="m68k"],
 985         [riscv*], [ARCHTYPE="riscv"],
 986         [ARCHTYPE="unknown"]
 987 )
 988
 989 AC_SUBST(ARCHTYPE)
 990
 991 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
 992 AC_MSG_CHECKING([for architecture support of userspace callstack tracing from the kernel])
 993 AS_IF([test "x$ARCHTYPE" = "xx86"],[
 994         # Userspace callstack capture is only supported by the Linux kernel on x86.
 995         AC_MSG_RESULT([yes])
 996         have_modules_userspace_callstack_context=yes
 997         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
 998 ], [
 999         AC_MSG_RESULT([no])
1000         have_modules_userspace_callstack_context=no
1001 ])
1002 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context != xno])
1003
1004 # Export binaries build conditions.
1005 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1006 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1007 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1008 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1009 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1010
1011 # Export the tests and extras build conditions.
1012 AS_IF([\
1013 test "x$enable_bin_lttng" != "xno" && \
1014 test "x$enable_bin_lttng_consumerd" != "xno" && \
1015 test "x$enable_bin_lttng_crash" != "xno" && \
1016 test "x$enable_bin_lttng_relayd" != "xno" && \
1017 test "x$enable_bin_lttng_sessiond" != "xno"],
1018 [build_tests=yes],
1019 [build_tests=no]
1020 )
1021
1022 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1023 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1024
1025 # Export libraries build conditions.
1026 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
1027 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
1028 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1029 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
1030 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1031 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1032 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1033 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1034 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1035 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1036 AM_CONDITIONAL([BUILD_LIB_FD_TRACKER], [test x$build_lib_fd_tracker = xyes])
1037 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1038 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1039 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1040
1041 AM_CFLAGS="-Wall -fno-strict-aliasing $PTHREAD_CFLAGS"
1042 AC_SUBST(AM_CFLAGS)
1043
1044 # The order in which the include folders are searched is important.
1045 # The top_builddir should always be searched first in the event that a build
1046 # time generated file is included. An example of this is the "version.i" file.
1047 # In a scenario where lttng-tools is built from a distribution tarball and in a
1048 # out-of-tree manner, the generated "version.i" has priority on the one from
1049 # the source (distribution tarball) and must be found first.
1050 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1051 AC_SUBST(AM_CPPFLAGS)
1052
1053 lttngincludedir="${includedir}/lttng"
1054 AC_SUBST(lttngincludedir)
1055
1056 lttngactionincludedir="${includedir}/lttng/action"
1057 AC_SUBST(lttngactionincludedir)
1058
1059 lttngconditionincludedir="${includedir}/lttng/condition"
1060 AC_SUBST(lttngconditionincludedir)
1061
1062 lttngnotificationincludedir="${includedir}/lttng/notification"
1063 AC_SUBST(lttngnotificationincludedir)
1064
1065 lttngtriggerincludedir="${includedir}/lttng/trigger"
1066 AC_SUBST(lttngtriggerincludedir)
1067
1068 lttnglibexecdir="${libdir}/lttng/libexec"
1069 AC_SUBST(lttnglibexecdir)
1070
1071 AC_CONFIG_FILES([
1072         Makefile
1073         doc/Makefile
1074         doc/man/Makefile
1075         doc/man/asciidoc-attrs.conf
1076         include/Makefile
1077         extras/Makefile
1078         extras/bindings/Makefile
1079         extras/bindings/swig/Makefile
1080         extras/bindings/swig/python/Makefile
1081         extras/core-handler/Makefile
1082         src/Makefile
1083         src/common/Makefile
1084         src/common/kernel-ctl/Makefile
1085         src/common/kernel-consumer/Makefile
1086         src/common/consumer/Makefile
1087         src/common/ust-consumer/Makefile
1088         src/common/hashtable/Makefile
1089         src/common/sessiond-comm/Makefile
1090         src/common/compat/Makefile
1091         src/common/relayd/Makefile
1092         src/common/testpoint/Makefile
1093         src/common/index/Makefile
1094         src/common/health/Makefile
1095         src/common/config/Makefile
1096         src/common/string-utils/Makefile
1097         src/common/fd-tracker/Makefile
1098         src/lib/Makefile
1099         src/lib/lttng-ctl/Makefile
1100         src/lib/lttng-ctl/filter/Makefile
1101         src/lib/lttng-ctl/lttng-ctl.pc
1102         src/bin/Makefile
1103         src/bin/lttng-consumerd/Makefile
1104         src/bin/lttng-sessiond/Makefile
1105         src/bin/lttng-relayd/Makefile
1106         src/bin/lttng/Makefile
1107         src/bin/lttng-crash/Makefile
1108         tests/Makefile
1109         tests/destructive/Makefile
1110         tests/regression/Makefile
1111         tests/regression/kernel/Makefile
1112         tests/regression/tools/Makefile
1113         tests/regression/tools/streaming/Makefile
1114         tests/regression/tools/filtering/Makefile
1115         tests/regression/tools/health/Makefile
1116         tests/regression/tools/tracefile-limits/Makefile
1117         tests/regression/tools/snapshots/Makefile
1118         tests/regression/tools/live/Makefile
1119         tests/regression/tools/exclusion/Makefile
1120         tests/regression/tools/save-load/Makefile
1121         tests/regression/tools/save-load/configuration/Makefile
1122         tests/regression/tools/mi/Makefile
1123         tests/regression/tools/wildcard/Makefile
1124         tests/regression/tools/crash/Makefile
1125         tests/regression/tools/regen-metadata/Makefile
1126         tests/regression/tools/regen-statedump/Makefile
1127         tests/regression/tools/notification/Makefile
1128         tests/regression/tools/rotation/Makefile
1129         tests/regression/tools/base-path/Makefile
1130         tests/regression/tools/metadata/Makefile
1131         tests/regression/tools/working-directory/Makefile
1132         tests/regression/tools/relayd-grouping/Makefile
1133         tests/regression/ust/Makefile
1134         tests/regression/ust/nprocesses/Makefile
1135         tests/regression/ust/high-throughput/Makefile
1136         tests/regression/ust/low-throughput/Makefile
1137         tests/regression/ust/before-after/Makefile
1138         tests/regression/ust/buffers-pid/Makefile
1139         tests/regression/ust/periodical-metadata-flush/Makefile
1140         tests/regression/ust/multi-session/Makefile
1141         tests/regression/ust/multi-lib/Makefile
1142         tests/regression/ust/overlap/Makefile
1143         tests/regression/ust/overlap/demo/Makefile
1144         tests/regression/ust/linking/Makefile
1145         tests/regression/ust/daemon/Makefile
1146         tests/regression/ust/exit-fast/Makefile
1147         tests/regression/ust/fork/Makefile
1148         tests/regression/ust/libc-wrapper/Makefile
1149         tests/regression/ust/baddr-statedump/Makefile
1150         tests/regression/ust/ust-dl/Makefile
1151         tests/regression/ust/java-jul/Makefile
1152         tests/regression/ust/java-log4j/Makefile
1153         tests/regression/ust/python-logging/Makefile
1154         tests/regression/ust/getcpu-override/Makefile
1155         tests/regression/ust/clock-override/Makefile
1156         tests/regression/ust/type-declarations/Makefile
1157         tests/regression/ust/rotation-destroy-flush/Makefile
1158         tests/regression/ust/blocking/Makefile
1159         tests/regression/ust/namespaces/Makefile
1160         tests/stress/Makefile
1161         tests/unit/Makefile
1162         tests/unit/ini_config/Makefile
1163         tests/perf/Makefile
1164         tests/utils/Makefile
1165         tests/utils/tap/Makefile
1166         tests/utils/testapp/Makefile
1167         tests/utils/testapp/gen-ns-events/Makefile
1168         tests/utils/testapp/gen-ust-events/Makefile
1169         tests/utils/testapp/gen-ust-events-ns/Makefile
1170         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1171         tests/utils/testapp/gen-ust-nevents/Makefile
1172         tests/utils/testapp/gen-ust-nevents-str/Makefile
1173         tests/utils/testapp/gen-syscall-events/Makefile
1174         tests/utils/testapp/gen-ust-tracef/Makefile
1175         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1176         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1177         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1178 ])
1179
1180 # Inject variable into python test script.
1181 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1182 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1183 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1184 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1185
1186 AC_OUTPUT
1187
1188 #
1189 # Mini-report on what will be built.
1190 #
1191
1192 PPRINT_INIT
1193 PPRINT_SET_INDENT(1)
1194 PPRINT_SET_TS(38)
1195
1196 AS_ECHO
1197 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1198 AS_ECHO
1199
1200 AS_IF([test -n "$report_fold"], [
1201         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1202 ], [
1203         AS_ECHO("$version_description")
1204 ])
1205
1206 AS_ECHO
1207 PPRINT_SUBTITLE([Features])
1208
1209 # Target architecture we're building for.
1210 target_arch=$host_cpu
1211 [
1212 for f in $CFLAGS; do
1213         if test $f = "-m32"; then
1214                         target_arch="32-bit"
1215         elif test $f = "-m64"; then
1216                         target_arch="64-bit"
1217         fi
1218 done
1219 ]
1220 PPRINT_PROP_STRING([Target architecture], $target_arch)
1221
1222 # kmod enabled/disabled
1223 test "x$with_kmod" != "xno" && value=1 || value=0
1224 PPRINT_PROP_BOOL([libkmod support], $value)
1225
1226 # LTTng-UST enabled/disabled
1227 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1228 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1229
1230 AS_ECHO
1231 PPRINT_SUBTITLE([Binaries])
1232
1233 # List binaries to be built
1234 test x$enable_bin_lttng != xno && value=1 || value=0
1235 PPRINT_PROP_BOOL([lttng], $value)
1236
1237 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1238 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1239
1240 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1241 PPRINT_PROP_BOOL([lttng-crash], $value)
1242
1243 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1244 PPRINT_PROP_BOOL([lttng-relayd], $value)
1245
1246 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1247 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1248
1249 # Extras
1250 test x$enable_extras != xno && value=1 || value=0
1251 AS_ECHO
1252 PPRINT_SET_INDENT(0)
1253 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1254 PPRINT_SET_INDENT(1)
1255
1256 AS_ECHO
1257 PPRINT_SUBTITLE([Tests])
1258
1259 # Print clear message that tests won't be built
1260 AS_IF([test "x$build_tests" = "xno"],[
1261         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1262 ])
1263
1264 # LTTng UST Java agent JUL tests enabled/disabled
1265 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1266 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1267
1268 # LTTng UST Java agent Log4j tests enabled/disabled
1269 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1270 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1271
1272 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1273 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1274
1275 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1276 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1277
1278 # LTTng UST Java agent Log4j tests enabled/disabled
1279 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1280 PPRINT_PROP_BOOL([LTTng-UST SDT uprobe tests], $value)
1281
1282 #Python binding enabled/disabled
1283 test "x$enable_python_binding" = xyes && value=1 || value=0
1284 AS_ECHO
1285 PPRINT_SET_INDENT(0)
1286 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1287
1288 # man pages build enabled/disabled
1289 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1290
1291 AS_IF([test "x$man_pages_opt" != "xno"], [
1292         AS_IF([test "x$in_git_repo" = "xyes"], [
1293                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1294         ], [
1295                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1296                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1297                 ], [
1298                         PPRINT_PROP_STRING([build_man_pages_msg],
1299                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1300                                 $PPRINT_COLOR_SUBTITLE)
1301                 ])
1302         ])
1303 ], [
1304         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1305 ])
1306
1307 m4_popdef([build_man_pages_msg])
1308
1309 test "x$embedded_help" = xyes && value=1 || value=0
1310 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1311
1312 PPRINT_SET_INDENT(1)
1313
1314 report_bindir="`eval eval echo $bindir`"
1315 report_libdir="`eval eval echo $libdir`"
1316
1317 # Print the bindir and libdir this `make install' will install into.
1318 AS_ECHO
1319 PPRINT_SUBTITLE([Install directories])
1320 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1321 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1322
1323 AS_ECHO
1324 PPRINT_SUBTITLE([Search directories])
1325
1326 # If we build the sessiond, print the paths it will use
1327 AS_IF([test "$SESSIOND_BIN" = ""],[
1328         path="$report_bindir/lttng-sessiond"
1329 ],[
1330         path="$SESSIOND_BIN"
1331 ])
1332 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1333
1334 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1335         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1336 ],[
1337         path="$CONSUMERD32_BIN"
1338 ])
1339 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1340
1341 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1342         path="`eval eval echo $libdir`"
1343 ],[
1344         path="$CONSUMERD32_LIBDIR"
1345 ])
1346 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1347
1348 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1349         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1350 ],[
1351         path="$CONSUMERD64_BIN"
1352 ])
1353 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1354
1355 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1356         path="`eval eval echo $libdir`"
1357 ],[
1358         path="$CONSUMERD64_LIBDIR"
1359 ])
1360 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1361 PPRINT_SET_INDENT(0)
1362
1363 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1364         AS_ECHO
1365         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1366
1367 Note that the man pages are already built in this distribution tarball,
1368 therefore asciidoc and xmlto are only needed if you intend to modify
1369 their sources.
1370
1371 Also note that the installed man pages will contain the project's
1372 default command-line option and environment variable values.
1373
1374 Use --disable-man-pages to completely disable building and installing
1375 the man pages.])
1376 ])