configure.ac

   1 dnl SPDX-License-Identifier: GPL-2.0-only
   2 AC_PREREQ([2.64])
   3 AC_INIT([lttng-tools],[2.13.0-rc1],[jeremie.galarneau@efficios.com],[],[https://lttng.org])
   4
   5 AC_CONFIG_HEADERS([include/config.h])
   6 AC_CONFIG_AUX_DIR([config])
   7 AC_CONFIG_MACRO_DIR([m4])
   8
   9 AC_CANONICAL_TARGET
  10 AC_CANONICAL_HOST
  11
  12 AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-pax nostdinc])
  13 AM_MAINTAINER_MODE([enable])
  14
  15 # Enable silent rules if available (Introduced in AM 1.11)
  16 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  17
  18 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  19
  20 # Checks for C compiler
  21 AC_USE_SYSTEM_EXTENSIONS
  22 AC_SYS_LARGEFILE
  23 AC_PROG_CC
  24 # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70
  25 m4_version_prereq([2.70], [], [AC_PROG_CC_STDC])
  26 AC_PROG_CXX
  27 RW_PROG_CXX_WORKS
  28 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  29
  30 # Detect warning flags supported by the compiler, append them to WARN_CFLAGS.
  31 #
  32 # Pass -Werror as an extra flag during the test: this is needed to make the
  33 # -Wunknown-warning-option diagnostic fatal with clang.
  34 AX_APPEND_COMPILE_FLAGS([ dnl
  35                 -Wall dnl
  36                 dnl We currently get this warning when building with Clang:
  37                 dnl
  38                 dnl /usr/include/setjmp.h:54:12: error: declaration of built-in function '__sigsetjmp' requires the declaration of the 'jmp_buf' type, commonly provided in the header <setjmp.h>. [-Werror,-Wincomplete-setjmp-declaration]
  39                 dnl extern int __sigsetjmp (struct __jmp_buf_tag __env[1], int __savemask) __THROWNL;
  40                 dnl            ^
  41                 -Wno-incomplete-setjmp-declaration dnl
  42                 -Wdiscarded-qualifiers dnl
  43                 -Wmissing-declarations dnl
  44                 -Wmissing-prototypes dnl
  45                 -Wmissing-parameter-type dnl
  46                 -Wold-style-definition dnl
  47                 -Wstrict-prototypes dnl
  48                 -Wshadow dnl
  49         ],
  50         [WARN_CFLAGS],
  51         [-Werror])
  52
  53 # When given, add -Werror to WARN_CFLAGS.
  54 AC_ARG_ENABLE([Werror],
  55         [AS_HELP_STRING([--enable-Werror], [Treat compiler warnings as errors.])]
  56 )
  57 AS_IF([test "x$enable_Werror" = "xyes"],
  58         [WARN_CFLAGS="${WARN_CFLAGS} -Werror"]
  59 )
  60
  61 # Checks for programs.
  62 AC_PROG_GREP
  63 AC_PROG_MAKE_SET
  64 AC_PROG_SED
  65 AC_PATH_PROG([report_fold], [fold])
  66 LT_INIT
  67
  68 # Check for objcopy, required by the base address statedump and dynamic linker tests
  69 AC_CHECK_TOOL([OBJCOPY], [objcopy], [no])
  70 AS_IF([test "x$OBJCOPY" = "xno"],
  71         [AC_MSG_WARN([Cannot find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])]
  72 )
  73 AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno])
  74
  75 # check for pgrep
  76 AC_PATH_PROG([PGREP], [pgrep], [no])
  77 AM_CONDITIONAL([HAVE_PGREP], [test "x$PGREP" != "xno"])
  78
  79 # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
  80 # is not distributed in tarballs
  81 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
  82 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
  83
  84 # check for bison
  85 AC_PROG_YACC
  86 BISON=$YACC
  87 AX_PROG_BISON_VERSION([2.4], [have_bison=yes])
  88
  89 AS_IF([test "x$have_bison" != "xyes"], [
  90   AS_IF([test "x$in_git_repo" = "xyes"], [
  91     AC_MSG_FAILURE([
  92 Bison >= 2.4 is required when building from the Git repository. You can
  93 set the YACC variable to override automatic detection.
  94     ])
  95   ], [
  96     AC_MSG_WARN([
  97 Missing Bison >= 2.4. Note that the parser files are already built in
  98 this distribution tarball, so Bison is only needed if you intend to
  99 modify their sources. You can set the YACC variable to override automatic
 100 detection.
 101     ])
 102   ])
 103 ])
 104 AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"])
 105
 106 # check for flex
 107 # Prior to autoconf 2.70, AC_PROG_FLEX did not take an argument. This is not a
 108 # problem since the argument is silently ignored by older versions.
 109 AC_PROG_LEX([noyywrap])
 110 FLEX=$LEX
 111 AX_PROG_FLEX_VERSION([2.5.35], [have_flex=yes])
 112
 113 AS_IF([test "x$have_flex" != "xyes"], [
 114   AS_IF([test "x$in_git_repo" = "xyes"], [
 115     AC_MSG_FAILURE([
 116 Flex >= 2.5.35 is required when building from the Git repository. You can
 117 set the LEX variable to override automatic detection.
 118     ])
 119   ], [
 120     AC_MSG_WARN([
 121 Missing Flex >= 2.5.35. Note that the lexer files are already built in
 122 this distribution tarball, so Flex is only needed if you intend to
 123 modify their sources. You can set the LEX variable to override automatic
 124 detection.
 125     ])
 126   ])
 127 ])
 128 AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"])
 129
 130
 131 # Checks for typedefs, structures, and compiler characteristics.
 132 AC_C_INLINE
 133 AC_TYPE_INT32_T
 134 AC_TYPE_INT64_T
 135 AC_TYPE_MODE_T
 136 AC_TYPE_OFF_T
 137 AC_TYPE_PID_T
 138 AC_TYPE_SIZE_T
 139 AC_TYPE_SSIZE_T
 140 AC_TYPE_UID_T
 141 AC_TYPE_UINT16_T
 142 AC_TYPE_UINT32_T
 143 AC_TYPE_UINT64_T
 144 AC_TYPE_UINT8_T
 145
 146 AX_C___ATTRIBUTE__
 147 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 148         [:],
 149         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 150
 151 AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])])
 152
 153 # Check if linker has the -no-pie option.
 154 AX_CHECK_LINK_FLAG([-no-pie], [linker_have_no_pie_option=yes])
 155 AM_CONDITIONAL([LINKER_HAVE_NO_PIE_OPTION], [test "x$linker_have_no_pie_option" = "xyes"])
 156
 157 AX_LIB_SOCKET_NSL
 158
 159 LT_NO_UNDEFINED=""
 160 AS_CASE([$host_os],
 161   [cygwin*],
 162     [
 163       LT_NO_UNDEFINED="-no-undefined"
 164     ],
 165   [cygwin*|darwin*|mingw*|solaris*],
 166     [
 167       # On platforms where we only support the relayd, disable the other binaries by default
 168       AS_IF([test "x$enable_bin_lttng" = "x" ], [enable_bin_lttng=no])
 169       AS_IF([test "x$enable_bin_lttng_consumerd" = "x" ], [enable_bin_lttng_consumerd=no])
 170       AS_IF([test "x$enable_bin_lttng_crash" = "x" ], [enable_bin_lttng_crash=no])
 171       AS_IF([test "x$enable_bin_lttng_sessiond" = "x" ], [enable_bin_lttng_sessiond=no])
 172       AS_IF([test "x$enable_extras" = "x" ], [enable_extras=no])
 173       AS_IF([test "x$with_lttng_ust" = "x" ], [with_lttng_ust=no])
 174     ]
 175 )
 176
 177 AC_SUBST(LT_NO_UNDEFINED)
 178
 179 # Compute minor/major/patchlevel version numbers
 180 major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
 181 minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
 182 patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
 183
 184 AC_SUBST([MAJOR_VERSION], [$major_version])
 185 AC_SUBST([MINOR_VERSION], [$minor_version])
 186 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
 187 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number])
 188 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number])
 189 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number])
 190
 191 version_name="Nordicité"
 192 version_description="The product of a collaboration between Champ Libre and Boréale, this farmhouse IPA is brewed with Kveik yeast and Québec-grown barley, oats and juniper branches. The result is a remarkable fruity hazy golden IPA that offers a balanced touch of resinous and woodsy bitterness."
 193 version_description_c=$(echo $version_description | $SED 's/"/\\"/g')
 194
 195 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "")
 196 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "")
 197
 198 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
 199 AC_ARG_ENABLE(libtool-linkdep-fixup,
 200         AS_HELP_STRING([--disable-libtool-linkdep-fixup],
 201                         [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]),
 202         libtool_fixup=$enableval,
 203         libtool_fixup=yes)
 204
 205 AS_IF([test "x$libtool_fixup" = "xyes"],
 206             [
 207             libtool_m4="$srcdir/m4/libtool.m4"
 208             libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
 209             AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
 210             libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
 211             AS_IF([test $libtool_flag_pattern_count -ne 0],
 212             [
 213                   AC_MSG_RESULT([$libtool_flag_pattern_count])
 214                   AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
 215                   $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
 216                   ],
 217                   [
 218                   AC_MSG_RESULT([none])
 219                   ])
 220             ])
 221
 222 AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno])
 223
 224 AC_CHECK_HEADERS([ \
 225         sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \
 226         signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \
 227         getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \
 228         netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \
 229         sys/mount.h sys/param.h sys/time.h elf.h
 230 ])
 231
 232 AM_CONDITIONAL([HAVE_ELF_H], [test x$ac_cv_header_elf_h = xyes])
 233
 234 # Basic functions check
 235 AC_CHECK_FUNCS([ \
 236         atexit bzero clock_gettime dup2 fdatasync fls ftruncate \
 237         gethostbyname gethostname getpagesize localtime_r memchr memrchr memset \
 238         mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \
 239         strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \
 240         strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \
 241         sched_getcpu sysconf sync_file_range
 242 ])
 243
 244 # Check for pthread_setname_np and pthread_getname_np
 245 LTTNG_PTHREAD_SETNAME_NP
 246 LTTNG_PTHREAD_GETNAME_NP
 247
 248 # Check if clock_gettime, timer_create, timer_settime, and timer_delete are available in lib rt, and if so,
 249 # add -lrt to LIBS
 250 AC_CHECK_LIB([rt], [clock_gettime, timer_create, timer_settime, timer_delete])
 251
 252 # Checks for dl.
 253 AC_CHECK_LIB([dl], [dlopen], [
 254         have_libdl=yes
 255         libdl_name=dl
 256         DL_LIBS="-ldl"
 257 ], [
 258         # libdl not found, check for dlopen in libc.
 259         AC_CHECK_LIB([c], [dlopen], [
 260                 have_libc_dl=yes
 261                 libdl_name=c
 262                 DL_LIBS="-lc"
 263         ], [
 264                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 265         ])
 266 ])
 267 AC_SUBST(DL_LIBS)
 268
 269 # Check if libdl has dlmopen support.
 270 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 271 AC_CHECK_LIB([$libdl_name], [dlmopen], [
 272         AC_DEFINE([HAVE_DLMOPEN], [1])
 273         HAVE_DLMOPEN=1
 274 ], [
 275         HAVE_DLMOPEN=0
 276 ])
 277 AC_SUBST(HAVE_DLMOPEN)
 278
 279 # Babeltrace viewer check
 280 AC_ARG_WITH([babeltrace-bin],
 281         AS_HELP_STRING([--with-babeltrace-bin],
 282         [Location of the babeltrace viewer executable (including the filename)]),
 283         [BABELTRACE_BIN="$withval"],
 284         [BABELTRACE_BIN=''])
 285 AC_SUBST([BABELTRACE_BIN])
 286
 287 AC_ARG_WITH([babeltrace2-bin],
 288         AS_HELP_STRING([--with-babeltrace2-bin],
 289         [Location of the babeltrace2 viewer executable (including the filename)]),
 290         [BABELTRACE2_BIN="$withval"],
 291         [BABELTRACE2_BIN=''])
 292 AC_SUBST([BABELTRACE2_BIN])
 293
 294 AC_ARG_WITH([consumerd32-bin],
 295         AS_HELP_STRING([--with-consumerd32-bin],
 296         [Location of the 32-bit consumerd executable (including the filename)]),
 297         [CONSUMERD32_BIN="$withval"],
 298         [CONSUMERD32_BIN=''])
 299 AC_SUBST([CONSUMERD32_BIN])
 300
 301 AC_ARG_WITH([consumerd64-bin],
 302         AS_HELP_STRING([--with-consumerd64-bin],
 303         [Location of the 64-bit consumerd executable (including the filename)]),
 304         [CONSUMERD64_BIN="$withval"],
 305         [CONSUMERD64_BIN=''])
 306 AC_SUBST([CONSUMERD64_BIN])
 307
 308 AC_ARG_WITH([consumerd32-libdir],
 309         AS_HELP_STRING([--with-consumerd32-libdir],
 310         [Directory containing the 32-bit consumerd libraries]),
 311         [CONSUMERD32_LIBDIR="$withval"],
 312         [CONSUMERD32_LIBDIR=''])
 313 AC_SUBST([CONSUMERD32_LIBDIR])
 314
 315 AC_ARG_WITH([consumerd64-libdir],
 316         AS_HELP_STRING([--with-consumerd64-libdir],
 317         [Directory containing the 64-bit consumerd libraries]),
 318         [CONSUMERD64_LIBDIR="$withval"],
 319         [CONSUMERD64_LIBDIR=''])
 320 AC_SUBST([CONSUMERD64_LIBDIR])
 321
 322 AC_ARG_WITH([sessiond-bin],
 323         AS_HELP_STRING([--with-sessiond-bin],
 324         [Location of the sessiond executable (including the filename)]),
 325         [SESSIOND_BIN="$withval"],
 326         [SESSIOND_BIN=''])
 327 AC_SUBST([SESSIOND_BIN])
 328
 329 AC_ARG_WITH([lttng-system-rundir],
 330         AS_HELP_STRING([--with-lttng-system-rundir],
 331         [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]),
 332         [LTTNG_SYSTEM_RUNDIR="$withval"],
 333         [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"])
 334 AC_SUBST([LTTNG_SYSTEM_RUNDIR])
 335
 336 AC_ARG_ENABLE([test-java-agent-jul],
 337         [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])],
 338         [test_java_agent_jul=$enableval],
 339         [test_java_agent_jul=no]
 340 )
 341
 342 AC_ARG_ENABLE([test-java-agent-log4j],
 343         [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])],
 344         [test_java_agent_log4j=$enableval],
 345         [test_java_agent_log4j=no]
 346 )
 347
 348 AC_ARG_ENABLE([test-java-agent-all],
 349         [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])],
 350         [test_java_agent_jul=$enableval
 351          test_java_agent_log4j=$enableval],
 352         [:]
 353 )
 354
 355 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.])
 356 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable])
 357 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.])
 358 AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.])
 359 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.])
 360 AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE2_BIN], "$BABELTRACE2_BIN", [Location of the babeltrace2 viewer executable.])
 361 AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.])
 362 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory])
 363
 364 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 365         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 366         $1="$2"
 367         AC_SUBST([$1])
 368 ])
 369
 370 AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [
 371         AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1])
 372         $1="$2"
 373         AC_SUBST([$1])
 374 ])
 375
 376 # Default values
 377 m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [16384])
 378 m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4])
 379 m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0])
 380 m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0])
 381 m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000])
 382 m4_define([_DEFAULT_CHANNEL_MONITOR_TIMER], [1000000])
 383 m4_define([_DEFAULT_CHANNEL_BLOCKING_TIMEOUT], [0])
 384 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_BEGIN], [5345])
 385 _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT_RANGE_END], [5354])
 386 _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5])
 387 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 388 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0])
 389 _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0])
 390 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 391 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER])
 392 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 393 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [1048576])
 394 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 395 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 396 _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_BLOCKING_TIMEOUT], [_DEFAULT_CHANNEL_BLOCKING_TIMEOUT])
 397 _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000])
 398 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096])
 399 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0])
 400 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2])
 401 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096])
 402 _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 403 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342])
 404 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343])
 405 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344])
 406 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 407 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0])
 408 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_BLOCKING_TIMEOUT], [0])
 409 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 410 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE])
 411 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 412 _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 413 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER])
 414 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0])
 415 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_BLOCKING_TIMEOUT], [0])
 416 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM])
 417 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [524288])
 418 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER])
 419 _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_MONITOR_TIMER], [_DEFAULT_CHANNEL_MONITOR_TIMER])
 420 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost])
 421 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0])
 422 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0])
 423 _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost])
 424 _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_RELAYD_CTRL_MAX_PAYLOAD_SIZE], [134217728])
 425 _AC_DEFINE_AND_SUBST([DEFAULT_ROTATE_PENDING_TIMER], [500000])
 426 _AC_DEFINE_AND_SUBST([DEFAULT_EVENT_NOTIFIER_ERROR_COUNT_MAP_SIZE], [4096])
 427
 428 # Command short descriptions
 429 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to be recorded])
 430 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_TRIGGER], [Add a trigger])
 431 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CLEAR], [Clear a tracing session])
 432 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session])
 433 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Destroy tracing sessions])
 434 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable channels])
 435 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable recording event rules])
 436 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_ROTATION], [Unset a tracing session rotation schedule])
 437 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable a channel])
 438 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable recording event rules])
 439 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_ROTATION], [Set a tracing session rotation schedule])
 440 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Show the help of a command])
 441 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions and instrumentation points])
 442 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST_TRIGGERS], [List triggers])
 443 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations])
 444 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REGENERATE], [Regenerate specific tracing session data])
 445 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_REMOVE_TRIGGER], [Remove a trigger])
 446 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ROTATE], [Archive the current trace chunk of a tracing session])
 447 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations])
 448 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set the current tracing session])
 449 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Take a tracing session snapshot])
 450 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start a tracing session])
 451 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Show the status of the current tracing session])
 452 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop a tracing session])
 453 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Allow specific processes to record events])
 454 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Disallow specific processes to record events])
 455 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show LTTng-tools version information])
 456 _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Launch a trace reader])
 457
 458 if test "x$prefix" = "xNONE"; then
 459         prefix=$ac_default_prefix
 460 fi
 461 CONFDIR=`eval echo $sysconfdir`
 462 AC_SUBST(CONFDIR)
 463 AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.])
 464
 465 AX_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR], [datadir], [LTTng system data directory.])
 466
 467 # Check libpopt
 468 PKG_CHECK_MODULES([POPT], [popt],
 469   [
 470     dnl PKG_CHECK_MODULES defines POPT_LIBS
 471   ],
 472   [
 473     AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location])
 474     AC_MSG_WARN([Finding libpopt without pkg-config.])
 475     AC_CHECK_LIB([popt],
 476       [poptGetContext],
 477       [POPT_LIBS="-lpopt"],
 478       [
 479         AC_MSG_FAILURE([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location])
 480       ]
 481     )
 482   ]
 483 )
 484 AC_SUBST(POPT_LIBS)
 485
 486 PKG_CHECK_MODULES([libxml2], [libxml-2.0 >= 2.7.6])
 487
 488 AC_CHECK_FUNC([clock_gettime], [AC_DEFINE_UNQUOTED([LTTNG_HAVE_CLOCK_GETTIME], 1, [Has clock_gettime() support.])])
 489
 490 # URCU library version needed or newer
 491 PKG_CHECK_MODULES([URCU], [liburcu >= 0.9])
 492 PKG_CHECK_MODULES([URCU_BP], [liburcu-bp >= 0.9])
 493 PKG_CHECK_MODULES([URCU_CDS], [liburcu-cds >= 0.9])
 494 AM_CPPFLAGS="$AM_CPPFLAGS $URCU_CFLAGS"
 495
 496 # Check for libkmod, it will be auto-neabled if found but won't fail if it's not,
 497 # it can be explicitly disabled with --without-kmod
 498 AH_TEMPLATE([HAVE_KMOD], [Define if you have kmod support])
 499 AC_ARG_WITH([kmod],
 500   [AS_HELP_STRING([--with-kmod], [build with lkmod support @<:@default=check@:>@])],
 501   [],
 502   [with_kmod=check]
 503 )
 504
 505 AS_IF([test "x$with_kmod" != "xno"],
 506   [
 507     AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module],
 508       [
 509         AC_DEFINE([HAVE_KMOD], [1])
 510         KMOD_LIBS="-lkmod"
 511       ],
 512       [
 513         if test "x$with_kmod" != xcheck; then
 514           AC_MSG_FAILURE([Cannot find libkmod. Use [LDFLAGS]=-Ldir and [CPPFLAGS]=-Idir to specify its location.])
 515         else
 516           with_kmod=no
 517         fi
 518       ]
 519     )
 520   ]
 521 )
 522 AC_SUBST(KMOD_LIBS)
 523
 524 # Check for liblttng-ust-ctl, fail if it's not found,
 525 # it can be explicitly disabled with --without-lttng-ust
 526 AH_TEMPLATE([HAVE_LIBLTTNG_UST_CTL], [Define if you have LTTng-UST control support])
 527 AC_ARG_WITH([lttng-ust],
 528   [AS_HELP_STRING([--without-lttng-ust], [build without LTTng-UST (Userspace Tracing) support])],
 529   [],
 530   [with_lttng_ust=yes]
 531 )
 532
 533 AS_IF([test "x$with_lttng_ust" = "xyes"], [
 534   AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1])
 535
 536   # Check for liblttng-ust
 537   PKG_CHECK_MODULES([UST], [lttng-ust >= $major_version.$minor_version])
 538
 539   # Check for liblttng-ust-ctl
 540   PKG_CHECK_MODULES([UST_CTL], [lttng-ust-ctl >= $major_version.$minor_version])
 541
 542   AM_CPPFLAGS="$AM_CPPFLAGS $UST_CFLAGS"
 543 ])
 544
 545 AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$with_lttng_ust" = "xyes"])
 546
 547
 548 # Check for fmemopen
 549 AC_CHECK_LIB([c], [fmemopen],
 550 [
 551         AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.])
 552 ]
 553 )
 554
 555 # check for libpfm
 556 AC_CHECK_LIB([pfm], [pfm_initialize],
 557              [
 558               have_libpfm=yes
 559               ])
 560 AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBPFM], [test "x$have_libpfm" = "xyes"])
 561
 562 # For Python
 563 # SWIG version needed or newer:
 564 swig_version=2.0.0
 565
 566 AC_ARG_ENABLE([python-bindings],
 567               [AS_HELP_STRING([--enable-python-bindings],
 568                               [compile Python bindings])],
 569               [enable_python_binding=$enableval], [enable_python_binding=no])
 570
 571 AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes])
 572
 573 if test "x$enable_python_binding" = xyes; then
 574   AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ])
 575   AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ])
 576   AM_PATH_PYTHON([3.0])
 577
 578   AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config])
 579   AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config])
 580   AS_IF([test -z "$PYTHON_INCLUDE"], [
 581     AS_IF([test -z "$PYTHON_CONFIG"], [
 582       AC_PATH_PROGS([PYTHON_CONFIG],
 583                     [python$PYTHON_VERSION-config python-config],
 584                     [no],
 585                     [`dirname $PYTHON`])
 586       AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])])
 587     ])
 588     AC_MSG_CHECKING([python include flags])
 589     PYTHON_INCLUDE=`$PYTHON_CONFIG --includes`
 590     AC_MSG_RESULT([$PYTHON_INCLUDE])
 591   ])
 592
 593 else
 594     AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl
 595 [if you want Python bindings.])
 596
 597 fi
 598
 599 # Epoll check. If not present, the build will fallback on poll() API
 600 AX_HAVE_EPOLL(
 601         [AX_CONFIG_FEATURE_ENABLE(epoll)],
 602         [AX_CONFIG_FEATURE_DISABLE(epoll)]
 603 )
 604 AX_CONFIG_FEATURE(
 605         [epoll], [This platform supports epoll(7)],
 606         [HAVE_EPOLL], [This platform supports epoll(7).]
 607 )
 608
 609 AS_IF([test "x$ac_cv_func_dirfd" = "xyes"],
 610         [AX_CONFIG_FEATURE_ENABLE(dirfd)],
 611         [AX_CONFIG_FEATURE_DISABLE(dirfd)]
 612 )
 613 AX_CONFIG_FEATURE(
 614         [dirfd], [Use directory file descriptors],
 615         [HAVE_DIRFD], [This platform supports directory file descriptors.]
 616 )
 617
 618 AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"])
 619 AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"])
 620
 621 if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then
 622         AX_JAVA_OPTIONS
 623         AX_PROG_JAVAC
 624         AX_PROG_JAVA
 625         AX_PROG_JAR
 626
 627         AX_CHECK_CLASSPATH
 628
 629         # Check for Java UST agent common class first
 630         AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent)
 631         if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then
 632                 AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"])
 633         fi
 634
 635         if test "x$test_java_agent_jul" = "xyes"; then
 636                 # Check for JUL agent class
 637                 AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler)
 638                 if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then
 639                         AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"])
 640                 fi
 641         fi
 642
 643         if test "x$test_java_agent_log4j" = "xyes"; then
 644                 # Check for Log4j agent class
 645                 AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender)
 646                 if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then
 647                         AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"])
 648                 fi
 649
 650                 # Check for Log4j class
 651                 AX_CHECK_CLASS(org.apache.log4j.Logger)
 652                 if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then
 653                         AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 654                 fi
 655         fi
 656 fi
 657
 658 # enable building man pages (user's intention)
 659 AC_ARG_ENABLE(
 660         man-pages,
 661         AS_HELP_STRING(
 662                 [--disable-man-pages],
 663                 [Do not build and install man pages (already built in a distributed tarball)]
 664         ),
 665         [man_pages_opt=$enableval],
 666         [man_pages_opt=yes]
 667 )
 668
 669 # check for asciidoc and xmlto if we enabled building the man pages
 670 have_asciidoc_xmlto=no
 671 warn_prebuilt_man_pages=no
 672
 673 AS_IF([test "x$man_pages_opt" = "xyes"], [
 674         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 675         AC_PATH_PROG([XMLTO], [xmlto], [no])
 676
 677         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 678                 AS_IF([test "x$in_git_repo" = "xyes"], [
 679                         # this is an error because we're in the Git repo, which
 680                         # means the man pages are not already generated for us,
 681                         # thus asciidoc/xmlto are required because we were asked
 682                         # to build the man pages
 683                         AC_MSG_ERROR([
 684 You need asciidoc and xmlto to build the LTTng-tools man pages. Use
 685 --disable-man-pages to disable building the man pages, in which case
 686 they will not be installed.
 687                         ])
 688                 ], [
 689                         # only warn here: since we're in the tarball, the man
 690                         # pages should already be generated at this point, thus
 691                         # asciidoc/xmlto are not strictly required
 692                         warn_prebuilt_man_pages=yes
 693                 ])
 694         ], [
 695                 have_asciidoc_xmlto=yes
 696         ])
 697 ])
 698
 699 # export man page build condition: build the man pages if the user
 700 # asked for it, and if the tools are available
 701 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 702 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 703
 704 AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.])
 705
 706 # embedded --help message
 707 AC_ARG_ENABLE(
 708         [embedded-help],
 709         AS_HELP_STRING(
 710                 [--enable-embedded-help],
 711                 [Embed the --help messages in the executable files]
 712         ),
 713         [embedded_help=$enableval],
 714         [embedded_help=no]
 715 )
 716 AS_IF([test "x$embedded_help" = "xyes"], [
 717         AS_IF([test "x$man_pages_opt" = "xno"], [
 718                 AC_MSG_ERROR([You need the --enable-man-pages option with the --enable-embedded-help option.])
 719         ])
 720         AC_PATH_PROG([man_prog_path], [man], [no])
 721         AS_IF([test "x$man_prog_path" = "xno"], [
 722                 AC_MSG_ERROR([You need man with the --enable-embedded-help option.])
 723         ])
 724         AC_DEFINE_UNQUOTED([LTTNG_EMBED_HELP], 1, [Embed --help messages.])
 725         AC_SUBST([MANPROG], [$man_prog_path])
 726 ])
 727 AM_CONDITIONAL([EMBED_HELP], [test "x$embedded_help" != "xno"])
 728
 729 # Python agent test
 730 UST_PYTHON_AGENT="lttngust"
 731
 732 AC_ARG_ENABLE(test-python2-agent,
 733         AS_HELP_STRING([--enable-test-python2-agent],
 734                 [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect]
 735         ),[:],[test_python2_agent_autodetect=yes]
 736 )
 737
 738 AC_ARG_ENABLE(test-python3-agent,
 739         AS_HELP_STRING([--enable-test-python3-agent],
 740                 [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect]
 741         ),[:],[test_python3_agent_autodetect=yes]
 742 )
 743
 744 AC_ARG_ENABLE(test-python-agent-all,
 745         AS_HELP_STRING([--enable-test-python-agent-all],
 746                 [enable test for all python{2/3} agent.]
 747         ),
 748 )
 749
 750 AS_IF([test ! -z "$enable_test_python_agent_all"], [
 751        unset test_python2_agent_autodetect
 752        unset test_python3_agent_autodetect
 753 ])
 754
 755 AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [
 756        enable_test_python2_agent=yes
 757        enable_test_python3_agent=yes
 758 ])
 759
 760 AS_IF([test "x$enable_test_python_agent_all" = "xno"], [
 761        enable_test_python2_agent=no
 762        enable_test_python3_agent=no
 763 ])
 764
 765
 766 AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [
 767         AS_IF([test -z "$PYTHON2"], [
 768                         PYTHON2=python2
 769                 ], [
 770                         AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check])
 771         ])
 772
 773         AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2])
 774         AS_IF([test -z "$PYTHON2_BIN"], [
 775                 AS_IF([test -z "$test_python2_agent_autodetect"],[
 776                         AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path])
 777                 ])
 778         ], [
 779                 AC_MSG_CHECKING([for python2 lttng-ust agent])
 780                 AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 781                         PYTHON2_AGENT=$PYTHON2_BIN
 782                         AC_MSG_RESULT([yes])
 783                         RUN_PYTHON_AGENT_TEST=yes
 784                 ], [
 785                         AC_MSG_RESULT([no])
 786                         AS_IF([test -z "$test_python2_agent_autodetect"],[
 787                                 AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 788                         ])
 789                 ])
 790
 791         ])
 792
 793 ])
 794
 795 AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [
 796         AS_IF([test -z "$PYTHON3"], [
 797                 PYTHON3=python3
 798         ], [
 799                 AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check])
 800         ])
 801
 802         AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3])
 803         AS_IF([test -z "$PYTHON3_BIN"], [
 804                 AS_IF([test -z "$test_python3_agent_autodetect"],[
 805                         AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path])
 806                 ])
 807         ], [
 808                 AC_MSG_CHECKING([for python3 lttng-ust agent])
 809                 AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [
 810                         PYTHON3_AGENT=$PYTHON3_BIN
 811                         AC_MSG_RESULT([yes])
 812                         RUN_PYTHON_AGENT_TEST=yes
 813                 ], [
 814                         AC_MSG_RESULT([no])
 815                         AS_IF([test -z "$test_python3_agent_autodetect"],[
 816                                 AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.])
 817                         ])
 818                 ])
 819
 820         ])
 821 ])
 822 AC_SUBST([RUN_PYTHON_AGENT_TEST])
 823 AC_SUBST([PYTHON2_AGENT])
 824 AC_SUBST([PYTHON3_AGENT])
 825
 826 AC_ARG_ENABLE([test-sdt-uprobe],
 827   [AS_HELP_STRING([--enable-test-sdt-uprobe], [enable the LTTng UST SDT uprobe tests [default=autodetect]])],
 828   [test_sdt_uprobe="$enableval"],
 829   [test_sdt_uprobe=autodetect]
 830 )
 831
 832 AS_IF([test "$test_sdt_uprobe" != "no"], [
 833   LTTNG_CHECK_SDT_WORKS
 834   AC_PATH_PROG([DTRACE], [dtrace])
 835 ])
 836
 837 AS_IF([test "$test_sdt_uprobe" = "yes"], [
 838   AS_IF([test "$lttng_cv_sdt_works" = "no"], [
 839     AC_MSG_ERROR([Cannot find 'sys/sdt.h'.])
 840   ])
 841   AS_IF([test "x$DTRACE" = "x"], [
 842     AC_MSG_ERROR([Cannot find SystemTap dtrace. You can set the DTRACE variable to override automatic detection.])
 843   ])
 844 ])
 845
 846 AS_IF([test "$test_sdt_uprobe" = "autodetect"], [
 847   AS_IF([test "$lttng_cv_sdt_works" = "yes"], [
 848     AS_IF([test "x$DTRACE" != "x"], [
 849       test_sdt_uprobe=yes
 850     ])
 851   ])
 852 ])
 853
 854 AM_CONDITIONAL([TEST_SDT_UPROBE], [test "$test_sdt_uprobe" = "yes"])
 855
 856 # Arguments for binaries build exclusion
 857 AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries]))
 858 AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd],
 859               [Disable the build of lttng-consumerd binaries]))
 860 AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries]))
 861 AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd],
 862               [Disable the build of lttng-relayd binaries]))
 863 AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond],
 864               [Disable the build of lttng-sessiond binaries]))
 865 AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras],
 866               [Disable the build of the extra components]))
 867
 868
 869 # Always build libconfig since it a dependency of libcommon
 870 build_lib_config=yes
 871
 872 build_lib_compat=no
 873 build_lib_consumer=no
 874 build_lib_hashtable=no
 875 build_lib_health=no
 876 build_lib_index=no
 877 build_lib_kernel_consumer=no
 878 build_lib_kernel_ctl=no
 879 build_lib_lttng_ctl=no
 880 build_lib_relayd=no
 881 build_lib_fd_tracker=no
 882 build_lib_sessiond_comm=no
 883 build_lib_testpoint=no
 884 build_lib_ust_consumer=no
 885
 886 # There is an overlap for enabled dependencies, but this makes everything
 887 # simpler. libcommon and libconfig are always compiled so they are not repeated
 888 # here.
 889
 890 # Enable binary dependencies.
 891 AS_IF([test x$enable_bin_lttng != xno],
 892       [
 893        build_lib_lttng_ctl=yes
 894       ]
 895 )
 896
 897 AS_IF([test x$enable_bin_lttng_consumerd != xno],
 898       [
 899        build_lib_consumer=yes
 900        build_lib_sessiond_comm=yes
 901        build_lib_index=yes
 902        build_lib_health=yes
 903        build_lib_testpoint=yes
 904       ]
 905 )
 906
 907 AS_IF([test x$enable_bin_lttng_crash != xno],
 908       # Do nothing since libconfig and libcommon are built by default.
 909       []
 910 )
 911
 912 AS_IF([test x$enable_bin_lttng_relayd != xno],
 913       [
 914        build_lib_lttng_ctl=yes
 915        build_lib_sessiond_comm=yes
 916        build_lib_hashtable=yes
 917        build_lib_compat=yes
 918        build_lib_index=yes
 919        build_lib_health=yes
 920        build_lib_testpoint=yes
 921        build_lib_fd_tracker=yes
 922       ]
 923 )
 924 AS_IF([test x$enable_bin_lttng_sessiond != xno],
 925       [
 926        build_lib_lttng_ctl=yes
 927        build_lib_sessiond_comm=yes
 928        build_lib_kernel_ctl=yes
 929        build_lib_hashtable=yes
 930        build_lib_compat=yes
 931        build_lib_relayd=yes
 932        build_lib_testpoint=yes
 933        build_lib_health=yes
 934       ]
 935 )
 936
 937 # Libraries dependencies enabling
 938 AS_IF([test x$build_lib_lttng_ctl = xyes],
 939       [
 940        build_lib_sessiond_comm=yes
 941        build_lib_hashtable=yes
 942       ]
 943 )
 944
 945 AS_IF([test x$build_lib_consumer = xyes],
 946       [
 947        build_lib_sessiond_comm=yes
 948        build_lib_kernel_consumer=yes
 949        build_lib_hashtable=yes
 950        build_lib_compat=yes
 951        build_lib_relayd=yes
 952        AS_IF([test "x$with_lttng_ust" = "xyes"], [build_lib_ust_consumer=yes])
 953       ]
 954 )
 955
 956 AS_IF([test x$build_lib_kernel_consumer = xyes],
 957       [
 958        build_lib_kernel_ctl=yes
 959        build_lib_relayd=yes
 960       ]
 961 )
 962
 963 AS_IF([test x$build_lib_relayd = xyes],
 964       [
 965        build_lib_sessiond_comm=yes
 966       ]
 967 )
 968
 969 # Find arch type
 970 AS_CASE([$host_cpu],
 971         [k1om], [ARCHTYPE="x86"],
 972         [i386], [ARCHTYPE="x86"],
 973         [i486], [ARCHTYPE="x86"],
 974         [i586], [ARCHTYPE="x86"],
 975         [i686], [ARCHTYPE="x86"],
 976         [amd64], [ARCHTYPE="x86"],
 977         [x86_64], [ARCHTYPE="x86"],
 978         [powerpc], [ARCHTYPE="ppc"],
 979         [ppc64], [ARCHTYPE="ppc"],
 980         [powerpc64], [ARCHTYPE="ppc"],
 981         [powerpc64le], [ARCHTYPE="ppc"],
 982         [ppc], [ARCHTYPE="ppc"],
 983         [s390], [ARCHTYPE="s390"],
 984         [s390x], [ARCHTYPE="s390"],
 985         [sparc], [ARCHTYPE="sparc64"],
 986         [sparc64], [ARCHTYPE="sparc64"],
 987         [alpha*], [ARCHTYPE="alpha"],
 988         [ia64], [ARCHTYPE="ia64"],
 989         [arm*], [ARCHTYPE="arm"],
 990         [aarch64*], [ARCHTYPE="aarch64"],
 991         [mips*], [ARCHTYPE="mips"],
 992         [nios2*], [ARCHTYPE="nios2"],
 993         [tile*], [ARCHTYPE="tile"],
 994         [hppa*], [ARCHTYPE="hppa"],
 995         [m68k], [ARCHTYPE="m68k"],
 996         [riscv*], [ARCHTYPE="riscv"],
 997         [ARCHTYPE="unknown"]
 998 )
 999
