| 1 | /** |
| 2 | * Copyright (C) 2016-2018 - Michael Jeanson <mjeanson@efficios.com> |
| 3 | * |
| 4 | * This program is free software: you can redistribute it and/or modify |
| 5 | * it under the terms of the GNU General Public License as published by |
| 6 | * the Free Software Foundation, either version 3 of the License, or |
| 7 | * (at your option) any later version. |
| 8 | * |
| 9 | * This program is distributed in the hope that it will be useful, |
| 10 | * but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 11 | * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 12 | * GNU General Public License for more details. |
| 13 | * |
| 14 | * You should have received a copy of the GNU General Public License |
| 15 | * along with this program. If not, see <http://www.gnu.org/licenses/>. |
| 16 | */ |
| 17 | |
| 18 | import hudson.model.* |
| 19 | import hudson.AbortException |
| 20 | import hudson.console.HyperlinkNote |
| 21 | import java.util.concurrent.CancellationException |
| 22 | import org.eclipse.jgit.api.Git |
| 23 | import org.eclipse.jgit.lib.Ref |
| 24 | |
| 25 | |
| 26 | class InvalidKVersionException extends Exception { |
| 27 | public InvalidKVersionException(String message) { |
| 28 | super(message) |
| 29 | } |
| 30 | } |
| 31 | |
| 32 | class EmptyKVersionException extends Exception { |
| 33 | public EmptyKVersionException(String message) { |
| 34 | super(message) |
| 35 | } |
| 36 | } |
| 37 | |
| 38 | class RTKVersion implements Comparable<RTKVersion> { |
| 39 | |
| 40 | Integer major = 0 |
| 41 | Integer majorB = 0 |
| 42 | Integer minor = 0 |
| 43 | Integer patch = 0 |
| 44 | Integer rt = 0 |
| 45 | |
| 46 | RTKVersion() {} |
| 47 | |
| 48 | RTKVersion(version) { |
| 49 | this.parse(version) |
| 50 | } |
| 51 | |
| 52 | static RTKVersion minKVersion() { |
| 53 | return new RTKVersion("v0.0.0-rt0-rebase") |
| 54 | } |
| 55 | |
| 56 | static RTKVersion maxKVersion() { |
| 57 | return new RTKVersion("v" + Integer.MAX_VALUE + ".0.0-rt0-rebase") |
| 58 | } |
| 59 | |
| 60 | static RTKVersion factory(version) { |
| 61 | return new RTKVersion(version) |
| 62 | } |
| 63 | |
| 64 | def parse(version) { |
| 65 | this.major = 0 |
| 66 | this.majorB = 0 |
| 67 | this.minor = 0 |
| 68 | this.patch = 0 |
| 69 | this.rt = 0 |
| 70 | |
| 71 | if (!version) { |
| 72 | throw new EmptyKVersionException("Empty kernel version") |
| 73 | } |
| 74 | |
| 75 | def match = version =~ /^v(\d+)\.(\d+)(\.(\d+))?(\.(\d+))?(-rt(\d+)-rebase)$/ |
| 76 | if (!match) { |
| 77 | throw new InvalidKVersionException("Invalid kernel version: ${version}") |
| 78 | } |
| 79 | |
| 80 | Integer offset = 0; |
| 81 | |
| 82 | // Major |
| 83 | this.major = Integer.parseInt(match.group(1)) |
| 84 | if (this.major <= 2) { |
| 85 | offset = 2 |
| 86 | this.majorB = Integer.parseInt(match.group(2)) |
| 87 | } |
| 88 | |
| 89 | // Minor |
| 90 | if (match.group(2 + offset) != null) { |
| 91 | this.minor = Integer.parseInt(match.group(2 + offset)) |
| 92 | } |
| 93 | |
| 94 | // Patch level |
| 95 | if (match.group(4 + offset) != null) { |
| 96 | this.patch = Integer.parseInt(match.group(4 + offset)) |
| 97 | } |
| 98 | |
| 99 | // RT |
| 100 | this.rt = Integer.parseInt(match.group(8)) |
| 101 | } |
| 102 | |
| 103 | // Return true if both version are of the same stable branch |
| 104 | Boolean isSameStable(RTKVersion o) { |
| 105 | if (this.major != o.major) { |
| 106 | return false |
| 107 | } |
| 108 | if (this.majorB != o.majorB) { |
| 109 | return false |
| 110 | } |
| 111 | if (this.minor != o.minor) { |
| 112 | return false |
| 113 | } |
| 114 | |
| 115 | return true |
| 116 | } |
| 117 | |
| 118 | @Override int compareTo(RTKVersion o) { |
| 119 | if (this.major != o.major) { |
| 120 | return Integer.compare(this.major, o.major) |
| 121 | } |
| 122 | if (this.majorB != o.majorB) { |
| 123 | return Integer.compare(this.majorB, o.majorB) |
| 124 | } |
| 125 | if (this.minor != o.minor) { |
| 126 | return Integer.compare(this.minor, o.minor) |
| 127 | } |
| 128 | if (this.patch != o.patch) { |
| 129 | return Integer.compare(this.patch, o.patch) |
| 130 | } |
| 131 | if (this.rt != o.rt) { |
| 132 | return Integer.compare(this.rt, o.rt) |
| 133 | } |
| 134 | |
| 135 | // Same version |
| 136 | return 0; |
| 137 | } |
| 138 | |
| 139 | String toString() { |
| 140 | String vString = "v${this.major}" |
| 141 | |
| 142 | if (this.majorB > 0) { |
| 143 | vString = vString.concat(".${this.majorB}") |
| 144 | } |
| 145 | |
| 146 | vString = vString.concat(".${this.minor}") |
| 147 | |
| 148 | if (this.patch > 0) { |
| 149 | vString = vString.concat(".${this.patch}") |
| 150 | } |
| 151 | |
| 152 | if (this.rt > 0) { |
| 153 | vString = vString.concat("-rt${this.rt}-rebase") |
| 154 | } |
| 155 | return vString |
| 156 | } |
| 157 | } |
| 158 | |
| 159 | |
| 160 | // Retrieve parameters of the current build |
| 161 | def mbranch = build.getEnvironment(listener).get('GIT_BRANCH').minus('origin/') |
| 162 | def maxConcurrentBuild = build.buildVariableResolver.resolve('maxConcurrentBuild') |
| 163 | def kgitrepo = build.buildVariableResolver.resolve('kgitrepo') |
| 164 | def kverfloor_raw = build.buildVariableResolver.resolve('kverfloor') |
| 165 | def kverceil_raw = build.buildVariableResolver.resolve('kverceil') |
| 166 | def kverfilter = build.buildVariableResolver.resolve('kverfilter') |
| 167 | def job = Hudson.instance.getJob(build.buildVariableResolver.resolve('kbuildjob')) |
| 168 | def currentJobName = build.project.getFullDisplayName() |
| 169 | def gitmodpath = build.getEnvironment(listener).get('WORKSPACE') + "/src/lttng-modules" |
| 170 | |
| 171 | // Get the out variable |
| 172 | def config = new HashMap() |
| 173 | def bindings = getBinding() |
| 174 | config.putAll(bindings.getVariables()) |
| 175 | def out = config['out'] |
| 176 | |
| 177 | |
| 178 | // Get the lttng-modules git url |
| 179 | def gitmodrepo = Git.open(new File(gitmodpath)) |
| 180 | def mgitrepo = gitmodrepo.getRepository().getConfig().getString("remote", "origin", "url") |
| 181 | |
| 182 | // Get tags from git repository |
| 183 | def refs = Git.lsRemoteRepository().setTags(true).setRemote(kgitrepo).call() |
| 184 | |
| 185 | // Get kernel versions to build |
| 186 | def kversions = [] |
| 187 | def tagMatchStrs = [ |
| 188 | ~/^refs\/tags\/(v[\d\.]+(-rt(\d+)-rebase))$/, |
| 189 | ] |
| 190 | def blacklist = [ |
| 191 | ~/v4\.11\.8-rt5-rebase/, |
| 192 | ~/v4\.11\.9-rt6-rebase/, |
| 193 | ~/v4\.11\.9-rt7-rebase/, |
| 194 | ~/v4\.11\.12-rt8-rebase/, |
| 195 | ~/v4\.11\.12-rt9-rebase/, |
| 196 | ~/v4\.11\.12-rt10-rebase/, |
| 197 | ~/v4\.11\.12-rt11-rebase/, |
| 198 | ~/v4\.11\.12-rt12-rebase/, |
| 199 | ~/v4\.11\.12-rt13-rebase/, |
| 200 | ~/v3\.6.*-rebase/, |
| 201 | ~/v3\.8.*-rebase/, |
| 202 | ] |
| 203 | |
| 204 | def kversionFactory = new RTKVersion() |
| 205 | |
| 206 | // Parse kernel versions |
| 207 | def kverfloor = "" |
| 208 | try { |
| 209 | kverfloor = kversionFactory.factory(kverfloor_raw) |
| 210 | } catch (EmptyKVersionException e) { |
| 211 | kverfloor = kversionFactory.minKVersion() |
| 212 | } |
| 213 | |
| 214 | def kverceil = "" |
| 215 | try { |
| 216 | kverceil = kversionFactory.factory(kverceil_raw) |
| 217 | } catch (EmptyKVersionException e) { |
| 218 | kverceil = kversionFactory.maxKVersion() |
| 219 | } |
| 220 | |
| 221 | // Build a sorted list of versions to build |
| 222 | for (ref in refs) { |
| 223 | for (tagMatchStr in tagMatchStrs) { |
| 224 | def tagMatch = ref.getName() =~ tagMatchStr |
| 225 | |
| 226 | if (tagMatch) { |
| 227 | def kversion_raw = tagMatch.group(1) |
| 228 | def blacklisted = false |
| 229 | |
| 230 | // Check if the kversion is blacklisted |
| 231 | for (blackMatchStr in blacklist) { |
| 232 | def blackMatch = kversion_raw =~ blackMatchStr |
| 233 | |
| 234 | if (blackMatch) { |
| 235 | blacklisted = true |
| 236 | break; |
| 237 | } |
| 238 | } |
| 239 | |
| 240 | if (!blacklisted) { |
| 241 | def v = kversionFactory.factory(kversion_raw) |
| 242 | |
| 243 | if ((v >= kverfloor) && (v < kverceil)) { |
| 244 | kversions.add(v) |
| 245 | } |
| 246 | } |
| 247 | } |
| 248 | } |
| 249 | } |
| 250 | |
| 251 | kversions.sort() |
| 252 | |
| 253 | //println "Pre filtering kernel versions:" |
| 254 | //for (k in kversions) { |
| 255 | // println k |
| 256 | //} |
| 257 | |
| 258 | switch (kverfilter) { |
| 259 | case 'stable-head': |
| 260 | // Keep only the head of each stable branch |
| 261 | println('Filter kernel versions to keep only the latest point release of each stable branch.') |
| 262 | |
| 263 | for (i = 0; i < kversions.size(); i++) { |
| 264 | def curr = kversions[i] |
| 265 | def next = i < kversions.size() - 1 ? kversions[i + 1] : null |
| 266 | |
| 267 | if (next != null) { |
| 268 | if (curr.isSameStable(next)) { |
| 269 | kversions.remove(i) |
| 270 | i-- |
| 271 | } |
| 272 | } |
| 273 | } |
| 274 | break |
| 275 | |
| 276 | default: |
| 277 | // No filtering of kernel versions |
| 278 | println('No kernel versions filtering selected.') |
| 279 | break |
| 280 | } |
| 281 | |
| 282 | |
| 283 | println "Building the following kernel versions:" |
| 284 | for (k in kversions) { |
| 285 | println k |
| 286 | } |
| 287 | |
| 288 | // Debug: Stop build here |
| 289 | //throw new InterruptedException() |
| 290 | |
| 291 | def joburl = HyperlinkNote.encodeTo('/' + job.url, job.fullDisplayName) |
| 292 | |
| 293 | def allBuilds = [] |
| 294 | def ongoingBuild = [] |
| 295 | def failedRuns = [] |
| 296 | def isFailed = false |
| 297 | def similarJobQueued = 0; |
| 298 | |
| 299 | // Loop while we have kernel versions remaining or jobs running |
| 300 | while ( kversions.size() != 0 || ongoingBuild.size() != 0 ) { |
| 301 | |
| 302 | if(ongoingBuild.size() < maxConcurrentBuild.toInteger() && kversions.size() != 0) { |
| 303 | def kversion = kversions.pop() |
| 304 | def job_params = [ |
| 305 | new StringParameterValue('mversion', mbranch), |
| 306 | new StringParameterValue('mgitrepo', mgitrepo), |
| 307 | new StringParameterValue('ktag', kversion.toString()), |
| 308 | new StringParameterValue('kgitrepo', kgitrepo), |
| 309 | ] |
| 310 | |
| 311 | // Launch the parametrized build |
| 312 | def param_build = job.scheduleBuild2(0, new Cause.UpstreamCause(build), new ParametersAction(job_params)) |
| 313 | println "triggering ${joburl} for the ${mbranch} branch on kernel ${kversion}" |
| 314 | |
| 315 | // Add it to the ongoing build queue |
| 316 | ongoingBuild.push(param_build) |
| 317 | |
| 318 | } else { |
| 319 | |
| 320 | println "Waiting... Queued: " + kversions.size() + " Running: " + ongoingBuild.size() |
| 321 | try { |
| 322 | Thread.sleep(10000) |
| 323 | } catch(e) { |
| 324 | if (e in InterruptedException) { |
| 325 | build.setResult(hudson.model.Result.ABORTED) |
| 326 | throw new InterruptedException() |
| 327 | } else { |
| 328 | throw(e) |
| 329 | } |
| 330 | } |
| 331 | |
| 332 | // Abort job if a newer instance is queued |
| 333 | similarJobQueued = Hudson.instance.queue.items.count{it.task.getFullDisplayName() == currentJobName} |
| 334 | if ( similarJobQueued > 0 ) { |
| 335 | build.setResult(hudson.model.Result.ABORTED) |
| 336 | throw new InterruptedException() |
| 337 | } |
| 338 | |
| 339 | def i = ongoingBuild.iterator() |
| 340 | while ( i.hasNext() ) { |
| 341 | currentBuild = i.next() |
| 342 | if ( currentBuild.isCancelled() || currentBuild.isDone() ) { |
| 343 | // Remove from queue |
| 344 | i.remove() |
| 345 | |
| 346 | // Print results |
| 347 | def matrixParent = currentBuild.get() |
| 348 | allBuilds.add(matrixParent) |
| 349 | def kernelStr = matrixParent.buildVariableResolver.resolve("ktag") |
| 350 | println "${matrixParent.fullDisplayName} (${kernelStr}) completed with status ${matrixParent.result}" |
| 351 | |
| 352 | // Process child runs of matrixBuild |
| 353 | def childRuns = matrixParent.getRuns() |
| 354 | for ( childRun in childRuns ) { |
| 355 | println "\t${childRun.fullDisplayName} (${kernelStr}) completed with status ${childRun.result}" |
| 356 | if (childRun.result != Result.SUCCESS) { |
| 357 | failedRuns.add(childRun) |
| 358 | isFailed = true |
| 359 | } |
| 360 | } |
| 361 | } |
| 362 | } |
| 363 | } |
| 364 | } |
| 365 | |
| 366 | // Get log of failed runs |
| 367 | for (failedRun in failedRuns) { |
| 368 | println "---START---" |
| 369 | failedRun.writeWholeLogTo(out) |
| 370 | println "---END---" |
| 371 | } |
| 372 | |
| 373 | println "---Build report---" |
| 374 | for (b in allBuilds) { |
| 375 | def kernelStr = b.buildVariableResolver.resolve("ktag") |
| 376 | println "${b.fullDisplayName} (${kernelStr}) completed with status ${b.result}" |
| 377 | // Cleanup builds |
| 378 | try { |
| 379 | b.delete() |
| 380 | } catch (all) {} |
| 381 | } |
| 382 | |
| 383 | // Mark this build failed if any child build has failed |
| 384 | if (isFailed) { |
| 385 | build.setResult(hudson.model.Result.FAILURE) |
| 386 | } |
| 387 | |
| 388 | // EOF |