configure.ac

   1 dnl SPDX-License-Identifier: GPL-2.0-only
   2 AC_PREREQ([2.64])
   3 AC_INIT([lttng-tools],[2.12.13],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   4
   5 AC_CONFIG_HEADERS([include/config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 # Checks for C compiler
  19 AC_USE_SYSTEM_EXTENSIONS
  20 AC_SYS_LARGEFILE
  21 AC_PROG_CC
  22 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  23 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  24 AC_PROG_CXX
  25 RW_PROG_CXX_WORKS
  26 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  27
  28 # Detect warning flags supported by the compiler, append them to WARN_CFLAGS.
  29 #
  30 # Pass -Werror as an extra flag during the test: this is needed to make the
  31 # -Wunknown-warning-option diagnostic fatal with clang.
  32 AX_APPEND_COMPILE_FLAGS([ dnl
  33                 -Wall dnl
  34                 dnl We currently get this warning when building with Clang:
  35                 dnl
  36                 dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration]
  37                 dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL;
  38                 dnl            ^
  39                 -Wno-incomplete-setjmp-declaration dnl
  40                 -Wdiscarded-qualifiers dnl
  41                 -Wmissing-declarations dnl
  42                 -Wmissing-prototypes dnl
  43                 -Wmissing-parameter-type dnl
  44                 -Wold-style-definition dnl
  45                 -Wstrict-prototypes dnl
  46         ],
  47         [WARN_CFLAGS],
  48         [-Werror])
  49
  50 # When given, add -Werror to WARN_CFLAGS.
  51 AC_ARG_ENABLE([Werror],
  52         [AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])]
  53 )
  54 AS_IF([test "x$enable_Werror" = "xyes"],
  55         [WARN_CFLAGS="${WARN_CFLAGS} -Werror"]
  56 )
  57
  58 # Checks for programs.
  59 AC_PROG_GREP
  60 AC_PROG_MAKE_SET
  61 AC_PROG_SED
  62 AC_PATH_PROG([report_fold], [fold])
  63 LT_INIT
  64
  65 # Check for objcopy, required by the base address statedump and dynamic linker tests
  66 AC_CHECK_TOOL([OBJCOPY], [objcopy])
  67 AS_IF([test "x$OBJCOPY" = "x"],
  68         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  69 )
  70 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != "x"])
  71
  72 # check for pgrep
  73 AC_PATH_PROG([PGREP], [pgrep])
  74 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "x"])
  75
  76 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
  77 # is not distributed in tarballs
  78 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
  79 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
  80
  81 # check for bison
  82 AC_PROG_YACC
  83 BISON=$YACC
  84 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  85
  86 AS_IF([test "x$have_bison" != "xyes"], [
  87   AS_IF([test "x$in_git_repo" = "xyes"], [
  88     AC_MSG_FAILURE([
  89 Bison >= 2.4 is required when building from the Git repository. You can
  90 set the YACC variable to override automatic detection.
  91     ])
  92   ], [
  93     AC_MSG_WARN([
  94 Missing Bison >= 2.4. Note that the parser files are already built in
  95 this distribution tarball, so Bison is only needed if you intend to
  96 modify their sources. You can set the YACC variable to override automatic
  97 detection.
  98     ])
  99   ])
 100 ])
 101 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 102
 103 # check for flex
 104 # Prior to autoconf 2.70, AC_PROG_FLEX did not take an argument. This is not a
 105 # problem since the argument is silently ignored by older versions.
 106 AC_PROG_LEX([noyywrap])
 107 FLEX=$LEX
 108 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 109
 110 AS_IF([test "x$have_flex" != "xyes"], [
 111   AS_IF([test "x$in_git_repo" = "xyes"], [
 112     AC_MSG_FAILURE([
 113 Flex >= 2.5.35 is required when building from the Git repository. You can
 114 set the LEX variable to override automatic detection.
 115     ])
 116   ], [
 117     AC_MSG_WARN([
 118 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 119 this distribution tarball, so Flex is only needed if you intend to
 120 modify their sources. You can set the LEX variable to override automatic
 121 detection.
 122     ])
 123   ])
 124 ])
 125 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 126
 127
 128 # Checks for typedefs, structures, and compiler characteristics.
 129 AC_C_INLINE
 130 AC_TYPE_INT32_T
 131 AC_TYPE_INT64_T
 132 AC_TYPE_MODE_T
 133 AC_TYPE_OFF_T
 134 AC_TYPE_PID_T
 135 AC_TYPE_SIZE_T
 136 AC_TYPE_SSIZE_T
 137 AC_TYPE_UID_T
 138 AC_TYPE_UINT16_T
 139 AC_TYPE_UINT32_T
 140 AC_TYPE_UINT64_T
 141 AC_TYPE_UINT8_T
 142
 143 AX_C___ATTRIBUTE__
 144 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 145         [:],
 146         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 147
 148 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 149
 150 # Check if linker has the -no-pie option.
 151 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 152 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 153
 154 AX_LIB_SOCKET_NSL
 155
 156 LT_NO_UNDEFINED=""
 157 AS_CASE([$host_os],
 158   [cygwin*],
 159     [
 160       LT_NO_UNDEFINED="-no-undefined"
 161     ],
 162   [cygwin*|darwin*|mingw*|solaris*],
 163     [
 164       # On platforms where we only support the relayd, disable the other binaries by default
 165       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 166       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 167       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 168       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 169       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 170       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 171     ]
 172 )
 173
 174 AC_SUBST(LT_NO_UNDEFINED)
 175
 176 # Compute minor/major/patchlevel version numbers
 177 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 178 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 179 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 180
 181 AC_SUBST([MAJOR_VERSION], [$major_version])
 182 AC_SUBST([MINOR_VERSION], [$minor_version])
 183 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 184 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 185 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 186 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 187
 188 version_name="(Ta) Meilleure"
 189 version_description="Ta Meilleure is a Northeast IPA beer brewed by Lagabière. Translating to \"Your best one\", this beer gives out strong aromas of passion fruit, lemon, and peaches. Tastewise, expect a lot of fruit, a creamy texture, and a smooth lingering hop bitterness."
 190 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 191
 192 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 193 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 194
 195 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 196 AC_ARG_ENABLE(libtool-linkdep-fixup,
 197         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 198                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 199         libtool_fixup=$enableval,
 200         libtool_fixup=yes)
 201
 202 AS_IF([test "x$libtool_fixup" = "xyes"],
 203             [
 204             libtool_m4="$srcdir/m4/libtool.m4"
 205             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 206             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 207             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 208             AS_IF([test $libtool_flag_pattern_count -ne 0],
 209             [
 210                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 211                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 212                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 213                   ],
 214                   [
 215                   AC_MSG_RESULT([none])
 216                   ])
 217             ])
 218
 219 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 220
 221 AC_CHECK_HEADERS([ \
 222         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 223         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 224         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 225         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 226         sys/mount.h sys/param.h sys/time.h elf.h sys/random.h sys/syscall.h
 227 ])
 228
 229 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 230
 231 # Basic functions check
 232 AC_CHECK_FUNCS([ \
 233         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 234         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 235         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 236         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 237         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 238         sched_getcpu sysconf sync_file_range getrandom
 239 ])
 240
 241 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 242 # add -lrt to LIBS
 243 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 244
 245 # Checks for dl.
 246 AC_CHECK_LIB([dl], [dlopen], [
 247         have_libdl=yes
 248         libdl_name=dl
 249         DL_LIBS="-ldl"
 250 ], [
 251         # libdl not found, check for dlopen in libc.
 252         AC_CHECK_LIB([c], [dlopen], [
 253                 have_libc_dl=yes
 254                 libdl_name=c
 255                 DL_LIBS="-lc"
 256         ], [
 257                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 258         ])
 259 ])
 260 AC_SUBST(DL_LIBS)
 261
 262 # Check if libdl has dlmopen support.
 263 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 264 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 265         AC_DEFINE([HAVE_DLMOPEN], [1])
 266         HAVE_DLMOPEN=1
 267 ], [
 268         HAVE_DLMOPEN=0
 269 ])
 270 AC_SUBST(HAVE_DLMOPEN)
 271
 272 # Babeltrace viewer check
 273 AC_ARG_WITH([babeltrace-bin],
 274         AS_HELP_STRING([--with-babeltrace-bin],
 275         [Location of the babeltrace viewer executable (including the filename)]),
 276         [BABELTRACE_BIN="$withval"],
 277         [BABELTRACE_BIN=''])
 278 AC_SUBST([BABELTRACE_BIN])
 279
 280 AC_ARG_WITH([babeltrace2-bin],
 281         AS_HELP_STRING([--with-babeltrace2-bin],
 282         [Location of the babeltrace2 viewer executable (including the filename)]),
 283         [BABELTRACE2_BIN="$withval"],
 284         [BABELTRACE2_BIN=''])
 285 AC_SUBST([BABELTRACE2_BIN])
 286
 287 AC_ARG_WITH([consumerd32-bin],
 288         AS_HELP_STRING([--with-consumerd32-bin],
 289         [Location of the 32-bit consumerd executable (including the filename)]),
 290         [CONSUMERD32_BIN="$withval"],
 291         [CONSUMERD32_BIN=''])
 292 AC_SUBST([CONSUMERD32_BIN])
 293
 294 AC_ARG_WITH([consumerd64-bin],
 295         AS_HELP_STRING([--with-consumerd64-bin],
 296         [Location of the 64-bit consumerd executable (including the filename)]),
 297         [CONSUMERD64_BIN="$withval"],
 298         [CONSUMERD64_BIN=''])
 299 AC_SUBST([CONSUMERD64_BIN])
 300
 301 AC_ARG_WITH([consumerd32-libdir],
 302         AS_HELP_STRING([--with-consumerd32-libdir],
 303         [Directory containing the 32-bit consumerd libraries]),
 304         [CONSUMERD32_LIBDIR="$withval"],
 305         [CONSUMERD32_LIBDIR=''])
 306 AC_SUBST([CONSUMERD32_LIBDIR])
 307
 308 AC_ARG_WITH([consumerd64-libdir],
 309         AS_HELP_STRING([--with-consumerd64-libdir],
 310         [Directory containing the 64-bit consumerd libraries]),
 311         [CONSUMERD64_LIBDIR="$withval"],
 312         [CONSUMERD64_LIBDIR=''])
 313 AC_SUBST([CONSUMERD64_LIBDIR])
 314
 315 AC_ARG_WITH([sessiond-bin],
 316         AS_HELP_STRING([--with-sessiond-bin],
 317         [Location of the sessiond executable (including the filename)]),
 318         [SESSIOND_BIN="$withval"],
 319         [SESSIOND_BIN=''])
 320 AC_SUBST([SESSIOND_BIN])
 321
 322 AC_ARG_WITH([lttng-system-rundir],
 323         AS_HELP_STRING([--with-lttng-system-rundir],
 324         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 325         [LTTNG_SYSTEM_RUNDIR="$withval"],
 326         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 327 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 328
 329 AC_ARG_ENABLE([test-java-agent-jul],
 330         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 331         [test_java_agent_jul=$enableval],
 332         [test_java_agent_jul=no]
 333 )
 334
 335 AC_ARG_ENABLE([test-java-agent-log4j],
 336         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j 1.x tests [default=no]])],
 337         [test_java_agent_log4j=$enableval],
 338         [test_java_agent_log4j=no]
 339 )
 340
 341 AC_ARG_ENABLE([test-java-agent-log4j2],
 342         [AS_HELP_STRING([--enable-test-java-agent-log4j2],[enable the LTTng UST Java agent Log4j 2.x tests [default=no]])],
 343         [test_java_agent_log4j2=$enableval],
 344         [test_java_agent_log4j2=no]
 345 )
 346
 347 AC_ARG_ENABLE([test-java-agent-all],
 348         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 349         [test_java_agent_jul=$enableval
 350          test_java_agent_log4j=$enableval],
 351         [:]
 352 )
 353
 354 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 355 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 356 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 357 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 358 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 359 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.])
 360 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 361 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 362
 363 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 364         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 365         $1="$2"
 366         AC_SUBST([$1])
 367 ])
 368
 369 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 370         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 371         $1="$2"
 372         AC_SUBST([$1])
 373 ])
 374
 375 # Default values
 376 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 377 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 378 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 379 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 380 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 381 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 382 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 383 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 384 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 385 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 386 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 387 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 388 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 389 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 390 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 391 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 392 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 393 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 394 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 395 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 396 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 397 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 398 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 399 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 400 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 401 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 402 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 403 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 404 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 405 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 406 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 407 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 408 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 409 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 410 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 411 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 412 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 413 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 414 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 415 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 416 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 417 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 418 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 419 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 420 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 421 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 422 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 423 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 424 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 425
 426 # Command short descriptions
 427 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 428 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 429 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a tracing session])
 430 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 431 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 432 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 433 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
 434 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 435 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 436 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
 437 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 438 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 439 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 440 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 441 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk])
 442 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 443 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 444 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 445 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 446 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 447 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 448 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
 449 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
 450 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 451 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 452 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 453 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 454
 455 if test "x$prefix" = "xNONE"; then
 456         prefix=$ac_default_prefix
 457 fi
 458 CONFDIR=`eval echo $sysconfdir`
 459 AC_SUBST(CONFDIR)
 460 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 461
 462 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
 463
 464 # Check libpopt
 465 PKG_CHECK_MODULES([POPT], [popt],
 466   [
 467     dnl PKG_CHECK_MODULES defines POPT_LIBS
 468   ],
 469   [
 470     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 471     AC_MSG_WARN([Finding libpopt without pkg-config.])
 472     AC_CHECK_LIB([popt],
 473       [poptGetContext],
 474       [POPT_LIBS="-lpopt"],
 475       [
 476         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 477       ]
 478     )
 479   ]
 480 )
 481 AC_SUBST(POPT_LIBS)
 482
 483 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 484
 485 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 486
 487 # URCU library version needed or newer
 488 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.11.0 is needed])
 489
 490 # Check liburcu needed function calls
 491 AC_CHECK_DECL([cds_list_add], [],
 492         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 493 AC_CHECK_DECL([cds_wfcq_init], [],
 494         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 495 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 496         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 497 AC_CHECK_DECL([futex_async], [],
 498         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 499 AC_CHECK_DECL([rcu_thread_offline], [],
 500         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 501 AC_CHECK_DECL([rcu_thread_online], [],
 502         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 503 AC_CHECK_DECL([caa_likely], [],
 504         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 505 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [:],
 506         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 507
 508 #Function added in urcu 0.7.0
 509 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 510         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 511 )
 512
 513 #Function added in urcu 0.11.0
 514 AC_CHECK_DECL([urcu_memb_barrier], [],
 515         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/urcu-memb.h>]]
 516 )
 517
 518 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 519 # it can be explicitly disabled with --without-kmod
 520 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 521 AC_ARG_WITH([kmod],
 522   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 523   [],
 524   [with_kmod=check]
 525 )
 526
 527 AS_IF([test "x$with_kmod" != "xno"],
 528   [
 529     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 530       [
 531         AC_DEFINE([HAVE_KMOD], [1])
 532         KMOD_LIBS="-lkmod"
 533       ],
 534       [
 535         if test "x$with_kmod" != xcheck; then
 536           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 537         else
 538           with_kmod=no
 539         fi
 540       ]
 541     )
 542   ]
 543 )
 544 AC_SUBST(KMOD_LIBS)
 545
 546 # Check for liblttng-ust-ctl, fail if it's not found,
 547 # it can be explicitly disabled with --without-lttng-ust
 548 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 549 AC_ARG_WITH([lttng-ust],
 550   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 551   [],
 552   [with_lttng_ust=yes]
 553 )
 554
 555 AS_IF([test "x$with_lttng_ust" = "xyes"], [
 556   AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 557
 558   # Check for liblttng-ust
 559   PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
 560
 561   # Check for liblttng-ust-ctl
 562   PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
 563
 564   AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
 565 ])
 566
 567 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 568
 569
 570 # Check for fmemopen
 571 AC_CHECK_LIB([c], [fmemopen],
 572 [
 573         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 574 ]
 575 )
 576
 577 # check for libpfm
 578 AC_CHECK_LIB([pfm], [pfm_initialize],
 579              [
 580               have_libpfm=yes
 581               ])
 582 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 583
 584 # For Python
 585 # SWIG version needed or newer:
 586 swig_version=2.0.0
 587
 588 AC_ARG_ENABLE([python-bindings],
 589               [AS_HELP_STRING([--enable-python-bindings],
 590                               [compile Python bindings])],
 591               [enable_python_binding=$enableval], [enable_python_binding=no])
 592
 593 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 594
 595 if test "x$enable_python_binding" = xyes; then
 596   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 597   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 598   AM_PATH_PYTHON([3.0])
 599
 600   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 601   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 602   AS_IF([test -z "$PYTHON_INCLUDE"], [
 603     AS_IF([test -z "$PYTHON_CONFIG"], [
 604       AC_PATH_PROGS([PYTHON_CONFIG],
 605                     [python$PYTHON_VERSION-config python-config],
 606                     [],
 607                     [`dirname $PYTHON`])
 608       AS_IF([test "x$PYTHON_CONFIG" = "x"], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 609     ])
 610     AC_MSG_CHECKING([python include flags])
 611     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 612     AC_MSG_RESULT([$PYTHON_INCLUDE])
 613   ])
 614
 615 else
 616     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 617 [if you want Python bindings.])
 618
 619 fi
 620
 621 # Epoll check. If not present, the build will fallback on poll() API
 622 AX_HAVE_EPOLL(
 623         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 624         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 625 )
 626 AX_CONFIG_FEATURE(
 627         [epoll], [This platform supports epoll(7)],
 628         [HAVE_EPOLL], [This platform supports epoll(7).],
 629         [enable_epoll="yes"], [enable_epoll="no"]
 630 )
 631 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 632
 633 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
 634         [AX_CONFIG_FEATURE_ENABLE(dirfd)],
 635         [AX_CONFIG_FEATURE_DISABLE(dirfd)]
 636 )
 637 AX_CONFIG_FEATURE(
 638         [dirfd], [Use directory file descriptors],
 639         [COMPAT_DIRFD], [This platform supports directory file descriptors.],
 640         [enable_dirfd="yes"], [enable_dirfd="no"]
 641 )
 642 AM_CONDITIONAL([COMPAT_DIRFD], [ test "$enable_dirfd" = "yes" ])
 643
 644 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 645 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 646 AM_CONDITIONAL([TEST_JAVA_LOG4J2_AGENT], [test "x$test_java_agent_log4j2" = "xyes"])
 647
 648 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes" || test "x$test_java_agent_log4j2" = "xyes"; then
 649         AX_JAVA_OPTIONS
 650         AX_PROG_JAVAC
 651         AX_PROG_JAVA
 652         AX_PROG_JAR
 653
 654         AX_CHECK_CLASSPATH
 655
 656         # Check for Java UST agent common class first
 657         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 658         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 659                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 660         fi
 661
 662         if test "x$test_java_agent_jul" = "xyes"; then
 663                 # Check for JUL agent class
 664                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 665                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 666                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 667                 fi
 668         fi
 669
 670         if test "x$test_java_agent_log4j" = "xyes"; then
 671                 # Check for Log4j agent class
 672                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 673                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 674                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 675                 fi
 676
 677                 # Check for Log4j class
 678                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 679                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 680                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 681                 fi
 682         fi
 683
 684         if test "x$test_java_agent_log4j2" = "xyes"; then
 685                 # Check for Log4j2 agent class
 686                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j2.LttngLogAppender)
 687                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j2_LttngLogAppender" = "xno"; then
 688                         AC_MSG_ERROR([The UST Java agent Log4j 2.x class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j2.jar"])
 689                 fi
 690
 691                 # Check for Log4j 2.x classes
 692                 AX_CHECK_CLASS([org.apache.logging.log4j.Logger])
 693                 AX_CHECK_CLASS([org.apache.logging.log4j.core.Core])
 694                 if test "x$ac_cv_class_org_apache_logging_log4j_Logger" = "xno" || test "x$ac_cv_class_org_apache_logging_log4j_core_Core" = "xno"; then
 695                         AC_MSG_ERROR([The Log4j 2.x API or core class was not found. Please specify the location of the jars via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j-core.jar:/path/to/log4j-api.jar"])
 696                 fi
 697         fi
 698 fi
 699
 700 # enable building man pages (user's intention)
 701 AC_ARG_ENABLE(
 702         man-pages,
 703         AS_HELP_STRING(
 704                 [--disable-man-pages],
 705                 [Do not build and install man pages (already built in a distributed tarball)]
 706         ),
 707         [man_pages_opt=$enableval],
 708         [man_pages_opt=yes]
 709 )
 710
 711 # check for asciidoc and xmlto if we enabled building the man pages
 712 have_asciidoc_xmlto=no
 713 warn_prebuilt_man_pages=no
 714
 715 AS_IF([test "x$man_pages_opt" = "xyes"], [
 716         AC_PATH_PROG([ASCIIDOC], [asciidoc])
 717         AC_PATH_PROG([XMLTO], [xmlto])
 718
 719         AS_IF([test "x$ASCIIDOC" = "x" || test "x$XMLTO" = "x"], [
 720                 AS_IF([test "x$in_git_repo" = "xyes"], [
 721                         # this is an error because we're in the Git repo, which
 722                         # means the man pages are not already generated for us,
 723                         # thus asciidoc/xmlto are required because we were asked
 724                         # to build the man pages
 725                         AC_MSG_ERROR([
 726 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 727 --disable-man-pages to disable building the man pages, in which case
 728 they will not be installed.
 729                         ])
 730                 ], [
 731                         # only warn here: since we're in the tarball, the man
 732                         # pages should already be generated at this point, thus
 733                         # asciidoc/xmlto are not strictly required
 734                         warn_prebuilt_man_pages=yes
 735                 ])
 736         ], [
 737                 have_asciidoc_xmlto=yes
 738         ])
 739 ])
 740
 741 # export man page build condition: build the man pages if the user
 742 # asked for it, and if the tools are available
 743 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 744 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 745
 746 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 747
 748 # embedded --help message
 749 AC_ARG_ENABLE(
 750         [embedded-help],
 751         AS_HELP_STRING(
 752                 [--enable-embedded-help],
 753                 [Embed the --help messages in the executable files]
 754         ),
 755         [embedded_help=$enableval],
 756         [embedded_help=no]
 757 )
 758 AS_IF([test "x$embedded_help" = "xyes"], [
 759         AS_IF([test "x$man_pages_opt" = "xno"], [
 760                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 761         ])
 762         AC_PATH_PROG([man_prog_path], [man])
 763         AS_IF([test "x$man_prog_path" = "x"], [
 764                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 765         ])
 766         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 767         AC_SUBST([MANPROG], [$man_prog_path])
 768 ])
 769 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 770
 771 # Python agent test
 772 UST_PYTHON_AGENT="lttngust"
 773
 774 AC_ARG_ENABLE(test-python2-agent,
 775         AS_HELP_STRING([--enable-test-python2-agent],
 776                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 777         ),[:],[test_python2_agent_autodetect=yes]
 778 )
 779
 780 AC_ARG_ENABLE(test-python3-agent,
 781         AS_HELP_STRING([--enable-test-python3-agent],
 782                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 783         ),[:],[test_python3_agent_autodetect=yes]
 784 )
 785
 786 AC_ARG_ENABLE(test-python-agent-all,
 787         AS_HELP_STRING([--enable-test-python-agent-all],
 788                 [enable test for all python{2/3} agent.]
 789         ),
 790 )
 791
 792 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 793        unset test_python2_agent_autodetect
 794        unset test_python3_agent_autodetect
 795 ])
 796
 797 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 798        enable_test_python2_agent=yes
 799        enable_test_python3_agent=yes
 800 ])
 801
 802 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 803        enable_test_python2_agent=no
 804        enable_test_python3_agent=no
 805 ])
 806
 807
 808 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 809         AS_IF([test -z "$PYTHON2"], [
 810                         PYTHON2=python2
 811                 ], [
 812                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 813         ])
 814
 815         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 816         AS_IF([test -z "$PYTHON2_BIN"], [
 817                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 818                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 819                 ])
 820         ], [
 821                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 822                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 823                         PYTHON2_AGENT=$PYTHON2_BIN
 824                         AC_MSG_RESULT([yes])
 825                         RUN_PYTHON_AGENT_TEST=yes
 826                 ], [
 827                         AC_MSG_RESULT([no])
 828                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 829                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 830                         ])
 831                 ])
 832
 833         ])
 834
 835 ])
 836
 837 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 838         AS_IF([test -z "$PYTHON3"], [
 839                 PYTHON3=python3
 840         ], [
 841                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 842         ])
 843
 844         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 845         AS_IF([test -z "$PYTHON3_BIN"], [
 846                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 847                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 848                 ])
 849         ], [
 850                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 851                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 852                         PYTHON3_AGENT=$PYTHON3_BIN
 853                         AC_MSG_RESULT([yes])
 854                         RUN_PYTHON_AGENT_TEST=yes
 855                 ], [
 856                         AC_MSG_RESULT([no])
 857                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 858                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 859                         ])
 860                 ])
 861
 862         ])
 863 ])
 864 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 865 AC_SUBST([PYTHON2_AGENT])
 866 AC_SUBST([PYTHON3_AGENT])
 867
 868 AC_ARG_ENABLE([test-sdt-uprobe],
 869   [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
 870   [test_sdt_uprobe="$enableval"],
 871   [test_sdt_uprobe=autodetect]
 872 )
 873
 874 AS_IF([test "$test_sdt_uprobe" != "no"], [
 875   LTTNG_CHECK_SDT_WORKS
 876   AC_PATH_PROG([DTRACE], [dtrace])
 877 ])
 878
 879 AS_IF([test "$test_sdt_uprobe" = "yes"], [
 880   AS_IF([test "$lttng_cv_sdt_works" = "no"], [
 881     AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
 882   ])
 883   AS_IF([test "x$DTRACE" = "x"], [
 884     AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
 885   ])
 886 ])
 887
 888 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
 889   AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
 890     AS_IF([test "x$DTRACE" != "x"], [
 891       test_sdt_uprobe=yes
 892     ])
 893   ])
 894 ])
 895
 896 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
 897
 898 # Arguments for binaries build exclusion
 899 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 900 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 901               [Disable the build of lttng-consumerd binaries]))
 902 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 903 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 904               [Disable the build of lttng-relayd binaries]))
 905 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 906               [Disable the build of lttng-sessiond binaries]))
 907 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 908               [Disable the build of the extra components]))
 909
 910
 911 # Always build libconfig since it a dependency of libcommon
 912 build_lib_config=yes
 913
 914 build_lib_compat=no
 915 build_lib_consumer=no
 916 build_lib_hashtable=no
 917 build_lib_health=no
 918 build_lib_index=no
 919 build_lib_kernel_consumer=no
 920 build_lib_kernel_ctl=no
 921 build_lib_lttng_ctl=no
 922 build_lib_relayd=no
 923 build_lib_fd_tracker=no
 924 build_lib_sessiond_comm=no
 925 build_lib_testpoint=no
 926 build_lib_ust_consumer=no
 927
 928 # There is an overlap for enabled dependencies, but this makes everything
 929 # simpler. libcommon and libconfig are always compiled so they are not repeated
 930 # here.
 931
 932 # Enable binary dependencies.
 933 AS_IF([test x$enable_bin_lttng != xno],
 934       [
 935        build_lib_lttng_ctl=yes
 936       ]
 937 )
 938
 939 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 940       [
 941        build_lib_consumer=yes
 942        build_lib_sessiond_comm=yes
 943        build_lib_index=yes
 944        build_lib_health=yes
 945        build_lib_testpoint=yes
 946       ]
 947 )
 948
 949 AS_IF([test x$enable_bin_lttng_crash != xno],
 950       # Do nothing since libconfig and libcommon are built by default.
 951       []
 952 )
 953
 954 AS_IF([test x$enable_bin_lttng_relayd != xno],
 955       [
 956        build_lib_lttng_ctl=yes
 957        build_lib_sessiond_comm=yes
 958        build_lib_hashtable=yes
 959        build_lib_compat=yes
 960        build_lib_index=yes
 961        build_lib_health=yes
 962        build_lib_testpoint=yes
 963        build_lib_fd_tracker=yes
 964       ]
 965 )
 966 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 967       [
 968        build_lib_lttng_ctl=yes
 969        build_lib_sessiond_comm=yes
 970        build_lib_kernel_ctl=yes
 971        build_lib_hashtable=yes
 972        build_lib_compat=yes
 973        build_lib_relayd=yes
 974        build_lib_testpoint=yes
 975        build_lib_health=yes
 976       ]
 977 )
 978
 979 # Libraries dependencies enabling
 980 AS_IF([test x$build_lib_lttng_ctl = xyes],
 981       [
 982        build_lib_sessiond_comm=yes
 983        build_lib_hashtable=yes
 984       ]
 985 )
 986
 987 AS_IF([test x$build_lib_consumer = xyes],
 988       [
 989        build_lib_sessiond_comm=yes
 990        build_lib_kernel_consumer=yes
 991        build_lib_hashtable=yes
 992        build_lib_compat=yes
 993        build_lib_relayd=yes
 994        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 995       ]
 996 )
 997
 998 AS_IF([test x$build_lib_kernel_consumer = xyes],
 999       [
1000        build_lib_kernel_ctl=yes
1001        build_lib_relayd=yes
1002       ]
1003 )
1004
1005 AS_IF([test x$build_lib_relayd = xyes],
1006       [
1007        build_lib_sessiond_comm=yes
1008       ]
1009 )
1010
1011 # Find arch type
1012 AS_CASE([$host_cpu],
1013         [k1om], [ARCHTYPE="x86"],
1014         [i386], [ARCHTYPE="x86"],
1015         [i486], [ARCHTYPE="x86"],
1016         [i586], [ARCHTYPE="x86"],
1017         [i686], [ARCHTYPE="x86"],
1018         [amd64], [ARCHTYPE="x86"],
1019         [x86_64], [ARCHTYPE="x86"],
1020         [powerpc], [ARCHTYPE="ppc"],
1021         [ppc64], [ARCHTYPE="ppc"],
1022         [powerpc64], [ARCHTYPE="ppc"],
1023         [powerpc64le], [ARCHTYPE="ppc"],
1024         [ppc], [ARCHTYPE="ppc"],
1025         [s390], [ARCHTYPE="s390"],
1026         [s390x], [ARCHTYPE="s390"],
1027         [sparc], [ARCHTYPE="sparc64"],
1028         [sparc64], [ARCHTYPE="sparc64"],
1029         [alpha*], [ARCHTYPE="alpha"],
1030         [ia64], [ARCHTYPE="ia64"],
1031         [arm*], [ARCHTYPE="arm"],
1032         [aarch64*], [ARCHTYPE="aarch64"],
1033         [mips*], [ARCHTYPE="mips"],
1034         [nios2*], [ARCHTYPE="nios2"],
1035         [tile*], [ARCHTYPE="tile"],
1036         [hppa*], [ARCHTYPE="hppa"],
1037         [m68k], [ARCHTYPE="m68k"],
1038         [riscv*], [ARCHTYPE="riscv"],
1039         [ARCHTYPE="unknown"]
1040 )
1041
1042 AC_SUBST(ARCHTYPE)
1043
1044 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1045 AC_MSG_CHECKING([for architecture support of userspace callstack tracing from the kernel])
1046 AS_IF([test "x$ARCHTYPE" = "xx86"],[
1047         # Userspace callstack capture is only supported by the Linux kernel on x86.
1048         AC_MSG_RESULT([yes])
1049         have_modules_userspace_callstack_context=yes
1050         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1051 ], [
1052         AC_MSG_RESULT([no])
1053         have_modules_userspace_callstack_context=no
1054 ])
1055 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context != xno])
1056
1057 # Export binaries build conditions.
1058 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1059 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1060 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1061 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1062 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1063
1064 # Export the tests and extras build conditions.
1065 AS_IF([\
1066 test "x$enable_bin_lttng" != "xno" && \
1067 test "x$enable_bin_lttng_consumerd" != "xno" && \
1068 test "x$enable_bin_lttng_crash" != "xno" && \
1069 test "x$enable_bin_lttng_relayd" != "xno" && \
1070 test "x$enable_bin_lttng_sessiond" != "xno"],
1071 [build_tests=yes],
1072 [build_tests=no]
1073 )
1074
1075 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1076 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1077
1078 # Export libraries build conditions.
1079 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
1080 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
1081 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1082 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
1083 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1084 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1085 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1086 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1087 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1088 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1089 AM_CONDITIONAL([BUILD_LIB_FD_TRACKER], [test x$build_lib_fd_tracker = xyes])
1090 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1091 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1092 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1093
1094 AM_CFLAGS="${WARN_CFLAGS} -fno-strict-aliasing $PTHREAD_CFLAGS"
1095 AC_SUBST(AM_CFLAGS)
1096
1097 # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...".
1098 AM_LDFLAGS=""
1099 AC_SUBST(AM_LDFLAGS)
1100
1101 # The order in which the include folders are searched is important.
1102 # The top_builddir should always be searched first in the event that a build
1103 # time generated file is included. An example of this is the "version.i" file.
1104 # In a scenario where lttng-tools is built from a distribution tarball and in a
1105 # out-of-tree manner, the generated "version.i" has priority on the one from
1106 # the source (distribution tarball) and must be found first.
1107 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1108 AC_SUBST(AM_CPPFLAGS)
1109
1110 lttngincludedir="${includedir}/lttng"
1111 AC_SUBST(lttngincludedir)
1112
1113 lttngactionincludedir="${includedir}/lttng/action"
1114 AC_SUBST(lttngactionincludedir)
1115
1116 lttngconditionincludedir="${includedir}/lttng/condition"
1117 AC_SUBST(lttngconditionincludedir)
1118
1119 lttngnotificationincludedir="${includedir}/lttng/notification"
1120 AC_SUBST(lttngnotificationincludedir)
1121
1122 lttngtriggerincludedir="${includedir}/lttng/trigger"
1123 AC_SUBST(lttngtriggerincludedir)
1124
1125 lttnglibexecdir="${libdir}/lttng/libexec"
1126 AC_SUBST(lttnglibexecdir)
1127
1128 AC_CONFIG_FILES([
1129         Makefile
1130         doc/Makefile
1131         doc/man/Makefile
1132         doc/man/asciidoc-attrs.conf
1133         include/Makefile
1134         extras/Makefile
1135         extras/bindings/Makefile
1136         extras/bindings/swig/Makefile
1137         extras/bindings/swig/python/Makefile
1138         extras/core-handler/Makefile
1139         src/Makefile
1140         src/common/Makefile
1141         src/common/kernel-ctl/Makefile
1142         src/common/kernel-consumer/Makefile
1143         src/common/consumer/Makefile
1144         src/common/ust-consumer/Makefile
1145         src/common/hashtable/Makefile
1146         src/common/sessiond-comm/Makefile
1147         src/common/compat/Makefile
1148         src/common/relayd/Makefile
1149         src/common/testpoint/Makefile
1150         src/common/index/Makefile
1151         src/common/health/Makefile
1152         src/common/config/Makefile
1153         src/common/string-utils/Makefile
1154         src/common/fd-tracker/Makefile
1155         src/lib/Makefile
1156         src/lib/lttng-ctl/Makefile
1157         src/lib/lttng-ctl/filter/Makefile
1158         src/lib/lttng-ctl/lttng-ctl.pc
1159         src/bin/Makefile
1160         src/bin/lttng-consumerd/Makefile
1161         src/bin/lttng-sessiond/Makefile
1162         src/bin/lttng-relayd/Makefile
1163         src/bin/lttng/Makefile
1164         src/bin/lttng-crash/Makefile
1165         tests/Makefile
1166         tests/destructive/Makefile
1167         tests/regression/Makefile
1168         tests/regression/kernel/Makefile
1169         tests/regression/tools/Makefile
1170         tests/regression/tools/streaming/Makefile
1171         tests/regression/tools/filtering/Makefile
1172         tests/regression/tools/health/Makefile
1173         tests/regression/tools/tracefile-limits/Makefile
1174         tests/regression/tools/snapshots/Makefile
1175         tests/regression/tools/live/Makefile
1176         tests/regression/tools/exclusion/Makefile
1177         tests/regression/tools/save-load/Makefile
1178         tests/regression/tools/save-load/configuration/Makefile
1179         tests/regression/tools/mi/Makefile
1180         tests/regression/tools/wildcard/Makefile
1181         tests/regression/tools/crash/Makefile
1182         tests/regression/tools/regen-metadata/Makefile
1183         tests/regression/tools/regen-statedump/Makefile
1184         tests/regression/tools/notification/Makefile
1185         tests/regression/tools/rotation/Makefile
1186         tests/regression/tools/base-path/Makefile
1187         tests/regression/tools/metadata/Makefile
1188         tests/regression/tools/tracker/Makefile
1189         tests/regression/tools/working-directory/Makefile
1190         tests/regression/tools/relayd-grouping/Makefile
1191         tests/regression/tools/clear/Makefile
1192         tests/regression/ust/Makefile
1193         tests/regression/ust/nprocesses/Makefile
1194         tests/regression/ust/high-throughput/Makefile
1195         tests/regression/ust/low-throughput/Makefile
1196         tests/regression/ust/before-after/Makefile
1197         tests/regression/ust/buffers-pid/Makefile
1198         tests/regression/ust/periodical-metadata-flush/Makefile
1199         tests/regression/ust/multi-session/Makefile
1200         tests/regression/ust/multi-lib/Makefile
1201         tests/regression/ust/overlap/Makefile
1202         tests/regression/ust/overlap/demo/Makefile
1203         tests/regression/ust/linking/Makefile
1204         tests/regression/ust/daemon/Makefile
1205         tests/regression/ust/exit-fast/Makefile
1206         tests/regression/ust/fork/Makefile
1207         tests/regression/ust/libc-wrapper/Makefile
1208         tests/regression/ust/baddr-statedump/Makefile
1209         tests/regression/ust/ust-dl/Makefile
1210         tests/regression/ust/java-jul/Makefile
1211         tests/regression/ust/java-log4j/Makefile
1212         tests/regression/ust/java-log4j2/Makefile
1213         tests/regression/ust/python-logging/Makefile
1214         tests/regression/ust/getcpu-override/Makefile
1215         tests/regression/ust/clock-override/Makefile
1216         tests/regression/ust/type-declarations/Makefile
1217         tests/regression/ust/rotation-destroy-flush/Makefile
1218         tests/regression/ust/blocking/Makefile
1219         tests/regression/ust/namespaces/Makefile
1220         tests/stress/Makefile
1221         tests/unit/Makefile
1222         tests/unit/ini_config/Makefile
1223         tests/perf/Makefile
1224         tests/utils/Makefile
1225         tests/utils/tap/Makefile
1226         tests/utils/testapp/Makefile
1227         tests/utils/testapp/gen-ns-events/Makefile
1228         tests/utils/testapp/gen-kernel-test-events/Makefile
1229         tests/utils/testapp/gen-ust-events/Makefile
1230         tests/utils/testapp/gen-ust-events-ns/Makefile
1231         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1232         tests/utils/testapp/gen-ust-nevents/Makefile
1233         tests/utils/testapp/gen-ust-nevents-str/Makefile
1234         tests/utils/testapp/gen-syscall-events/Makefile
1235         tests/utils/testapp/gen-ust-tracef/Makefile
1236         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1237         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1238         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1239 ])
1240
1241 # Inject variable into python test script.
1242 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1243 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1244 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1245 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1246
1247 AC_OUTPUT
1248
1249 #
1250 # Mini-report on what will be built.
1251 #
1252
1253 PPRINT_INIT
1254 PPRINT_SET_INDENT(1)
1255 PPRINT_SET_TS(38)
1256
1257 AS_ECHO
1258 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1259 AS_ECHO
1260
1261 AS_IF([test -n "$report_fold"], [
1262         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1263 ], [
1264         AS_ECHO("$version_description")
1265 ])
1266
1267 AS_ECHO
1268 PPRINT_SUBTITLE([Features])
1269
1270 # Target architecture we're building for.
1271 target_arch=$host_cpu
1272 [
1273 for f in $CFLAGS; do
1274         if test $f = "-m32"; then
1275                         target_arch="32-bit"
1276         elif test $f = "-m64"; then
1277                         target_arch="64-bit"
1278         fi
1279 done
1280 ]
1281 PPRINT_PROP_STRING([Target architecture], $target_arch)
1282
1283 # kmod enabled/disabled
1284 test "x$with_kmod" != "xno" && value=1 || value=0
1285 PPRINT_PROP_BOOL([libkmod support], $value)
1286
1287 # LTTng-UST enabled/disabled
1288 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1289 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1290
1291 AS_ECHO
1292 PPRINT_SUBTITLE([Binaries])
1293
1294 # List binaries to be built
1295 test x$enable_bin_lttng != xno && value=1 || value=0
1296 PPRINT_PROP_BOOL([lttng], $value)
1297
1298 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1299 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1300
1301 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1302 PPRINT_PROP_BOOL([lttng-crash], $value)
1303
1304 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1305 PPRINT_PROP_BOOL([lttng-relayd], $value)
1306
1307 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1308 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1309
1310 # Extras
1311 test x$enable_extras != xno && value=1 || value=0
1312 AS_ECHO
1313 PPRINT_SET_INDENT(0)
1314 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1315 PPRINT_SET_INDENT(1)
1316
1317 AS_ECHO
1318 PPRINT_SUBTITLE([Tests])
1319
1320 # Print clear message that tests won't be built
1321 AS_IF([test "x$build_tests" = "xno"],[
1322         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1323 ])
1324
1325 # LTTng UST Java agent JUL tests enabled/disabled
1326 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1327 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1328
1329 # LTTng UST Java agent Log4j 1.x tests enabled/disabled
1330 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1331 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j 1.x tests], $value)
1332
1333 # LTTng UST Java agent Log4j 2.x tests enabled/disabled
1334 test "x$test_java_agent_log4j2" = "xyes" && value=1 || value=0
1335 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j 2.x tests], $value)
1336
1337 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1338 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1339
1340 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1341 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1342
1343 # userspace-probe SDT instrumentation tests enabled/disabled
1344 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1345 PPRINT_PROP_BOOL([LTTng-modules SDT uprobe tests], $value)
1346
1347 #Python binding enabled/disabled
1348 test "x$enable_python_binding" = xyes && value=1 || value=0
1349 AS_ECHO
1350 PPRINT_SET_INDENT(0)
1351 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1352
1353 # man pages build enabled/disabled
1354 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1355
1356 AS_IF([test "x$man_pages_opt" != "xno"], [
1357         AS_IF([test "x$in_git_repo" = "xyes"], [
1358                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1359         ], [
1360                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1361                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1362                 ], [
1363                         PPRINT_PROP_STRING([build_man_pages_msg],
1364                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1365                                 $PPRINT_COLOR_SUBTITLE)
1366                 ])
1367         ])
1368 ], [
1369         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1370 ])
1371
1372 m4_popdef([build_man_pages_msg])
1373
1374 test "x$embedded_help" = xyes && value=1 || value=0
1375 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1376
1377 PPRINT_SET_INDENT(1)
1378
1379 report_bindir="`eval eval echo $bindir`"
1380 report_libdir="`eval eval echo $libdir`"
1381
1382 # Print the bindir and libdir this `make install' will install into.
1383 AS_ECHO
1384 PPRINT_SUBTITLE([Install directories])
1385 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1386 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1387
1388 AS_ECHO
1389 PPRINT_SUBTITLE([Search directories])
1390
1391 # If we build the sessiond, print the paths it will use
1392 AS_IF([test "$SESSIOND_BIN" = ""],[
1393         path="$report_bindir/lttng-sessiond"
1394 ],[
1395         path="$SESSIOND_BIN"
1396 ])
1397 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1398
1399 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1400         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1401 ],[
1402         path="$CONSUMERD32_BIN"
1403 ])
1404 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1405
1406 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1407         path="`eval eval echo $libdir`"
1408 ],[
1409         path="$CONSUMERD32_LIBDIR"
1410 ])
1411 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1412
1413 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1414         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1415 ],[
1416         path="$CONSUMERD64_BIN"
1417 ])
1418 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1419
1420 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1421         path="`eval eval echo $libdir`"
1422 ],[
1423         path="$CONSUMERD64_LIBDIR"
1424 ])
1425 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1426 PPRINT_SET_INDENT(0)
1427
1428 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1429         AS_ECHO
1430         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1431
1432 Note that the man pages are already built in this distribution tarball,
1433 therefore asciidoc and xmlto are only needed if you intend to modify
1434 their sources.
1435
1436 Also note that the installed man pages will contain the project's
1437 default command-line option and environment variable values.
1438
1439 Use --disable-man-pages to completely disable building and installing
1440 the man pages.])
1441 ])