| 1 | dnl SPDX-License-Identifier: LGPL-2.1-only |
| 2 | dnl |
| 3 | dnl Copyright (C) 2021 EfficiOS, Inc. |
| 4 | dnl |
| 5 | dnl Process this file with autoconf to produce a configure script. |
| 6 | |
| 7 | # Project version information |
| 8 | m4_define([urcu_version_major], [0]) |
| 9 | m4_define([urcu_version_minor], [13]) |
| 10 | m4_define([urcu_version_patch], [0]) |
| 11 | m4_define([urcu_version_dev_stage], [-pre]) |
| 12 | m4_define([urcu_version], urcu_version_major[.]urcu_version_minor[.]urcu_version_patch[]urcu_version_dev_stage) |
| 13 | |
| 14 | # Library version information of "liburcu" |
| 15 | # Following the numbering scheme proposed by libtool for the library version |
| 16 | # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html |
| 17 | m4_define([urcu_lib_version_current], [7]) |
| 18 | m4_define([urcu_lib_version_revision], [0]) |
| 19 | m4_define([urcu_lib_version_age], [1]) |
| 20 | m4_define([urcu_lib_version], urcu_lib_version_current[:]urcu_lib_version_revision[:]urcu_lib_version_age) |
| 21 | |
| 22 | |
| 23 | ## ## |
| 24 | ## Autoconf base setup ## |
| 25 | ## ## |
| 26 | |
| 27 | AC_PREREQ([2.69]) |
| 28 | AC_INIT([userspace-rcu],[urcu_version],[mathieu dot desnoyers at efficios dot com],[],[http://liburcu.org/]) |
| 29 | |
| 30 | AC_CONFIG_HEADERS([include/config.h include/urcu/config.h]) |
| 31 | AC_CONFIG_AUX_DIR([config]) |
| 32 | AC_CONFIG_MACRO_DIR([m4]) |
| 33 | |
| 34 | AC_CANONICAL_TARGET |
| 35 | AC_CANONICAL_HOST |
| 36 | |
| 37 | |
| 38 | ## ## |
| 39 | ## Automake base setup ## |
| 40 | ## ## |
| 41 | |
| 42 | AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip nostdinc -Wall -Wno-portability -Werror]) |
| 43 | AM_MAINTAINER_MODE([enable]) |
| 44 | |
| 45 | # Enable silent rules by default |
| 46 | AM_SILENT_RULES([yes]) |
| 47 | |
| 48 | |
| 49 | ## ## |
| 50 | ## OS and Arch specific defaults ## |
| 51 | ## ## |
| 52 | |
| 53 | AS_CASE([$host], |
| 54 | [*-cygwin*], [LT_NO_UNDEFINED="-no-undefined"] |
| 55 | ) |
| 56 | |
| 57 | |
| 58 | ## ## |
| 59 | ## C compiler checks ## |
| 60 | ## ## |
| 61 | |
| 62 | # Choose the C compiler |
| 63 | AC_PROG_CC |
| 64 | # AC_PROG_CC_STDC was merged in AC_PROG_CC in autoconf 2.70 |
| 65 | m4_version_prereq([2.70], [], [AC_PROG_CC_STDC]) |
| 66 | |
| 67 | # Make sure the C compiler supports C99 |
| 68 | AS_IF([test "$ac_cv_prog_cc_c99" = "no"], [AC_MSG_ERROR([The compiler does not support C99])]) |
| 69 | |
| 70 | # Enable available system extensions and LFS support |
| 71 | AC_USE_SYSTEM_EXTENSIONS |
| 72 | AC_SYS_LARGEFILE |
| 73 | |
| 74 | # Make sure the C compiler supports __attribute__ |
| 75 | AX_C___ATTRIBUTE__ |
| 76 | AS_IF([test "x$ax_cv___attribute__" != "xyes"], |
| 77 | [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])]) |
| 78 | |
| 79 | # Make sure we have pthread support |
| 80 | AX_PTHREAD([], [AC_MSG_ERROR([Could not configure pthread support])]) |
| 81 | |
| 82 | # Make sure the C compiler supports weak symbols |
| 83 | AX_SYS_WEAK_ALIAS |
| 84 | AS_IF([test "x$ax_cv_sys_weak_alias" = "xno"], |
| 85 | [AC_MSG_ERROR([Your platform doesn't support weak symbols.])]) |
| 86 | |
| 87 | # Checks for typedefs, structures, and compiler characteristics. |
| 88 | AC_C_INLINE |
| 89 | AC_C_TYPEOF |
| 90 | AC_TYPE_INT32_T |
| 91 | AC_TYPE_PID_T |
| 92 | AC_TYPE_SIZE_T |
| 93 | AC_TYPE_SSIZE_T |
| 94 | AC_TYPE_UINT16_T |
| 95 | AC_TYPE_UINT32_T |
| 96 | AC_TYPE_UINT64_T |
| 97 | AC_TYPE_UINT8_T |
| 98 | |
| 99 | |
| 100 | ## ## |
| 101 | ## Header checks ## |
| 102 | ## ## |
| 103 | |
| 104 | AC_HEADER_STDBOOL |
| 105 | AC_CHECK_HEADERS([ \ |
| 106 | limits.h \ |
| 107 | stddef.h \ |
| 108 | sys/param.h \ |
| 109 | sys/time.h \ |
| 110 | ]) |
| 111 | |
| 112 | |
| 113 | ## ## |
| 114 | ## Programs checks ## |
| 115 | ## ## |
| 116 | |
| 117 | AC_PROG_AWK |
| 118 | AC_PROG_GREP |
| 119 | AC_PROG_MAKE_SET |
| 120 | AC_CHECK_PROGS(NPROC, [nproc gnproc]) |
| 121 | AC_CHECK_PROG(GETCONF, [getconf]) |
| 122 | AS_IF([test "x$NPROC" != "x"], |
| 123 | [NPROC_CMD=$NPROC], |
| 124 | [AS_IF([test "x$GETCONF" != "x"], |
| 125 | [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"], |
| 126 | [NPROC_CMD="echo 1"] |
| 127 | )] |
| 128 | ) |
| 129 | AC_SUBST([NPROC_CMD], [$NPROC_CMD]) |
| 130 | |
| 131 | # Initialize and configure libtool |
| 132 | LT_INIT |
| 133 | |
| 134 | |
| 135 | ## ## |
| 136 | ## Library checks ## |
| 137 | ## ## |
| 138 | |
| 139 | # Checks for library functions. |
| 140 | AC_FUNC_MMAP |
| 141 | AC_FUNC_FORK |
| 142 | AC_CHECK_FUNCS([ \ |
| 143 | atexit \ |
| 144 | getcpuid \ |
| 145 | gettid \ |
| 146 | gettimeofday \ |
| 147 | memeset \ |
| 148 | memset \ |
| 149 | munmap \ |
| 150 | rand_r \ |
| 151 | sched_getcpu \ |
| 152 | sched_setaffinity \ |
| 153 | strerror \ |
| 154 | strtoul \ |
| 155 | sysconf \ |
| 156 | ]) |
| 157 | |
| 158 | # AC_FUNC_MALLOC causes problems when cross-compiling. |
| 159 | #AC_FUNC_MALLOC |
| 160 | |
| 161 | # Search for clock_gettime() in -lrt |
| 162 | AC_SEARCH_LIBS([clock_gettime], [rt], [ |
| 163 | AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1], [clock_gettime() is detected.]) |
| 164 | ]) |
| 165 | |
| 166 | |
| 167 | ## ## |
| 168 | ## Optionnal features selection ## |
| 169 | ## ## |
| 170 | |
| 171 | # Allow to fallback to FIXME if the membarrier syscall is unavailable on the |
| 172 | # running kernel, when disabled, abort if the syscall is unavailable. Applies |
| 173 | # to default and bulletproof flavors. |
| 174 | # Enabled by default |
| 175 | AE_FEATURE_DEFAULT_ENABLE |
| 176 | AE_FEATURE([sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.]) |
| 177 | |
| 178 | # Use compiler Thread Local Storage, when disabled use pthread_getspecific() to emulate TLS. |
| 179 | # Enabled by default |
| 180 | AE_FEATURE_DEFAULT_ENABLE |
| 181 | AE_FEATURE([compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]) |
| 182 | |
| 183 | # smp-support configure option |
| 184 | # Enabled by default |
| 185 | AE_FEATURE_DEFAULT_ENABLE |
| 186 | AE_FEATURE([smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems.]) |
| 187 | |
| 188 | # RCU debugging option |
| 189 | # Disabled by default |
| 190 | AE_FEATURE_DEFAULT_DISABLE |
| 191 | AE_FEATURE([rcu-debug], [Enable internal debugging self-checks. Introduces a performance penalty.]) |
| 192 | |
| 193 | # rculfhash iterator debugging |
| 194 | # Disabled by default |
| 195 | AE_FEATURE_DEFAULT_DISABLE |
| 196 | AE_FEATURE([cds-lfht-iter-debug], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.]) |
| 197 | |
| 198 | |
| 199 | ## ## |
| 200 | ## Set defines for optional features conditionnals in the source code ## |
| 201 | ## ## |
| 202 | |
| 203 | AE_IF_FEATURE_DISABLED([sys-membarrier-fallback], [ |
| 204 | AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1], [Require the operating system to support the membarrier system call for default and bulletproof flavors.]) |
| 205 | ]) |
| 206 | |
| 207 | AE_IF_FEATURE_ENABLED([compiler-tls], [ |
| 208 | AC_DEFINE([CONFIG_RCU_TLS], [1], [Use compiler provided Thread Local Storage.]) |
| 209 | ]) |
| 210 | |
| 211 | AE_IF_FEATURE_ENABLED([smp-support], [ |
| 212 | AC_DEFINE([CONFIG_RCU_SMP], [1], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.]) |
| 213 | ]) |
| 214 | |
| 215 | AE_IF_FEATURE_ENABLED([rcu-debug], [ |
| 216 | AC_DEFINE([CONFIG_RCU_DEBUG], [1], [Enable internal debugging self-checks. Introduces a performance penalty.]) |
| 217 | ]) |
| 218 | |
| 219 | AE_IF_FEATURE_ENABLED([cds-lfht-iter-debug], [ |
| 220 | AC_DEFINE([CONFIG_CDS_LFHT_ITER_DEBUG], [1], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.]) |
| 221 | ]) |
| 222 | |
| 223 | |
| 224 | ## ## |
| 225 | ## Set automake variables for optional feature conditionnals in Makefile.am ## |
| 226 | ## ## |
| 227 | |
| 228 | # Building the examples requires the shared libraries to be enabled |
| 229 | AM_CONDITIONAL([ENABLE_EXAMPLES], AE_IS_FEATURE_ENABLED([shared])) |
| 230 | |
| 231 | |
| 232 | ## ## |
| 233 | ## Substitute variables for use in Makefile.am ## |
| 234 | ## ## |
| 235 | |
| 236 | # Library versions for libtool |
| 237 | AC_SUBST([URCU_LIBRARY_VERSION], [urcu_lib_version]) |
| 238 | |
| 239 | AC_SUBST(LT_NO_UNDEFINED) |
| 240 | |
| 241 | # The order in which the include folders are searched is important. |
| 242 | # The top_builddir should always be searched first in the event that a build |
| 243 | # time generated file is included. |
| 244 | AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h" |
| 245 | AC_SUBST(AM_CPPFLAGS) |
| 246 | |
| 247 | AM_CFLAGS="-Wall -Wextra -Wno-unused-parameter $PTHREAD_CFLAGS" |
| 248 | AC_SUBST(AM_CFLAGS) |
| 249 | |
| 250 | |
| 251 | ## ## |
| 252 | ## Output files generated by configure ## |
| 253 | ## ## |
| 254 | |
| 255 | AC_CONFIG_FILES([ |
| 256 | Makefile |
| 257 | doc/Makefile |
| 258 | doc/examples/Makefile |
| 259 | include/Makefile |
| 260 | src/Makefile |
| 261 | tests/Makefile |
| 262 | tests/common/Makefile |
| 263 | tests/unit/Makefile |
| 264 | tests/benchmark/Makefile |
| 265 | tests/regression/Makefile |
| 266 | tests/utils/Makefile |
| 267 | src/liburcu.pc |
| 268 | src/liburcu-bp.pc |
| 269 | src/liburcu-cds.pc |
| 270 | src/liburcu-qsbr.pc |
| 271 | src/liburcu-mb.pc |
| 272 | src/liburcu-signal.pc |
| 273 | ]) |
| 274 | |
| 275 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_global.tap]) |
| 276 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_percpu.tap]) |
| 277 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_perthread.tap]) |
| 278 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_global.tap]) |
| 279 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_percpu.tap]) |
| 280 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_perthread.tap]) |
| 281 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_global.tap]) |
| 282 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_percpu.tap]) |
| 283 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_perthread.tap]) |
| 284 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_global.tap]) |
| 285 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_percpu.tap]) |
| 286 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_perthread.tap]) |
| 287 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_global.tap]) |
| 288 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_percpu.tap]) |
| 289 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_perthread.tap]) |
| 290 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_global.tap]) |
| 291 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_percpu.tap]) |
| 292 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_perthread.tap]) |
| 293 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_global.tap]) |
| 294 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_percpu.tap]) |
| 295 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_perthread.tap]) |
| 296 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_global.tap]) |
| 297 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_percpu.tap]) |
| 298 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_perthread.tap]) |
| 299 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_global.tap]) |
| 300 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap]) |
| 301 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap]) |
| 302 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_global.tap]) |
| 303 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap]) |
| 304 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap]) |
| 305 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_global.tap]) |
| 306 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap]) |
| 307 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap]) |
| 308 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_global.tap]) |
| 309 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap]) |
| 310 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap]) |
| 311 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_global.tap]) |
| 312 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap]) |
| 313 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap]) |
| 314 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_global.tap]) |
| 315 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap]) |
| 316 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap]) |
| 317 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_global.tap]) |
| 318 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap]) |
| 319 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap]) |
| 320 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_global.tap]) |
| 321 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap]) |
| 322 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap]) |
| 323 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_global.tap]) |
| 324 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_percpu.tap]) |
| 325 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_perthread.tap]) |
| 326 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_global.tap]) |
| 327 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_percpu.tap]) |
| 328 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_perthread.tap]) |
| 329 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_global.tap]) |
| 330 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_percpu.tap]) |
| 331 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_perthread.tap]) |
| 332 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_global.tap]) |
| 333 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_percpu.tap]) |
| 334 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_perthread.tap]) |
| 335 | |
| 336 | |
| 337 | AC_OUTPUT |
| 338 | |
| 339 | # |
| 340 | # Mini-report on what will be built. |
| 341 | # |
| 342 | |
| 343 | PPRINT_INIT |
| 344 | PPRINT_SET_INDENT(1) |
| 345 | PPRINT_SET_TS(38) |
| 346 | |
| 347 | AS_ECHO |
| 348 | AS_ECHO("${PPRINT_COLOR_BLDBLU}Userspace-RCU $PACKAGE_VERSION${PPRINT_COLOR_RST}") |
| 349 | AS_ECHO |
| 350 | |
| 351 | PPRINT_SUBTITLE([Features]) |
| 352 | |
| 353 | PPRINT_PROP_STRING([Target architecture], $host_cpu) |
| 354 | |
| 355 | # SMP support enabled/disabled |
| 356 | AE_IS_FEATURE_ENABLED([smp-support]) && value=1 || value=0 |
| 357 | PPRINT_PROP_BOOL([SMP support], $value) |
| 358 | |
| 359 | # TLS |
| 360 | AE_IS_FEATURE_ENABLED([compiler-tls]) && value="compiler TLS" || value="pthread_getspecific()" |
| 361 | PPRINT_PROP_STRING([Thread Local Storage (TLS)], [$value]) |
| 362 | |
| 363 | # clock_gettime() available |
| 364 | test "x$ac_cv_search_function_clock_gettime" != "xno" && value=1 || value=0 |
| 365 | PPRINT_PROP_BOOL([clock_gettime()], $value) |
| 366 | |
| 367 | # Require membarrier |
| 368 | AE_IS_FEATURE_ENABLED([sys-membarrier-fallback]) && value=0 || value=1 |
| 369 | PPRINT_PROP_BOOL([Require membarrier], $value) |
| 370 | |
| 371 | # RCU debug enabled/disabled |
| 372 | AE_IS_FEATURE_ENABLED([rcu-debug]) && value=1 || value=0 |
| 373 | PPRINT_PROP_BOOL([Internal debugging], $value) |
| 374 | |
| 375 | # rculfhash iterator debug enabled/disabled |
| 376 | AE_IS_FEATURE_ENABLED([cds-lfht-iter-debug]) && value=1 || value=0 |
| 377 | PPRINT_PROP_BOOL([Lock-free HT iterator debugging], $value) |
| 378 | |
| 379 | PPRINT_PROP_BOOL([Multi-flavor support], 1) |
| 380 | |
| 381 | report_bindir="`eval eval echo $bindir`" |
| 382 | report_libdir="`eval eval echo $libdir`" |
| 383 | |
| 384 | # Print the bindir and libdir this 'make install' will install into. |
| 385 | AS_ECHO |
| 386 | PPRINT_SUBTITLE([Install directories]) |
| 387 | PPRINT_PROP_STRING([Binaries], [$report_bindir]) |
| 388 | PPRINT_PROP_STRING([Libraries], [$report_libdir]) |
| 389 | |