configure.ac

   1 dnl SPDX-License-Identifier: GPL-2.0-only
   2 AC_PREREQ([2.64])
   3 AC_INIT([lttng-tools],[2.13.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   4
   5 AC_CONFIG_HEADERS([include/config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  19
  20 # Checks for C compiler
  21 AC_USE_SYSTEM_EXTENSIONS
  22 AC_SYS_LARGEFILE
  23 AC_PROG_CC
  24 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  25 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  26 AC_PROG_CXX
  27 RW_PROG_CXX_WORKS
  28 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  29
  30 # Detect warning flags supported by the compiler, append them to WARN_CFLAGS.
  31 #
  32 # Pass -Werror as an extra flag during the test: this is needed to make the
  33 # -Wunknown-warning-option diagnostic fatal with clang.
  34 AX_APPEND_COMPILE_FLAGS([ dnl
  35                 -Wall dnl
  36                 dnl We currently get this warning when building with Clang:
  37                 dnl
  38                 dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration]
  39                 dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL;
  40                 dnl            ^
  41                 -Wno-incomplete-setjmp-declaration dnl
  42                 -Wdiscarded-qualifiers dnl
  43                 -Wmissing-declarations dnl
  44                 -Wmissing-prototypes dnl
  45                 -Wmissing-parameter-type dnl
  46                 -Wold-style-definition dnl
  47                 -Wstrict-prototypes dnl
  48                 -Wshadow dnl
  49         ],
  50         [WARN_CFLAGS],
  51         [-Werror])
  52
  53 # When given, add -Werror to WARN_CFLAGS.
  54 AC_ARG_ENABLE([Werror],
  55         [AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])]
  56 )
  57 AS_IF([test "x$enable_Werror" = "xyes"],
  58         [WARN_CFLAGS="${WARN_CFLAGS} -Werror"]
  59 )
  60
  61 # Checks for programs.
  62 AC_PROG_GREP
  63 AC_PROG_MAKE_SET
  64 AC_PROG_SED
  65 AC_PATH_PROG([report_fold], [fold])
  66 LT_INIT
  67
  68 # Check for objcopy, required by the base address statedump and dynamic linker tests
  69 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
  70 AS_IF([test "x$OBJCOPY" = "xno"],
  71         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  72 )
  73 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  74
  75 # check for pgrep
  76 AC_PATH_PROG([PGREP], [pgrep], [no])
  77 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
  78
  79 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
  80 # is not distributed in tarballs
  81 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
  82 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
  83
  84 # check for bison
  85 AC_PROG_YACC
  86 BISON=$YACC
  87 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  88
  89 AS_IF([test "x$have_bison" != "xyes"], [
  90   AS_IF([test "x$in_git_repo" = "xyes"], [
  91     AC_MSG_FAILURE([
  92 Bison >= 2.4 is required when building from the Git repository. You can
  93 set the YACC variable to override automatic detection.
  94     ])
  95   ], [
  96     AC_MSG_WARN([
  97 Missing Bison >= 2.4. Note that the parser files are already built in
  98 this distribution tarball, so Bison is only needed if you intend to
  99 modify their sources. You can set the YACC variable to override automatic
 100 detection.
 101     ])
 102   ])
 103 ])
 104 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 105
 106 # check for flex
 107 # Prior to autoconf 2.70, AC_PROG_FLEX did not take an argument. This is not a
 108 # problem since the argument is silently ignored by older versions.
 109 AC_PROG_LEX([noyywrap])
 110 FLEX=$LEX
 111 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 112
 113 AS_IF([test "x$have_flex" != "xyes"], [
 114   AS_IF([test "x$in_git_repo" = "xyes"], [
 115     AC_MSG_FAILURE([
 116 Flex >= 2.5.35 is required when building from the Git repository. You can
 117 set the LEX variable to override automatic detection.
 118     ])
 119   ], [
 120     AC_MSG_WARN([
 121 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 122 this distribution tarball, so Flex is only needed if you intend to
 123 modify their sources. You can set the LEX variable to override automatic
 124 detection.
 125     ])
 126   ])
 127 ])
 128 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 129
 130
 131 # Checks for typedefs, structures, and compiler characteristics.
 132 AC_C_INLINE
 133 AC_TYPE_INT32_T
 134 AC_TYPE_INT64_T
 135 AC_TYPE_MODE_T
 136 AC_TYPE_OFF_T
 137 AC_TYPE_PID_T
 138 AC_TYPE_SIZE_T
 139 AC_TYPE_SSIZE_T
 140 AC_TYPE_UID_T
 141 AC_TYPE_UINT16_T
 142 AC_TYPE_UINT32_T
 143 AC_TYPE_UINT64_T
 144 AC_TYPE_UINT8_T
 145
 146 AX_C___ATTRIBUTE__
 147 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 148         [:],
 149         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 150
 151 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 152
 153 # Check if linker has the -no-pie option.
 154 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 155 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 156
 157 AX_LIB_SOCKET_NSL
 158
 159 LT_NO_UNDEFINED=""
 160 AS_CASE([$host_os],
 161   [cygwin*],
 162     [
 163       LT_NO_UNDEFINED="-no-undefined"
 164     ],
 165   [cygwin*|darwin*|mingw*|solaris*],
 166     [
 167       # On platforms where we only support the relayd, disable the other binaries by default
 168       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 169       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 170       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 171       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 172       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 173       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 174     ]
 175 )
 176
 177 AC_SUBST(LT_NO_UNDEFINED)
 178
 179 # Compute minor/major/patchlevel version numbers
 180 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 181 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 182 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 183
 184 AC_SUBST([MAJOR_VERSION], [$major_version])
 185 AC_SUBST([MINOR_VERSION], [$minor_version])
 186 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 187 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 188 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 189 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 190
 191 version_name="N-Beer"
 192 version_description="An alcoholic drink made from yeast-fermented malt flavored with hops."
 193 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 194
 195 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 196 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 197
 198 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 199 AC_ARG_ENABLE(libtool-linkdep-fixup,
 200         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 201                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 202         libtool_fixup=$enableval,
 203         libtool_fixup=yes)
 204
 205 AS_IF([test "x$libtool_fixup" = "xyes"],
 206             [
 207             libtool_m4="$srcdir/m4/libtool.m4"
 208             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 209             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 210             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 211             AS_IF([test $libtool_flag_pattern_count -ne 0],
 212             [
 213                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 214                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 215                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 216                   ],
 217                   [
 218                   AC_MSG_RESULT([none])
 219                   ])
 220             ])
 221
 222 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 223
 224 AC_CHECK_HEADERS([ \
 225         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 226         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 227         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 228         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 229         sys/mount.h sys/param.h sys/time.h elf.h
 230 ])
 231
 232 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 233
 234 # Basic functions check
 235 AC_CHECK_FUNCS([ \
 236         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 237         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 238         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 239         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 240         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 241         sched_getcpu sysconf sync_file_range
 242 ])
 243
 244 # Check for pthread_setname_np and pthread_getname_np
 245 LTTNG_PTHREAD_SETNAME_NP
 246 LTTNG_PTHREAD_GETNAME_NP
 247
 248 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 249 # add -lrt to LIBS
 250 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 251
 252 # Checks for dl.
 253 AC_CHECK_LIB([dl], [dlopen], [
 254         have_libdl=yes
 255         libdl_name=dl
 256         DL_LIBS="-ldl"
 257 ], [
 258         # libdl not found, check for dlopen in libc.
 259         AC_CHECK_LIB([c], [dlopen], [
 260                 have_libc_dl=yes
 261                 libdl_name=c
 262                 DL_LIBS="-lc"
 263         ], [
 264                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 265         ])
 266 ])
 267 AC_SUBST(DL_LIBS)
 268
 269 # Check if libdl has dlmopen support.
 270 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 271 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 272         AC_DEFINE([HAVE_DLMOPEN], [1])
 273         HAVE_DLMOPEN=1
 274 ], [
 275         HAVE_DLMOPEN=0
 276 ])
 277 AC_SUBST(HAVE_DLMOPEN)
 278
 279 # Babeltrace viewer check
 280 AC_ARG_WITH([babeltrace-bin],
 281         AS_HELP_STRING([--with-babeltrace-bin],
 282         [Location of the babeltrace viewer executable (including the filename)]),
 283         [BABELTRACE_BIN="$withval"],
 284         [BABELTRACE_BIN=''])
 285 AC_SUBST([BABELTRACE_BIN])
 286
 287 AC_ARG_WITH([babeltrace2-bin],
 288         AS_HELP_STRING([--with-babeltrace2-bin],
 289         [Location of the babeltrace2 viewer executable (including the filename)]),
 290         [BABELTRACE2_BIN="$withval"],
 291         [BABELTRACE2_BIN=''])
 292 AC_SUBST([BABELTRACE2_BIN])
 293
 294 AC_ARG_WITH([consumerd32-bin],
 295         AS_HELP_STRING([--with-consumerd32-bin],
 296         [Location of the 32-bit consumerd executable (including the filename)]),
 297         [CONSUMERD32_BIN="$withval"],
 298         [CONSUMERD32_BIN=''])
 299 AC_SUBST([CONSUMERD32_BIN])
 300
 301 AC_ARG_WITH([consumerd64-bin],
 302         AS_HELP_STRING([--with-consumerd64-bin],
 303         [Location of the 64-bit consumerd executable (including the filename)]),
 304         [CONSUMERD64_BIN="$withval"],
 305         [CONSUMERD64_BIN=''])
 306 AC_SUBST([CONSUMERD64_BIN])
 307
 308 AC_ARG_WITH([consumerd32-libdir],
 309         AS_HELP_STRING([--with-consumerd32-libdir],
 310         [Directory containing the 32-bit consumerd libraries]),
 311         [CONSUMERD32_LIBDIR="$withval"],
 312         [CONSUMERD32_LIBDIR=''])
 313 AC_SUBST([CONSUMERD32_LIBDIR])
 314
 315 AC_ARG_WITH([consumerd64-libdir],
 316         AS_HELP_STRING([--with-consumerd64-libdir],
 317         [Directory containing the 64-bit consumerd libraries]),
 318         [CONSUMERD64_LIBDIR="$withval"],
 319         [CONSUMERD64_LIBDIR=''])
 320 AC_SUBST([CONSUMERD64_LIBDIR])
 321
 322 AC_ARG_WITH([sessiond-bin],
 323         AS_HELP_STRING([--with-sessiond-bin],
 324         [Location of the sessiond executable (including the filename)]),
 325         [SESSIOND_BIN="$withval"],
 326         [SESSIOND_BIN=''])
 327 AC_SUBST([SESSIOND_BIN])
 328
 329 AC_ARG_WITH([lttng-system-rundir],
 330         AS_HELP_STRING([--with-lttng-system-rundir],
 331         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 332         [LTTNG_SYSTEM_RUNDIR="$withval"],
 333         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 334 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 335
 336 AC_ARG_ENABLE([test-java-agent-jul],
 337         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 338         [test_java_agent_jul=$enableval],
 339         [test_java_agent_jul=no]
 340 )
 341
 342 AC_ARG_ENABLE([test-java-agent-log4j],
 343         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 344         [test_java_agent_log4j=$enableval],
 345         [test_java_agent_log4j=no]
 346 )
 347
 348 AC_ARG_ENABLE([test-java-agent-all],
 349         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 350         [test_java_agent_jul=$enableval
 351          test_java_agent_log4j=$enableval],
 352         [:]
 353 )
 354
 355 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 356 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 357 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 358 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 359 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 360 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.])
 361 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 362 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 363
 364 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 365         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 366         $1="$2"
 367         AC_SUBST([$1])
 368 ])
 369
 370 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 371         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 372         $1="$2"
 373         AC_SUBST([$1])
 374 ])
 375
 376 # Default values
 377 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 378 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 379 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 380 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 381 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 382 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 383 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 384 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 385 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 386 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 387 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 388 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 389 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 390 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 391 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 392 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 393 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 394 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 395 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 396 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 397 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 398 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 399 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 400 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 401 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 402 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 403 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 404 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 405 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 406 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 407 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 408 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 409 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 410 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 411 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 412 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 413 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 414 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 415 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 416 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 417 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 418 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 419 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 420 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 421 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 422 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 423 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 424 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 425 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 426 _AC_DEFINE_AND_SUBST([DEFAULT_EVENT_NOTIFIER_ERROR_COUNT_MAP_SIZE], [4096])
 427
 428 # Command short descriptions
 429 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 430 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 431 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a tracing session])
 432 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 433 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 434 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 435 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
 436 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 437 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 438 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
 439 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 440 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 441 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 442 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 443 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive a tracing session's current trace chunk])
 444 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 445 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 446 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 447 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 448 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 449 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 450 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a rotation schedule])
 451 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a rotation schedule])
 452 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 453 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 454 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 455 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 456
 457 if test "x$prefix" = "xNONE"; then
 458         prefix=$ac_default_prefix
 459 fi
 460 CONFDIR=`eval echo $sysconfdir`
 461 AC_SUBST(CONFDIR)
 462 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 463
 464 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
 465
 466 # Check libpopt
 467 PKG_CHECK_MODULES([POPT], [popt],
 468   [
 469     dnl PKG_CHECK_MODULES defines POPT_LIBS
 470   ],
 471   [
 472     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 473     AC_MSG_WARN([Finding libpopt without pkg-config.])
 474     AC_CHECK_LIB([popt],
 475       [poptGetContext],
 476       [POPT_LIBS="-lpopt"],
 477       [
 478         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 479       ]
 480     )
 481   ]
 482 )
 483 AC_SUBST(POPT_LIBS)
 484
 485 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 486
 487 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 488
 489 # URCU library version needed or newer
 490 PKG_CHECK_MODULES([URCU], [liburcu >= 0.9])
 491 PKG_CHECK_MODULES([URCU_BP], [liburcu-bp >= 0.9])
 492 PKG_CHECK_MODULES([URCU_CDS], [liburcu-cds >= 0.9])
 493 AM_CPPFLAGS="$AM_CPPFLAGS $URCU_CFLAGS"
 494
 495 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 496 # it can be explicitly disabled with --without-kmod
 497 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 498 AC_ARG_WITH([kmod],
 499   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 500   [],
 501   [with_kmod=check]
 502 )
 503
 504 AS_IF([test "x$with_kmod" != "xno"],
 505   [
 506     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 507       [
 508         AC_DEFINE([HAVE_KMOD], [1])
 509         KMOD_LIBS="-lkmod"
 510       ],
 511       [
 512         if test "x$with_kmod" != xcheck; then
 513           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 514         else
 515           with_kmod=no
 516         fi
 517       ]
 518     )
 519   ]
 520 )
 521 AC_SUBST(KMOD_LIBS)
 522
 523 # Check for liblttng-ust-ctl, fail if it's not found,
 524 # it can be explicitly disabled with --without-lttng-ust
 525 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 526 AC_ARG_WITH([lttng-ust],
 527   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 528   [],
 529   [with_lttng_ust=yes]
 530 )
 531
 532 AS_IF([test "x$with_lttng_ust" = "xyes"], [
 533   AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 534
 535   # Check for liblttng-ust
 536   PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
 537
 538   # Check for liblttng-ust-ctl
 539   PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
 540
 541   AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
 542 ])
 543
 544 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 545
 546
 547 # Check for fmemopen
 548 AC_CHECK_LIB([c], [fmemopen],
 549 [
 550         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 551 ]
 552 )
 553
 554 # check for libpfm
 555 AC_CHECK_LIB([pfm], [pfm_initialize],
 556              [
 557               have_libpfm=yes
 558               ])
 559 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 560
 561 # For Python
 562 # SWIG version needed or newer:
 563 swig_version=2.0.0
 564
 565 AC_ARG_ENABLE([python-bindings],
 566               [AS_HELP_STRING([--enable-python-bindings],
 567                               [compile Python bindings])],
 568               [enable_python_binding=$enableval], [enable_python_binding=no])
 569
 570 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 571
 572 if test "x$enable_python_binding" = xyes; then
 573   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 574   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 575   AM_PATH_PYTHON([3.0])
 576
 577   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 578   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 579   AS_IF([test -z "$PYTHON_INCLUDE"], [
 580     AS_IF([test -z "$PYTHON_CONFIG"], [
 581       AC_PATH_PROGS([PYTHON_CONFIG],
 582                     [python$PYTHON_VERSION-config python-config],
 583                     [no],
 584                     [`dirname $PYTHON`])
 585       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 586     ])
 587     AC_MSG_CHECKING([python include flags])
 588     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 589     AC_MSG_RESULT([$PYTHON_INCLUDE])
 590   ])
 591
 592 else
 593     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 594 [if you want Python bindings.])
 595
 596 fi
 597
 598 # Epoll check. If not present, the build will fallback on poll() API
 599 AX_HAVE_EPOLL(
 600         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 601         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 602 )
 603 AX_CONFIG_FEATURE(
 604         [epoll], [This platform supports epoll(7)],
 605         [HAVE_EPOLL], [This platform supports epoll(7).]
 606 )
 607
 608 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
 609         [AX_CONFIG_FEATURE_ENABLE(dirfd)],
 610         [AX_CONFIG_FEATURE_DISABLE(dirfd)]
 611 )
 612 AX_CONFIG_FEATURE(
 613         [dirfd], [Use directory file descriptors],
 614         [HAVE_DIRFD], [This platform supports directory file descriptors.]
 615 )
 616
 617 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 618 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 619
 620 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 621         AX_JAVA_OPTIONS
 622         AX_PROG_JAVAC
 623         AX_PROG_JAVA
 624         AX_PROG_JAR
 625
 626         AX_CHECK_CLASSPATH
 627
 628         # Check for Java UST agent common class first
 629         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 630         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 631                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 632         fi
 633
 634         if test "x$test_java_agent_jul" = "xyes"; then
 635                 # Check for JUL agent class
 636                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 637                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 638                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 639                 fi
 640         fi
 641
 642         if test "x$test_java_agent_log4j" = "xyes"; then
 643                 # Check for Log4j agent class
 644                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 645                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 646                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 647                 fi
 648
 649                 # Check for Log4j class
 650                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 651                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 652                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 653                 fi
 654         fi
 655 fi
 656
 657 # enable building man pages (user's intention)
 658 AC_ARG_ENABLE(
 659         man-pages,
 660         AS_HELP_STRING(
 661                 [--disable-man-pages],
 662                 [Do not build and install man pages (already built in a distributed tarball)]
 663         ),
 664         [man_pages_opt=$enableval],
 665         [man_pages_opt=yes]
 666 )
 667
 668 # check for asciidoc and xmlto if we enabled building the man pages
 669 have_asciidoc_xmlto=no
 670 warn_prebuilt_man_pages=no
 671
 672 AS_IF([test "x$man_pages_opt" = "xyes"], [
 673         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 674         AC_PATH_PROG([XMLTO], [xmlto], [no])
 675
 676         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 677                 AS_IF([test "x$in_git_repo" = "xyes"], [
 678                         # this is an error because we're in the Git repo, which
 679                         # means the man pages are not already generated for us,
 680                         # thus asciidoc/xmlto are required because we were asked
 681                         # to build the man pages
 682                         AC_MSG_ERROR([
 683 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 684 --disable-man-pages to disable building the man pages, in which case
 685 they will not be installed.
 686                         ])
 687                 ], [
 688                         # only warn here: since we're in the tarball, the man
 689                         # pages should already be generated at this point, thus
 690                         # asciidoc/xmlto are not strictly required
 691                         warn_prebuilt_man_pages=yes
 692                 ])
 693         ], [
 694                 have_asciidoc_xmlto=yes
 695         ])
 696 ])
 697
 698 # export man page build condition: build the man pages if the user
 699 # asked for it, and if the tools are available
 700 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 701 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 702
 703 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 704
 705 # embedded --help message
 706 AC_ARG_ENABLE(
 707         [embedded-help],
 708         AS_HELP_STRING(
 709                 [--enable-embedded-help],
 710                 [Embed the --help messages in the executable files]
 711         ),
 712         [embedded_help=$enableval],
 713         [embedded_help=no]
 714 )
 715 AS_IF([test "x$embedded_help" = "xyes"], [
 716         AS_IF([test "x$man_pages_opt" = "xno"], [
 717                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 718         ])
 719         AC_PATH_PROG([man_prog_path], [man], [no])
 720         AS_IF([test "x$man_prog_path" = "xno"], [
 721                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 722         ])
 723         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 724         AC_SUBST([MANPROG], [$man_prog_path])
 725 ])
 726 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 727
 728 # Python agent test
 729 UST_PYTHON_AGENT="lttngust"
 730
 731 AC_ARG_ENABLE(test-python2-agent,
 732         AS_HELP_STRING([--enable-test-python2-agent],
 733                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 734         ),[:],[test_python2_agent_autodetect=yes]
 735 )
 736
 737 AC_ARG_ENABLE(test-python3-agent,
 738         AS_HELP_STRING([--enable-test-python3-agent],
 739                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 740         ),[:],[test_python3_agent_autodetect=yes]
 741 )
 742
 743 AC_ARG_ENABLE(test-python-agent-all,
 744         AS_HELP_STRING([--enable-test-python-agent-all],
 745                 [enable test for all python{2/3} agent.]
 746         ),
 747 )
 748
 749 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 750        unset test_python2_agent_autodetect
 751        unset test_python3_agent_autodetect
 752 ])
 753
 754 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 755        enable_test_python2_agent=yes
 756        enable_test_python3_agent=yes
 757 ])
 758
 759 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 760        enable_test_python2_agent=no
 761        enable_test_python3_agent=no
 762 ])
 763
 764
 765 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 766         AS_IF([test -z "$PYTHON2"], [
 767                         PYTHON2=python2
 768                 ], [
 769                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 770         ])
 771
 772         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 773         AS_IF([test -z "$PYTHON2_BIN"], [
 774                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 775                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 776                 ])
 777         ], [
 778                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 779                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 780                         PYTHON2_AGENT=$PYTHON2_BIN
 781                         AC_MSG_RESULT([yes])
 782                         RUN_PYTHON_AGENT_TEST=yes
 783                 ], [
 784                         AC_MSG_RESULT([no])
 785                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 786                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 787                         ])
 788                 ])
 789
 790         ])
 791
 792 ])
 793
 794 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 795         AS_IF([test -z "$PYTHON3"], [
 796                 PYTHON3=python3
 797         ], [
 798                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 799         ])
 800
 801         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 802         AS_IF([test -z "$PYTHON3_BIN"], [
 803                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 804                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 805                 ])
 806         ], [
 807                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 808                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 809                         PYTHON3_AGENT=$PYTHON3_BIN
 810                         AC_MSG_RESULT([yes])
 811                         RUN_PYTHON_AGENT_TEST=yes
 812                 ], [
 813                         AC_MSG_RESULT([no])
 814                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 815                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 816                         ])
 817                 ])
 818
 819         ])
 820 ])
 821 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 822 AC_SUBST([PYTHON2_AGENT])
 823 AC_SUBST([PYTHON3_AGENT])
 824
 825 AC_ARG_ENABLE([test-sdt-uprobe],
 826   [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
 827   [test_sdt_uprobe="$enableval"],
 828   [test_sdt_uprobe=autodetect]
 829 )
 830
 831 AS_IF([test "$test_sdt_uprobe" != "no"], [
 832   LTTNG_CHECK_SDT_WORKS
 833   AC_PATH_PROG([DTRACE], [dtrace])
 834 ])
 835
 836 AS_IF([test "$test_sdt_uprobe" = "yes"], [
 837   AS_IF([test "$lttng_cv_sdt_works" = "no"], [
 838     AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
 839   ])
 840   AS_IF([test "x$DTRACE" = "x"], [
 841     AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
 842   ])
 843 ])
 844
 845 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
 846   AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
 847     AS_IF([test "x$DTRACE" != "x"], [
 848       test_sdt_uprobe=yes
 849     ])
 850   ])
 851 ])
 852
 853 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
 854
 855 # Arguments for binaries build exclusion
 856 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 857 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 858               [Disable the build of lttng-consumerd binaries]))
 859 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 860 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 861               [Disable the build of lttng-relayd binaries]))
 862 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 863               [Disable the build of lttng-sessiond binaries]))
 864 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 865               [Disable the build of the extra components]))
 866
 867
 868 # Always build libconfig since it a dependency of libcommon
 869 build_lib_config=yes
 870
 871 build_lib_compat=no
 872 build_lib_consumer=no
 873 build_lib_hashtable=no
 874 build_lib_health=no
 875 build_lib_index=no
 876 build_lib_kernel_consumer=no
 877 build_lib_kernel_ctl=no
 878 build_lib_lttng_ctl=no
 879 build_lib_relayd=no
 880 build_lib_fd_tracker=no
 881 build_lib_sessiond_comm=no
 882 build_lib_testpoint=no
 883 build_lib_ust_consumer=no
 884
 885 # There is an overlap for enabled dependencies, but this makes everything
 886 # simpler. libcommon and libconfig are always compiled so they are not repeated
 887 # here.
 888
 889 # Enable binary dependencies.
 890 AS_IF([test x$enable_bin_lttng != xno],
 891       [
 892        build_lib_lttng_ctl=yes
 893       ]
 894 )
 895
 896 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 897       [
 898        build_lib_consumer=yes
 899        build_lib_sessiond_comm=yes
 900        build_lib_index=yes
 901        build_lib_health=yes
 902        build_lib_testpoint=yes
 903       ]
 904 )
 905
 906 AS_IF([test x$enable_bin_lttng_crash != xno],
 907       # Do nothing since libconfig and libcommon are built by default.
 908       []
 909 )
 910
 911 AS_IF([test x$enable_bin_lttng_relayd != xno],
 912       [
 913        build_lib_lttng_ctl=yes
 914        build_lib_sessiond_comm=yes
 915        build_lib_hashtable=yes
 916        build_lib_compat=yes
 917        build_lib_index=yes
 918        build_lib_health=yes
 919        build_lib_testpoint=yes
 920        build_lib_fd_tracker=yes
 921       ]
 922 )
 923 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 924       [
 925        build_lib_lttng_ctl=yes
 926        build_lib_sessiond_comm=yes
 927        build_lib_kernel_ctl=yes
 928        build_lib_hashtable=yes
 929        build_lib_compat=yes
 930        build_lib_relayd=yes
 931        build_lib_testpoint=yes
 932        build_lib_health=yes
 933       ]
 934 )
 935
 936 # Libraries dependencies enabling
 937 AS_IF([test x$build_lib_lttng_ctl = xyes],
 938       [
 939        build_lib_sessiond_comm=yes
 940        build_lib_hashtable=yes
 941       ]
 942 )
 943
 944 AS_IF([test x$build_lib_consumer = xyes],
 945       [
 946        build_lib_sessiond_comm=yes
 947        build_lib_kernel_consumer=yes
 948        build_lib_hashtable=yes
 949        build_lib_compat=yes
 950        build_lib_relayd=yes
 951        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 952       ]
 953 )
 954
 955 AS_IF([test x$build_lib_kernel_consumer = xyes],
 956       [
 957        build_lib_kernel_ctl=yes
 958        build_lib_relayd=yes
 959       ]
 960 )
 961
 962 AS_IF([test x$build_lib_relayd = xyes],
 963       [
 964        build_lib_sessiond_comm=yes
 965       ]
 966 )
 967
 968 # Find arch type
 969 AS_CASE([$host_cpu],
 970         [k1om], [ARCHTYPE="x86"],
 971         [i386], [ARCHTYPE="x86"],
 972         [i486], [ARCHTYPE="x86"],
 973         [i586], [ARCHTYPE="x86"],
 974         [i686], [ARCHTYPE="x86"],
 975         [amd64], [ARCHTYPE="x86"],
 976         [x86_64], [ARCHTYPE="x86"],
 977         [powerpc], [ARCHTYPE="ppc"],
 978         [ppc64], [ARCHTYPE="ppc"],
 979         [powerpc64], [ARCHTYPE="ppc"],
 980         [powerpc64le], [ARCHTYPE="ppc"],
 981         [ppc], [ARCHTYPE="ppc"],
 982         [s390], [ARCHTYPE="s390"],
 983         [s390x], [ARCHTYPE="s390"],
 984         [sparc], [ARCHTYPE="sparc64"],
 985         [sparc64], [ARCHTYPE="sparc64"],
 986         [alpha*], [ARCHTYPE="alpha"],
 987         [ia64], [ARCHTYPE="ia64"],
 988         [arm*], [ARCHTYPE="arm"],
 989         [aarch64*], [ARCHTYPE="aarch64"],
 990         [mips*], [ARCHTYPE="mips"],
 991         [nios2*], [ARCHTYPE="nios2"],
 992         [tile*], [ARCHTYPE="tile"],
 993         [hppa*], [ARCHTYPE="hppa"],
 994         [m68k], [ARCHTYPE="m68k"],
 995         [riscv*], [ARCHTYPE="riscv"],
 996         [ARCHTYPE="unknown"]
 997 )
 998
 999 AC_SUBST(ARCHTYPE)
