configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[1.9.5],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
   9 # note: remember to update tracepoint.h dlopen() to match this version
  10 # number. TODO: eventually automate by exporting the major number.
  11
  12 AC_CONFIG_AUX_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AC_CONFIG_MACRO_DIR([config])
  16 AM_INIT_AUTOMAKE([foreign])
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  19 AC_CONFIG_HEADERS([config.h include/lttng/config.h])
  20 AH_TEMPLATE([HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  21
  22 # Compute minor/major/patchlevel version numbers
  23 AC_PROG_SED
  24 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*$/\1/')
  25 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*$/\1/')
  26 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\)$/\1/')
  27 AC_SUBST([MAJOR_VERSION], [$major_version])
  28 AC_SUBST([MINOR_VERSION], [$minor_version])
  29 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  30 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  31 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  32 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  33
  34
  35 # Checks for programs.
  36 AC_PROG_CC
  37 AC_PROG_CXX
  38 AC_PROG_MAKE_SET
  39 LT_INIT
  40
  41 ## Checks for libraries.
  42 AC_CHECK_LIB([dl], [dlopen])
  43 AC_CHECK_LIB([pthread], [pthread_create])
  44
  45 # Check for libuuid
  46 AC_CHECK_LIB([uuid], [uuid_generate], [],
  47         [AC_MSG_ERROR([Cannot find libuuid. Use [LDFLAGS]=-Ldir to specify its location.])]
  48 )
  49
  50 # Checks for header files.
  51 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
  52
  53 # Checks for typedefs, structures, and compiler characteristics.
  54 AC_C_INLINE
  55 #AC_TYPE_INT16_T
  56 #AC_TYPE_INT32_T
  57 #AC_TYPE_INT64_T
  58 #AC_TYPE_INT8_T
  59 #AC_TYPE_PID_T
  60 #AC_TYPE_SIZE_T
  61 #AC_TYPE_SSIZE_T
  62 #AC_TYPE_UINT16_T
  63 #AC_TYPE_UINT32_T
  64 #AC_TYPE_UINT64_T
  65 #AC_TYPE_UINT8_T
  66 #AC_CHECK_TYPES([ptrdiff_t])
  67
  68 # Checks for library functions.
  69 AC_FUNC_MALLOC
  70 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol])
  71
  72 CFLAGS="-Wall $CFLAGS"
  73
  74 # Check for texinfo, required for building the documentation
  75 # TODO: make this (and building the documentation) optional
  76 AC_CHECK_PROG([TEXINFO], [makeinfo], [yes])
  77 AS_IF([test "x$TEXINFO" != "xyes"],[
  78         AC_MSG_ERROR([Please install the 'texinfo' program and make sure 'makeinfo' is in the PATH.])
  79 ])
  80
  81 # URCU
  82
  83 # urcu - check if we just find the headers it out of the box.
  84 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CFLAGS]=-Idir to specify their location.
  85 This error can also occur when the liburcu package's configure script has not been run.])])
  86
  87 AC_MSG_CHECKING([caa_likely()])
  88 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
  89 #include <urcu/compiler.h>
  90 void fct(void)
  91 {
  92         if (caa_likely(1)) {
  93         }
  94 }
  95 ]])],[
  96         AC_MSG_RESULT([yes])
  97 ],[
  98         AC_MSG_RESULT([no])
  99         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 100
 101 ])
 102
 103 # urcu - check that URCU lib is available to compilation
 104 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 105
 106 # urcu - check that URCU lib is at least version 0.6
 107 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 108
 109
 110 # Check for various supplementary host information (beyond the
 111 # triplet) which might affect the library format choices.  E.g., we
 112 # can be building with `i686-unknown-linux-gnu-gcc -m64'
 113
 114 case "${host}" in
 115 changequote(,)dnl
 116   i[34567]86-*-linux*)
 117 changequote([,])dnl
 118     AC_CACHE_CHECK([if building for x86-64], [ust_cv_i386_is_x86_64],
 119                     [save_CPPFLAGS="$CPPFLAGS"
 120                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 121                     AC_EGREP_CPP([got it], [
 122 #if __x86_64__
 123 got it
 124 #endif
 125                  ], [ust_cv_i386_is_x86_64=yes],
 126                     [ust_cv_i386_is_x86_64=no])
 127                     CPPFLAGS="$save_CPPFLAGS"])
 128     ;;
 129 esac
 130
 131 AC_MSG_CHECKING([library format for the host system])
 132 case $host_cpu in
 133 changequote(,)dnl
 134         i[3456]86)
 135 changequote([,])dnl
 136           if test "$ust_cv_i386_is_x86_64" = yes ; then
 137              LIBFORMAT="elf64-x86-64"
 138           else
 139              LIBFORMAT="elf32-i386"
 140           fi
 141           ;;
 142         x86_64) LIBFORMAT="elf64-x86-64" ;;
 143         powerpc) LIBFORMAT="elf32-powerpc" ;;
 144         ppc64) LIBFORMAT="elf64-powerpc" ;;
 145         powerpc64) LIBFORMAT="elf64-powerpc" ;;
 146         s390) LIBFORMAT="elf32-s390"; NO_UNALIGNED_ACCESS=1 ;;
 147         s390x) LIBFORMAT="elf64-s390"; NO_UNALIGNED_ACCESS=1 ;;
 148         armv5) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 149         arm) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 150         mips*) LIBFORMAT=""; NO_UNALIGNED_ACCESS=1;;
 151         *) AC_MSG_ERROR([unable to detect library format (unsupported architecture ($host_cpu)?)]) ;;
 152 esac
 153 AC_SUBST(LIBFORMAT)
 154 AC_MSG_RESULT($LIBFORMAT)
 155
 156 if test "x$host_cpu" = "xarm" ; then
 157 AC_MSG_CHECKING([checking for armv5])
 158 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 159 #ifndef __ARM_ARCH_5TEJ__
 160 #error "no arm5 here"
 161 #endif
 162 ]])],[
 163         AC_MSG_RESULT([yes])
 164         NO_UNALIGNED_ACCESS=1
 165
 166 ],[
 167         AC_MSG_RESULT([no])
 168
 169 ])
 170 fi
 171 if test x$NO_UNALIGNED_ACCESS = x ; then
 172 AC_DEFINE([HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 173 fi
 174
 175 # Set compile flags to java include files if given
 176 AC_ARG_WITH([java-jdk],
 177         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 178         [JAVA_JDK=$withval],
 179         [JAVA_JDK=""]
 180 )
 181 AS_IF([test $JAVA_JDK],[
 182         AS_IF([test -d $JAVA_JDK],[
 183                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 184                 SUBDIRS=`find $JAVA_JDK/include -type d`
 185                 CFLAGS+=" "
 186                 CFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 187                 CFLAGS+=" "
 188         ],[
 189                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 190         ])
 191 ])
 192
 193 # Check for JNI header files if requested
 194 AC_ARG_WITH([jni-interface],
 195         [AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
 196         [jni_interface=$withval],
 197         [jni_interface=no]
 198 )
 199
 200 AS_IF([test "x$jni_interface" = "xyes"],[
 201         AC_CHECK_HEADERS([jni.h],[],[
 202         AC_MSG_ERROR([missing jni.h
 203 Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
 204 Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
 205         ])
 206 ])
 207 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 208
 209 #currently disabled.
 210         #tests/hello2/Makefile
 211         #tests/basic/Makefile
 212         #tests/simple_include/Makefile
 213         #tests/snprintf/Makefile
 214         #tests/test-nevents/Makefile
 215         #tests/test-libustinstr-malloc/Makefile
 216         #tests/dlopen/Makefile
 217         #tests/same_line_marker/Makefile
 218         #tests/trace_event/Makefile
 219         #tests/tracepoint/Makefile
 220         #tests/tracepoint/benchmark/Makefile
 221         #tests/register_test/Makefile
 222         #tests/libustctl_function_#tests/Makefile
 223         #tests/exit-fast/Makefile
 224         #tests/basic_long/Makefile
 225
 226 AC_CONFIG_FILES([
 227         Makefile
 228         include/Makefile
 229         include/lttng/ust-version.h
 230         snprintf/Makefile
 231         libringbuffer/Makefile
 232         liblttng-ust-comm/Makefile
 233         liblttng-ust/Makefile
 234         liblttng-ust-ctl/Makefile
 235         liblttng-ust-fork/Makefile
 236         liblttng-ust-java/Makefile
 237         liblttng-ust-libc/Makefile
 238         tests/Makefile
 239         tests/hello/Makefile
 240         tests/hello-static-lib/Makefile
 241         tests/hello.cxx/Makefile
 242         tests/demo/Makefile
 243         tests/fork/Makefile
 244         tests/ust-basic-tracing/Makefile
 245         tests/ust-multi-test/Makefile
 246         lttng-ust.pc
 247 ])
 248 AC_OUTPUT