configure.ac

   1 dnl SPDX-License-Identifier: GPL-2.0-only
   2 AC_PREREQ([2.64])
   3 AC_INIT([lttng-tools],[2.14.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   4
   5 AC_CONFIG_HEADERS([include/config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18
  19 ##                   ##
  20 ## C compiler checks ##
  21 ##                   ##
  22
  23 # Choose the C compiler
  24 AC_PROG_CC
  25 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  26 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  27
  28 # Make sure the C compiler supports C99
  29 AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])])
  30
  31 # Enable available system extensions and LFS support
  32 AC_USE_SYSTEM_EXTENSIONS
  33 AC_SYS_LARGEFILE
  34
  35 # Make sure the C compiler supports __attribute__
  36 AX_C___ATTRIBUTE__
  37 AS_IF([test "x$ax_cv___attribute__" != "xyes"],
  38   [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  39
  40 # Make sure we have pthread support
  41 AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])])
  42
  43 # Checks for typedefs, structures, and compiler characteristics.
  44 AC_C_INLINE
  45 AC_TYPE_INT32_T
  46 AC_TYPE_INT64_T
  47 AC_TYPE_MODE_T
  48 AC_TYPE_OFF_T
  49 AC_TYPE_PID_T
  50 AC_TYPE_SIZE_T
  51 AC_TYPE_SSIZE_T
  52 AC_TYPE_UID_T
  53 AC_TYPE_UINT16_T
  54 AC_TYPE_UINT32_T
  55 AC_TYPE_UINT64_T
  56 AC_TYPE_UINT8_T
  57
  58 # Detect warning flags supported by the C and C++ compilers and append them to
  59 # WARN_CFLAGS and WARN_CXXFLAGS.
  60 m4_define([WARN_FLAGS_LIST], [ dnl
  61   -Wall dnl
  62   dnl We currently get this warning when building with Clang:
  63   dnl
  64   dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration]
  65   dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL;
  66   dnl            ^
  67   -Wno-incomplete-setjmp-declaration dnl
  68   -Wdiscarded-qualifiers dnl
  69   -Wmissing-declarations dnl
  70   -Wmissing-prototypes dnl
  71   -Wmissing-parameter-type dnl
  72   -Wshadow dnl
  73   -Wno-gnu-folding-constant dnl
  74   -Wsuggest-attribute=format dnl
  75   -Wformat=2 dnl
  76   dnl GCC enables this with -Wall in C++, and that generates a
  77   dnl lot of warnings that have on average a low value to fix.
  78   -Wno-sign-compare dnl
  79 ])
  80
  81 # Pass -Werror as an extra flag during the test: this is needed to make the
  82 # -Wunknown-warning-option diagnostic fatal with clang.
  83 AC_LANG_PUSH([C])
  84 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CFLAGS], [-Werror])
  85 AC_LANG_POP([C])
  86
  87 # The test used in AX_APPEND_COMPILE_FLAGS, generated using AC_LANG_PROGRAM, is
  88 # written in such a way that it triggers warnings with the following warning
  89 # flags.  So they would always end up disabled if we put them there, because
  90 # the test program would not build.
  91 #
  92 # Enable them here unconditionally.  They are supported by GCC >= 4.8 and by
  93 # Clang >= 3.3 (required by the project) and are only valid for C code.
  94 WARN_CFLAGS="${WARN_CFLAGS} -Wold-style-definition -Wstrict-prototypes"
  95
  96 # Disable 'strict aliasing' if the C compiler supports it.
  97 AC_LANG_PUSH([C])
  98 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CFLAGS], [-Werror])
  99 AC_LANG_POP([C])
 100
 101
 102 ##                     ##
 103 ## C++ compiler checks ##
 104 ##                     ##
 105
 106 # Find a C++11 compiler with GNU extensions (-std=gnu++11)
 107 AX_CXX_COMPILE_STDCXX([11], [ext], [mandatory])
 108
 109 # Pass -Werror as an extra flag during the test: this is needed to make the
 110 # -Wunknown-warning-option diagnostic fatal with clang.
 111 AC_LANG_PUSH([C++])
 112 AX_APPEND_COMPILE_FLAGS([WARN_FLAGS_LIST], [WARN_CXXFLAGS], [-Werror])
 113 AC_LANG_POP([C++])
 114
 115 # Disable 'strict aliasing' if the C++ compiler supports it.
 116 AC_LANG_PUSH([C++])
 117 AX_APPEND_COMPILE_FLAGS([-fno-strict-aliasing], [OPT_CXXFLAGS], [-Werror])
 118 AC_LANG_POP([C++])
 119
 120
 121 # When given, add -Werror to WARN_CFLAGS and WARN_CXXFLAGS.
 122 AC_ARG_ENABLE([Werror],[
 123   AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])
 124 ])
 125
 126 AS_IF([test "x$enable_Werror" = "xyes"], [
 127   WARN_CFLAGS="${WARN_CFLAGS} -Werror"
 128   WARN_CXXFLAGS="${WARN_CXXFLAGS} -Werror"
 129 ])
 130
 131 # Checks for programs.
 132 AC_PROG_GREP
 133 AC_PROG_MAKE_SET
 134 AC_PROG_SED
 135 AC_PATH_PROG([report_fold], [fold])
 136 LT_INIT
 137
 138 # Check for objcopy, required by the base address statedump and dynamic linker tests
 139 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
 140 AS_IF([test "x$OBJCOPY" = "xno"],
 141         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
 142 )
 143 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
 144
 145 # check for pgrep
 146 AC_PATH_PROG([PGREP], [pgrep], [no])
 147 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
 148
 149 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 150 # is not distributed in tarballs
 151 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 152 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 153
 154 # check for bison
 155 AC_PROG_YACC
 156 BISON=$YACC
 157 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
 158
 159 AS_IF([test "x$have_bison" != "xyes"], [
 160   AS_IF([test "x$in_git_repo" = "xyes"], [
 161     AC_MSG_FAILURE([
 162 Bison >= 2.4 is required when building from the Git repository. You can
 163 set the YACC variable to override automatic detection.
 164     ])
 165   ], [
 166     AC_MSG_WARN([
 167 Missing Bison >= 2.4. Note that the parser files are already built in
 168 this distribution tarball, so Bison is only needed if you intend to
 169 modify their sources. You can set the YACC variable to override automatic
 170 detection.
 171     ])
 172   ])
 173 ])
 174 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 175
 176 # check for flex
 177 # Prior to autoconf 2.70, AC_PROG_FLEX did not take an argument. This is not a
 178 # problem since the argument is silently ignored by older versions.
 179 AC_PROG_LEX([noyywrap])
 180 FLEX=$LEX
 181 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 182
 183 AS_IF([test "x$have_flex" != "xyes"], [
 184   AS_IF([test "x$in_git_repo" = "xyes"], [
 185     AC_MSG_FAILURE([
 186 Flex >= 2.5.35 is required when building from the Git repository. You can
 187 set the LEX variable to override automatic detection.
 188     ])
 189   ], [
 190     AC_MSG_WARN([
 191 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 192 this distribution tarball, so Flex is only needed if you intend to
 193 modify their sources. You can set the LEX variable to override automatic
 194 detection.
 195     ])
 196   ])
 197 ])
 198 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 199
 200
 201
 202 # Check if linker has the -no-pie option.
 203 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 204 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 205
 206 AX_LIB_SOCKET_NSL
 207
 208 LT_NO_UNDEFINED=""
 209 AS_CASE([$host_os],
 210   [cygwin*],
 211     [
 212       LT_NO_UNDEFINED="-no-undefined"
 213     ],
 214   [cygwin*|darwin*|mingw*|solaris*],
 215     [
 216       # On platforms where we only support the relayd, disable the other binaries by default
 217       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 218       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 219       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 220       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 221       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 222       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 223     ]
 224 )
 225
 226 AC_SUBST(LT_NO_UNDEFINED)
 227
 228 # Compute minor/major/patchlevel version numbers
 229 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 230 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 231 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 232
 233 AC_SUBST([MAJOR_VERSION], [$major_version])
 234 AC_SUBST([MINOR_VERSION], [$minor_version])
 235 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 236 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 237 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 238 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 239
 240 version_name="O-Beer"
 241 version_description="An alcoholic drink made from yeast-fermented malt flavored with hops."
 242 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 243
 244 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 245 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 246
 247 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 248 AC_ARG_ENABLE(libtool-linkdep-fixup,
 249         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 250                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 251         libtool_fixup=$enableval,
 252         libtool_fixup=yes)
 253
 254 AS_IF([test "x$libtool_fixup" = "xyes"],
 255             [
 256             libtool_m4="$srcdir/m4/libtool.m4"
 257             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 258             AC_MSG_CHECKING([for occurrence(s) of link_all_deplibs = no in $libtool_m4])
 259             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 260             AS_IF([test $libtool_flag_pattern_count -ne 0],
 261             [
 262                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 263                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 264                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 265                   ],
 266                   [
 267                   AC_MSG_RESULT([none])
 268                   ])
 269             ])
 270
 271 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 272
 273 AC_CHECK_HEADERS([ \
 274         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 275         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 276         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 277         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 278         sys/mount.h sys/param.h sys/time.h elf.h
 279 ])
 280
 281 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 282
 283 # Basic functions check
 284 AC_CHECK_FUNCS([ \
 285         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 286         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 287         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 288         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 289         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 290         sched_getcpu sysconf sync_file_range
 291 ])
 292
 293 # Check for pthread_setname_np and pthread_getname_np
 294 LTTNG_PTHREAD_SETNAME_NP
 295 LTTNG_PTHREAD_GETNAME_NP
 296
 297 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 298 # add -lrt to LIBS
 299 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 300
 301 # Checks for dl.
 302 AC_CHECK_LIB([dl], [dlopen], [
 303         have_libdl=yes
 304         libdl_name=dl
 305         DL_LIBS="-ldl"
 306 ], [
 307         # libdl not found, check for dlopen in libc.
 308         AC_CHECK_LIB([c], [dlopen], [
 309                 have_libc_dl=yes
 310                 libdl_name=c
 311                 DL_LIBS="-lc"
 312         ], [
 313                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 314         ])
 315 ])
 316 AC_SUBST(DL_LIBS)
 317
 318 # Check if libdl has dlmopen support.
 319 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 320 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 321         AC_DEFINE([HAVE_DLMOPEN], [1])
 322         HAVE_DLMOPEN=1
 323 ], [
 324         HAVE_DLMOPEN=0
 325 ])
 326 AC_SUBST(HAVE_DLMOPEN)
 327
 328 # Babeltrace viewer check
 329 AC_ARG_WITH([babeltrace-bin],
 330         AS_HELP_STRING([--with-babeltrace-bin],
 331         [Location of the babeltrace viewer executable (including the filename)]),
 332         [BABELTRACE_BIN="$withval"],
 333         [BABELTRACE_BIN=''])
 334 AC_SUBST([BABELTRACE_BIN])
 335
 336 AC_ARG_WITH([babeltrace2-bin],
 337         AS_HELP_STRING([--with-babeltrace2-bin],
 338         [Location of the babeltrace2 viewer executable (including the filename)]),
 339         [BABELTRACE2_BIN="$withval"],
 340         [BABELTRACE2_BIN=''])
 341 AC_SUBST([BABELTRACE2_BIN])
 342
 343 AC_ARG_WITH([consumerd32-bin],
 344         AS_HELP_STRING([--with-consumerd32-bin],
 345         [Location of the 32-bit consumerd executable (including the filename)]),
 346         [CONSUMERD32_BIN="$withval"],
 347         [CONSUMERD32_BIN=''])
 348 AC_SUBST([CONSUMERD32_BIN])
 349
 350 AC_ARG_WITH([consumerd64-bin],
 351         AS_HELP_STRING([--with-consumerd64-bin],
 352         [Location of the 64-bit consumerd executable (including the filename)]),
 353         [CONSUMERD64_BIN="$withval"],
 354         [CONSUMERD64_BIN=''])
 355 AC_SUBST([CONSUMERD64_BIN])
 356
 357 AC_ARG_WITH([consumerd32-libdir],
 358         AS_HELP_STRING([--with-consumerd32-libdir],
 359         [Directory containing the 32-bit consumerd libraries]),
 360         [CONSUMERD32_LIBDIR="$withval"],
 361         [CONSUMERD32_LIBDIR=''])
 362 AC_SUBST([CONSUMERD32_LIBDIR])
 363
 364 AC_ARG_WITH([consumerd64-libdir],
 365         AS_HELP_STRING([--with-consumerd64-libdir],
 366         [Directory containing the 64-bit consumerd libraries]),
 367         [CONSUMERD64_LIBDIR="$withval"],
 368         [CONSUMERD64_LIBDIR=''])
 369 AC_SUBST([CONSUMERD64_LIBDIR])
 370
 371 AC_ARG_WITH([sessiond-bin],
 372         AS_HELP_STRING([--with-sessiond-bin],
 373         [Location of the sessiond executable (including the filename)]),
 374         [SESSIOND_BIN="$withval"],
 375         [SESSIOND_BIN=''])
 376 AC_SUBST([SESSIOND_BIN])
 377
 378 AC_ARG_WITH([lttng-system-rundir],
 379         AS_HELP_STRING([--with-lttng-system-rundir],
 380         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 381         [LTTNG_SYSTEM_RUNDIR="$withval"],
 382         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 383 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 384
 385 AC_ARG_ENABLE([test-java-agent-jul],
 386         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 387         [test_java_agent_jul=$enableval],
 388         [test_java_agent_jul=no]
 389 )
 390
 391 AC_ARG_ENABLE([test-java-agent-log4j],
 392         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 393         [test_java_agent_log4j=$enableval],
 394         [test_java_agent_log4j=no]
 395 )
 396
 397 AC_ARG_ENABLE([test-java-agent-all],
 398         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 399         [test_java_agent_jul=$enableval
 400          test_java_agent_log4j=$enableval],
 401         [:]
 402 )
 403
 404 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 405 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 406 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 407 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 408 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 409 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.])
 410 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 411 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 412
 413 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 414         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 415         $1="$2"
 416         AC_SUBST([$1])
 417 ])
 418
 419 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 420         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 421         $1="$2"
 422         AC_SUBST([$1])
 423 ])
 424
 425 # Default values
 426 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 427 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 428 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 429 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 430 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 431 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 432 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 433 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 434 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 435 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 436 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 437 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 438 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 439 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 440 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 441 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 442 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 443 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 444 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 445 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 446 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 447 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 448 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 449 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 450 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 451 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 452 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 453 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 454 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 455 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 456 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 457 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 458 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 459 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 460 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 461 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 462 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 463 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 464 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 465 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 466 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 467 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 468 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 469 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 470 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 471 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 472 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 473 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 474 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 475 _AC_DEFINE_AND_SUBST([DEFAULT_EVENT_NOTIFIER_ERROR_COUNT_MAP_SIZE], [4096])
 476
 477 # Command short descriptions
 478 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to be recorded])
 479 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_TRIGGER], [Add a trigger])
 480 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a recording session])
 481 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a recording session])
 482 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Destroy recording sessions])
 483 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable channels])
 484 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable recording event rules])
 485 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a recording session rotation schedule])
 486 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable a channel])
 487 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable recording event rules])
 488 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a recording session rotation schedule])
 489 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Show the help of a command])
 490 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List recording sessions and instrumentation points])
 491 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST_TRIGGERS], [List triggers])
 492 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load recording session configurations])
 493 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Regenerate specific recording session data])
 494 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REMOVE_TRIGGER], [Remove a trigger])
 495 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive the current trace chunk of a recording session])
 496 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save recording session configurations])
 497 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set the current recording session])
 498 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Take a recording session snapshot])
 499 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start a recording session])
 500 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Show the status of the current recording session])
 501 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop a recording session])
 502 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Allow specific processes to record events])
 503 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Disallow specific processes to record events])
 504 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show LTTng-tools version information])
 505 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Launch a trace reader])
 506
 507 if test "x$prefix" = "xNONE"; then
 508         prefix=$ac_default_prefix
 509 fi
 510 CONFDIR=`eval echo $sysconfdir`
 511 AC_SUBST(CONFDIR)
 512 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 513
 514 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
 515
 516 # Check libpopt
 517 PKG_CHECK_MODULES([POPT], [popt],
 518   [
 519     dnl PKG_CHECK_MODULES defines POPT_LIBS
 520   ],
 521   [
 522     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 523     AC_MSG_WARN([Finding libpopt without pkg-config.])
 524     AC_CHECK_LIB([popt],
 525       [poptGetContext],
 526       [POPT_LIBS="-lpopt"],
 527       [
 528         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 529       ]
 530     )
 531   ]
 532 )
 533 AC_SUBST(POPT_LIBS)
 534
 535 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 536
 537 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 538
 539 # URCU library version needed or newer
 540 PKG_CHECK_MODULES([URCU], [liburcu >= 0.11])
 541 PKG_CHECK_MODULES([URCU_CDS], [liburcu-cds >= 0.11])
 542 AM_CPPFLAGS="$AM_CPPFLAGS $URCU_CFLAGS"
 543
 544 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 545 # it can be explicitly disabled with --without-kmod
 546 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 547 AC_ARG_WITH([kmod],
 548   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 549   [],
 550   [with_kmod=check]
 551 )
 552
 553 AS_IF([test "x$with_kmod" != "xno"],
 554   [
 555     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 556       [
 557         AC_DEFINE([HAVE_KMOD], [1])
 558         KMOD_LIBS="-lkmod"
 559       ],
 560       [
 561         if test "x$with_kmod" != xcheck; then
 562           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 563         else
 564           with_kmod=no
 565         fi
 566       ]
 567     )
 568   ]
 569 )
 570 AC_SUBST(KMOD_LIBS)
 571
 572 # Check for liblttng-ust-ctl, fail if it's not found,
 573 # it can be explicitly disabled with --without-lttng-ust
 574 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 575 AC_ARG_WITH([lttng-ust],
 576   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 577   [],
 578   [with_lttng_ust=yes]
 579 )
 580
 581 AS_IF([test "x$with_lttng_ust" = "xyes"], [
 582   AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 583
 584   # Check for liblttng-ust
 585   PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
 586
 587   # Check for liblttng-ust-ctl
 588   PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
 589
 590   AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
 591 ])
 592
 593 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 594
 595
 596 # Check for fmemopen
 597 AC_CHECK_LIB([c], [fmemopen],
 598 [
 599         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 600 ]
 601 )
 602
 603 # check for libpfm
 604 AC_CHECK_LIB([pfm], [pfm_initialize],
 605              [
 606               have_libpfm=yes
 607               ])
 608 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 609
 610 # For Python
 611 # SWIG version needed or newer:
 612 swig_version=2.0.0
 613
 614 AC_ARG_ENABLE([python-bindings],
 615               [AS_HELP_STRING([--enable-python-bindings],
 616                               [compile Python bindings])],
 617               [enable_python_binding=$enableval], [enable_python_binding=no])
 618
 619 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 620
 621 if test "x$enable_python_binding" = xyes; then
 622   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 623   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 624   AM_PATH_PYTHON([3.0])
 625
 626   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 627   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 628   AS_IF([test -z "$PYTHON_INCLUDE"], [
 629     AS_IF([test -z "$PYTHON_CONFIG"], [
 630       AC_PATH_PROGS([PYTHON_CONFIG],
 631                     [python$PYTHON_VERSION-config python-config],
 632                     [no],
 633                     [`dirname $PYTHON`])
 634       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 635     ])
 636     AC_MSG_CHECKING([python include flags])
 637     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 638     AC_MSG_RESULT([$PYTHON_INCLUDE])
 639   ])
 640
 641 else
 642     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 643 [if you want Python bindings.])
 644
 645 fi
 646
 647 # Epoll check. If not present, the build will fallback on poll() API
 648 AX_HAVE_EPOLL(
 649         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 650         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 651 )
 652 AX_CONFIG_FEATURE(
 653         [epoll], [This platform supports epoll(7)],
 654         [HAVE_EPOLL], [This platform supports epoll(7).]
 655 )
 656
 657 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
 658         [AX_CONFIG_FEATURE_ENABLE(dirfd)],
 659         [AX_CONFIG_FEATURE_DISABLE(dirfd)]
 660 )
 661 AX_CONFIG_FEATURE(
 662         [dirfd], [Use directory file descriptors],
 663         [HAVE_DIRFD], [This platform supports directory file descriptors.]
 664 )
 665
 666 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 667 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 668
 669 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 670         AX_JAVA_OPTIONS
 671         AX_PROG_JAVAC
 672         AX_PROG_JAVA
 673         AX_PROG_JAR
 674
 675         AX_CHECK_CLASSPATH
 676
 677         # Check for Java UST agent common class first
 678         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 679         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 680                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 681         fi
 682
 683         if test "x$test_java_agent_jul" = "xyes"; then
 684                 # Check for JUL agent class
 685                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 686                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 687                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 688                 fi
 689         fi
 690
 691         if test "x$test_java_agent_log4j" = "xyes"; then
 692                 # Check for Log4j agent class
 693                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 694                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 695                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 696                 fi
 697
 698                 # Check for Log4j class
 699                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 700                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 701                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 702                 fi
 703         fi
 704 fi
 705
 706 # enable building man pages (user's intention)
 707 AC_ARG_ENABLE(
 708         man-pages,
 709         AS_HELP_STRING(
 710                 [--disable-man-pages],
 711                 [Do not build and install man pages (already built in a distributed tarball)]
 712         ),
 713         [man_pages_opt=$enableval],
 714         [man_pages_opt=yes]
 715 )
 716
 717 # check for asciidoc and xmlto if we enabled building the man pages
 718 have_asciidoc_xmlto=no
 719 warn_prebuilt_man_pages=no
 720
 721 AS_IF([test "x$man_pages_opt" = "xyes"], [
 722         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 723         AC_PATH_PROG([XMLTO], [xmlto], [no])
 724
 725         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 726                 AS_IF([test "x$in_git_repo" = "xyes"], [
 727                         # this is an error because we're in the Git repo, which
 728                         # means the man pages are not already generated for us,
 729                         # thus asciidoc/xmlto are required because we were asked
 730                         # to build the man pages
 731                         AC_MSG_ERROR([
 732 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 733 --disable-man-pages to disable building the man pages, in which case
 734 they will not be installed.
 735                         ])
 736                 ], [
 737                         # only warn here: since we're in the tarball, the man
 738                         # pages should already be generated at this point, thus
 739                         # asciidoc/xmlto are not strictly required
 740                         warn_prebuilt_man_pages=yes
 741                 ])
 742         ], [
 743                 have_asciidoc_xmlto=yes
 744         ])
 745 ])
 746
 747 # export man page build condition: build the man pages if the user
 748 # asked for it, and if the tools are available
 749 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 750 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 751
 752 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 753
 754 # embedded --help message
 755 AC_ARG_ENABLE(
 756         [embedded-help],
 757         AS_HELP_STRING(
 758                 [--enable-embedded-help],
 759                 [Embed the --help messages in the executable files]
 760         ),
 761         [embedded_help=$enableval],
 762         [embedded_help=no]
 763 )
 764 AS_IF([test "x$embedded_help" = "xyes"], [
 765         AS_IF([test "x$man_pages_opt" = "xno"], [
 766                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 767         ])
 768         AC_PATH_PROG([man_prog_path], [man], [no])
 769         AS_IF([test "x$man_prog_path" = "xno"], [
 770                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 771         ])
 772         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 773         AC_SUBST([MANPROG], [$man_prog_path])
 774 ])
 775 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 776
 777 # Python agent test
 778 UST_PYTHON_AGENT="lttngust"
 779
 780 AC_ARG_ENABLE(test-python2-agent,
 781         AS_HELP_STRING([--enable-test-python2-agent],
 782                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 783         ),[:],[test_python2_agent_autodetect=yes]
 784 )
 785
 786 AC_ARG_ENABLE(test-python3-agent,
 787         AS_HELP_STRING([--enable-test-python3-agent],
 788                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 789         ),[:],[test_python3_agent_autodetect=yes]
 790 )
 791
 792 AC_ARG_ENABLE(test-python-agent-all,
 793         AS_HELP_STRING([--enable-test-python-agent-all],
 794                 [enable test for all python{2/3} agent.]
 795         ),
 796 )
 797
 798 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 799        unset test_python2_agent_autodetect
 800        unset test_python3_agent_autodetect
 801 ])
 802
 803 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 804        enable_test_python2_agent=yes
 805        enable_test_python3_agent=yes
 806 ])
 807
 808 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 809        enable_test_python2_agent=no
 810        enable_test_python3_agent=no
 811 ])
 812
 813
 814 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 815         AS_IF([test -z "$PYTHON2"], [
 816                         PYTHON2=python2
 817                 ], [
 818                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 819         ])
 820
 821         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 822         AS_IF([test -z "$PYTHON2_BIN"], [
 823                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 824                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 825                 ])
 826         ], [
 827                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 828                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 829                         PYTHON2_AGENT=$PYTHON2_BIN
 830                         AC_MSG_RESULT([yes])
 831                         RUN_PYTHON_AGENT_TEST=yes
 832                 ], [
 833                         AC_MSG_RESULT([no])
 834                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 835                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 836                         ])
 837                 ])
 838
 839         ])
 840
 841 ])
 842
 843 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 844         AS_IF([test -z "$PYTHON3"], [
 845                 PYTHON3=python3
 846         ], [
 847                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 848         ])
 849
 850         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 851         AS_IF([test -z "$PYTHON3_BIN"], [
 852                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 853                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 854                 ])
 855         ], [
 856                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 857                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 858                         PYTHON3_AGENT=$PYTHON3_BIN
 859                         AC_MSG_RESULT([yes])
 860                         RUN_PYTHON_AGENT_TEST=yes
 861                 ], [
 862                         AC_MSG_RESULT([no])
 863                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 864                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 865                         ])
 866                 ])
 867
 868         ])
 869 ])
 870 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 871 AC_SUBST([PYTHON2_AGENT])
 872 AC_SUBST([PYTHON3_AGENT])
 873
 874 AC_ARG_ENABLE([test-sdt-uprobe],
 875   [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
 876   [test_sdt_uprobe="$enableval"],
 877   [test_sdt_uprobe=autodetect]
 878 )
 879
 880 AS_IF([test "$test_sdt_uprobe" != "no"], [
 881   LTTNG_CHECK_SDT_WORKS
 882   AC_PATH_PROG([DTRACE], [dtrace])
 883 ])
 884
 885 AS_IF([test "$test_sdt_uprobe" = "yes"], [
 886   AS_IF([test "$lttng_cv_sdt_works" = "no"], [
 887     AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
 888   ])
 889   AS_IF([test "x$DTRACE" = "x"], [
 890     AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
 891   ])
 892 ])
 893
 894 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
 895   AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
 896     AS_IF([test "x$DTRACE" != "x"], [
 897       test_sdt_uprobe=yes
 898     ])
 899   ])
 900 ])
 901
 902 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
 903
 904 # Arguments for binaries build exclusion
 905 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 906 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 907               [Disable the build of lttng-consumerd binaries]))
 908 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 909 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 910               [Disable the build of lttng-relayd binaries]))
 911 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 912               [Disable the build of lttng-sessiond binaries]))
 913 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 914               [Disable the build of the extra components]))
 915
 916
 917 build_lib_consumer=no
 918 build_lib_health=no
 919 build_lib_index=no
 920 build_lib_kernel_consumer=no
 921 build_lib_kernel_ctl=no
 922 build_lib_lttng_ctl=no
 923 build_lib_relayd=no
 924 build_lib_sessiond_comm=no
 925 build_lib_testpoint=no
 926 build_lib_ust_consumer=no
 927
 928 # There is an overlap for enabled dependencies, but this makes everything
 929 # simpler. libcommon and libconfig are always compiled so they are not repeated
 930 # here.
 931
 932 # Enable binary dependencies.
 933 AS_IF([test x$enable_bin_lttng != xno],
 934       [
 935        build_lib_lttng_ctl=yes
 936       ]
 937 )
 938
 939 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 940       [
 941        build_lib_consumer=yes
 942        build_lib_sessiond_comm=yes
 943        build_lib_index=yes
 944        build_lib_health=yes
 945        build_lib_testpoint=yes
 946       ]
 947 )
 948
 949 AS_IF([test x$enable_bin_lttng_crash != xno],
 950       # Do nothing since libconfig and libcommon are built by default.
 951       []
 952 )
 953
 954 AS_IF([test x$enable_bin_lttng_relayd != xno],
 955       [
 956        build_lib_sessiond_comm=yes
 957        build_lib_index=yes
 958        build_lib_health=yes
 959        build_lib_testpoint=yes
 960       ]
 961 )
 962 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 963       [
 964        build_lib_lttng_ctl=yes
 965        build_lib_sessiond_comm=yes
 966        build_lib_kernel_ctl=yes
 967        build_lib_relayd=yes
 968        build_lib_testpoint=yes
 969        build_lib_health=yes
 970       ]
 971 )
 972
 973 # Libraries dependencies enabling
 974 AS_IF([test x$build_lib_lttng_ctl = xyes],
 975       [
 976        build_lib_sessiond_comm=yes
 977       ]
 978 )
 979
 980 AS_IF([test x$build_lib_consumer = xyes],
 981       [
 982        build_lib_sessiond_comm=yes
 983        build_lib_kernel_consumer=yes
 984        build_lib_relayd=yes
 985        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 986       ]
 987 )
 988
 989 AS_IF([test x$build_lib_kernel_consumer = xyes],
 990       [
 991        build_lib_kernel_ctl=yes
 992        build_lib_relayd=yes
 993       ]
 994 )
 995
 996 AS_IF([test x$build_lib_relayd = xyes],
 997       [
 998        build_lib_sessiond_comm=yes
 999       ]
1000 )
1001
1002 # Find arch type
1003 AS_CASE([$host_cpu],
1004         [k1om], [ARCHTYPE="x86"],
1005         [i386], [ARCHTYPE="x86"],
1006         [i486], [ARCHTYPE="x86"],
1007         [i586], [ARCHTYPE="x86"],
1008         [i686], [ARCHTYPE="x86"],
1009         [amd64], [ARCHTYPE="x86"],
1010         [x86_64], [ARCHTYPE="x86"],
1011         [powerpc], [ARCHTYPE="ppc"],
1012         [ppc64], [ARCHTYPE="ppc"],
1013         [powerpc64], [ARCHTYPE="ppc"],
1014         [powerpc64le], [ARCHTYPE="ppc"],
1015         [ppc], [ARCHTYPE="ppc"],
1016         [s390], [ARCHTYPE="s390"],
1017         [s390x], [ARCHTYPE="s390"],
1018         [sparc], [ARCHTYPE="sparc64"],
1019         [sparc64], [ARCHTYPE="sparc64"],
1020         [alpha*], [ARCHTYPE="alpha"],
1021         [ia64], [ARCHTYPE="ia64"],
1022         [arm*], [ARCHTYPE="arm"],
1023         [aarch64*], [ARCHTYPE="aarch64"],
1024         [mips*], [ARCHTYPE="mips"],
1025         [nios2*], [ARCHTYPE="nios2"],
1026         [tile*], [ARCHTYPE="tile"],
1027         [hppa*], [ARCHTYPE="hppa"],
1028         [m68k], [ARCHTYPE="m68k"],
1029         [riscv*], [ARCHTYPE="riscv"],
1030         [ARCHTYPE="unknown"]
1031 )
1032
1033 AC_SUBST(ARCHTYPE)
1034
1035 AS_CASE([$host_os],
1036         [linux*], [OSTYPE="linux"],
1037         [freebsd*], [OSTYPE="freebsd"],
1038         [solaris*], [OSTYPE="solaris"],
1039         [cygwin*], [OSTYPE="cygwin"],
1040         [mingw*], [OSTYPE="mingw"],
1041         [OSTYPE="unknown"]
1042 )
1043 AC_SUBST(OSTYPE)
1044 AM_CONDITIONAL([IS_LINUX], [test $OSTYPE = "linux"])
1045
1046
1047
1048 # Userspace callstack capture is only supported by the Linux kernel on x86.
1049 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1050 AS_IF([test "x$ARCHTYPE" = "xx86" && test "x$OSTYPE" = "xlinux"],[
1051         have_modules_userspace_callstack_context=yes
1052         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1053 ])
1054 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context = xyes])
1055
1056 # Export binaries build conditions.
1057 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1058 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1059 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1060 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1061 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1062
1063 # Export the tests and extras build conditions.
1064 AS_IF([\
1065 test "x$enable_bin_lttng" != "xno" && \
1066 test "x$enable_bin_lttng_consumerd" != "xno" && \
1067 test "x$enable_bin_lttng_crash" != "xno" && \
1068 test "x$enable_bin_lttng_relayd" != "xno" && \
1069 test "x$enable_bin_lttng_sessiond" != "xno"],
1070 [build_tests=yes],
1071 [build_tests=no]
1072 )
1073
1074 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1075 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1076
1077 # Export libraries build conditions.
1078 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1079 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1080 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1081 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1082 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1083 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1084 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1085 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1086 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1087 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1088
1089 AM_CFLAGS="-fvisibility=hidden $OPT_CFLAGS $WARN_CFLAGS $PTHREAD_CFLAGS"
1090 AC_SUBST(AM_CFLAGS)
1091
1092 AM_CXXFLAGS="-fvisibility=hidden -fvisibility-inlines-hidden $OPT_CXXFLAGS $WARN_CXXFLAGS $PTHREAD_CFLAGS"
1093 AC_SUBST(AM_CXXFLAGS)
1094
1095 # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...".
1096 AM_LDFLAGS=""
1097 AC_SUBST(AM_LDFLAGS)
1098
1099 # The order in which the include folders are searched is important.
1100 # The top_builddir should always be searched first in the event that a build
1101 # time generated file is included. An example of this is the "version.i" file.
1102 # In a scenario where lttng-tools is built from a distribution tarball and in a
1103 # out-of-tree manner, the generated "version.i" has priority on the one from
1104 # the source (distribution tarball) and must be found first.
1105 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1106 AC_SUBST(AM_CPPFLAGS)
1107
1108 lttngincludedir="${includedir}/lttng"
1109 AC_SUBST(lttngincludedir)
1110
1111 lttngactionincludedir="${includedir}/lttng/action"
1112 AC_SUBST(lttngactionincludedir)
1113
1114 lttngconditionincludedir="${includedir}/lttng/condition"
1115 AC_SUBST(lttngconditionincludedir)
1116
1117 lttngnotificationincludedir="${includedir}/lttng/notification"
1118 AC_SUBST(lttngnotificationincludedir)
1119
1120 lttngtriggerincludedir="${includedir}/lttng/trigger"
1121 AC_SUBST(lttngtriggerincludedir)
1122
1123 lttngeventruleincludedir="${includedir}/lttng/event-rule"
1124 AC_SUBST(lttngeventruleincludedir)
1125
1126 lttnglibexecdir="${libdir}/lttng/libexec"
1127 AC_SUBST(lttnglibexecdir)
1128
1129 AC_CONFIG_FILES([
1130         Makefile
1131         doc/Makefile
1132         doc/examples/Makefile
1133         doc/examples/rotation/Makefile
1134         doc/examples/trigger-condition-event-matches/Makefile
1135         doc/man/Makefile
1136         doc/man/asciidoc-attrs.conf
1137         include/Makefile
1138         extras/Makefile
1139         extras/bindings/Makefile
1140         extras/bindings/swig/Makefile
1141         extras/bindings/swig/python/Makefile
1142         extras/core-handler/Makefile
1143         src/Makefile
1144         src/common/Makefile
1145         src/common/argpar/Makefile
1146         src/common/bytecode/Makefile
1147         src/common/kernel-ctl/Makefile
1148         src/common/kernel-consumer/Makefile
1149         src/common/consumer/Makefile
1150         src/common/ust-consumer/Makefile
1151         src/common/hashtable/Makefile
1152         src/common/sessiond-comm/Makefile
1153         src/common/compat/Makefile
1154         src/common/relayd/Makefile
1155         src/common/testpoint/Makefile
1156         src/common/index/Makefile
1157         src/common/health/Makefile
1158         src/common/config/Makefile
1159         src/common/ini-config/Makefile
1160         src/common/string-utils/Makefile
1161         src/common/fd-tracker/Makefile
1162         src/common/filter/Makefile
1163         src/lib/Makefile
1164         src/lib/lttng-ctl/Makefile
1165         src/lib/lttng-ctl/lttng-ctl.pc
1166         src/bin/Makefile
1167         src/bin/lttng-consumerd/Makefile
1168         src/bin/lttng-sessiond/Makefile
1169         src/bin/lttng-relayd/Makefile
1170         src/bin/lttng/Makefile
1171         src/bin/lttng-crash/Makefile
1172         src/vendor/Makefile
1173         src/vendor/msgpack/Makefile
1174         tests/Makefile
1175         tests/destructive/Makefile
1176         tests/regression/Makefile
1177         tests/regression/kernel/Makefile
1178         tests/regression/tools/Makefile
1179         tests/regression/tools/streaming/Makefile
1180         tests/regression/tools/filtering/Makefile
1181         tests/regression/tools/health/Makefile
1182         tests/regression/tools/tracefile-limits/Makefile
1183         tests/regression/tools/snapshots/Makefile
1184         tests/regression/tools/live/Makefile
1185         tests/regression/tools/exclusion/Makefile
1186         tests/regression/tools/save-load/Makefile
1187         tests/regression/tools/save-load/configuration/Makefile
1188         tests/regression/tools/mi/Makefile
1189         tests/regression/tools/wildcard/Makefile
1190         tests/regression/tools/channel/Makefile
1191         tests/regression/tools/crash/Makefile
1192         tests/regression/tools/regen-metadata/Makefile
1193         tests/regression/tools/regen-statedump/Makefile
1194         tests/regression/tools/notification/Makefile
1195         tests/regression/tools/rotation/Makefile
1196         tests/regression/tools/base-path/Makefile
1197         tests/regression/tools/metadata/Makefile
1198         tests/regression/tools/tracker/Makefile
1199         tests/regression/tools/working-directory/Makefile
1200         tests/regression/tools/relayd-grouping/Makefile
1201         tests/regression/tools/clear/Makefile
1202         tests/regression/tools/trigger/Makefile
1203         tests/regression/tools/trigger/rate-policy/Makefile
1204         tests/regression/tools/trigger/start-stop/Makefile
1205         tests/regression/tools/trigger/utils/Makefile
1206         tests/regression/tools/trigger/name/Makefile
1207         tests/regression/tools/trigger/hidden/Makefile
1208         tests/regression/ust/Makefile
1209         tests/regression/ust/nprocesses/Makefile
1210         tests/regression/ust/high-throughput/Makefile
1211         tests/regression/ust/low-throughput/Makefile
1212         tests/regression/ust/before-after/Makefile
1213         tests/regression/ust/buffers-pid/Makefile
1214         tests/regression/ust/periodical-metadata-flush/Makefile
1215         tests/regression/ust/multi-session/Makefile
1216         tests/regression/ust/multi-lib/Makefile
1217         tests/regression/ust/overlap/Makefile
1218         tests/regression/ust/overlap/demo/Makefile
1219         tests/regression/ust/linking/Makefile
1220         tests/regression/ust/daemon/Makefile
1221         tests/regression/ust/exit-fast/Makefile
1222         tests/regression/ust/fork/Makefile
1223         tests/regression/ust/libc-wrapper/Makefile
1224         tests/regression/ust/baddr-statedump/Makefile
1225         tests/regression/ust/ust-dl/Makefile
1226         tests/regression/ust/java-jul/Makefile
1227         tests/regression/ust/java-log4j/Makefile
1228         tests/regression/ust/getcpu-override/Makefile
1229         tests/regression/ust/clock-override/Makefile
1230         tests/regression/ust/type-declarations/Makefile
1231         tests/regression/ust/rotation-destroy-flush/Makefile
1232         tests/regression/ust/blocking/Makefile
1233         tests/regression/ust/namespaces/Makefile
1234         tests/stress/Makefile
1235         tests/unit/Makefile
1236         tests/unit/ini_config/Makefile
1237         tests/perf/Makefile
1238         tests/utils/Makefile
1239         tests/utils/tap/Makefile
1240         tests/utils/testapp/Makefile
1241         tests/utils/testapp/gen-ns-events/Makefile
1242         tests/utils/testapp/gen-kernel-test-events/Makefile
1243         tests/utils/testapp/gen-py-events/Makefile
1244         tests/utils/testapp/gen-ust-events/Makefile
1245         tests/utils/testapp/gen-ust-events-ns/Makefile
1246         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1247         tests/utils/testapp/gen-ust-nevents/Makefile
1248         tests/utils/testapp/gen-ust-nevents-str/Makefile
1249         tests/utils/testapp/gen-syscall-events/Makefile
1250         tests/utils/testapp/gen-ust-tracef/Makefile
1251         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1252         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1253         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1254         tests/utils/xml-utils/Makefile
1255 ])
1256
1257 # Inject variable into python test script.
1258 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1259 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1260 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1261 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1262
1263 AC_OUTPUT
1264
1265 #
1266 # Mini-report on what will be built.
1267 #
1268
1269 PPRINT_INIT
1270 PPRINT_SET_INDENT(1)
1271 PPRINT_SET_TS(38)
1272
1273 AS_ECHO
1274 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1275 AS_ECHO
1276
1277 AS_IF([test -n "$report_fold"], [
1278         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1279 ], [
1280         AS_ECHO("$version_description")
1281 ])
1282
1283 AS_ECHO
1284 PPRINT_SUBTITLE([Features])
1285
1286 # Target architecture we're building for.
1287 target_arch=$host_cpu
1288 [
1289 for f in $CFLAGS; do
1290         if test $f = "-m32"; then
1291                         target_arch="32-bit"
1292         elif test $f = "-m64"; then
1293                         target_arch="64-bit"
1294         fi
1295 done
1296 ]
1297 PPRINT_PROP_STRING([Target architecture], $target_arch)
1298
1299 # kmod enabled/disabled
1300 test "x$with_kmod" != "xno" && value=1 || value=0
1301 PPRINT_PROP_BOOL([libkmod support], $value)
1302
1303 # LTTng-UST enabled/disabled
1304 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1305 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1306
1307 AS_ECHO
1308 PPRINT_SUBTITLE([Binaries])
1309
1310 # List binaries to be built
1311 test x$enable_bin_lttng != xno && value=1 || value=0
1312 PPRINT_PROP_BOOL([lttng], $value)
1313
1314 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1315 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1316
1317 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1318 PPRINT_PROP_BOOL([lttng-crash], $value)
1319
1320 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1321 PPRINT_PROP_BOOL([lttng-relayd], $value)
1322
1323 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1324 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1325
1326 # Extras
1327 test x$enable_extras != xno && value=1 || value=0
1328 AS_ECHO
1329 PPRINT_SET_INDENT(0)
1330 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1331 PPRINT_SET_INDENT(1)
1332
1333 AS_ECHO
1334 PPRINT_SUBTITLE([Tests])
1335
1336 # Print clear message that tests won't be built
1337 AS_IF([test "x$build_tests" = "xno"],[
1338         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1339 ])
1340
1341 # LTTng UST Java agent JUL tests enabled/disabled
1342 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1343 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1344
1345 # LTTng UST Java agent Log4j tests enabled/disabled
1346 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1347 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1348
1349 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1350 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1351
1352 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1353 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1354
1355 # userspace-probe SDT instrumentation tests enabled/disabled
1356 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1357 PPRINT_PROP_BOOL([LTTng-modules SDT uprobe tests], $value)
1358
1359 #Python binding enabled/disabled
1360 test "x$enable_python_binding" = xyes && value=1 || value=0
1361 AS_ECHO
1362 PPRINT_SET_INDENT(0)
1363 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1364
1365 # man pages build enabled/disabled
1366 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1367
1368 AS_IF([test "x$man_pages_opt" != "xno"], [
1369         AS_IF([test "x$in_git_repo" = "xyes"], [
1370                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1371         ], [
1372                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1373                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1374                 ], [
1375                         PPRINT_PROP_STRING([build_man_pages_msg],
1376                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1377                                 $PPRINT_COLOR_SUBTITLE)
1378                 ])
1379         ])
1380 ], [
1381         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1382 ])
1383
1384 m4_popdef([build_man_pages_msg])
1385
1386 test "x$embedded_help" = xyes && value=1 || value=0
1387 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1388
1389 PPRINT_SET_INDENT(1)
1390
1391 report_bindir="`eval eval echo $bindir`"
1392 report_libdir="`eval eval echo $libdir`"
1393
1394 # Print the bindir and libdir this `make install' will install into.
1395 AS_ECHO
1396 PPRINT_SUBTITLE([Install directories])
1397 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1398 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1399
1400 AS_ECHO
1401 PPRINT_SUBTITLE([Search directories])
1402
1403 # If we build the sessiond, print the paths it will use
1404 AS_IF([test "$SESSIOND_BIN" = ""],[
1405         path="$report_bindir/lttng-sessiond"
1406 ],[
1407         path="$SESSIOND_BIN"
1408 ])
1409 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1410
1411 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1412         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1413 ],[
1414         path="$CONSUMERD32_BIN"
1415 ])
1416 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1417
1418 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1419         path="`eval eval echo $libdir`"
1420 ],[
1421         path="$CONSUMERD32_LIBDIR"
1422 ])
1423 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1424
1425 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1426         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1427 ],[
1428         path="$CONSUMERD64_BIN"
1429 ])
1430 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1431
1432 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1433         path="`eval eval echo $libdir`"
1434 ],[
1435         path="$CONSUMERD64_LIBDIR"
1436 ])
1437 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1438 PPRINT_SET_INDENT(0)
1439
1440 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1441         AS_ECHO
1442         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1443
1444 Note that the man pages are already built in this distribution tarball,
1445 therefore asciidoc and xmlto are only needed if you intend to modify
1446 their sources.
1447
1448 Also note that the installed man pages will contain the project's
1449 default command-line option and environment variable values.
1450
1451 Use --disable-man-pages to completely disable building and installing
1452 the man pages.])
1453 ])