configure.ac

   1 dnl Version infos
   2 m4_define([V_MAJOR], [2])
   3 m4_define([V_MINOR], [11])
   4 m4_define([V_PATCH], [0])
   5 m4_define([V_EXTRA], [rc1])
   6 m4_define([V_NAME], [[Lafontaine]])
   7 m4_define([V_DESC], [[A modern Saison beer from Montréal's Oshlag microbrewery, Lafontaine is a refreshing, zesty, rice beer with hints of fruit and spices.]])
   8
   9 m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH])
  10 m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])])
  11
  12 AC_PREREQ(2.59)
  13 AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com], [], [https://lttng.org])
  14
  15 dnl Substitute minor/major/patchlevel version numbers
  16 AC_SUBST([MAJOR_VERSION], [V_MAJOR])
  17 AC_SUBST([MINOR_VERSION], [V_MINOR])
  18 AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH])
  19
  20 # Following the numbering scheme proposed by libtool for the library version
  21 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
  22 # This is the library version of liblttng-ust.
  23 m4_define([UST_LIB_V_MAJOR], [0])
  24 m4_define([UST_LIB_V_MINOR], [0])
  25 m4_define([UST_LIB_V_PATCH], [0])
  26
  27 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [UST_LIB_V_MAJOR:UST_LIB_V_MINOR:UST_LIB_V_PATCH])
  28 AC_DEFINE([CONFIG_LTTNG_UST_LIBRARY_VERSION_MAJOR], [UST_LIB_V_MAJOR], [Major SONAME number of the ust library])
  29 # note: remember to update tracepoint.h dlopen() to match this version
  30 # number. TODO: eventually automate by exporting the major number.
  31
  32 # This is the library version of liblttng-ust-ctl, used internally by
  33 # liblttng-ust, lttng-sessiond, and lttng-consumerd.
  34 AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [4:0:0])
  35
  36 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  37 AC_CONFIG_AUX_DIR([config])
  38 AC_CONFIG_MACRO_DIR([m4])
  39 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  40
  41 AC_CANONICAL_TARGET
  42 AC_CANONICAL_HOST
  43
  44 AM_INIT_AUTOMAKE([1.9 foreign dist-bzip2 no-dist-gzip tar-ustar])
  45 AM_MAINTAINER_MODE([enable])
  46
  47 # Enable silent rules if available (Introduced in AM 1.11)
  48 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  49
  50 AC_REQUIRE_AUX_FILE([tap-driver.sh])
  51
  52 # Checks for C compiler
  53 AC_USE_SYSTEM_EXTENSIONS
  54 AC_SYS_LARGEFILE
  55 AC_PROG_CC
  56 AC_PROG_CC_STDC
  57 AC_PROG_CXX
  58 rw_PROG_CXX_WORKS
  59 AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"])
  60
  61 # Check if the compiler support weak symbols
  62 AX_SYS_WEAK_ALIAS
  63
  64 AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [
  65         AC_MSG_ERROR([Your platform doesn't support weak symbols.])
  66 ])
  67
  68 # Checks for programs.
  69 AC_PROG_SED
  70 AC_PROG_GREP
  71 AC_PROG_LN_S
  72 AC_PROG_MKDIR_P
  73 AC_PROG_MAKE_SET
  74 AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"])
  75 AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"])
  76
  77 # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321.
  78 AC_ARG_ENABLE([libtool-linkdep-fixup], [
  79 AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)])
  80 ], [
  81         libtool_fixup=$enableval
  82 ], [
  83         libtool_fixup=yes
  84 ])
  85
  86 AS_IF([test "x$libtool_fixup" = "xyes"], [
  87         libtool_m4="$srcdir/m4/libtool.m4"
  88         libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)"
  89         AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4])
  90         libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4)
  91
  92         AS_IF([test $libtool_flag_pattern_count -ne 0], [
  93         AC_MSG_RESULT([$libtool_flag_pattern_count])
  94         AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown])
  95                 $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4
  96         ], [
  97                 AC_MSG_RESULT([none])
  98         ])
  99 ])
 100 LT_INIT([disable-static])
 101
 102 AC_MSG_CHECKING([whether shared libraries are enabled])
 103 AS_IF([test "x$enable_shared" = "xyes"], [
 104         AC_MSG_RESULT([yes])
 105 ], [
 106         AC_MSG_RESULT([no])
 107         AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled])
 108 ])
 109
 110 # Checks for typedefs, structures, and compiler characteristics.
 111 AC_C_INLINE
 112 AC_TYPE_INT8_T
 113 AC_TYPE_INT16_T
 114 AC_TYPE_INT32_T
 115 AC_TYPE_INT64_T
 116 AC_TYPE_MODE_T
 117 AC_TYPE_OFF_T
 118 AC_TYPE_PID_T
 119 AC_TYPE_SIZE_T
 120 AC_TYPE_SSIZE_T
 121 AC_TYPE_UID_T
 122 AC_TYPE_UINT8_T
 123 AC_TYPE_UINT16_T
 124 AC_TYPE_UINT32_T
 125 AC_TYPE_UINT64_T
 126 AC_CHECK_TYPES([ptrdiff_t])
 127
 128 AX_C___ATTRIBUTE__
 129 AS_IF([test "x$ax_cv___attribute__" = "xyes"],
 130         [:],
 131         [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])])
 132
 133 # Checks for library functions.
 134 AC_FUNC_CHOWN
 135 AC_FUNC_FORK
 136 AC_FUNC_MMAP
 137 AC_FUNC_REALLOC
 138 AC_FUNC_STRERROR_R
 139 AC_FUNC_STRNLEN
 140 AC_CHECK_FUNCS([ \
 141         atexit \
 142         clock_gettime \
 143         ftruncate \
 144         getpagesize \
 145         gettimeofday \
 146         localeconv \
 147         memchr \
 148         memmove \
 149         memset \
 150         mkdir \
 151         munmap \
 152         realpath \
 153         sched_getcpu \
 154         socket \
 155         strchr \
 156         strdup \
 157         strerror \
 158         strtol \
 159         sysconf \
 160 ])
 161
 162 # AC_FUNC_MALLOC causes problems when cross-compiling.
 163 #AC_FUNC_MALLOC
 164
 165 # Checks for header files.
 166 AC_HEADER_STDBOOL
 167 AC_CHECK_HEADERS([ \
 168         arpa/inet.h \
 169         fcntl.h \
 170         float.h \
 171         limits.h \
 172         locale.h \
 173         stddef.h \
 174         sys/socket.h \
 175         sys/time.h \
 176         wchar.h \
 177 ])
 178
 179 # Set architecture specific options
 180 AS_CASE([$host_cpu],
 181         [i[[3456]]86], [],
 182         [x86_64], [],
 183         [amd64], [],
 184         [powerpc], [],
 185         [ppc64], [],
 186         [ppc64le], [],
 187         [powerpc64], [],
 188         [powerpc64le], [],
 189         [s390], [NO_UNALIGNED_ACCESS=1],
 190         [s390x], [NO_UNALIGNED_ACCESS=1],
 191         [arm*], [
 192                 NO_UNALIGNED_ACCESS=1
 193                 NO_NUMA=1
 194                 ],
 195         [aarch64*], [NO_UNALIGNED_ACCESS=1],
 196         [mips*], [NO_UNALIGNED_ACCESS=1],
 197         [tile*], [NO_UNALIGNED_ACCESS=1],
 198         [
 199                 UNSUPPORTED_ARCH=1
 200                 NO_UNALIGNED_ACCESS=1
 201         ])
 202
 203 # Configuration options, which will be installed in the config.h
 204 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
 205 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
 206 AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h])
 207
 208 # Checks for libraries.
 209 AC_CHECK_LIB([dl], [dlopen], [
 210         libdl_name=dl
 211         DL_LIBS="-ldl"
 212 ], [
 213         #libdl not found, check for dlopen in libc.
 214         AC_CHECK_LIB([c], [dlopen], [
 215                 libdl_name=c
 216                 DL_LIBS="-lc"
 217         ], [
 218                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
 219         ])
 220 ])
 221 AC_SUBST(DL_LIBS)
 222
 223 # Check if libdl has dlmopen support.
 224 AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."])
 225 AC_CHECK_LIB([$libdl_name], [dlmopen],
 226         [AC_DEFINE([HAVE_DLMOPEN], [1])]
 227 )
 228
 229 AC_CHECK_LIB([pthread], [pthread_create])
 230 AC_CHECK_LIB([pthread], [pthread_setname_np],
 231         AC_DEFINE([HAVE_PTHREAD_SETNAME_NP], [1], [Define to 1 if pthread_setname_np is available.]),
 232         AC_CHECK_LIB([pthread], [pthread_set_name_np],
 233                 AC_DEFINE([HAVE_PTHREAD_SET_NAME_NP], [1], [Define to 1 if pthread_set_name_np is available.]),
 234                 AC_MSG_RESULT([pthread setname/set_name not found.])))
 235
 236 # Check for dlfcn.h
 237 AC_CHECK_HEADER([dlfcn.h])
 238 AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [
 239         AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [
 240                 #define _GNU_SOURCE /* Required on Linux to get GNU extensions */
 241                 #include <dlfcn.h>
 242         ])
 243 ], [
 244         ac_cv_have_decl_RTLD_DI_LINKMAP="no"
 245 ])
 246
 247 AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"])
 248
 249 # URCU
 250
 251 # urcu - check if we just find the headers it out of the box.
 252 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 253 This error can also occur when the liburcu package's configure script has not been run.])])
 254
 255 # urcu-cds - check that URCU Concurrent Data Structure lib is available to compilation
 256 # Part of Userspace RCU library 0.7.2 or better.
 257 AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], [AC_MSG_ERROR([Cannot find
 258 liburcu-cds lib, part of Userspace RCU 0.7 or better. Use [LDFLAGS]=-Ldir to specify its location.])])
 259
 260 AC_MSG_CHECKING([caa_likely()])
 261 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 262         #include <urcu/compiler.h>
 263         void fct(void)
 264         {
 265                 if (caa_likely(1)) {
 266                 }
 267         }
 268 ]])], [
 269         AC_MSG_RESULT([yes])
 270 ], [
 271         AC_MSG_RESULT([no])
 272         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 273 ])
 274
 275 # urcu - check that URCU lib is available to compilation
 276 AC_CHECK_LIB([urcu-bp], [urcu_bp_synchronize_rcu], [], [AC_MSG_ERROR([Cannot find liburcu-bp 0.11 or newer. Use [LDFLAGS]=-Ldir to specify its location.])])
 277
 278 # urcu - check that URCU lib is at least version 0.11
 279 AC_CHECK_LIB([urcu-bp], [urcu_bp_call_rcu], [], [AC_MSG_ERROR([liburcu 0.11 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 280
 281 # numa.h integration
 282 AS_IF([test "x$NO_NUMA" = "x1"],[
 283       AS_IF([test "x$enable_numa" = "x" ], [enable_numa=no])
 284 ])
 285
 286 AC_ARG_ENABLE([numa], [
 287 AS_HELP_STRING([--disable-numa], [disable NUMA support])
 288 ], [
 289         enable_numa=$enableval
 290 ], [
 291         enable_numa=yes
 292 ])
 293
 294 AS_IF([test "x$enable_numa" = "xyes"], [
 295         # numa - check that numa lib is available
 296         AC_CHECK_LIB([numa], [numa_available], [],
 297 [AC_MSG_ERROR([libnuma is not available. Please either install it (e.g. libnuma-dev) or use [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure argument to disable NUMA support.])])
 298         have_libnuma=yes
 299 ])
 300 AM_CONDITIONAL([HAVE_LIBNUMA], [test "x$have_libnuma" = "xyes"])
 301
 302 # optional linux/perf_event.h
 303 AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], [])
 304
 305 # Perf event counters are supported on all architectures supported by
 306 # perf, using the read system call as fallback.
 307 AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"])
 308
 309 AS_IF([test "x$have_perf_event" = "xyes"], [
 310         AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1])
 311 ])
 312
 313 AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [
 314         AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 315 ])
 316
 317 # Check for JNI header files if requested
 318 AC_ARG_ENABLE([jni-interface], [
 319 AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]])
 320 ], [
 321         jni_interface=$enableval
 322 ], [
 323         jni_interface=no
 324 ])
 325
 326 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 327
 328
 329 AC_ARG_ENABLE([java-agent-jul], [
 330 AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]])
 331 ], [
 332         java_agent_jul=$enableval
 333 ], [
 334         java_agent_jul=no
 335 ])
 336
 337 AC_ARG_ENABLE([java-agent-log4j], [
 338 AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]])
 339 ], [
 340         java_agent_log4j=$enableval
 341 ], [
 342         java_agent_log4j=no
 343 ])
 344
 345 AC_ARG_ENABLE([java-agent-all], [
 346 AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]])
 347 ], [
 348         java_agent_jul=$enableval
 349         java_agent_log4j=$enableval
 350 ], [:])
 351
 352 AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"])
 353 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"])
 354 AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"])
 355
 356 AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [
 357         AX_JAVA_OPTIONS
 358         AX_PROG_JAVAC
 359         AX_PROG_JAVA
 360         AX_PROG_JAR
 361
 362         AX_JNI_INCLUDE_DIR
 363         for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS
 364         do
 365                 JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR"
 366         done
 367
 368         saved_CPPFLAGS="$CPPFLAGS"
 369         CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS"
 370         AX_PROG_JAVAH
 371         CPPFLAGS="$saved_CPPFLAGS"
 372 ])
 373
 374 AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"])
 375
 376 AS_IF([test "x$java_agent_log4j" = "xyes"], [
 377         AX_CHECK_CLASSPATH
 378         AX_CHECK_CLASS([org.apache.log4j.Logger])
 379         AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [
 380                 AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"])
 381         ])
 382 ])
 383
 384 # Option to build the python agent
 385 AC_ARG_ENABLE([python-agent], [
 386 AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]])
 387 ], [
 388         python_agent=$enableval
 389 ], [:])
 390 AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"])
 391 AS_IF([test "x$python_agent" = "xyes"], [
 392         AM_PATH_PYTHON([2.7])
 393 ])
 394
 395 # sdt.h integration
 396 AC_ARG_WITH([sdt], [
 397 AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]])
 398 ], [
 399         with_sdt=$withval
 400 ], [
 401         with_sdt="no"
 402 ])
 403
 404 AS_IF([test "x$with_sdt" = "xyes"], [
 405         AC_MSG_CHECKING([STAP_PROBEV()])
 406         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 407                 #define SDT_USE_VARIADIC
 408                 #include <sys/sdt.h>
 409                 void fct(void)
 410                 {
 411                         STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 412                 }
 413         ]])], [
 414                 AC_MSG_RESULT([yes])
 415                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 416         ], [
 417                 AC_MSG_RESULT([no])
 418                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 419         ])
 420 ])
 421
 422 AC_ARG_WITH([lttng-system-rundir], [
 423 AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]),
 424 ], [
 425         lttng_system_rundir="$withval"
 426 ], [
 427         lttng_system_rundir="/var/run/lttng"
 428 ])
 429 AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"],
 430                 [LTTng system runtime directory])
 431
 432 AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"])
 433 AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"])
 434
 435 # Enable building examples
 436 AC_ARG_ENABLE(
 437         examples,
 438         AS_HELP_STRING(
 439                 [--disable-examples],
 440                 [Do not build and install examples]
 441         ),
 442         [enable_examples=$enableval],
 443         [enable_examples=yes]
 444 )
 445
 446 AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" != "xno"])
 447
 448 # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file
 449 # is not distributed in tarballs.
 450 AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no])
 451 AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"])
 452
 453 # Enable building man pages (user's intention).
 454 AC_ARG_ENABLE(
 455         man-pages,
 456         AS_HELP_STRING(
 457                 [--disable-man-pages],
 458                 [Do not build and install man pages (already built in a distributed tarball)]
 459         ),
 460         [man_pages_opt=$enableval],
 461         [man_pages_opt=yes]
 462 )
 463
 464 # Check for asciidoc and xmlto if we enabled building the man pages.
 465 have_asciidoc_xmlto=no
 466 warn_prebuilt_man_pages=no
 467
 468 AS_IF([test "x$man_pages_opt" = "xyes"], [
 469         AC_PATH_PROG([ASCIIDOC], [asciidoc], [no])
 470         AC_PATH_PROG([XMLTO], [xmlto], [no])
 471
 472         AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [
 473                 AS_IF([test "x$in_git_repo" = "xyes"], [
 474                         # This is an error because we're in the Git repo, which
 475                         # means the man pages are not already generated for us,
 476                         # thus asciidoc/xmlto are required because we were asked
 477                         # to build the man pages.
 478                         AC_MSG_ERROR([
 479 Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use
 480 --disable-man-pages to disable building the man pages, in which case
 481 they will not be installed.
 482                         ])
 483                 ], [
 484                         # Only warn here: since we're in the tarball, the man
 485                         # pages should already be generated at this point, thus
 486                         # asciidoc/xmlto are not strictly required.
 487                         warn_prebuilt_man_pages=yes
 488                 ])
 489         ], [
 490                 have_asciidoc_xmlto=yes
 491         ])
 492 ])
 493
 494 # Export man page build condition: build the man pages if the user
 495 # asked for it, and if the tools are available.
 496 AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"])
 497 AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"])
 498
 499 # Default values
 500 AC_DEFUN([_AC_DEFINE_AND_SUBST], [
 501         AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1])
 502         $1="$2"
 503         AC_SUBST([$1])
 504 ])
 505
 506 _AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000])
 507
 508 AM_CFLAGS="-Wall"
 509 AC_SUBST(AM_CFLAGS)
 510 AC_SUBST(JNI_CPPFLAGS)
 511
 512 AC_CONFIG_FILES([
 513         Makefile
 514         doc/Makefile
 515         doc/examples/Makefile
 516         doc/man/Makefile
 517         include/Makefile
 518         include/lttng/ust-version.h
 519         snprintf/Makefile
 520         libringbuffer/Makefile
 521         liblttng-ust-comm/Makefile
 522         liblttng-ust/Makefile
 523         liblttng-ust-ctl/Makefile
 524         liblttng-ust-fork/Makefile
 525         liblttng-ust-dl/Makefile
 526         liblttng-ust-fd/Makefile
 527         liblttng-ust-java/Makefile
 528         liblttng-ust-java-agent/Makefile
 529         liblttng-ust-java-agent/java/Makefile
 530         liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile
 531         liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile
 532         liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile
 533         liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile
 534         liblttng-ust-java-agent/jni/Makefile
 535         liblttng-ust-java-agent/jni/common/Makefile
 536         liblttng-ust-java-agent/jni/jul/Makefile
 537         liblttng-ust-java-agent/jni/log4j/Makefile
 538         liblttng-ust-libc-wrapper/Makefile
 539         liblttng-ust-cyg-profile/Makefile
 540         liblttng-ust-python-agent/Makefile
 541         python-lttngust/Makefile
 542         python-lttngust/setup.py
 543         python-lttngust/lttngust/__init__.py
 544         tools/Makefile
 545         tests/Makefile
 546         tests/ctf-types/Makefile
 547         tests/hello/Makefile
 548         tests/hello-many/Makefile
 549         tests/hello.cxx/Makefile
 550         tests/same_line_tracepoint/Makefile
 551         tests/snprintf/Makefile
 552         tests/ust-elf/Makefile
 553         tests/benchmark/Makefile
 554         tests/utils/Makefile
 555         tests/test-app-ctx/Makefile
 556         tests/gcc-weak-hidden/Makefile
 557         lttng-ust.pc
 558 ])
 559
 560 # Create link for python agent for the VPATH guru.
 561 AC_CONFIG_LINKS([
 562         python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py
 563         python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py
 564         python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py
 565         python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py
 566 ])
 567
 568 AC_CONFIG_FILES([tests/ust-elf/test_ust_elf],[chmod +x tests/ust-elf/test_ust_elf])
 569
 570 AC_OUTPUT
 571
 572
 573 #
 574 # Mini-report on what will be built.
 575 #
 576
 577 PPRINT_INIT
 578 PPRINT_SET_INDENT(1)
 579 PPRINT_SET_TS(38)
 580
 581 AS_ECHO
 582 AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"V_NAME\"$PPRINT_COLOR_RST")
 583 AS_ECHO
 584
 585 AS_ECHO("V_DESC")
 586
 587 AS_ECHO
 588 PPRINT_SUBTITLE([System])
 589
 590 PPRINT_PROP_STRING([Target architecture], $host_cpu)
 591
 592 test "x$NO_UNALIGNED_ACCESS" != "x1" && value=1 || value=0
 593 PPRINT_PROP_BOOL([Efficient unaligned memory access], $value)
 594
 595 AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[
 596        PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.])
 597 ])
 598
 599 AS_ECHO
 600 PPRINT_SUBTITLE([Features])
 601 PPRINT_SET_INDENT(1)
 602
 603 test "x$with_sdt" = "xyes" && value=1 || value=0
 604 PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt])
 605
 606 test "x$java_agent_jul" = xyes && value=1 || value=0
 607 PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul])
 608
 609 test "x$java_agent_log4j" = xyes && value=1 || value=0
 610 PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j])
 611
 612 test "x$jni_interface" = xyes && value=1 || value=0
 613 PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface])
 614
 615 test "x$python_agent" = xyes && value=1 || value=0
 616 PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent])
 617
 618 test "x$have_perf_event" = "xyes" && value=1 || value=0
 619 PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value)
 620
 621 test "x$enable_numa" = xyes && value=1 || value=0
 622 PPRINT_PROP_BOOL([NUMA], $value)
 623
 624 AS_ECHO
 625 PPRINT_SET_INDENT(0)
 626
 627 test "x$enable_examples" = xyes && value=1 || value=0
 628 PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE)
 629
 630 # man pages build enabled/disabled
 631 m4_pushdef([build_man_pages_msg], [Build and install man pages])
 632
 633 AS_IF([test "x$man_pages_opt" != "xno"], [
 634         AS_IF([test "x$in_git_repo" = "xyes"], [
 635                 PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 636         ], [
 637                 AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [
 638                         PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE)
 639                 ], [
 640                         PPRINT_PROP_STRING([build_man_pages_msg],
 641                                 [${PPRINT_COLOR_BLDGRN}yes (already built)],
 642                                 $PPRINT_COLOR_SUBTITLE)
 643                 ])
 644         ])
 645 ], [
 646         PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE)
 647 ])
 648
 649 m4_popdef([build_man_pages_msg])
 650
 651 PPRINT_SET_INDENT(1)
 652
 653 report_bindir="`eval eval echo $bindir`"
 654 report_libdir="`eval eval echo $libdir`"
 655
 656 # Print the bindir and libdir this `make install' will install into.
 657 AS_ECHO
 658 PPRINT_SUBTITLE([Install directories])
 659 PPRINT_PROP_STRING([Binaries], [$report_bindir])
 660 PPRINT_PROP_STRING([Libraries], [$report_libdir])
 661
 662 AS_ECHO
 663 PPRINT_SUBTITLE([System directories])
 664
 665 PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir])
 666
 667 PPRINT_SET_INDENT(0)
 668
 669 AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [
 670         AS_ECHO
 671         PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages.
 672
 673 Note that the man pages are already built in this distribution tarball,
 674 therefore asciidoc and xmlto are only needed if you intend to modify
 675 their sources.
 676
 677 Use --disable-man-pages to completely disable building and installing
 678 the man pages.])
 679 ])