configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([ust], [1.9.0], [mathieu dot desnoyers at efficios dot com])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CANONICAL_TARGET
   7 AC_CANONICAL_HOST
   8 AC_CONFIG_MACRO_DIR([config])
   9 AM_INIT_AUTOMAKE([foreign])
  10 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  11 AC_CONFIG_SRCDIR([include/ust/tracepoint.h])
  12 AC_CONFIG_HEADERS([config.h include/ust/config.h])
  13 AH_TEMPLATE([HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  14 # Compute minor/major version numbers
  15 major_version=`echo AC_PACKAGE_VERSION | sed 's/\..*//'`
  16 minor_version=`echo AC_PACKAGE_VERSION | sed 's/.*\.//' | sed 's/^0//'`
  17 AC_SUBST([MAJOR_VERSION], [$major_version])
  18 AC_SUBST([MINOR_VERSION], [$minor_version])
  19 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  20 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  21
  22
  23 # Checks for programs.
  24 AC_PROG_CC
  25 AC_PROG_MAKE_SET
  26 AC_PROG_LIBTOOL
  27
  28 ## Checks for libraries.
  29 AC_CHECK_LIB([dl], [dlopen])
  30 AC_CHECK_LIB([pthread], [pthread_create])
  31
  32 # Checks for header files.
  33 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
  34
  35 # Checks for typedefs, structures, and compiler characteristics.
  36 AC_C_INLINE
  37 #AC_TYPE_INT16_T
  38 #AC_TYPE_INT32_T
  39 #AC_TYPE_INT64_T
  40 #AC_TYPE_INT8_T
  41 #AC_TYPE_PID_T
  42 #AC_TYPE_SIZE_T
  43 #AC_TYPE_SSIZE_T
  44 #AC_TYPE_UINT16_T
  45 #AC_TYPE_UINT32_T
  46 #AC_TYPE_UINT64_T
  47 #AC_TYPE_UINT8_T
  48 #AC_CHECK_TYPES([ptrdiff_t])
  49
  50 # Checks for library functions.
  51 AC_FUNC_MALLOC
  52 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol])
  53
  54 CFLAGS="-Wall $CFLAGS"
  55
  56 # URCU
  57
  58 # urcu - check if we just find the headers it out of the box.
  59 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CFLAGS]=-Idir to specify their location.
  60 This error can also occur when the liburcu package's configure script has not been run.])])
  61
  62 # urcu - check that URCU lib is available to compilation
  63 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
  64
  65 # urcu - check that URCU lib is at least version 0.6
  66 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
  67
  68
  69 # Check for various supplementary host information (beyond the
  70 # triplet) which might affect the library format choices.  E.g., we
  71 # can be building with `i686-unknown-linux-gnu-gcc -m64'
  72
  73 case "${host}" in
  74 changequote(,)dnl
  75   i[34567]86-*-linux*)
  76 changequote([,])dnl
  77     AC_CACHE_CHECK([if building for x86-64], [ust_cv_i386_is_x86_64],
  78                     [save_CPPFLAGS="$CPPFLAGS"
  79                     CPPFLAGS="$CPPFLAGS $CFLAGS"
  80                     AC_EGREP_CPP([got it], [
  81 #if __x86_64__
  82 got it
  83 #endif
  84                  ], [ust_cv_i386_is_x86_64=yes],
  85                     [ust_cv_i386_is_x86_64=no])
  86                     CPPFLAGS="$save_CPPFLAGS"])
  87     ;;
  88 esac
  89
  90 AC_MSG_CHECKING([library format for the host system])
  91 case $host_cpu in
  92 changequote(,)dnl
  93         i[3456]86)
  94 changequote([,])dnl
  95           if test "$ust_cv_i386_is_x86_64" = yes ; then
  96              LIBFORMAT="elf64-x86-64"
  97           else
  98              LIBFORMAT="elf32-i386"
  99           fi
 100           ;;
 101         x86_64) LIBFORMAT="elf64-x86-64" ;;
 102         powerpc) LIBFORMAT="elf32-powerpc" ;;
 103         ppc64) LIBFORMAT="elf64-powerpc" ;;
 104         s390) LIBFORMAT="elf32-s390" ;;
 105         s390x) LIBFORMAT="elf64-s390" ;;
 106         armv5) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 107         arm) LIBFORMAT="elf32-littlearm" ;;
 108         mips*) LIBFORMAT="" ;;
 109         *) AC_MSG_ERROR([unable to detect library format (unsupported architecture ($host_cpu)?)]) ;;
 110 esac
 111 AC_SUBST(LIBFORMAT)
 112 AC_MSG_RESULT($LIBFORMAT)
 113
 114 if test "x$host_cpu" = "xarm" ; then
 115 AC_MSG_CHECKING([checking for armv5])
 116 AC_TRY_COMPILE(
 117 [
 118 ],
 119 [
 120 #ifndef __ARM_ARCH_5TEJ__
 121 #error "no arm5 here"
 122 #endif
 123 ],
 124 [
 125         AC_MSG_RESULT([yes])
 126         NO_UNALIGNED_ACCESS=1
 127 ]
 128 ,
 129 [
 130         AC_MSG_RESULT([no])
 131 ]
 132 )
 133 fi
 134 if test x$NO_UNALIGNED_ACCESS = x ; then
 135 AC_DEFINE([HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 136 fi
 137
 138 AC_CONFIG_FILES([
 139         Makefile
 140         doc/Makefile
 141         doc/man/Makefile
 142         doc/info/Makefile
 143         include/Makefile
 144         libringbuffer/Makefile
 145         libust/Makefile
 146         tests/Makefile
 147         tests/hello/Makefile
 148         tests/hello2/Makefile
 149         tests/basic/Makefile
 150         tests/basic_long/Makefile
 151         tests/fork/Makefile
 152         tests/simple_include/Makefile
 153         tests/snprintf/Makefile
 154         tests/test-nevents/Makefile
 155         tests/test-libustinstr-malloc/Makefile
 156         tests/dlopen/Makefile
 157         tests/same_line_marker/Makefile
 158         tests/trace_event/Makefile
 159         tests/tracepoint/Makefile
 160         tests/tracepoint/benchmark/Makefile
 161         tests/register_test/Makefile
 162         tests/libustctl_function_tests/Makefile
 163         tests/exit-fast/Makefile
 164         libustinstr-malloc/Makefile
 165         libustfork/Makefile
 166         snprintf/Makefile
 167         ust.pc
 168         include/ust/version.h
 169 ])
 170 AC_OUTPUT