configure.ac

   1 AC_PREREQ([2.64])
   2 AC_INIT([lttng-tools],[2.10.0-pre],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   3
   4 AC_CONFIG_HEADERS([include/config.h])
   5 AC_CONFIG_AUX_DIR([config])
   6 AC_CONFIG_MACRO_DIR([m4])
   7
   8 AC_CANONICAL_TARGET
   9 AC_CANONICAL_HOST
  10
  11 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax])
  12 AM_MAINTAINER_MODE([enable])
  13
  14 # Enable silent rules if available (Introduced in AM 1.11)
  15 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  16
  17 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  18
  19 # Checks for C compiler
  20 AC_USE_SYSTEM_EXTENSIONS
  21 AC_SYS_LARGEFILE
  22 AC_PROG_CC
  23 AC_PROG_CC_STDC
  24
  25 # Checks for programs.
  26 AC_PROG_GREP
  27 AC_PROG_LEX
  28 AC_PROG_MAKE_SET
  29 AC_PROG_SED
  30 AC_PROG_YACC
  31 AC_PATH_PROG(report_fold, fold)
  32 LT_INIT
  33
  34 # Check for objcopy, required by the base address statedump and dynamic linker tests
  35 AC_CHECK_TOOL([OBJCOPY], objcopy, no)
  36 AS_IF([test "x$OBJCOPY" = xno],
  37         [AC_MSG_WARN([Cannont find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  38 )
  39 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  40
  41 # Checks for typedefs, structures, and compiler characteristics.
  42 AC_C_INLINE
  43 AC_TYPE_INT32_T
  44 AC_TYPE_INT64_T
  45 AC_TYPE_MODE_T
  46 AC_TYPE_OFF_T
  47 AC_TYPE_PID_T
  48 AC_TYPE_SIZE_T
  49 AC_TYPE_SSIZE_T
  50 AC_TYPE_UID_T
  51 AC_TYPE_UINT16_T
  52 AC_TYPE_UINT32_T
  53 AC_TYPE_UINT64_T
  54 AC_TYPE_UINT8_T
  55
  56 AX_C___ATTRIBUTE__
  57 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
  58         [:],
  59         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
  60
  61 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
  62 LIBS="$PTHREAD_LIBS $LIBS"
  63 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
  64 CC="$PTHREAD_CC"
  65
  66 AX_LIB_SOCKET_NSL
  67
  68 LT_NO_UNDEFINED=""
  69 AS_CASE([$host_os],
  70   [cygwin*],
  71     [
  72       LT_NO_UNDEFINED="-no-undefined"
  73     ]
  74 )
  75
  76 AC_SUBST(LT_NO_UNDEFINED)
  77
  78 # Compute minor/major/patchlevel version numbers
  79 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  80 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  81 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  82
  83 AC_SUBST([MAJOR_VERSION], [$major_version])
  84 AC_SUBST([MINOR_VERSION], [$minor_version])
  85 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  86 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
  87 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
  88 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
  89
  90 version_name="Codename TBD"
  91 version_description='Description TBD'
  92 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
  93
  94 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
  95 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
  96
  97 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  98 AC_ARG_ENABLE(libtool-linkdep-fixup,
  99         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 100                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 101         libtool_fixup=$enableval,
 102         libtool_fixup=yes)
 103
 104 AS_IF([test "x$libtool_fixup" = "xyes"],
 105             [
 106             libtool_m4="$srcdir/m4/libtool.m4"
 107             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 108             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 109             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 110             AS_IF([test $libtool_flag_pattern_count -ne 0],
 111             [
 112                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 113                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 114                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 115                   ],
 116                   [
 117                   AC_MSG_RESULT([none])
 118                   ])
 119             ])
 120
 121 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 122
 123 AC_CHECK_HEADERS([ \
 124         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 125         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 126         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 127         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 128         sys/mount.h sys/param.h sys/time.h
 129 ])
 130
 131 # Basic functions check
 132 AC_CHECK_FUNCS([ \
 133         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 134         gethostbyname gethostname getpagesize localtime_r memchr memset \
 135         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 136         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 137         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 138 ])
 139
 140 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 141 # add -lrt to LIBS
 142 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 143
 144 # Babeltrace viewer check
 145 AC_ARG_WITH([babeltrace-bin],
 146         AS_HELP_STRING([--with-babeltrace-bin],
 147         [Location of the babeltrace viewer executable (including the filename)]),
 148         [BABELTRACE_BIN="$withval"],
 149         [BABELTRACE_BIN=''])
 150 AC_SUBST([BABELTRACE_BIN])
 151
 152 # lttv-gui
 153 AC_ARG_WITH([lttv-gui-bin],
 154         AS_HELP_STRING([--with-lttv-gui-bin],
 155    [Location of the lttv GUI viewer executable (including the filename)]),
 156    [LTTV_GUI_BIN="$withval"],
 157    [LTTV_GUI_BIN=''])
 158 AC_SUBST([LTTV_GUI_BIN])
 159
 160 AC_ARG_WITH([consumerd32-bin],
 161         AS_HELP_STRING([--with-consumerd32-bin],
 162         [Location of the 32-bit consumerd executable (including the filename)]),
 163         [CONSUMERD32_BIN="$withval"],
 164         [CONSUMERD32_BIN=''])
 165 AC_SUBST([CONSUMERD32_BIN])
 166
 167 AC_ARG_WITH([consumerd64-bin],
 168         AS_HELP_STRING([--with-consumerd64-bin],
 169         [Location of the 64-bit consumerd executable (including the filename)]),
 170         [CONSUMERD64_BIN="$withval"],
 171         [CONSUMERD64_BIN=''])
 172 AC_SUBST([CONSUMERD64_BIN])
 173
 174 AC_ARG_WITH([consumerd32-libdir],
 175         AS_HELP_STRING([--with-consumerd32-libdir],
 176         [Directory containing the 32-bit consumerd libraries]),
 177         [CONSUMERD32_LIBDIR="$withval"],
 178         [CONSUMERD32_LIBDIR=''])
 179 AC_SUBST([CONSUMERD32_LIBDIR])
 180
 181 AC_ARG_WITH([consumerd64-libdir],
 182         AS_HELP_STRING([--with-consumerd64-libdir],
 183         [Directory containing the 64-bit consumerd libraries]),
 184         [CONSUMERD64_LIBDIR="$withval"],
 185         [CONSUMERD64_LIBDIR=''])
 186 AC_SUBST([CONSUMERD64_LIBDIR])
 187
 188 AC_ARG_WITH([sessiond-bin],
 189         AS_HELP_STRING([--with-sessiond-bin],
 190         [Location of the sessiond executable (including the filename)]),
 191         [SESSIOND_BIN="$withval"],
 192         [SESSIOND_BIN=''])
 193 AC_SUBST([SESSIOND_BIN])
 194
 195 AC_ARG_WITH([lttng-system-rundir],
 196         AS_HELP_STRING([--with-lttng-system-rundir],
 197         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 198         [LTTNG_SYSTEM_RUNDIR="$withval"],
 199         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 200 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 201
 202 AC_ARG_ENABLE([test-java-agent-jul],
 203         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 204         [test_java_agent_jul=$enableval],
 205         [test_java_agent_jul=no]
 206 )
 207
 208 AC_ARG_ENABLE([test-java-agent-log4j],
 209         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 210         [test_java_agent_log4j=$enableval],
 211         [test_java_agent_log4j=no]
 212 )
 213
 214 AC_ARG_ENABLE([test-java-agent-all],
 215         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 216         [test_java_agent_jul=$enableval
 217          test_java_agent_log4j=$enableval],
 218         [:]
 219 )
 220
 221 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 222 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 223 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 224 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 225 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 226 AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.])
 227 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 228 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 229
 230 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 231         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 232         $1="$2"
 233         AC_SUBST([$1])
 234 ])
 235
 236 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 237         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 238         $1="$2"
 239         AC_SUBST([$1])
 240 ])
 241
 242 # Default values
 243 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 244 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 245 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 246 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 247 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 248 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 249 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345])
 250 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 251 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 252 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 253 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 254 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 255 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 256 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 257 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 258 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 259 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 260 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 261 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 262 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 263 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 264 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 265 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 266 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 267 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 268 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 269 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 270 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 271 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 272 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 273 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 274 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 275 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 276 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 277 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 278 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 279 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 280 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 281 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 282 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 283 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 284 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 285
 286 # Command short descriptions
 287 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel])
 288 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 289 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions])
 290 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels])
 291 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules])
 292 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels])
 293 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules])
 294 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command])
 295 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events])
 296 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 297 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Manage an LTTng tracing session's data regeneration])
 298 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 299 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session])
 300 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session])
 301 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing])
 302 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session])
 303 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing])
 304 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources])
 305 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources])
 306 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information])
 307 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer])
 308
 309 if test "x$prefix" = "xNONE"; then
 310         prefix=$ac_default_prefix
 311 fi
 312 CONFDIR=`eval echo $sysconfdir`
 313 AC_SUBST(CONFDIR)
 314 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 315
 316 AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.])
 317
 318 #
 319 # Check for pthread
 320 AC_CHECK_LIB([pthread], [pthread_create], [],
 321         [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])]
 322 )
 323
 324 # Check libpopt
 325 PKG_CHECK_MODULES([POPT], [popt],
 326         [LIBS="$LIBS $POPT_LIBS"],
 327         [
 328                 AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 329                 AC_MSG_WARN([Finding libpopt without pkg-config.])
 330                 AC_CHECK_LIB([popt],
 331                         [poptGetContext],
 332                         [],
 333                         [
 334                                  AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 335                         ]
 336                 )
 337         ]
 338 )
 339
 340 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 341
 342 # Check for uuid in system libs
 343 AC_CHECK_FUNCS([uuid_generate],
 344 [
 345         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 346         link_with_libuuid=no
 347 ],
 348 [
 349 # First, check the pkg-config module is available, otherwise explicitly check
 350 # for libuuid, or uuid support in the C-library.
 351 PKG_CHECK_MODULES([UUID], [uuid],
 352 [
 353         LIBS="$LIBS $UUID_LIBS"
 354         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 355         link_with_libuuid=yes
 356 ],
 357 [
 358         # Check for libuuid
 359         AC_CHECK_LIB([uuid],
 360                 [uuid_generate],
 361                 [
 362                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.])
 363                         link_with_libuuid=yes
 364                 ],
 365                 [
 366                         # libuuid not found, check for uuid_create in libc.
 367                         AC_CHECK_LIB([c],
 368                                 [uuid_create],
 369                                 [
 370                                         AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
 371                                         link_with_libc_uuid=yes
 372                                 ],
 373                                 [
 374                                         AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 375                                 ]
 376                         )
 377                 ]
 378         )
 379 ])
 380 ])
 381
 382 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$link_with_libuuid" = "xyes"])
 383 AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$link_with_libc_uuid" = "xyes"])
 384
 385 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 386
 387 # URCU library version needed or newer
 388 m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed])
 389
 390 # Check liburcu needed function calls
 391 AC_CHECK_DECL([cds_list_add], [],
 392         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]])
 393 AC_CHECK_DECL([cds_wfcq_init], [],
 394         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 395 AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [],
 396         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]])
 397 AC_CHECK_DECL([futex_async], [],
 398         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]])
 399 AC_CHECK_DECL([rcu_thread_offline], [],
 400         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 401 AC_CHECK_DECL([rcu_thread_online], [],
 402         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 403 AC_CHECK_DECL([caa_likely], [],
 404         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]])
 405 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [],
 406         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])])
 407
 408 #Function added in urcu 0.7.0
 409 AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [],
 410         [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]
 411 )
 412
 413 # Check kmod library
 414 AC_ARG_WITH(kmod-prefix,
 415   AS_HELP_STRING([--with-kmod-prefix=PATH],
 416                 [Specify the installation prefix of the kmod library.
 417                 Headers must be in PATH/include; libraries in PATH/lib.]),
 418                 [
 419                         CPPFLAGS="$CPPFLAGS -I${withval}/include"
 420                         LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 421                 ])
 422
 423 AC_ARG_ENABLE(kmod,
 424         AS_HELP_STRING([--disable-kmod],[build without kmod support]),
 425         kmod_support=$enableval, kmod_support=yes)
 426
 427 AS_IF([test "x$kmod_support" = "xyes"], [
 428         AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 429                 [
 430                         AC_DEFINE([HAVE_KMOD], [1], [has kmod support])
 431                         LIBS="$LIBS -lkmod"
 432                         kmod_found=yes
 433                 ],
 434                 kmod_found=no
 435         )
 436 ])
 437 AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes])
 438
 439 AC_ARG_WITH(lttng-ust-prefix,
 440   AS_HELP_STRING([--with-lttng-ust-prefix=PATH],
 441                  [Specify the installation prefix of the lttng-ust library.
 442                   Headers must be in PATH/include; libraries in PATH/lib.]),
 443                   [
 444                     CPPFLAGS="$CPPFLAGS -I${withval}/include"
 445                     LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib"
 446                   ])
 447
 448 # Check liblttng-ust-ctl library
 449 AC_ARG_WITH(lttng-ust,
 450         AS_HELP_STRING([--without-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]),
 451         lttng_ust_support=$withval, lttng_ust_support=yes)
 452
 453 AS_IF([test "x$lttng_ust_support" = "xyes"], [
 454         AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer],
 455                 [
 456                         AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support])
 457                         lttng_ust_ctl_found=yes
 458                 ],
 459                 [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])],
 460                 [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl]
 461         )
 462 ])
 463 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes])
 464 AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range])
 465
 466 # check for dlopen
 467 AC_CHECK_LIB([dl], [dlopen],
 468 [
 469         have_libdl=yes
 470 ],
 471 [
 472         #libdl not found, check for dlopen in libc.
 473         AC_CHECK_LIB([c], [dlopen],
 474         [
 475                 have_libc_dl=yes
 476         ],
 477         [
 478                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 479         ])
 480 ])
 481 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
 482 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
 483
 484 # Check for fmemopen
 485 AC_CHECK_LIB([c], [fmemopen],
 486 [
 487         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 488 ]
 489 )
 490
 491 # Check for open_memstream
 492 AC_CHECK_LIB([c], [open_memstream],
 493 [
 494         AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.])
 495 ]
 496 )
 497
 498 # check for libpfm
 499 AC_CHECK_LIB([pfm], [pfm_initialize],
 500              [
 501               have_libpfm=yes
 502               ])
 503 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 504
 505 AC_ARG_ENABLE([git-version],
 506               [AC_HELP_STRING([--disable-git-version],
 507                               [Do not use the git version for the build])],
 508               [have_git_version=$enableval], [have_git_version=yes]
 509 )
 510
 511 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE],
 512         [test "x${have_git_version}" = "xyes"])
 513
 514 # For Python
 515 # SWIG version needed or newer:
 516 swig_version=2.0.0
 517
 518 AC_ARG_ENABLE([python-bindings],
 519               [AC_HELP_STRING([--enable-python-bindings],
 520                               [compile Python bindings])],
 521               [enable_python_binding=$enableval], [enable_python_binding=no])
 522
 523 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 524
 525 if test "x$enable_python_binding" = xyes; then
 526   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 527   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 528   AM_PATH_PYTHON([3.0])
 529
 530   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 531   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 532   AS_IF([test -z "$PYTHON_INCLUDE"], [
 533     AS_IF([test -z "$PYTHON_CONFIG"], [
 534       AC_PATH_PROGS([PYTHON_CONFIG],
 535                     [python$PYTHON_VERSION-config python-config],
 536                     [no],
 537                     [`dirname $PYTHON`])
 538       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 539     ])
 540     AC_MSG_CHECKING([python include flags])
 541     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 542     AC_MSG_RESULT([$PYTHON_INCLUDE])
 543   ])
 544
 545 else
 546     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 547 [if you want Python bindings.])
 548
 549 fi
 550
 551 # Epoll check. If not present, the build will fallback on poll() API
 552 AX_HAVE_EPOLL(
 553         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 554         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 555 )
 556 AX_CONFIG_FEATURE(
 557         [epoll], [This platform supports epoll(7)],
 558         [HAVE_EPOLL], [This platform supports epoll(7).],
 559         [enable_epoll="yes"], [enable_epoll="no"]
 560 )
 561 AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ])
 562
 563 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 564 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 565
 566 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 567         AX_JAVA_OPTIONS
 568         AX_PROG_JAVAC
 569         AX_PROG_JAVA
 570         AX_PROG_JAR
 571
 572         AX_CHECK_CLASSPATH
 573
 574         # Check for Java UST agent common class first
 575         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 576         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 577                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 578         fi
 579
 580         if test "x$test_java_agent_jul" = "xyes"; then
 581                 # Check for JUL agent class
 582                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 583                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 584                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 585                 fi
 586         fi
 587
 588         if test "x$test_java_agent_log4j" = "xyes"; then
 589                 # Check for Log4j agent class
 590                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 591                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 592                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 593                 fi
 594
 595                 # Check for Log4j class
 596                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 597                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 598                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 599                 fi
 600         fi
 601 fi
 602
 603 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 604 # is not distributed in tarballs
 605 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 606 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 607
 608 # enable building man pages (user's intention)
 609 AC_ARG_ENABLE(
 610         man-pages,
 611         AS_HELP_STRING(
 612                 [--disable-man-pages],
 613                 [Do not build and install man pages (already built in a distributed tarball)]
 614         ),
 615         [man_pages_opt=$enableval],
 616         [man_pages_opt=yes]
 617 )
 618
 619 # check for asciidoc and xmlto if we enabled building the man pages
 620 have_asciidoc_xmlto=no
 621 warn_prebuilt_man_pages=no
 622
 623 AS_IF([test "x$man_pages_opt" = "xyes"], [
 624         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 625         AC_PATH_PROG([XMLTO], [xmlto], [no])
 626
 627         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 628                 AS_IF([test "x$in_git_repo" = "xyes"], [
 629                         # this is an error because we're in the Git repo, which
 630                         # means the man pages are not already generated for us,
 631                         # thus asciidoc/xmlto are required because we were asked
 632                         # to build the man pages
 633                         AC_MSG_ERROR([
 634 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 635 --disable-man-pages to disable building the man pages, in which case
 636 they will not be installed.
 637                         ])
 638                 ], [
 639                         # only warn here: since we're in the tarball, the man
 640                         # pages should already be generated at this point, thus
 641                         # asciidoc/xmlto are not strictly required
 642                         warn_prebuilt_man_pages=yes
 643                 ])
 644         ], [
 645                 have_asciidoc_xmlto=yes
 646         ])
 647 ])
 648
 649 # export man page build condition: build the man pages if the user
 650 # asked for it, and if the tools are available
 651 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 652 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 653
 654 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 655
 656 # embedded --help message
 657 AC_ARG_ENABLE(
 658         [embedded-help],
 659         AS_HELP_STRING(
 660                 [--enable-embedded-help],
 661                 [Embed the --help messages in the executable files]
 662         ),
 663         [embedded_help=$enableval],
 664         [embedded_help=no]
 665 )
 666 AS_IF([test "x$embedded_help" = "xyes"], [
 667         AS_IF([test "x$man_pages_opt" = "xno"], [
 668                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 669         ])
 670         AC_PATH_PROG([man_prog_path], [man], [no])
 671         AS_IF([test "x$man_prog_path" = "xno"], [
 672                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 673         ])
 674         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 675         AC_SUBST([MANPROG], [$man_prog_path])
 676 ])
 677 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 678
 679 # Python agent test
 680 UST_PYTHON_AGENT="lttngust"
 681
 682 AC_ARG_ENABLE(test-python2-agent,
 683         AS_HELP_STRING([--enable-test-python2-agent],
 684                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 685         ),[:],[test_python2_agent_autodetect=yes]
 686 )
 687
 688 AC_ARG_ENABLE(test-python3-agent,
 689         AS_HELP_STRING([--enable-test-python3-agent],
 690                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 691         ),[:],[test_python3_agent_autodetect=yes]
 692 )
 693
 694 AC_ARG_ENABLE(test-python-agent-all,
 695         AS_HELP_STRING([--enable-test-python-agent-all],
 696                 [enable test for all python{2/3} agent.]
 697         ),
 698 )
 699
 700 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 701        unset test_python2_agent_autodetect
 702        unset test_python3_agent_autodetect
 703 ])
 704
 705 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 706        enable_test_python2_agent=yes
 707        enable_test_python3_agent=yes
 708 ])
 709
 710 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 711        enable_test_python2_agent=no
 712        enable_test_python3_agent=no
 713 ])
 714
 715
 716 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 717         AS_IF([test -z "$PYTHON2"], [
 718                         PYTHON2=python2
 719                 ], [
 720                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 721         ])
 722
 723         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 724         AS_IF([test -z "$PYTHON2_BIN"], [
 725                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 726                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 727                 ])
 728         ], [
 729                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 730                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 731                         PYTHON2_AGENT=$PYTHON2_BIN
 732                         AC_MSG_RESULT([yes])
 733                         RUN_PYTHON_AGENT_TEST=yes
 734                 ], [
 735                         AC_MSG_RESULT([no])
 736                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 737                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 738                         ])
 739                 ])
 740
 741         ])
 742
 743 ])
 744
 745 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 746         AS_IF([test -z "$PYTHON3"], [
 747                 PYTHON3=python3
 748         ], [
 749                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 750         ])
 751
 752         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 753         AS_IF([test -z "$PYTHON3_BIN"], [
 754                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 755                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 756                 ])
 757         ], [
 758                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 759                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 760                         PYTHON3_AGENT=$PYTHON3_BIN
 761                         AC_MSG_RESULT([yes])
 762                         RUN_PYTHON_AGENT_TEST=yes
 763                 ], [
 764                         AC_MSG_RESULT([no])
 765                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 766                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 767                         ])
 768                 ])
 769
 770         ])
 771 ])
 772 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 773 AC_SUBST([PYTHON2_AGENT])
 774 AC_SUBST([PYTHON3_AGENT])
 775
 776 # Arguments for binaries build exclusion
 777 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 778 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 779               [Disable the build of lttng-consumerd binaries]))
 780 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 781 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 782               [Disable the build of lttng-relayd binaries]))
 783 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 784               [Disable the build of lttng-sessiond binaries]))
 785 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 786               [Disable the build of the extra components]))
 787
 788
 789 # Always build libconfig since it a dependency of libcommon
 790 build_lib_config=yes
 791
 792 build_lib_compat=no
 793 build_lib_consumer=no
 794 build_lib_hashtable=no
 795 build_lib_health=no
 796 build_lib_index=no
 797 build_lib_kernel_consumer=no
 798 build_lib_kernel_ctl=no
 799 build_lib_lttng_ctl=no
 800 build_lib_relayd=no
 801 build_lib_sessiond_comm=no
 802 build_lib_testpoint=no
 803 build_lib_ust_consumer=no
 804
 805 # There is an overlap for enabled dependencies, but this makes everything
 806 # simpler. libcommon and libconfig are always compiled so they are not repeated
 807 # here.
 808
 809 # Enable binary dependencies.
 810 AS_IF([test x$enable_bin_lttng != xno],
 811       [
 812        build_lib_lttng_ctl=yes
 813       ]
 814 )
 815
 816 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 817       [
 818        build_lib_consumer=yes
 819        build_lib_sessiond_comm=yes
 820        build_lib_index=yes
 821        build_lib_health=yes
 822        build_lib_testpoint=yes
 823       ]
 824 )
 825
 826 AS_IF([test x$enable_bin_lttng_crash != xno],
 827       # Do nothing since libconfig and libcommon are built by default.
 828       []
 829 )
 830
 831 AS_IF([test x$enable_bin_lttng_relayd != xno],
 832       [
 833        build_lib_lttng_ctl=yes
 834        build_lib_sessiond_comm=yes
 835        build_lib_hashtable=yes
 836        build_lib_compat=yes
 837        build_lib_index=yes
 838        build_lib_health=yes
 839        build_lib_testpoint=yes
 840       ]
 841 )
 842 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 843       [
 844        build_lib_lttng_ctl=yes
 845        build_lib_sessiond_comm=yes
 846        build_lib_kernel_ctl=yes
 847        build_lib_hashtable=yes
 848        build_lib_compat=yes
 849        build_lib_relayd=yes
 850        build_lib_testpoint=yes
 851        build_lib_health=yes
 852        build_lib_health=yes
 853       ]
 854 )
 855
 856 # Libraries dependencies enabling
 857 AS_IF([test x$build_lib_lttng_ctl = xyes],
 858       [
 859        build_lib_sessiond_comm=yes
 860        build_lib_hashtable=yes
 861       ]
 862 )
 863
 864 AS_IF([test x$build_lib_consumer = xyes],
 865       [
 866        build_lib_sessiond_comm=yes
 867        build_lib_kernel_consumer=yes
 868        build_lib_hashtable=yes
 869        build_lib_compat=yes
 870        build_lib_relayd=yes
 871        AS_IF([test x$lttng_ust_ctl_found = xyes],[build_lib_ust_consumer=yes])
 872       ]
 873 )
 874
 875 AS_IF([test x$build_lib_kernel_consumer = xyes],
 876       [
 877        build_lib_kernel_ctl=yes
 878        build_lib_relayd=yes
 879       ]
 880 )
 881
 882 AS_IF([test x$build_lib_relayd = xyes],
 883       [
 884        build_lib_sessiond_comm=yes
 885       ]
 886 )
 887
 888
 889 # Export binaries build conditions.
 890 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
 891 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
 892 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
 893 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
 894 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
 895
 896 # Export the tests and extras build conditions.
 897 AS_IF([\
 898 test "x$enable_bin_lttng" != "xno" && \
 899 test "x$enable_bin_lttng_consumerd" != "xno" && \
 900 test "x$enable_bin_lttng_crash" != "xno" && \
 901 test "x$enable_bin_lttng_relayd" != "xno" && \
 902 test "x$enable_bin_lttng_sessiond" != "xno"],
 903 [build_tests=yes],
 904 [build_tests=no]
 905 )
 906
 907 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
 908 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
 909
 910 # Export libraries build conditions.
 911 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
 912 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
 913 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
 914 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
 915 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
 916 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
 917 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
 918 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
 919 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
 920 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
 921 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
 922 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
 923 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
 924
 925 # check for pgrep
 926 AC_PATH_PROG([PGREP], [pgrep], [no])
 927 AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"])
 928
 929 # check for bison
 930 have_bison=yes
 931
 932 AS_IF([test "x$(basename "$YACC")" != "xbison -y"], [have_bison=no])
 933 AC_PATH_PROG([BISON], [bison])
 934 AX_PROG_BISON_VERSION([2.4], [], [have_bison=no])
 935
 936 AS_IF([test "x$have_bison" = "xno"], [
 937         AS_IF([test "x$in_git_repo" = "xyes"], [
 938                 AC_MSG_ERROR([Bison >= 2.4 is required when building from the Git repository.])
 939         ], [
 940                 AC_MSG_WARN([
 941 Missing Bison >= 2.4. Note that the parser files are already built in
 942 this distribution tarball, so Bison is only needed if you intend to
 943 modify their sources.
 944                 ])
 945         ])
 946 ])
 947
 948 # export bison condition
 949 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 950
 951 # check for flex
 952 have_flex=yes
 953
 954 AS_IF([test "x$LEX" != "xflex"], [have_flex=no])
 955 AC_PATH_PROG([FLEX], [flex])
 956 AX_PROG_FLEX_VERSION([2.5.35], [], [have_flex=no])
 957
 958 AS_IF([test "x$have_flex" = "xno"], [
 959         AS_IF([test "x$in_git_repo" = "xyes"], [
 960                 AC_MSG_ERROR([Flex >= 2.5.35 is required when building from the Git repository.])
 961         ], [
 962                 AC_MSG_WARN([
 963 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 964 this distribution tarball, so Flex is only needed if you intend to
 965 modify their sources.
 966                 ])
 967         ])
 968 ])
 969
 970 # export flex condition
 971 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 972
 973 CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing"
 974
 975 DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h"
 976
 977 lttngincludedir="${includedir}/lttng"
 978 AC_SUBST(lttngincludedir)
 979
 980 lttngactionincludedir="${includedir}/lttng/action"
 981 AC_SUBST(lttngactionincludedir)
 982
 983 lttngconditionincludedir="${includedir}/lttng/condition"
 984 AC_SUBST(lttngconditionincludedir)
 985
 986 lttngnotificationincludedir="${includedir}/lttng/notification"
 987 AC_SUBST(lttngnotificationincludedir)
 988
 989 lttngtriggerincludedir="${includedir}/lttng/trigger"
 990 AC_SUBST(lttngtriggerincludedir)
 991
 992 AC_SUBST(DEFAULT_INCLUDES)
 993
 994 lttnglibexecdir="${libdir}/lttng/libexec"
 995 AC_SUBST(lttnglibexecdir)
 996
 997 AC_CONFIG_FILES([
 998         Makefile
 999         doc/Makefile
1000         doc/man/Makefile
1001         doc/man/asciidoc-attrs.conf
1002         include/Makefile
1003         extras/Makefile
1004         extras/bindings/Makefile
1005         extras/bindings/swig/Makefile
1006         extras/bindings/swig/python/Makefile
1007         extras/core-handler/Makefile
1008         src/Makefile
1009         src/common/Makefile
1010         src/common/kernel-ctl/Makefile
1011         src/common/kernel-consumer/Makefile
1012         src/common/consumer/Makefile
1013         src/common/ust-consumer/Makefile
1014         src/common/hashtable/Makefile
1015         src/common/sessiond-comm/Makefile
1016         src/common/compat/Makefile
1017         src/common/relayd/Makefile
1018         src/common/testpoint/Makefile
1019         src/common/index/Makefile
1020         src/common/health/Makefile
1021         src/common/config/Makefile
1022         src/common/string-utils/Makefile
1023         src/lib/Makefile
1024         src/lib/lttng-ctl/Makefile
1025         src/lib/lttng-ctl/filter/Makefile
1026         src/lib/lttng-ctl/lttng-ctl.pc
1027         src/bin/Makefile
1028         src/bin/lttng-consumerd/Makefile
1029         src/bin/lttng-sessiond/Makefile
1030         src/bin/lttng-relayd/Makefile
1031         src/bin/lttng/Makefile
1032         src/bin/lttng-crash/Makefile
1033         tests/Makefile
1034         tests/destructive/Makefile
1035         tests/regression/Makefile
1036         tests/regression/kernel/Makefile
1037         tests/regression/tools/Makefile
1038         tests/regression/tools/streaming/Makefile
1039         tests/regression/tools/filtering/Makefile
1040         tests/regression/tools/health/Makefile
1041         tests/regression/tools/tracefile-limits/Makefile
1042         tests/regression/tools/snapshots/Makefile
1043         tests/regression/tools/live/Makefile
1044         tests/regression/tools/exclusion/Makefile
1045         tests/regression/tools/save-load/Makefile
1046         tests/regression/tools/save-load/configuration/Makefile
1047         tests/regression/tools/mi/Makefile
1048         tests/regression/tools/wildcard/Makefile
1049         tests/regression/tools/crash/Makefile
1050         tests/regression/tools/regen-metadata/Makefile
1051         tests/regression/tools/regen-statedump/Makefile
1052         tests/regression/ust/Makefile
1053         tests/regression/ust/nprocesses/Makefile
1054         tests/regression/ust/high-throughput/Makefile
1055         tests/regression/ust/low-throughput/Makefile
1056         tests/regression/ust/before-after/Makefile
1057         tests/regression/ust/buffers-pid/Makefile
1058         tests/regression/ust/periodical-metadata-flush/Makefile
1059         tests/regression/ust/multi-session/Makefile
1060         tests/regression/ust/overlap/Makefile
1061         tests/regression/ust/overlap/demo/Makefile
1062         tests/regression/ust/linking/Makefile
1063         tests/regression/ust/daemon/Makefile
1064         tests/regression/ust/exit-fast/Makefile
1065         tests/regression/ust/fork/Makefile
1066         tests/regression/ust/libc-wrapper/Makefile
1067         tests/regression/ust/baddr-statedump/Makefile
1068         tests/regression/ust/ust-dl/Makefile
1069         tests/regression/ust/java-jul/Makefile
1070         tests/regression/ust/java-log4j/Makefile
1071         tests/regression/ust/python-logging/Makefile
1072         tests/regression/ust/getcpu-override/Makefile
1073         tests/regression/ust/clock-override/Makefile
1074         tests/regression/ust/type-declarations/Makefile
1075         tests/regression/ust/rotation-destroy-flush/Makefile
1076         tests/regression/ust/blocking/Makefile
1077         tests/stress/Makefile
1078         tests/unit/Makefile
1079         tests/unit/ini_config/Makefile
1080         tests/perf/Makefile
1081         tests/utils/Makefile
1082         tests/utils/tap/Makefile
1083         tests/utils/testapp/Makefile
1084         tests/utils/testapp/gen-ust-events/Makefile
1085         tests/utils/testapp/gen-ust-nevents/Makefile
1086         tests/utils/testapp/gen-ust-nevents-str/Makefile
1087         tests/utils/testapp/gen-ust-tracef/Makefile
1088 ])
1089
1090 # Inject variable into python test script.
1091 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1092 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1093 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1094
1095 AC_OUTPUT
1096
1097 #
1098 # Mini-report on what will be built.
1099 #
1100
1101 PPRINT_INIT
1102 PPRINT_SET_INDENT(1)
1103 PPRINT_SET_TS(38)
1104
1105 AS_ECHO
1106 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1107 AS_ECHO
1108
1109 AS_IF([test -n "$report_fold"], [
1110         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1111 ], [
1112         AS_ECHO("$version_description")
1113 ])
1114
1115 AS_ECHO
1116 PPRINT_SUBTITLE([Features])
1117
1118 # Target architecture we're building for.
1119 target_arch=$host_cpu
1120 [
1121 for f in $CFLAGS; do
1122         if test $f = "-m32"; then
1123                         target_arch="32-bit"
1124         elif test $f = "-m64"; then
1125                         target_arch="64-bit"
1126         fi
1127 done
1128 ]
1129 PPRINT_PROP_STRING([Target architecture], $target_arch)
1130
1131 # kmod enabled/disabled
1132 test "x$kmod_found" = "xyes" && value=1 || value=0
1133 PPRINT_PROP_BOOL([libkmod support], $value)
1134
1135 # LTTng-UST enabled/disabled
1136 test "x$lttng_ust_support" = "xyes" && value=1 || value=0
1137 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1138
1139 AS_ECHO
1140 PPRINT_SUBTITLE([Binaries])
1141
1142 # List binaries to be built
1143 test x$enable_bin_lttng != xno && value=1 || value=0
1144 PPRINT_PROP_BOOL([lttng], $value)
1145
1146 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1147 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1148
1149 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1150 PPRINT_PROP_BOOL([lttng-crash], $value)
1151
1152 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1153 PPRINT_PROP_BOOL([lttng-relayd], $value)
1154
1155 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1156 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1157
1158 # Extras
1159 test x$enable_extras != xno && value=1 || value=0
1160 AS_ECHO
1161 PPRINT_SET_INDENT(0)
1162 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1163 PPRINT_SET_INDENT(1)
1164
1165 AS_ECHO
1166 PPRINT_SUBTITLE([Tests])
1167
1168 # Print clear message that tests won't be built
1169 AS_IF([test "x$build_tests" = "xno"],[
1170         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1171 ])
1172
1173 # LTTng UST Java agent JUL tests enabled/disabled
1174 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1175 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1176
1177 # LTTng UST Java agent Log4j tests enabled/disabled
1178 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1179 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1180
1181 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1182 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1183
1184 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1185 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1186
1187 #Python binding enabled/disabled
1188 test "x$enable_python_binding" = xyes && value=1 || value=0
1189 AS_ECHO
1190 PPRINT_SET_INDENT(0)
1191 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1192
1193 # man pages build enabled/disabled
1194 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1195
1196 AS_IF([test "x$man_pages_opt" != "xno"], [
1197         AS_IF([test "x$in_git_repo" = "xyes"], [
1198                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1199         ], [
1200                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1201                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1202                 ], [
1203                         PPRINT_PROP_STRING([build_man_pages_msg],
1204                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1205                                 $PPRINT_COLOR_SUBTITLE)
1206                 ])
1207         ])
1208 ], [
1209         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1210 ])
1211
1212 m4_popdef([build_man_pages_msg])
1213
1214 test "x$embedded_help" = xyes && value=1 || value=0
1215 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1216
1217 PPRINT_SET_INDENT(1)
1218
1219 report_bindir="`eval eval echo $bindir`"
1220 report_libdir="`eval eval echo $libdir`"
1221
1222 # Print the bindir and libdir this `make install' will install into.
1223 AS_ECHO
1224 PPRINT_SUBTITLE([Install directories])
1225 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1226 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1227
1228 AS_ECHO
1229 PPRINT_SUBTITLE([Search directories])
1230
1231 # If we build the sessiond, print the paths it will use
1232 AS_IF([test "$SESSIOND_BIN" = ""],[
1233         path="$report_bindir/lttng-sessiond"
1234 ],[
1235         path="$SESSIOND_BIN"
1236 ])
1237 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1238
1239 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1240         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1241 ],[
1242         path="$CONSUMERD32_BIN"
1243 ])
1244 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1245
1246 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1247         path="`eval eval echo $libdir`"
1248 ],[
1249         path="$CONSUMERD32_LIBDIR"
1250 ])
1251 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1252
1253 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1254         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1255 ],[
1256         path="$CONSUMERD64_BIN"
1257 ])
1258 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1259
1260 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1261         path="`eval eval echo $libdir`"
1262 ],[
1263         path="$CONSUMERD64_LIBDIR"
1264 ])
1265 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1266 PPRINT_SET_INDENT(0)
1267
1268 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1269         AS_ECHO
1270         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1271
1272 Note that the man pages are already built in this distribution tarball,
1273 therefore asciidoc and xmlto are only needed if you intend to modify
1274 their sources.
1275
1276 Also note that the installed man pages will contain the project's
1277 default command-line option and environment variable values.
1278
1279 Use --disable-man-pages to completely disable building and installing
1280 the man pages.])
1281 ])