configure.ac

   1 dnl Version infos
   2 m4_define([V_MAJOR], [2])
   3 m4_define([V_MINOR], [12])
   4 m4_define([V_PATCH], [4])
   5 dnl m4_define([V_EXTRA], [])
   6 m4_define([V_NAME], [[(Ta) Meilleure]])
   7 m4_define([V_DESC], [[Ta Meilleure is a Northeast IPA beer brewed by Lagabière. Translating to "Your best one", this beer gives out strong aromas of passion fruit, lemon, and peaches. Tastewise, expect a lot of fruit, a creamy texture, and a smooth lingering hop bitterness.]])
   8
   9 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
  10 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
  11
  12 AC_PREREQ(2.59)
  13 AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com], [], [https://lttng.org])
  14
  15 dnl Substitute minor/major/patchlevel version numbers
  16 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
  17 AC_SUBST([MINOR_VERSION], [V_MINOR])
  18 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
  19
  20 # Following the numbering scheme proposed by libtool for the library version
  21 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  22 # This is the library version of liblttng-ust.
  23 m4_define([UST_LIB_V_MAJOR], [0])
  24 m4_define([UST_LIB_V_MINOR], [0])
  25 m4_define([UST_LIB_V_PATCH], [0])
  26
  27 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [UST_LIB_V_MAJOR:UST_LIB_V_MINOR:UST_LIB_V_PATCH])
  28 AC_DEFINE([CONFIG_LTTNG_UST_LIBRARY_VERSION_MAJOR], [UST_LIB_V_MAJOR], [Major SONAME number of the ust library])
  29 # note: remember to update tracepoint.h dlopen() to match this version
  30 # number. TODO: eventually automate by exporting the major number.
  31
  32 # This is the library version of liblttng-ust-ctl, used internally by
  33 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  34 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [4:0:0])
  35
  36 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  37 AC_CONFIG_AUX_DIR([config])
  38 AC_CONFIG_MACRO_DIR([m4])
  39 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  40
  41 AC_CANONICAL_TARGET
  42 AC_CANONICAL_HOST
  43
  44 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar])
  45 AM_MAINTAINER_MODE([enable])
  46
  47 # Enable silent rules if available (Introduced in AM 1.11)
  48 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  49
  50 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  51
  52 # Checks for C compiler
  53 AC_USE_SYSTEM_EXTENSIONS
  54 AC_SYS_LARGEFILE
  55 AC_PROG_CC
  56 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  57 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  58 AC_PROG_CXX
  59 RW_PROG_CXX_WORKS
  60 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  61
  62 # Check if the compiler support weak symbols
  63 AX_SYS_WEAK_ALIAS
  64
  65 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
  66         AC_MSG_ERROR([Your platform doesn't support weak symbols.])
  67 ])
  68
  69 # Checks for programs.
  70 AM_PROG_AR
  71 AC_PROG_SED
  72 AC_PROG_GREP
  73 AC_PROG_LN_S
  74 AC_PROG_MKDIR_P
  75 AC_PROG_MAKE_SET
  76 AC_CHECK_PROG([CMAKE], [cmake])
  77 AM_CONDITIONAL([HAVE_CMAKE], [test "x$CMAKE" != "x"])
  78
  79 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  80 AC_ARG_ENABLE([libtool-linkdep-fixup], [
  81 AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
  82 ], [
  83         libtool_fixup=$enableval
  84 ], [
  85         libtool_fixup=yes
  86 ])
  87
  88 AS_IF([test "x$libtool_fixup" = "xyes"], [
  89         libtool_m4="$srcdir/m4/libtool.m4"
  90         libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  91         AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  92         libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  93
  94         AS_IF([test $libtool_flag_pattern_count -ne 0], [
  95         AC_MSG_RESULT([$libtool_flag_pattern_count])
  96         AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  97                 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  98         ], [
  99                 AC_MSG_RESULT([none])
 100         ])
 101 ])
 102 LT_INIT([disable-static])
 103
 104 AC_MSG_CHECKING([whether shared libraries are enabled])
 105 AS_IF([test "x$enable_shared" = "xyes"], [
 106         AC_MSG_RESULT([yes])
 107 ], [
 108         AC_MSG_RESULT([no])
 109         AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 110 ])
 111
 112 # Checks for typedefs, structures, and compiler characteristics.
 113 AC_C_INLINE
 114 AC_TYPE_INT8_T
 115 AC_TYPE_INT16_T
 116 AC_TYPE_INT32_T
 117 AC_TYPE_INT64_T
 118 AC_TYPE_MODE_T
 119 AC_TYPE_OFF_T
 120 AC_TYPE_PID_T
 121 AC_TYPE_SIZE_T
 122 AC_TYPE_SSIZE_T
 123 AC_TYPE_UID_T
 124 AC_TYPE_UINT8_T
 125 AC_TYPE_UINT16_T
 126 AC_TYPE_UINT32_T
 127 AC_TYPE_UINT64_T
 128 AC_CHECK_TYPES([ptrdiff_t])
 129
 130 AX_C___ATTRIBUTE__
 131 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 132         [:],
 133         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 134
 135 # Checks for library functions.
 136 AC_FUNC_CHOWN
 137 AC_FUNC_FORK
 138 AC_FUNC_MMAP
 139 AC_FUNC_REALLOC
 140 AC_FUNC_STRERROR_R
 141 AC_FUNC_STRNLEN
 142 AC_CHECK_FUNCS([ \
 143         atexit \
 144         clock_gettime \
 145         ftruncate \
 146         getpagesize \
 147         gettimeofday \
 148         localeconv \
 149         memchr \
 150         memmove \
 151         memset \
 152         mkdir \
 153         munmap \
 154         realpath \
 155         sched_getcpu \
 156         socket \
 157         strchr \
 158         strdup \
 159         strerror \
 160         strtol \
 161         sysconf \
 162 ])
 163
 164 # AC_FUNC_MALLOC causes problems when cross-compiling.
 165 #AC_FUNC_MALLOC
 166
 167 # Checks for header files.
 168 AC_HEADER_STDBOOL
 169 AC_CHECK_HEADERS([ \
 170         arpa/inet.h \
 171         fcntl.h \
 172         float.h \
 173         limits.h \
 174         locale.h \
 175         stddef.h \
 176         sys/socket.h \
 177         sys/time.h \
 178         wchar.h \
 179 ])
 180
 181 # Set architecture specific options
 182 AS_CASE([$host_cpu],
 183         [i[[3456]]86], [],
 184         [x86_64], [],
 185         [amd64], [],
 186         [powerpc], [],
 187         [ppc64], [],
 188         [ppc64le], [],
 189         [powerpc64], [],
 190         [powerpc64le], [],
 191         [s390], [NO_UNALIGNED_ACCESS=1],
 192         [s390x], [NO_UNALIGNED_ACCESS=1],
 193         [arm*], [
 194                 NO_UNALIGNED_ACCESS=1
 195                 NO_NUMA=1
 196                 ],
 197         [aarch64*], [NO_UNALIGNED_ACCESS=1],
 198         [mips*], [NO_UNALIGNED_ACCESS=1],
 199         [tile*], [NO_UNALIGNED_ACCESS=1],
 200         [
 201                 UNSUPPORTED_ARCH=1
 202                 NO_UNALIGNED_ACCESS=1
 203         ])
 204
 205 # Configuration options, which will be installed in the config.h
 206 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
 207 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
 208 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
 209
 210 # Checks for libraries.
 211 AC_CHECK_LIB([dl], [dlopen], [
 212         libdl_name=dl
 213         DL_LIBS="-ldl"
 214 ], [
 215         #libdl not found, check for dlopen in libc.
 216         AC_CHECK_LIB([c], [dlopen], [
 217                 libdl_name=c
 218                 DL_LIBS="-lc"
 219         ], [
 220                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 221         ])
 222 ])
 223 AC_SUBST(DL_LIBS)
 224
 225 # Check if libdl has dlmopen support.
 226 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 227 AC_CHECK_LIB([$libdl_name], [dlmopen],
 228         [AC_DEFINE([HAVE_DLMOPEN], [1])]
 229 )
 230
 231 AC_CHECK_LIB([pthread], [pthread_create], [:])
 232 AC_CHECK_LIB([pthread], [pthread_setname_np],
 233         AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1], [Define to 1 if pthread_setname_np is available.]),
 234         AC_CHECK_LIB([pthread], [pthread_set_name_np],
 235                 AC_DEFINE([HAVE_PTHREAD_SET_NAME_NP], [1], [Define to 1 if pthread_set_name_np is available.]),
 236                 AC_MSG_RESULT([pthread setname/set_name not found.])))
 237
 238 # Check for dlfcn.h
 239 AC_CHECK_HEADER([dlfcn.h])
 240 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
 241         AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
 242                 #define _GNU_SOURCE /* Required on Linux to get GNU extensions */
 243                 #include <dlfcn.h>
 244         ])
 245 ], [
 246         ac_cv_have_decl_RTLD_DI_LINKMAP="no"
 247 ])
 248
 249 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 250
 251 # URCU
 252
 253 # urcu - check if we just find the headers it out of the box.
 254 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 255 This error can also occur when the liburcu package's configure script has not been run.])])
 256
 257 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 258 # Part of Userspace RCU library 0.7.2 or better.
 259 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [:], [AC_MSG_ERROR([Cannot find
 260 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 261
 262 AC_MSG_CHECKING([caa_likely()])
 263 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 264         #include <urcu/compiler.h>
 265         void fct(void)
 266         {
 267                 if (caa_likely(1)) {
 268                 }
 269         }
 270 ]])], [
 271         AC_MSG_RESULT([yes])
 272 ], [
 273         AC_MSG_RESULT([no])
 274         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 275 ])
 276
 277 # urcu - check that URCU lib is available to compilation
 278 AC_CHECK_LIB([urcu-bp], [urcu_bp_synchronize_rcu], [:], [AC_MSG_ERROR([Cannot find liburcu-bp 0.11 or newer. Use [LDFLAGS]=-Ldir to specify its location.])])
 279
 280 # urcu - check that URCU lib is at least version 0.11
 281 AC_CHECK_LIB([urcu-bp], [urcu_bp_call_rcu], [:], [AC_MSG_ERROR([liburcu 0.11 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 282
 283 # numa.h integration
 284 AS_IF([test "x$NO_NUMA" = "x1"],[
 285       AS_IF([test "x$enable_numa" = "x" ], [enable_numa=no])
 286 ])
 287
 288 AC_ARG_ENABLE([numa], [
 289 AS_HELP_STRING([--disable-numa], [disable NUMA support])
 290 ], [
 291         enable_numa=$enableval
 292 ], [
 293         enable_numa=yes
 294 ])
 295
 296 AS_IF([test "x$enable_numa" = "xyes"], [
 297         # numa - check that numa lib is available
 298         AC_CHECK_LIB([numa], [numa_available], [AC_DEFINE([HAVE_LIBNUMA], [1], [Define to 1 if libnuma is available.])],
 299 [AC_MSG_ERROR([libnuma is not available. Please either install it (e.g. libnuma-dev) or use [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure argument to disable NUMA support.])])
 300         have_libnuma=yes
 301 ])
 302 AM_CONDITIONAL([HAVE_LIBNUMA], [test "x$have_libnuma" = "xyes"])
 303
 304 # optional linux/perf_event.h
 305 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 306
 307 # Perf event counters are supported on all architectures supported by
 308 # perf, using the read system call as fallback.
 309 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
 310
 311 AS_IF([test "x$have_perf_event" = "xyes"], [
 312         AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 313 ])
 314
 315 AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
 316         AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 317 ])
 318
 319 # Check for JNI header files if requested
 320 AC_ARG_ENABLE([jni-interface], [
 321 AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
 322 ], [
 323         jni_interface=$enableval
 324 ], [
 325         jni_interface=no
 326 ])
 327
 328 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 329
 330
 331 AC_ARG_ENABLE([java-agent-jul], [
 332 AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
 333 ], [
 334         java_agent_jul=$enableval
 335 ], [
 336         java_agent_jul=no
 337 ])
 338
 339 AC_ARG_ENABLE([java-agent-log4j], [
 340 AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j 1.x support [default=no]])
 341 ], [
 342         java_agent_log4j=$enableval
 343 ], [
 344         java_agent_log4j=no
 345 ])
 346
 347 AC_ARG_ENABLE([java-agent-log4j2], [
 348 AS_HELP_STRING([--enable-java-agent-log4j2], [build the LTTng UST Java agent with Log4j 2.x support [default=no]])
 349 ], [
 350         java_agent_log4j2=$enableval
 351 ], [
 352         java_agent_log4j2=no
 353 ])
 354
 355 AC_ARG_ENABLE([java-agent-all], [
 356 AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
 357 ], [
 358         java_agent_jul=$enableval
 359         java_agent_log4j=$enableval
 360         # This backport to a stable branch requires the explicit use of
 361         # '--enable-java-agent-log4j2' to avoid introducing a new dependency in
 362         # an existing configuration.
 363         #java_agent_log4j2=$enableval
 364 ], [:])
 365
 366 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 367 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 368 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 369 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J2], [test "x$java_agent_log4j2" = "xyes"])
 370 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J_COMMON], [test "x$java_agent_log4j" = "xyes" || test "x$java_agent_log4j2" = "xyes"])
 371
 372 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes" || test "x$java_agent_log4j2" = "xyes"], [
 373         AX_JAVA_OPTIONS
 374         AX_PROG_JAVAC
 375         AX_PROG_JAVA
 376         AX_PROG_JAR
 377         AC_ARG_VAR([CLASSPATH], [Java class path])
 378
 379         AX_JNI_INCLUDE_DIR
 380         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 381         do
 382                 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
 383         done
 384
 385         saved_CPPFLAGS="$CPPFLAGS"
 386         CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 387         AX_PROG_JAVAH
 388         CPPFLAGS="$saved_CPPFLAGS"
 389 ])
 390
 391 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
 392
 393 AS_IF([test "x$java_agent_log4j" = "xyes"], [
 394         AX_CHECK_CLASSPATH
 395         AX_CHECK_CLASS([org.apache.log4j.Logger])
 396         AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 397                 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 398         ])
 399 ])
 400
 401 # The log4j 2.x agent requires the log4j core and api jars in the classpath
 402 AS_IF([test "x$java_agent_log4j2" = "xyes"], [
 403   AX_CHECK_CLASSPATH
 404   AX_CHECK_CLASS([org.apache.logging.log4j.Logger])
 405   AX_CHECK_CLASS([org.apache.logging.log4j.core.Core])
 406   AS_IF([test "x$ac_cv_class_org_apache_logging_log4j_Logger" = "xno" || test "x$ac_cv_class_org_apache_logging_log4j_core_Core" = "xno"], [
 407     AC_MSG_ERROR([dnl
 408 The UST Java agent support for log4j was requested but the Log4j classes were
 409 not found. Please specify the location of the Log4j API and core 2.x jars via the Java CLASSPATH
 410 environment variable, e.g. ./configure CLASSPATH="/path/to/log4j-core.jar:/path/to/log4j-api.jar"
 411 Current CLASSPATH: "$CLASSPATH"
 412     ])
 413   ])
 414 ])
 415
 416 # Option to build the python agent
 417 AC_ARG_ENABLE([python-agent], [
 418 AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
 419 ], [
 420         python_agent=$enableval
 421 ], [:])
 422 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 423 AS_IF([test "x$python_agent" = "xyes"], [
 424         AM_PATH_PYTHON([2.7])
 425 ])
 426
 427 # sdt.h integration
 428 AC_ARG_WITH([sdt], [
 429 AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
 430 ], [
 431         with_sdt=$withval
 432 ], [
 433         with_sdt="no"
 434 ])
 435
 436 AS_IF([test "x$with_sdt" = "xyes"], [
 437         AC_MSG_CHECKING([STAP_PROBEV()])
 438         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 439                 #define SDT_USE_VARIADIC
 440                 #include <sys/sdt.h>
 441                 void fct(void)
 442                 {
 443                         STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 444                 }
 445         ]])], [
 446                 AC_MSG_RESULT([yes])
 447                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 448         ], [
 449                 AC_MSG_RESULT([no])
 450                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 451         ])
 452 ])
 453
 454 AC_ARG_WITH([lttng-system-rundir], [
 455 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 456 ], [
 457         lttng_system_rundir="$withval"
 458 ], [
 459         lttng_system_rundir="/var/run/lttng"
 460 ])
 461 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 462                 [LTTng system runtime directory])
 463
 464 AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
 465 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
 466
 467 # Enable building examples
 468 AC_ARG_ENABLE(
 469         examples,
 470         AS_HELP_STRING(
 471                 [--disable-examples],
 472                 [Do not build and install examples]
 473         ),
 474         [enable_examples=$enableval],
 475         [enable_examples=yes]
 476 )
 477
 478 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" != "xno"])
 479
 480 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 481 # is not distributed in tarballs.
 482 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 483 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 484
 485 # Enable building man pages (user's intention).
 486 AC_ARG_ENABLE(
 487         man-pages,
 488         AS_HELP_STRING(
 489                 [--disable-man-pages],
 490                 [Do not build and install man pages (already built in a distributed tarball)]
 491         ),
 492         [man_pages_opt=$enableval],
 493         [man_pages_opt=yes]
 494 )
 495
 496 # Check for asciidoc and xmlto if we enabled building the man pages.
 497 have_asciidoc_xmlto=no
 498 warn_prebuilt_man_pages=no
 499
 500 AS_IF([test "x$man_pages_opt" = "xyes"], [
 501         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 502         AC_PATH_PROG([XMLTO], [xmlto], [no])
 503
 504         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 505                 AS_IF([test "x$in_git_repo" = "xyes"], [
 506                         # This is an error because we're in the Git repo, which
 507                         # means the man pages are not already generated for us,
 508                         # thus asciidoc/xmlto are required because we were asked
 509                         # to build the man pages.
 510                         AC_MSG_ERROR([
 511 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 512 --disable-man-pages to disable building the man pages, in which case
 513 they will not be installed.
 514                         ])
 515                 ], [
 516                         # Only warn here: since we're in the tarball, the man
 517                         # pages should already be generated at this point, thus
 518                         # asciidoc/xmlto are not strictly required.
 519                         warn_prebuilt_man_pages=yes
 520                 ])
 521         ], [
 522                 have_asciidoc_xmlto=yes
 523         ])
 524 ])
 525
 526 # Export man page build condition: build the man pages if the user
 527 # asked for it, and if the tools are available.
 528 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 529 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 530
 531 # Default values
 532 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 533         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 534         $1="$2"
 535         AC_SUBST([$1])
 536 ])
 537
 538 _AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
 539
 540 AM_CFLAGS="-Wall"
 541 AC_SUBST(AM_CFLAGS)
 542 AC_SUBST(JNI_CPPFLAGS)
 543
 544 AC_CONFIG_FILES([
 545         Makefile
 546         doc/Makefile
 547         doc/examples/Makefile
 548         doc/man/Makefile
 549         include/Makefile
 550         include/lttng/ust-version.h
 551         snprintf/Makefile
 552         libringbuffer/Makefile
 553         liblttng-ust-comm/Makefile
 554         liblttng-ust/Makefile
 555         liblttng-ust-ctl/Makefile
 556         liblttng-ust-fork/Makefile
 557         liblttng-ust-dl/Makefile
 558         liblttng-ust-fd/Makefile
 559         liblttng-ust-java/Makefile
 560         liblttng-ust-java-agent/Makefile
 561         liblttng-ust-java-agent/java/Makefile
 562         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 563         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 564         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 565         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 566         liblttng-ust-java-agent/java/lttng-ust-agent-log4j2/Makefile
 567         liblttng-ust-java-agent/jni/Makefile
 568         liblttng-ust-java-agent/jni/common/Makefile
 569         liblttng-ust-java-agent/jni/jul/Makefile
 570         liblttng-ust-java-agent/jni/log4j/Makefile
 571         liblttng-ust-libc-wrapper/Makefile
 572         liblttng-ust-cyg-profile/Makefile
 573         liblttng-ust-python-agent/Makefile
 574         python-lttngust/Makefile
 575         python-lttngust/setup.py
 576         python-lttngust/lttngust/__init__.py
 577         tools/Makefile
 578         tests/Makefile
 579         tests/ctf-types/Makefile
 580         tests/hello/Makefile
 581         tests/hello-many/Makefile
 582         tests/hello.cxx/Makefile
 583         tests/same_line_tracepoint/Makefile
 584         tests/snprintf/Makefile
 585         tests/ust-elf/Makefile
 586         tests/benchmark/Makefile
 587         tests/utils/Makefile
 588         tests/test-app-ctx/Makefile
 589         tests/gcc-weak-hidden/Makefile
 590         lttng-ust.pc
 591         lttng-ust-ctl.pc
 592 ])
 593
 594 # Create link for python agent for the VPATH guru.
 595 AC_CONFIG_LINKS([
 596         python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
 597         python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
 598         python-lttngust/lttngust/compat.py:python-lttngust/lttngust/compat.py
 599         python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
 600         python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
 601 ])
 602
 603 AC_CONFIG_FILES([tests/ust-elf/test_ust_elf],[chmod +x tests/ust-elf/test_ust_elf])
 604
 605 AC_OUTPUT
 606
 607
 608 #
 609 # Mini-report on what will be built.
 610 #
 611
 612 PPRINT_INIT
 613 PPRINT_SET_INDENT(1)
 614 PPRINT_SET_TS(38)
 615
 616 AS_ECHO
 617 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"V_NAME\"$PPRINT_COLOR_RST")
 618 AS_ECHO
 619
 620 AS_ECHO("V_DESC")
 621
 622 AS_ECHO
 623 PPRINT_SUBTITLE([System])
 624
 625 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 626
 627 test "x$NO_UNALIGNED_ACCESS" != "x1" && value=1 || value=0
 628 PPRINT_PROP_BOOL([Efficient unaligned memory access], $value)
 629
 630 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
 631        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 632 ])
 633
 634 AS_ECHO
 635 PPRINT_SUBTITLE([Features])
 636 PPRINT_SET_INDENT(1)
 637
 638 test "x$with_sdt" = "xyes" && value=1 || value=0
 639 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 640
 641 test "x$java_agent_jul" = xyes && value=1 || value=0
 642 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 643
 644 test "x$java_agent_log4j" = xyes && value=1 || value=0
 645 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j 1.x support)], $value, [use --enable-java-agent-log4j])
 646
 647 test "x$java_agent_log4j2" = xyes && value=1 || value=0
 648 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j 2.x support)], $value, [use --enable-java-agent-log4j2])
 649
 650 test "x$jni_interface" = xyes && value=1 || value=0
 651 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 652
 653 test "x$python_agent" = xyes && value=1 || value=0
 654 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 655
 656 test "x$have_perf_event" = "xyes" && value=1 || value=0
 657 PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value)
 658
 659 test "x$enable_numa" = xyes && value=1 || value=0
 660 PPRINT_PROP_BOOL([NUMA], $value)
 661
 662 AS_ECHO
 663 PPRINT_SET_INDENT(0)
 664
 665 test "x$enable_examples" = xyes && value=1 || value=0
 666 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 667
 668 # man pages build enabled/disabled
 669 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 670
 671 AS_IF([test "x$man_pages_opt" != "xno"], [
 672         AS_IF([test "x$in_git_repo" = "xyes"], [
 673                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 674         ], [
 675                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 676                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 677                 ], [
 678                         PPRINT_PROP_STRING([build_man_pages_msg],
 679                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
 680                                 $PPRINT_COLOR_SUBTITLE)
 681                 ])
 682         ])
 683 ], [
 684         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 685 ])
 686
 687 m4_popdef([build_man_pages_msg])
 688
 689 PPRINT_SET_INDENT(1)
 690
 691 report_bindir="`eval eval echo $bindir`"
 692 report_libdir="`eval eval echo $libdir`"
 693
 694 # Print the bindir and libdir this `make install' will install into.
 695 AS_ECHO
 696 PPRINT_SUBTITLE([Install directories])
 697 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 698 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 699
 700 AS_ECHO
 701 PPRINT_SUBTITLE([System directories])
 702
 703 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 704
 705 PPRINT_SET_INDENT(0)
 706
 707 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 708         AS_ECHO
 709         PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 710
 711 Note that the man pages are already built in this distribution tarball,
 712 therefore asciidoc and xmlto are only needed if you intend to modify
 713 their sources.
 714
 715 Use --disable-man-pages to completely disable building and installing
 716 the man pages.])
 717 ])