1000
1001 AS_CASE([$host_os],
1002         [linux*], [OSTYPE="linux"],
1003         [freebsd*], [OSTYPE="freebsd"],
1004         [solaris*], [OSTYPE="solaris"],
1005         [cygwin*], [OSTYPE="cygwin"],
1006         [mingw*], [OSTYPE="mingw"],
1007         [OSTYPE="unknown"]
1008 )
1009 AC_SUBST(OSTYPE)
1010 AM_CONDITIONAL([IS_LINUX], [test $OSTYPE = "linux"])
1011
1012
1013
1014 # Userspace callstack capture is only supported by the Linux kernel on x86.
1015 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1016 AS_IF([test "x$ARCHTYPE" = "xx86" && test "x$OSTYPE" = "xlinux"],[
1017         have_modules_userspace_callstack_context=yes
1018         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1019 ])
1020 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context = xyes])
1021
1022 # Export binaries build conditions.
1023 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1024 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1025 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1026 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1027 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1028
1029 # Export the tests and extras build conditions.
1030 AS_IF([\
1031 test "x$enable_bin_lttng" != "xno" && \
1032 test "x$enable_bin_lttng_consumerd" != "xno" && \
1033 test "x$enable_bin_lttng_crash" != "xno" && \
1034 test "x$enable_bin_lttng_relayd" != "xno" && \
1035 test "x$enable_bin_lttng_sessiond" != "xno"],
1036 [build_tests=yes],
1037 [build_tests=no]
1038 )
1039
1040 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1041 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1042
1043 # Export libraries build conditions.
1044 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
1045 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
1046 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1047 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
1048 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1049 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1050 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1051 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1052 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1053 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1054 AM_CONDITIONAL([BUILD_LIB_FD_TRACKER], [test x$build_lib_fd_tracker = xyes])
1055 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1056 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1057 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1058
1059 AM_CFLAGS="${WARN_CFLAGS} -fno-strict-aliasing $PTHREAD_CFLAGS"
1060 AC_SUBST(AM_CFLAGS)
1061
1062 # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...".
1063 AM_LDFLAGS=""
1064 AC_SUBST(AM_LDFLAGS)
1065
1066 # The order in which the include folders are searched is important.
1067 # The top_builddir should always be searched first in the event that a build
1068 # time generated file is included. An example of this is the "version.i" file.
1069 # In a scenario where lttng-tools is built from a distribution tarball and in a
1070 # out-of-tree manner, the generated "version.i" has priority on the one from
1071 # the source (distribution tarball) and must be found first.
1072 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1073 AC_SUBST(AM_CPPFLAGS)
1074
1075 lttngincludedir="${includedir}/lttng"
1076 AC_SUBST(lttngincludedir)
1077
1078 lttngactionincludedir="${includedir}/lttng/action"
1079 AC_SUBST(lttngactionincludedir)
1080
1081 lttngconditionincludedir="${includedir}/lttng/condition"
1082 AC_SUBST(lttngconditionincludedir)
1083
1084 lttngnotificationincludedir="${includedir}/lttng/notification"
1085 AC_SUBST(lttngnotificationincludedir)
1086
1087 lttngtriggerincludedir="${includedir}/lttng/trigger"
1088 AC_SUBST(lttngtriggerincludedir)
1089
1090 lttngeventruleincludedir="${includedir}/lttng/event-rule"
1091 AC_SUBST(lttngeventruleincludedir)
1092
1093 lttnglibexecdir="${libdir}/lttng/libexec"
1094 AC_SUBST(lttnglibexecdir)
1095
1096 AC_CONFIG_FILES([
1097         Makefile
1098         doc/Makefile
1099         doc/man/Makefile
1100         doc/man/asciidoc-attrs.conf
1101         include/Makefile
1102         extras/Makefile
1103         extras/bindings/Makefile
1104         extras/bindings/swig/Makefile
1105         extras/bindings/swig/python/Makefile
1106         extras/core-handler/Makefile
1107         src/Makefile
1108         src/common/Makefile
1109         src/common/argpar/Makefile
1110         src/common/bytecode/Makefile
1111         src/common/kernel-ctl/Makefile
1112         src/common/kernel-consumer/Makefile
1113         src/common/consumer/Makefile
1114         src/common/ust-consumer/Makefile
1115         src/common/hashtable/Makefile
1116         src/common/sessiond-comm/Makefile
1117         src/common/compat/Makefile
1118         src/common/relayd/Makefile
1119         src/common/testpoint/Makefile
1120         src/common/index/Makefile
1121         src/common/health/Makefile
1122         src/common/config/Makefile
1123         src/common/string-utils/Makefile
1124         src/common/fd-tracker/Makefile
1125         src/common/filter/Makefile
1126         src/lib/Makefile
1127         src/lib/lttng-ctl/Makefile
1128         src/lib/lttng-ctl/lttng-ctl.pc
1129         src/bin/Makefile
1130         src/bin/lttng-consumerd/Makefile
1131         src/bin/lttng-sessiond/Makefile
1132         src/bin/lttng-relayd/Makefile
1133         src/bin/lttng/Makefile
1134         src/bin/lttng-crash/Makefile
1135         src/vendor/Makefile
1136         src/vendor/msgpack/Makefile
1137         tests/Makefile
1138         tests/destructive/Makefile
1139         tests/regression/Makefile
1140         tests/regression/kernel/Makefile
1141         tests/regression/tools/Makefile
1142         tests/regression/tools/streaming/Makefile
1143         tests/regression/tools/filtering/Makefile
1144         tests/regression/tools/health/Makefile
1145         tests/regression/tools/tracefile-limits/Makefile
1146         tests/regression/tools/snapshots/Makefile
1147         tests/regression/tools/live/Makefile
1148         tests/regression/tools/exclusion/Makefile
1149         tests/regression/tools/save-load/Makefile
1150         tests/regression/tools/save-load/configuration/Makefile
1151         tests/regression/tools/mi/Makefile
1152         tests/regression/tools/wildcard/Makefile
1153         tests/regression/tools/crash/Makefile
1154         tests/regression/tools/regen-metadata/Makefile
1155         tests/regression/tools/regen-statedump/Makefile
1156         tests/regression/tools/notification/Makefile
1157         tests/regression/tools/rotation/Makefile
1158         tests/regression/tools/base-path/Makefile
1159         tests/regression/tools/metadata/Makefile
1160         tests/regression/tools/tracker/Makefile
1161         tests/regression/tools/working-directory/Makefile
1162         tests/regression/tools/relayd-grouping/Makefile
1163         tests/regression/tools/clear/Makefile
1164         tests/regression/tools/trigger/Makefile
1165         tests/regression/tools/trigger/start-stop/Makefile
1166         tests/regression/tools/trigger/utils/Makefile
1167         tests/regression/ust/Makefile
1168         tests/regression/ust/nprocesses/Makefile
1169         tests/regression/ust/high-throughput/Makefile
1170         tests/regression/ust/low-throughput/Makefile
1171         tests/regression/ust/before-after/Makefile
1172         tests/regression/ust/buffers-pid/Makefile
1173         tests/regression/ust/periodical-metadata-flush/Makefile
1174         tests/regression/ust/multi-session/Makefile
1175         tests/regression/ust/multi-lib/Makefile
1176         tests/regression/ust/overlap/Makefile
1177         tests/regression/ust/overlap/demo/Makefile
1178         tests/regression/ust/linking/Makefile
1179         tests/regression/ust/daemon/Makefile
1180         tests/regression/ust/exit-fast/Makefile
1181         tests/regression/ust/fork/Makefile
1182         tests/regression/ust/libc-wrapper/Makefile
1183         tests/regression/ust/baddr-statedump/Makefile
1184         tests/regression/ust/ust-dl/Makefile
1185         tests/regression/ust/java-jul/Makefile
1186         tests/regression/ust/java-log4j/Makefile
1187         tests/regression/ust/python-logging/Makefile
1188         tests/regression/ust/getcpu-override/Makefile
1189         tests/regression/ust/clock-override/Makefile
1190         tests/regression/ust/type-declarations/Makefile
1191         tests/regression/ust/rotation-destroy-flush/Makefile
1192         tests/regression/ust/blocking/Makefile
1193         tests/regression/ust/namespaces/Makefile
1194         tests/stress/Makefile
1195         tests/unit/Makefile
1196         tests/unit/ini_config/Makefile
1197         tests/perf/Makefile
1198         tests/utils/Makefile
1199         tests/utils/tap/Makefile
1200         tests/utils/testapp/Makefile
1201         tests/utils/testapp/gen-ns-events/Makefile
1202         tests/utils/testapp/gen-kernel-test-events/Makefile
1203         tests/utils/testapp/gen-ust-events/Makefile
1204         tests/utils/testapp/gen-ust-events-ns/Makefile
1205         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1206         tests/utils/testapp/gen-ust-nevents/Makefile
1207         tests/utils/testapp/gen-ust-nevents-str/Makefile
1208         tests/utils/testapp/gen-syscall-events/Makefile
1209         tests/utils/testapp/gen-ust-tracef/Makefile
1210         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1211         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1212         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1213 ])
1214
1215 # Inject variable into python test script.
1216 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1217 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1218 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1219 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1220
1221 AC_OUTPUT
1222
1223 #
1224 # Mini-report on what will be built.
1225 #
1226
1227 PPRINT_INIT
1228 PPRINT_SET_INDENT(1)
1229 PPRINT_SET_TS(38)
1230
1231 AS_ECHO
1232 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1233 AS_ECHO
1234
1235 AS_IF([test -n "$report_fold"], [
1236         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1237 ], [
1238         AS_ECHO("$version_description")
1239 ])
1240
1241 AS_ECHO
1242 PPRINT_SUBTITLE([Features])
1243
1244 # Target architecture we're building for.
1245 target_arch=$host_cpu
1246 [
1247 for f in $CFLAGS; do
1248         if test $f = "-m32"; then
1249                         target_arch="32-bit"
1250         elif test $f = "-m64"; then
1251                         target_arch="64-bit"
1252         fi
1253 done
1254 ]
1255 PPRINT_PROP_STRING([Target architecture], $target_arch)
1256
1257 # kmod enabled/disabled
1258 test "x$with_kmod" != "xno" && value=1 || value=0
1259 PPRINT_PROP_BOOL([libkmod support], $value)
1260
1261 # LTTng-UST enabled/disabled
1262 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1263 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1264
1265 AS_ECHO
1266 PPRINT_SUBTITLE([Binaries])
1267
1268 # List binaries to be built
1269 test x$enable_bin_lttng != xno && value=1 || value=0
1270 PPRINT_PROP_BOOL([lttng], $value)
1271
1272 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1273 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1274
1275 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1276 PPRINT_PROP_BOOL([lttng-crash], $value)
1277
1278 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1279 PPRINT_PROP_BOOL([lttng-relayd], $value)
1280
1281 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1282 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1283
1284 # Extras
1285 test x$enable_extras != xno && value=1 || value=0
1286 AS_ECHO
1287 PPRINT_SET_INDENT(0)
1288 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1289 PPRINT_SET_INDENT(1)
1290
1291 AS_ECHO
1292 PPRINT_SUBTITLE([Tests])
1293
1294 # Print clear message that tests won't be built
1295 AS_IF([test "x$build_tests" = "xno"],[
1296         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1297 ])
1298
1299 # LTTng UST Java agent JUL tests enabled/disabled
1300 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1301 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1302
1303 # LTTng UST Java agent Log4j tests enabled/disabled
1304 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1305 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1306
1307 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1308 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1309
1310 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1311 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1312
1313 # LTTng UST Java agent Log4j tests enabled/disabled
1314 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1315 PPRINT_PROP_BOOL([LTTng-UST SDT uprobe tests], $value)
1316
1317 #Python binding enabled/disabled
1318 test "x$enable_python_binding" = xyes && value=1 || value=0
1319 AS_ECHO
1320 PPRINT_SET_INDENT(0)
1321 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1322
1323 # man pages build enabled/disabled
1324 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1325
1326 AS_IF([test "x$man_pages_opt" != "xno"], [
1327         AS_IF([test "x$in_git_repo" = "xyes"], [
1328                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1329         ], [
1330                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1331                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1332                 ], [
1333                         PPRINT_PROP_STRING([build_man_pages_msg],
1334                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1335                                 $PPRINT_COLOR_SUBTITLE)
1336                 ])
1337         ])
1338 ], [
1339         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1340 ])
1341
1342 m4_popdef([build_man_pages_msg])
1343
1344 test "x$embedded_help" = xyes && value=1 || value=0
1345 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1346
1347 PPRINT_SET_INDENT(1)
1348
1349 report_bindir="`eval eval echo $bindir`"
1350 report_libdir="`eval eval echo $libdir`"
1351
1352 # Print the bindir and libdir this `make install' will install into.
1353 AS_ECHO
1354 PPRINT_SUBTITLE([Install directories])
1355 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1356 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1357
1358 AS_ECHO
1359 PPRINT_SUBTITLE([Search directories])
1360
1361 # If we build the sessiond, print the paths it will use
1362 AS_IF([test "$SESSIOND_BIN" = ""],[
1363         path="$report_bindir/lttng-sessiond"
1364 ],[
1365         path="$SESSIOND_BIN"
1366 ])
1367 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1368
1369 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1370         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1371 ],[
1372         path="$CONSUMERD32_BIN"
1373 ])
1374 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1375
1376 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1377         path="`eval eval echo $libdir`"
1378 ],[
1379         path="$CONSUMERD32_LIBDIR"
1380 ])
1381 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1382
1383 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1384         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1385 ],[
1386         path="$CONSUMERD64_BIN"
1387 ])
1388 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1389
1390 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1391         path="`eval eval echo $libdir`"
1392 ],[
1393         path="$CONSUMERD64_LIBDIR"
1394 ])
1395 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1396 PPRINT_SET_INDENT(0)
1397
1398 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1399         AS_ECHO
1400         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1401
1402 Note that the man pages are already built in this distribution tarball,
1403 therefore asciidoc and xmlto are only needed if you intend to modify
1404 their sources.
1405
1406 Also note that the installed man pages will contain the project's
1407 default command-line option and environment variable values.
1408
1409 Use --disable-man-pages to completely disable building and installing
1410 the man pages.])
1411 ])