1000 AC_SUBST(ARCHTYPE)
1001
1002 AS_CASE([$host_os],
1003         [linux*], [OSTYPE="linux"],
1004         [freebsd*], [OSTYPE="freebsd"],
1005         [solaris*], [OSTYPE="solaris"],
1006         [cygwin*], [OSTYPE="cygwin"],
1007         [mingw*], [OSTYPE="mingw"],
1008         [OSTYPE="unknown"]
1009 )
1010 AC_SUBST(OSTYPE)
1011 AM_CONDITIONAL([IS_LINUX], [test $OSTYPE = "linux"])
1012
1013
1014
1015 # Userspace callstack capture is only supported by the Linux kernel on x86.
1016 AH_TEMPLATE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [Define if you have LTTng-modules userspace callstack tracing support])
1017 AS_IF([test "x$ARCHTYPE" = "xx86" && test "x$OSTYPE" = "xlinux"],[
1018         have_modules_userspace_callstack_context=yes
1019         AC_DEFINE([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [1])
1020 ])
1021 AM_CONDITIONAL([HAVE_MODULES_USERSPACE_CALLSTACK_CONTEXT], [test x$have_modules_userspace_callstack_context = xyes])
1022
1023 # Export binaries build conditions.
1024 AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno])
1025 AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno])
1026 AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno])
1027 AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno])
1028 AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno])
1029
1030 # Export the tests and extras build conditions.
1031 AS_IF([\
1032 test "x$enable_bin_lttng" != "xno" && \
1033 test "x$enable_bin_lttng_consumerd" != "xno" && \
1034 test "x$enable_bin_lttng_crash" != "xno" && \
1035 test "x$enable_bin_lttng_relayd" != "xno" && \
1036 test "x$enable_bin_lttng_sessiond" != "xno"],
1037 [build_tests=yes],
1038 [build_tests=no]
1039 )
1040
1041 AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes])
1042 AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno])
1043
1044 # Export libraries build conditions.
1045 AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes])
1046 AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes])
1047 AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes])
1048 AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes])
1049 AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes])
1050 AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes])
1051 AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes])
1052 AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes])
1053 AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes])
1054 AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes])
1055 AM_CONDITIONAL([BUILD_LIB_FD_TRACKER], [test x$build_lib_fd_tracker = xyes])
1056 AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes])
1057 AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes])
1058 AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes])
1059
1060 AM_CFLAGS="${WARN_CFLAGS} -fno-strict-aliasing $PTHREAD_CFLAGS"
1061 AC_SUBST(AM_CFLAGS)
1062
1063 # This is set even though it is empty, so Makefiles can do "AM_LDFLAGS += ...".
1064 AM_LDFLAGS=""
1065 AC_SUBST(AM_LDFLAGS)
1066
1067 # The order in which the include folders are searched is important.
1068 # The top_builddir should always be searched first in the event that a build
1069 # time generated file is included. An example of this is the "version.i" file.
1070 # In a scenario where lttng-tools is built from a distribution tarball and in a
1071 # out-of-tree manner, the generated "version.i" has priority on the one from
1072 # the source (distribution tarball) and must be found first.
1073 AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/src -I\$(top_srcdir)/src -include config.h $AM_CPPFLAGS"
1074 AC_SUBST(AM_CPPFLAGS)
1075
1076 lttngincludedir="${includedir}/lttng"
1077 AC_SUBST(lttngincludedir)
1078
1079 lttngactionincludedir="${includedir}/lttng/action"
1080 AC_SUBST(lttngactionincludedir)
1081
1082 lttngconditionincludedir="${includedir}/lttng/condition"
1083 AC_SUBST(lttngconditionincludedir)
1084
1085 lttngnotificationincludedir="${includedir}/lttng/notification"
1086 AC_SUBST(lttngnotificationincludedir)
1087
1088 lttngtriggerincludedir="${includedir}/lttng/trigger"
1089 AC_SUBST(lttngtriggerincludedir)
1090
1091 lttngeventruleincludedir="${includedir}/lttng/event-rule"
1092 AC_SUBST(lttngeventruleincludedir)
1093
1094 lttnglibexecdir="${libdir}/lttng/libexec"
1095 AC_SUBST(lttnglibexecdir)
1096
1097 AC_CONFIG_FILES([
1098         Makefile
1099         doc/Makefile
1100         doc/examples/Makefile
1101         doc/examples/rotation/Makefile
1102         doc/examples/trigger-condition-event-matches/Makefile
1103         doc/man/Makefile
1104         doc/man/asciidoc-attrs.conf
1105         include/Makefile
1106         extras/Makefile
1107         extras/bindings/Makefile
1108         extras/bindings/swig/Makefile
1109         extras/bindings/swig/python/Makefile
1110         extras/core-handler/Makefile
1111         src/Makefile
1112         src/common/Makefile
1113         src/common/argpar/Makefile
1114         src/common/bytecode/Makefile
1115         src/common/kernel-ctl/Makefile
1116         src/common/kernel-consumer/Makefile
1117         src/common/consumer/Makefile
1118         src/common/ust-consumer/Makefile
1119         src/common/hashtable/Makefile
1120         src/common/sessiond-comm/Makefile
1121         src/common/compat/Makefile
1122         src/common/relayd/Makefile
1123         src/common/testpoint/Makefile
1124         src/common/index/Makefile
1125         src/common/health/Makefile
1126         src/common/config/Makefile
1127         src/common/string-utils/Makefile
1128         src/common/fd-tracker/Makefile
1129         src/common/filter/Makefile
1130         src/lib/Makefile
1131         src/lib/lttng-ctl/Makefile
1132         src/lib/lttng-ctl/lttng-ctl.pc
1133         src/bin/Makefile
1134         src/bin/lttng-consumerd/Makefile
1135         src/bin/lttng-sessiond/Makefile
1136         src/bin/lttng-relayd/Makefile
1137         src/bin/lttng/Makefile
1138         src/bin/lttng-crash/Makefile
1139         src/vendor/Makefile
1140         src/vendor/msgpack/Makefile
1141         tests/Makefile
1142         tests/destructive/Makefile
1143         tests/regression/Makefile
1144         tests/regression/kernel/Makefile
1145         tests/regression/tools/Makefile
1146         tests/regression/tools/streaming/Makefile
1147         tests/regression/tools/filtering/Makefile
1148         tests/regression/tools/health/Makefile
1149         tests/regression/tools/tracefile-limits/Makefile
1150         tests/regression/tools/snapshots/Makefile
1151         tests/regression/tools/live/Makefile
1152         tests/regression/tools/exclusion/Makefile
1153         tests/regression/tools/save-load/Makefile
1154         tests/regression/tools/save-load/configuration/Makefile
1155         tests/regression/tools/mi/Makefile
1156         tests/regression/tools/wildcard/Makefile
1157         tests/regression/tools/channel/Makefile
1158         tests/regression/tools/crash/Makefile
1159         tests/regression/tools/regen-metadata/Makefile
1160         tests/regression/tools/regen-statedump/Makefile
1161         tests/regression/tools/notification/Makefile
1162         tests/regression/tools/rotation/Makefile
1163         tests/regression/tools/base-path/Makefile
1164         tests/regression/tools/metadata/Makefile
1165         tests/regression/tools/tracker/Makefile
1166         tests/regression/tools/working-directory/Makefile
1167         tests/regression/tools/relayd-grouping/Makefile
1168         tests/regression/tools/clear/Makefile
1169         tests/regression/tools/trigger/Makefile
1170         tests/regression/tools/trigger/rate-policy/Makefile
1171         tests/regression/tools/trigger/start-stop/Makefile
1172         tests/regression/tools/trigger/utils/Makefile
1173         tests/regression/tools/trigger/name/Makefile
1174         tests/regression/ust/Makefile
1175         tests/regression/ust/nprocesses/Makefile
1176         tests/regression/ust/high-throughput/Makefile
1177         tests/regression/ust/low-throughput/Makefile
1178         tests/regression/ust/before-after/Makefile
1179         tests/regression/ust/buffers-pid/Makefile
1180         tests/regression/ust/periodical-metadata-flush/Makefile
1181         tests/regression/ust/multi-session/Makefile
1182         tests/regression/ust/multi-lib/Makefile
1183         tests/regression/ust/overlap/Makefile
1184         tests/regression/ust/overlap/demo/Makefile
1185         tests/regression/ust/linking/Makefile
1186         tests/regression/ust/daemon/Makefile
1187         tests/regression/ust/exit-fast/Makefile
1188         tests/regression/ust/fork/Makefile
1189         tests/regression/ust/libc-wrapper/Makefile
1190         tests/regression/ust/baddr-statedump/Makefile
1191         tests/regression/ust/ust-dl/Makefile
1192         tests/regression/ust/java-jul/Makefile
1193         tests/regression/ust/java-log4j/Makefile
1194         tests/regression/ust/python-logging/Makefile
1195         tests/regression/ust/getcpu-override/Makefile
1196         tests/regression/ust/clock-override/Makefile
1197         tests/regression/ust/type-declarations/Makefile
1198         tests/regression/ust/rotation-destroy-flush/Makefile
1199         tests/regression/ust/blocking/Makefile
1200         tests/regression/ust/namespaces/Makefile
1201         tests/stress/Makefile
1202         tests/unit/Makefile
1203         tests/unit/ini_config/Makefile
1204         tests/perf/Makefile
1205         tests/utils/Makefile
1206         tests/utils/tap/Makefile
1207         tests/utils/testapp/Makefile
1208         tests/utils/testapp/gen-ns-events/Makefile
1209         tests/utils/testapp/gen-kernel-test-events/Makefile
1210         tests/utils/testapp/gen-ust-events/Makefile
1211         tests/utils/testapp/gen-ust-events-ns/Makefile
1212         tests/utils/testapp/gen-syscall-events-callstack/Makefile
1213         tests/utils/testapp/gen-ust-nevents/Makefile
1214         tests/utils/testapp/gen-ust-nevents-str/Makefile
1215         tests/utils/testapp/gen-syscall-events/Makefile
1216         tests/utils/testapp/gen-ust-tracef/Makefile
1217         tests/utils/testapp/userspace-probe-elf-binary/Makefile
1218         tests/utils/testapp/userspace-probe-elf-cxx-binary/Makefile
1219         tests/utils/testapp/userspace-probe-sdt-binary/Makefile
1220 ])
1221
1222 # Inject variable into python test script.
1223 AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging])
1224 # Inject LTTNG_TOOLS_BUILD_WITH_LIBPFM variable in test script.
1225 AC_CONFIG_FILES([tests/perf/test_perf_raw],[chmod +x tests/perf/test_perf_raw])
1226 AC_CONFIG_FILES([tests/regression/ust/ust-dl/test_ust-dl],[chmod +x tests/regression/ust/ust-dl/test_ust-dl])
1227
1228 AC_OUTPUT
1229
1230 #
1231 # Mini-report on what will be built.
1232 #
1233
1234 PPRINT_INIT
1235 PPRINT_SET_INDENT(1)
1236 PPRINT_SET_TS(38)
1237
1238 AS_ECHO
1239 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST")
1240 AS_ECHO
1241
1242 AS_IF([test -n "$report_fold"], [
1243         AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`")
1244 ], [
1245         AS_ECHO("$version_description")
1246 ])
1247
1248 AS_ECHO
1249 PPRINT_SUBTITLE([Features])
1250
1251 # Target architecture we're building for.
1252 target_arch=$host_cpu
1253 [
1254 for f in $CFLAGS; do
1255         if test $f = "-m32"; then
1256                         target_arch="32-bit"
1257         elif test $f = "-m64"; then
1258                         target_arch="64-bit"
1259         fi
1260 done
1261 ]
1262 PPRINT_PROP_STRING([Target architecture], $target_arch)
1263
1264 # kmod enabled/disabled
1265 test "x$with_kmod" != "xno" && value=1 || value=0
1266 PPRINT_PROP_BOOL([libkmod support], $value)
1267
1268 # LTTng-UST enabled/disabled
1269 test "x$with_lttng_ust" = "xyes" && value=1 || value=0
1270 PPRINT_PROP_BOOL([LTTng-UST support], $value)
1271
1272 AS_ECHO
1273 PPRINT_SUBTITLE([Binaries])
1274
1275 # List binaries to be built
1276 test x$enable_bin_lttng != xno && value=1 || value=0
1277 PPRINT_PROP_BOOL([lttng], $value)
1278
1279 test x$enable_bin_lttng_consumerd != xno && value=1 || value=0
1280 PPRINT_PROP_BOOL([lttng-consumerd], $value)
1281
1282 test x$enable_bin_lttng_crash != xno && value=1 || value=0
1283 PPRINT_PROP_BOOL([lttng-crash], $value)
1284
1285 test x$enable_bin_lttng_relayd != xno && value=1 || value=0
1286 PPRINT_PROP_BOOL([lttng-relayd], $value)
1287
1288 test x$enable_bin_lttng_sessiond != xno && value=1 || value=0
1289 PPRINT_PROP_BOOL([lttng-sessiond], $value)
1290
1291 # Extras
1292 test x$enable_extras != xno && value=1 || value=0
1293 AS_ECHO
1294 PPRINT_SET_INDENT(0)
1295 PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE)
1296 PPRINT_SET_INDENT(1)
1297
1298 AS_ECHO
1299 PPRINT_SUBTITLE([Tests])
1300
1301 # Print clear message that tests won't be built
1302 AS_IF([test "x$build_tests" = "xno"],[
1303         PPRINT_WARN([Tests won't be built since some binaries were disabled])
1304 ])
1305
1306 # LTTng UST Java agent JUL tests enabled/disabled
1307 test "x$test_java_agent_jul" = "xyes" && value=1 || value=0
1308 PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value)
1309
1310 # LTTng UST Java agent Log4j tests enabled/disabled
1311 test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0
1312 PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value)
1313
1314 test ! -z "$PYTHON2_AGENT" && value=1 || value=0
1315 PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value)
1316
1317 test ! -z "$PYTHON3_AGENT" && value=1 || value=0
1318 PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value)
1319
1320 # LTTng UST Java agent Log4j tests enabled/disabled
1321 test "x$test_sdt_uprobe" = "xyes" && value=1 || value=0
1322 PPRINT_PROP_BOOL([LTTng-UST SDT uprobe tests], $value)
1323
1324 #Python binding enabled/disabled
1325 test "x$enable_python_binding" = xyes && value=1 || value=0
1326 AS_ECHO
1327 PPRINT_SET_INDENT(0)
1328 PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE)
1329
1330 # man pages build enabled/disabled
1331 m4_pushdef([build_man_pages_msg], [Build and install man pages])
1332
1333 AS_IF([test "x$man_pages_opt" != "xno"], [
1334         AS_IF([test "x$in_git_repo" = "xyes"], [
1335                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1336         ], [
1337                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
1338                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
1339                 ], [
1340                         PPRINT_PROP_STRING([build_man_pages_msg],
1341                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
1342                                 $PPRINT_COLOR_SUBTITLE)
1343                 ])
1344         ])
1345 ], [
1346         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
1347 ])
1348
1349 m4_popdef([build_man_pages_msg])
1350
1351 test "x$embedded_help" = xyes && value=1 || value=0
1352 PPRINT_PROP_BOOL([Embed --help messages], $value, $PPRINT_COLOR_SUBTITLE)
1353
1354 PPRINT_SET_INDENT(1)
1355
1356 report_bindir="`eval eval echo $bindir`"
1357 report_libdir="`eval eval echo $libdir`"
1358
1359 # Print the bindir and libdir this `make install' will install into.
1360 AS_ECHO
1361 PPRINT_SUBTITLE([Install directories])
1362 PPRINT_PROP_STRING([Binaries], [$report_bindir])
1363 PPRINT_PROP_STRING([Libraries], [$report_libdir])
1364
1365 AS_ECHO
1366 PPRINT_SUBTITLE([Search directories])
1367
1368 # If we build the sessiond, print the paths it will use
1369 AS_IF([test "$SESSIOND_BIN" = ""],[
1370         path="$report_bindir/lttng-sessiond"
1371 ],[
1372         path="$SESSIOND_BIN"
1373 ])
1374 PPRINT_PROP_STRING([lttng-sessiond executable], [$path])
1375
1376 AS_IF([test "$CONSUMERD32_BIN" = ""],[
1377         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1378 ],[
1379         path="$CONSUMERD32_BIN"
1380 ])
1381 PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path])
1382
1383 AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[
1384         path="`eval eval echo $libdir`"
1385 ],[
1386         path="$CONSUMERD32_LIBDIR"
1387 ])
1388 PPRINT_PROP_STRING([32-bit consumer libraries], [$path])
1389
1390 AS_IF([test "$CONSUMERD64_BIN" = ""],[
1391         path="`eval eval echo $lttnglibexecdir`/lttng-consumerd"
1392 ],[
1393         path="$CONSUMERD64_BIN"
1394 ])
1395 PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path])
1396
1397 AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[
1398         path="`eval eval echo $libdir`"
1399 ],[
1400         path="$CONSUMERD64_LIBDIR"
1401 ])
1402 PPRINT_PROP_STRING([64-bit consumer libraries], [$path])
1403 PPRINT_SET_INDENT(0)
1404
1405 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
1406         AS_ECHO
1407         PPRINT_WARN([You need asciidoc and xmlto to build the LTTng-tools man pages.
1408
1409 Note that the man pages are already built in this distribution tarball,
1410 therefore asciidoc and xmlto are only needed if you intend to modify
1411 their sources.
1412
1413 Also note that the installed man pages will contain the project's
1414 default command-line option and environment variable values.
1415
1416 Use --disable-man-pages to completely disable building and installing
1417 the man pages.])
1418 ])