| 1 | /* |
| 2 | * urcu_mbmin.spin: Promela code to validate urcu. See commit number |
| 3 | * 3a9e6e9df706b8d39af94d2f027210e2e7d4106e of Mathieu Desnoyer's |
| 4 | * git archive at git://lttng.org/userspace-rcu.git, but with |
| 5 | * memory barriers removed. |
| 6 | * |
| 7 | * This validates a single reader against a single updater. The |
| 8 | * updater is assumed to have smp_mb() barriers between each pair |
| 9 | * of operations, and this model validates that a signal-mediated |
| 10 | * broadcast barrier is required only at the beginning and end of |
| 11 | * the synchronize_rcu(). |
| 12 | * |
| 13 | * Note that the second half of a prior synchronize_rcu() is modelled |
| 14 | * as well as the current synchronize_rcu(). |
| 15 | * |
| 16 | * This program is free software; you can redistribute it and/or modify |
| 17 | * it under the terms of the GNU General Public License as published by |
| 18 | * the Free Software Foundation; either version 2 of the License, or |
| 19 | * (at your option) any later version. |
| 20 | * |
| 21 | * This program is distributed in the hope that it will be useful, |
| 22 | * but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 23 | * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 24 | * GNU General Public License for more details. |
| 25 | * |
| 26 | * You should have received a copy of the GNU General Public License |
| 27 | * along with this program; if not, write to the Free Software |
| 28 | * Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. |
| 29 | * |
| 30 | * Copyright (c) 2009 Paul E. McKenney, IBM Corporation. |
| 31 | */ |
| 32 | |
| 33 | /* Promela validation variables. */ |
| 34 | |
| 35 | bit removed = 0; /* Has RCU removal happened, e.g., list_del_rcu()? */ |
| 36 | bit free = 0; /* Has RCU reclamation happened, e.g., kfree()? */ |
| 37 | bit need_mb = 0; /* =1 says need reader mb, =0 for reader response. */ |
| 38 | byte reader_progress[4]; /* Count of read-side statement executions. */ |
| 39 | bit reader_done = 0; /* =0 says reader still running, =1 says done. */ |
| 40 | bit updater_done = 0; /* =0 says updater still running, =1 says done. */ |
| 41 | |
| 42 | /* Broadcast memory barriers to enable, prior synchronize_rcu() instance. */ |
| 43 | |
| 44 | /* #define MB_A */ /* Not required for correctness. */ |
| 45 | /* #define MB_B */ /* Not required for correctness. */ |
| 46 | /* #define MB_C */ /* Not required for correctness. */ |
| 47 | |
| 48 | /* Broadcast memory barriers to enable, current synchronize_rcu() instance. */ |
| 49 | |
| 50 | #define MB_D /* First broadcast barrier in synchronize_rcu(). */ |
| 51 | /* #define MB_E */ /* Not required for correctness. */ |
| 52 | /* #define MB_F */ /* Not required for correctness. */ |
| 53 | #define MB_G /* Last broadcast barrier in synchronize_rcu(). */ |
| 54 | |
| 55 | /* urcu definitions and variables, taken straight from the algorithm. */ |
| 56 | |
| 57 | #define RCU_GP_CTR_BIT (1 << 7) |
| 58 | #define RCU_GP_CTR_NEST_MASK (RCU_GP_CTR_BIT - 1) |
| 59 | |
| 60 | byte urcu_gp_ctr = 1; |
| 61 | byte urcu_active_readers = 0; |
| 62 | |
| 63 | /* Model the RCU read-side critical section. */ |
| 64 | |
| 65 | proctype urcu_reader() |
| 66 | { |
| 67 | bit done = 0; |
| 68 | bit mbok; |
| 69 | byte tmp; |
| 70 | byte tmp_removed; |
| 71 | byte tmp_free; |
| 72 | |
| 73 | /* Absorb any early requests for memory barriers. */ |
| 74 | do |
| 75 | :: need_mb == 1 -> |
| 76 | need_mb = 0; |
| 77 | :: 1 -> break; |
| 78 | od; |
| 79 | |
| 80 | /* |
| 81 | * Each pass through this loop executes one read-side statement |
| 82 | * from the following code fragment: |
| 83 | * |
| 84 | * rcu_read_lock(); [0a] |
| 85 | * rcu_read_lock(); [0b] |
| 86 | * p = rcu_dereference(global_p); [1] |
| 87 | * x = p->data; [2] |
| 88 | * rcu_read_unlock(); [3b] |
| 89 | * rcu_read_unlock(); [3a] |
| 90 | * |
| 91 | * Because we are modeling a weak-memory machine, these statements |
| 92 | * can be seen in any order, the only restriction being that |
| 93 | * rcu_read_unlock() cannot precede the corresponding rcu_read_lock(). |
| 94 | * The placement of the inner rcu_read_lock() and rcu_read_unlock() |
| 95 | * is non-deterministic, the above is but one possible placement. |
| 96 | * Intestingly enough, this model validates all possible placements |
| 97 | * of the inner rcu_read_lock() and rcu_read_unlock() statements, |
| 98 | * with the only constraint being that the rcu_read_lock() must |
| 99 | * precede the rcu_read_unlock(). |
| 100 | * |
| 101 | * We also respond to memory-barrier requests, but only if our |
| 102 | * execution happens to be ordered. If the current state is |
| 103 | * misordered, we ignore memory-barrier requests. |
| 104 | */ |
| 105 | do |
| 106 | :: 1 -> |
| 107 | if |
| 108 | :: reader_progress[0] < 2 -> /* [0a and 0b] */ |
| 109 | tmp = urcu_active_readers; |
| 110 | if |
| 111 | :: (tmp & RCU_GP_CTR_NEST_MASK) == 0 -> |
| 112 | tmp = urcu_gp_ctr; |
| 113 | do |
| 114 | :: (reader_progress[1] + |
| 115 | reader_progress[2] + |
| 116 | reader_progress[3] == 0) && need_mb == 1 -> |
| 117 | need_mb = 0; |
| 118 | :: need_mb == 0 && !updater_done -> skip; |
| 119 | :: 1 -> break; |
| 120 | od; |
| 121 | urcu_active_readers = tmp; |
| 122 | :: else -> |
| 123 | urcu_active_readers = tmp + 1; |
| 124 | fi; |
| 125 | reader_progress[0] = reader_progress[0] + 1; |
| 126 | :: reader_progress[1] == 0 -> /* [1] */ |
| 127 | tmp_removed = removed; |
| 128 | reader_progress[1] = 1; |
| 129 | :: reader_progress[2] == 0 -> /* [2] */ |
| 130 | tmp_free = free; |
| 131 | reader_progress[2] = 1; |
| 132 | :: ((reader_progress[0] > reader_progress[3]) && |
| 133 | (reader_progress[3] < 2)) -> /* [3a and 3b] */ |
| 134 | tmp = urcu_active_readers - 1; |
| 135 | urcu_active_readers = tmp; |
| 136 | reader_progress[3] = reader_progress[3] + 1; |
| 137 | :: else -> break; |
| 138 | fi; |
| 139 | |
| 140 | /* Process memory-barrier requests, if it is safe to do so. */ |
| 141 | atomic { |
| 142 | mbok = 0; |
| 143 | tmp = 0; |
| 144 | do |
| 145 | :: tmp < 4 && reader_progress[tmp] == 0 -> |
| 146 | tmp = tmp + 1; |
| 147 | break; |
| 148 | :: tmp < 4 && reader_progress[tmp] != 0 -> |
| 149 | tmp = tmp + 1; |
| 150 | :: tmp >= 4 && |
| 151 | reader_progress[0] == reader_progress[3] -> |
| 152 | done = 1; |
| 153 | break; |
| 154 | :: tmp >= 4 && |
| 155 | reader_progress[0] != reader_progress[3] -> |
| 156 | break; |
| 157 | od; |
| 158 | do |
| 159 | :: tmp < 4 && reader_progress[tmp] == 0 -> |
| 160 | tmp = tmp + 1; |
| 161 | :: tmp < 4 && reader_progress[tmp] != 0 -> |
| 162 | break; |
| 163 | :: tmp >= 4 -> |
| 164 | mbok = 1; |
| 165 | break; |
| 166 | od |
| 167 | |
| 168 | } |
| 169 | |
| 170 | if |
| 171 | :: mbok == 1 -> |
| 172 | /* We get here if mb processing is safe. */ |
| 173 | do |
| 174 | :: need_mb == 1 -> |
| 175 | need_mb = 0; |
| 176 | :: 1 -> break; |
| 177 | od; |
| 178 | :: else -> skip; |
| 179 | fi; |
| 180 | |
| 181 | /* |
| 182 | * Check to see if we have modeled the entire RCU read-side |
| 183 | * critical section, and leave if so. |
| 184 | */ |
| 185 | if |
| 186 | :: done == 1 -> break; |
| 187 | :: else -> skip; |
| 188 | fi |
| 189 | od; |
| 190 | assert((tmp_free == 0) || (tmp_removed == 1)); |
| 191 | |
| 192 | /* Reader has completed. */ |
| 193 | reader_done = 1; |
| 194 | |
| 195 | /* |
| 196 | * Process any late-arriving memory-barrier requests, and |
| 197 | * in addition create a progress cycle. |
| 198 | */ |
| 199 | reader_done = 1; |
| 200 | |
| 201 | do |
| 202 | :: need_mb == 1 -> |
| 203 | need_mb = 0; |
| 204 | :: 1 -> |
| 205 | progress_reader: |
| 206 | skip; |
| 207 | :: 1 -> break; |
| 208 | od; |
| 209 | } |
| 210 | |
| 211 | /* Model the RCU update process. */ |
| 212 | |
| 213 | proctype urcu_updater() |
| 214 | { |
| 215 | byte tmp; |
| 216 | |
| 217 | /* |
| 218 | * ---------------------------------------------------------------- |
| 219 | * prior synchronize_rcu(). |
| 220 | */ |
| 221 | |
| 222 | /* prior synchronize_rcu(), second counter flip. */ |
| 223 | #ifdef MB_A |
| 224 | need_mb = 1; /* mb() A (analogous to omitted barrier between E and F) */ |
| 225 | do |
| 226 | :: need_mb == 1 && !reader_done -> skip; |
| 227 | :: need_mb == 0 || reader_done -> break; |
| 228 | od; |
| 229 | #endif /* #ifdef MB_A */ |
| 230 | urcu_gp_ctr = urcu_gp_ctr + RCU_GP_CTR_BIT; |
| 231 | #ifdef MB_B |
| 232 | need_mb = 1; /* mb() B (analogous to F) */ |
| 233 | do |
| 234 | :: need_mb == 1 && !reader_done -> skip; |
| 235 | :: need_mb == 0 || reader_done -> break; |
| 236 | od; |
| 237 | #endif /* #ifdef MB_B */ |
| 238 | do |
| 239 | :: 1 -> |
| 240 | if |
| 241 | :: (urcu_active_readers & RCU_GP_CTR_NEST_MASK) != 0 && |
| 242 | (urcu_active_readers & ~RCU_GP_CTR_NEST_MASK) != |
| 243 | (urcu_gp_ctr & ~RCU_GP_CTR_NEST_MASK) -> |
| 244 | skip; |
| 245 | :: else -> break; |
| 246 | fi |
| 247 | od; |
| 248 | #ifdef MB_C |
| 249 | need_mb = 1; /* mb() C absolutely required by analogy with G */ |
| 250 | do |
| 251 | :: need_mb == 1 && !reader_done -> skip; |
| 252 | :: need_mb == 0 || reader_done -> break; |
| 253 | od; |
| 254 | #endif /* #ifdef MB_C */ |
| 255 | |
| 256 | /* Removal statement, e.g., list_del_rcu(). */ |
| 257 | removed = 1; |
| 258 | |
| 259 | /* |
| 260 | * prior synchronize_rcu(). |
| 261 | * ---------------------------------------------------------------- |
| 262 | */ |
| 263 | |
| 264 | /* |
| 265 | * ---------------------------------------------------------------- |
| 266 | * current synchronize_rcu(). |
| 267 | */ |
| 268 | |
| 269 | /* current synchronize_rcu(), first counter flip. */ |
| 270 | #ifdef MB_D |
| 271 | need_mb = 1; /* mb() D suggested */ |
| 272 | do |
| 273 | :: need_mb == 1 && !reader_done -> skip; |
| 274 | :: need_mb == 0 || reader_done -> break; |
| 275 | od; |
| 276 | #endif /* #ifdef MB_D */ |
| 277 | urcu_gp_ctr = urcu_gp_ctr + RCU_GP_CTR_BIT; |
| 278 | #ifdef MB_E |
| 279 | need_mb = 1; /* mb() E required if D not present */ |
| 280 | do |
| 281 | :: need_mb == 1 && !reader_done -> skip; |
| 282 | :: need_mb == 0 || reader_done -> break; |
| 283 | od; |
| 284 | #endif /* #ifdef MB_E */ |
| 285 | |
| 286 | /* current synchronize_rcu(), first-flip check plus second flip. */ |
| 287 | if |
| 288 | :: 1 -> |
| 289 | do |
| 290 | :: 1 -> |
| 291 | if |
| 292 | :: (urcu_active_readers & RCU_GP_CTR_NEST_MASK) != 0 && |
| 293 | (urcu_active_readers & ~RCU_GP_CTR_NEST_MASK) != |
| 294 | (urcu_gp_ctr & ~RCU_GP_CTR_NEST_MASK) -> |
| 295 | skip; |
| 296 | :: else -> break; |
| 297 | fi; |
| 298 | od; |
| 299 | urcu_gp_ctr = urcu_gp_ctr + RCU_GP_CTR_BIT; |
| 300 | :: 1 -> |
| 301 | tmp = urcu_gp_ctr; |
| 302 | urcu_gp_ctr = urcu_gp_ctr + RCU_GP_CTR_BIT; |
| 303 | do |
| 304 | :: 1 -> |
| 305 | if |
| 306 | :: (urcu_active_readers & RCU_GP_CTR_NEST_MASK) != 0 && |
| 307 | (urcu_active_readers & ~RCU_GP_CTR_NEST_MASK) != |
| 308 | (tmp & ~RCU_GP_CTR_NEST_MASK) -> |
| 309 | skip; |
| 310 | :: else -> break; |
| 311 | fi; |
| 312 | od; |
| 313 | fi; |
| 314 | |
| 315 | /* current synchronize_rcu(), second counter flip check. */ |
| 316 | #ifdef MB_F |
| 317 | need_mb = 1; /* mb() F not required */ |
| 318 | do |
| 319 | :: need_mb == 1 && !reader_done -> skip; |
| 320 | :: need_mb == 0 || reader_done -> break; |
| 321 | od; |
| 322 | #endif /* #ifdef MB_F */ |
| 323 | do |
| 324 | :: 1 -> |
| 325 | if |
| 326 | :: (urcu_active_readers & RCU_GP_CTR_NEST_MASK) != 0 && |
| 327 | (urcu_active_readers & ~RCU_GP_CTR_NEST_MASK) != |
| 328 | (urcu_gp_ctr & ~RCU_GP_CTR_NEST_MASK) -> |
| 329 | skip; |
| 330 | :: else -> break; |
| 331 | fi; |
| 332 | od; |
| 333 | #ifdef MB_G |
| 334 | need_mb = 1; /* mb() G absolutely required */ |
| 335 | do |
| 336 | :: need_mb == 1 && !reader_done -> skip; |
| 337 | :: need_mb == 0 || reader_done -> break; |
| 338 | od; |
| 339 | #endif /* #ifdef MB_G */ |
| 340 | |
| 341 | /* |
| 342 | * current synchronize_rcu(). |
| 343 | * ---------------------------------------------------------------- |
| 344 | */ |
| 345 | |
| 346 | /* free-up step, e.g., kfree(). */ |
| 347 | free = 1; |
| 348 | |
| 349 | /* We are done, so kill all the infinite loops in the reader. */ |
| 350 | updater_done = 1; |
| 351 | |
| 352 | /* Create a progress cycle. Correctness requires we get here. */ |
| 353 | do |
| 354 | :: 1 -> |
| 355 | progress_updater: |
| 356 | skip; |
| 357 | :: 1 -> break; |
| 358 | od; |
| 359 | } |
| 360 | |
| 361 | /* |
| 362 | * Initialize the array, spawn a reader and an updater. Because readers |
| 363 | * are independent of each other, only one reader is needed. |
| 364 | */ |
| 365 | |
| 366 | init { |
| 367 | atomic { |
| 368 | reader_progress[0] = 0; |
| 369 | reader_progress[1] = 0; |
| 370 | reader_progress[2] = 0; |
| 371 | reader_progress[3] = 0; |
| 372 | run urcu_reader(); |
| 373 | run urcu_updater(); |
| 374 | } |
| 375 | } |