configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_INIT([lttng-ust],[2.0.1],[mathieu dot desnoyers at efficios dot com])
   5
   6 # Following the numbering scheme proposed by libtool for the library version
   7 # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html
   8 AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [0:0:0])
   9 # note: remember to update tracepoint.h dlopen() to match this version
  10 # number. TODO: eventually automate by exporting the major number.
  11
  12 AC_CONFIG_AUX_DIR([config])
  13 AC_CANONICAL_TARGET
  14 AC_CANONICAL_HOST
  15 AC_CONFIG_MACRO_DIR([config])
  16 AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip])
  17 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  18 AC_CONFIG_SRCDIR([include/lttng/tracepoint.h])
  19
  20 # Configuration options, which will be installed in the config.h
  21 AC_CONFIG_HEADERS([config.h include/lttng/ust-config.h])
  22 AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.])
  23 AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h])
  24
  25 # Compute minor/major/patchlevel version numbers
  26 AC_PROG_SED
  27 major_version=$(echo AC_PACKAGE_VERSION | sed 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/')
  28 minor_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/')
  29 patchlevel_version=$(echo AC_PACKAGE_VERSION | sed 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/')
  30 AC_SUBST([MAJOR_VERSION], [$major_version])
  31 AC_SUBST([MINOR_VERSION], [$minor_version])
  32 AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version])
  33 AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [UST major version number])
  34 AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [UST minor version number])
  35 AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [UST patchlevel version number])
  36
  37 version_name="Annedd'ale"
  38 version_description="New type of beer, 100% from Quebec, flavored with sapin beaumier needles, with a touch of hops."
  39 AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], [UST version name])
  40 AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description"], [UST version description])
  41
  42 # Checks for programs.
  43 AC_PROG_CC
  44 AC_PROG_CXX
  45 AC_PROG_MAKE_SET
  46 LT_INIT
  47
  48 ## Checks for libraries.
  49 AC_CHECK_LIB([dl], [dlopen],
  50 [
  51         have_libdl=yes
  52 ],
  53 [
  54         #libdl not found, check for dlopen in libc.
  55         AC_CHECK_LIB([c], [dlopen],
  56         [
  57                 have_libc_dl=yes
  58         ],
  59         [
  60                 AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.])
  61         ])
  62 ])
  63 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"])
  64 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"])
  65
  66 AC_CHECK_LIB([pthread], [pthread_create])
  67
  68 # Check for libuuid
  69 AC_CHECK_LIB([uuid], [uuid_generate],
  70 [
  71         AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBUUID], 1, [Has libuuid support.])
  72         have_libuuid=yes
  73 ],
  74 [
  75         # libuuid not found, check for uuid_create in libc.
  76         AC_CHECK_LIB([c], [uuid_create],
  77         [
  78                 AC_DEFINE_UNQUOTED([LTTNG_UST_HAVE_LIBC_UUID], 1, [Has libc uuid support.])
  79                 have_libc_uuid=yes
  80         ],
  81         [
  82                 AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Use [LDFLAGS]=-Ldir to specify their location.])
  83         ])
  84 ]
  85 )
  86 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"])
  87 AM_CONDITIONAL([LTTNG_UST_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"])
  88
  89 # Checks for header files.
  90 #AC_CHECK_HEADERS([fcntl.h stdint.h stdlib.h string.h sys/socket.h sys/time.h unistd.h])
  91
  92 # Checks for typedefs, structures, and compiler characteristics.
  93 AC_C_INLINE
  94 #AC_TYPE_INT16_T
  95 #AC_TYPE_INT32_T
  96 #AC_TYPE_INT64_T
  97 #AC_TYPE_INT8_T
  98 #AC_TYPE_PID_T
  99 #AC_TYPE_SIZE_T
 100 #AC_TYPE_SSIZE_T
 101 #AC_TYPE_UINT16_T
 102 #AC_TYPE_UINT32_T
 103 #AC_TYPE_UINT64_T
 104 #AC_TYPE_UINT8_T
 105 #AC_CHECK_TYPES([ptrdiff_t])
 106
 107 # Checks for library functions.
 108 AC_FUNC_MALLOC
 109 AC_CHECK_FUNCS([gettimeofday munmap socket strerror strtol sched_getcpu sysconf])
 110
 111 CFLAGS="-Wall $CFLAGS"
 112
 113 # Check for texinfo, required for building the documentation
 114 # TODO: make this (and building the documentation) optional
 115 AC_CHECK_PROG([TEXINFO], [makeinfo], [yes])
 116 AS_IF([test "x$TEXINFO" != "xyes"],[
 117         AC_MSG_ERROR([Please install the 'texinfo' program and make sure 'makeinfo' is in the PATH.])
 118 ])
 119
 120 # URCU
 121
 122 # urcu - check if we just find the headers it out of the box.
 123 AC_CHECK_HEADERS([urcu-bp.h], [], [AC_MSG_ERROR([Cannot find [URCU] headers (urcu-bp.h). Use [CPPFLAGS]=-Idir to specify their location.
 124 This error can also occur when the liburcu package's configure script has not been run.])])
 125
 126 AC_MSG_CHECKING([caa_likely()])
 127 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 128 #include <urcu/compiler.h>
 129 void fct(void)
 130 {
 131         if (caa_likely(1)) {
 132         }
 133 }
 134 ]])],[
 135         AC_MSG_RESULT([yes])
 136 ],[
 137         AC_MSG_RESULT([no])
 138         AC_MSG_ERROR([Please upgrade your version of liburcu to 0.6.6 or better])
 139
 140 ])
 141
 142 # urcu - check that URCU lib is available to compilation
 143 AC_CHECK_LIB([urcu-bp], [synchronize_rcu_bp], [], [AC_MSG_ERROR([Cannot find liburcu-bp lib. Use [LDFLAGS]=-Ldir to specify its location.])])
 144
 145 # urcu - check that URCU lib is at least version 0.6
 146 AC_CHECK_LIB([urcu-bp], [call_rcu_bp], [], [AC_MSG_ERROR([liburcu 0.6 or newer is needed, please update your version or use [LDFLAGS]=-Ldir to specify the right location.])])
 147
 148
 149 # Check for various supplementary host information (beyond the
 150 # triplet) which might affect the library format choices.  E.g., we
 151 # can be building with `i686-unknown-linux-gnu-gcc -m64'
 152
 153 case "${host}" in
 154 changequote(,)dnl
 155   i[34567]86-*-linux*)
 156 changequote([,])dnl
 157     AC_CACHE_CHECK([if building for x86-64], [ust_cv_i386_is_x86_64],
 158                     [save_CPPFLAGS="$CPPFLAGS"
 159                     CPPFLAGS="$CPPFLAGS $CFLAGS"
 160                     AC_EGREP_CPP([got it], [
 161 #if __x86_64__
 162 got it
 163 #endif
 164                  ], [ust_cv_i386_is_x86_64=yes],
 165                     [ust_cv_i386_is_x86_64=no])
 166                     CPPFLAGS="$save_CPPFLAGS"])
 167     ;;
 168 esac
 169
 170 AC_MSG_CHECKING([library format for the host system])
 171 case $host_cpu in
 172 changequote(,)dnl
 173         i[3456]86)
 174 changequote([,])dnl
 175           if test "$ust_cv_i386_is_x86_64" = yes ; then
 176              LIBFORMAT="elf64-x86-64"
 177           else
 178              LIBFORMAT="elf32-i386"
 179           fi
 180           ;;
 181         x86_64) LIBFORMAT="elf64-x86-64" ;;
 182         amd64) LIBFORMAT="elf64-x86-64" ;;
 183         powerpc) LIBFORMAT="elf32-powerpc" ;;
 184         ppc64) LIBFORMAT="elf64-powerpc" ;;
 185         powerpc64) LIBFORMAT="elf64-powerpc" ;;
 186         s390) LIBFORMAT="elf32-s390"; NO_UNALIGNED_ACCESS=1 ;;
 187         s390x) LIBFORMAT="elf64-s390"; NO_UNALIGNED_ACCESS=1 ;;
 188         armv5) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 189         arm) LIBFORMAT="elf32-littlearm"; NO_UNALIGNED_ACCESS=1 ;;
 190         mips*) LIBFORMAT=""; NO_UNALIGNED_ACCESS=1;;
 191         *) AC_MSG_ERROR([unable to detect library format (unsupported architecture ($host_cpu)?)]) ;;
 192 esac
 193 AC_SUBST(LIBFORMAT)
 194 AC_MSG_RESULT($LIBFORMAT)
 195
 196 if test "x$host_cpu" = "xarm" ; then
 197 AC_MSG_CHECKING([checking for armv5])
 198 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 199 #ifndef __ARM_ARCH_5TEJ__
 200 #error "no arm5 here"
 201 #endif
 202 ]])],[
 203         AC_MSG_RESULT([yes])
 204         NO_UNALIGNED_ACCESS=1
 205
 206 ],[
 207         AC_MSG_RESULT([no])
 208
 209 ])
 210 fi
 211 if test x$NO_UNALIGNED_ACCESS = x ; then
 212 AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1])
 213 fi
 214
 215 # Set compile flags to java include files if given
 216 AC_ARG_WITH([java-jdk],
 217         [AS_HELP_STRING([--with-java-jdk=DIR],[use the Java JDK in DIR. Ex : $JAVA_HOME.])],
 218         [JAVA_JDK=$withval],
 219         [JAVA_JDK=""]
 220 )
 221 AS_IF([test $JAVA_JDK],[
 222         AS_IF([test -d $JAVA_JDK],[
 223                 AC_MSG_RESULT([using Java includes in $JAVA_SDK])
 224                 SUBDIRS=`find $JAVA_JDK/include -type d`
 225                 CPPFLAGS+=" "
 226                 CPPFLAGS+=`for x in $SUBDIRS; do echo -n "-I$x "; done`
 227                 CPPFLAGS+=" "
 228         ],[
 229                 AC_MSG_ERROR(Unable to find Java include files in $JAVA_JDK)
 230         ])
 231 ])
 232
 233 # Check for JNI header files if requested
 234 AC_ARG_WITH([jni-interface],
 235         [AS_HELP_STRING([--with-jni-interface],[build JNI interface between C and Java. Needs Java include files [default=no]])],
 236         [jni_interface=$withval],
 237         [jni_interface=no]
 238 )
 239
 240 AS_IF([test "x$jni_interface" = "xyes"],[
 241         AC_CHECK_HEADERS([jni.h],[],[
 242         AC_MSG_ERROR([missing jni.h
 243 Make sure Sun Java, OpenJDK or GCJ is installed and that this header file exists in the system path.
 244 Use the --with-java-jdk=DIR flag to point to your Java include files, or disable the JNI interface.])
 245         ])
 246 ])
 247 AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"])
 248
 249 # sdt.h integration
 250 AC_ARG_WITH([sdt],
 251         [AS_HELP_STRING([--with-sdt],[provide SystemTap integration via sdt.h [default=no]])],
 252         [with_sdt=$withval],
 253         [with_sdt="no"]
 254 )
 255
 256 AS_IF([test "x$with_sdt" = "xyes"],[
 257         AC_MSG_CHECKING([STAP_PROBEV()])
 258         AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 259         #define SDT_USE_VARIADIC
 260         #include <sys/sdt.h>
 261         void fct(void)
 262         {
 263                 STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10);
 264         }
 265         ]])],[
 266                 AC_MSG_RESULT([yes])
 267                 AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1])
 268         ],[
 269                 AC_MSG_RESULT([no])
 270                 AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h])
 271         ])
 272 ])
 273
 274 #currently disabled.
 275         #tests/hello2/Makefile
 276         #tests/basic/Makefile
 277         #tests/simple_include/Makefile
 278         #tests/snprintf/Makefile
 279         #tests/test-nevents/Makefile
 280         #tests/test-libustinstr-malloc/Makefile
 281         #tests/dlopen/Makefile
 282         #tests/same_line_marker/Makefile
 283         #tests/trace_event/Makefile
 284         #tests/tracepoint/Makefile
 285         #tests/tracepoint/benchmark/Makefile
 286         #tests/register_test/Makefile
 287         #tests/libustctl_function_#tests/Makefile
 288         #tests/exit-fast/Makefile
 289         #tests/basic_long/Makefile
 290
 291 AC_CONFIG_FILES([
 292         Makefile
 293         doc/Makefile
 294         doc/examples/Makefile
 295         include/Makefile
 296         include/lttng/ust-version.h
 297         snprintf/Makefile
 298         libringbuffer/Makefile
 299         liblttng-ust-comm/Makefile
 300         liblttng-ust/Makefile
 301         liblttng-ust-ctl/Makefile
 302         liblttng-ust-fork/Makefile
 303         liblttng-ust-java/Makefile
 304         liblttng-ust-libc-wrapper/Makefile
 305         tools/Makefile
 306         tests/Makefile
 307         tests/hello/Makefile
 308         tests/hello-static-lib/Makefile
 309         tests/hello.cxx/Makefile
 310         tests/demo/Makefile
 311         tests/fork/Makefile
 312         tests/ust-basic-tracing/Makefile
 313         tests/ust-multi-test/Makefile
 314         lttng-ust.pc
 315 ])
 316
 317 AC_OUTPUT
 318
 319 AS_ECHO()
 320 AS_ECHO("Version name: $version_name")
 321 AS_ECHO("$version_description")
 322
 323 # Report on the configuration options
 324 AS_ECHO()
 325 AS_ECHO("LTTng-UST will be built with the following options:")
 326 AS_ECHO("Library format: $LIBFORMAT")
 327
 328 AS_ECHO()
 329 AS_ECHO_N("Java support (JNI): ")
 330 AS_IF([test "x$jni_interface" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 331
 332 AS_ECHO_N("sdt.h integration:  ")
 333 AS_IF([test "x$with_sdt" = "xyes"], [AS_ECHO("Enabled")], [AS_ECHO("Disabled")])
 334
 335 AS_ECHO()
 336 AS_ECHO("Type 'make' to compile.")
 337