| 1 | AC_PREREQ(2.59) |
| 2 | AC_INIT([userspace-rcu],[0.12.0],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/]) |
| 3 | |
| 4 | # Following the numbering scheme proposed by libtool for the library version |
| 5 | # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html |
| 6 | AC_SUBST([URCU_LIBRARY_VERSION], [7:0:1]) |
| 7 | |
| 8 | AC_CONFIG_HEADERS([include/config.h include/urcu/config.h]) |
| 9 | AC_CONFIG_AUX_DIR([config]) |
| 10 | AC_CONFIG_MACRO_DIR([m4]) |
| 11 | |
| 12 | AC_CANONICAL_TARGET |
| 13 | AC_CANONICAL_HOST |
| 14 | |
| 15 | AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip nostdinc]) |
| 16 | AM_MAINTAINER_MODE([enable]) |
| 17 | |
| 18 | # Enable silent rules if available (Introduced in AM 1.11) |
| 19 | m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])]) |
| 20 | |
| 21 | AC_REQUIRE_AUX_FILE([tap-driver.sh]) |
| 22 | |
| 23 | AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.]) |
| 24 | AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.]) |
| 25 | AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.]) |
| 26 | AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.]) |
| 27 | AH_TEMPLATE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [Require the operating system to support the membarrier system call for default and bulletproof flavors.]) |
| 28 | AH_TEMPLATE([CONFIG_RCU_DEBUG], [Enable internal debugging self-checks. Introduces a performance penalty.]) |
| 29 | AH_TEMPLATE([CONFIG_CDS_LFHT_ITER_DEBUG], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.]) |
| 30 | |
| 31 | # Allow requiring the operating system to support the membarrier system |
| 32 | # call. Applies to default and bulletproof flavors. |
| 33 | AC_ARG_ENABLE([sys-membarrier-fallback], |
| 34 | AS_HELP_STRING([--disable-sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.]), |
| 35 | [def_sys_membarrier_fallback=$enableval], |
| 36 | [def_sys_membarrier_fallback="yes"]) |
| 37 | AS_IF([test "x$def_sys_membarrier_fallback" != "xyes"], [AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1])]) |
| 38 | |
| 39 | # Allow overriding storage used for TLS variables. |
| 40 | AC_ARG_ENABLE([compiler-tls], |
| 41 | AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]), |
| 42 | [def_compiler_tls=$enableval], |
| 43 | [def_compiler_tls="yes"]) |
| 44 | |
| 45 | # Checks for C compiler |
| 46 | AC_USE_SYSTEM_EXTENSIONS |
| 47 | AC_PROG_CC |
| 48 | AC_PROG_CC_STDC |
| 49 | |
| 50 | AS_IF([test "x$def_compiler_tls" = "xyes"], AC_DEFINE([CONFIG_RCU_TLS], [1]), [:]) |
| 51 | |
| 52 | # Checks for programs. |
| 53 | AC_PROG_AWK |
| 54 | AC_PROG_MAKE_SET |
| 55 | AC_CHECK_PROGS(NPROC, [nproc gnproc]) |
| 56 | AC_CHECK_PROGS(GETCONF, [getconf]) |
| 57 | AS_IF([test "x$NPROC" != "x"], |
| 58 | [NPROC_CMD=$NPROC], |
| 59 | [AS_IF([test "x$GETCONF" != "x"], |
| 60 | [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"], |
| 61 | [NPROC_CMD="echo 1"] |
| 62 | )] |
| 63 | ) |
| 64 | AC_SUBST([NPROC_CMD], [$NPROC_CMD]) |
| 65 | |
| 66 | LT_INIT |
| 67 | |
| 68 | # Checks for typedefs, structures, and compiler characteristics. |
| 69 | AC_C_INLINE |
| 70 | AC_TYPE_PID_T |
| 71 | AC_TYPE_SIZE_T |
| 72 | AC_TYPE_SSIZE_T |
| 73 | AC_TYPE_UINT16_T |
| 74 | AC_TYPE_INT32_T |
| 75 | AC_TYPE_UINT32_T |
| 76 | AC_TYPE_UINT64_T |
| 77 | AC_TYPE_UINT8_T |
| 78 | |
| 79 | AX_C___ATTRIBUTE__ |
| 80 | AS_IF([test "x$ax_cv___attribute__" = "xyes"], |
| 81 | [:], |
| 82 | [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])]) |
| 83 | |
| 84 | AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])]) |
| 85 | |
| 86 | AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS" |
| 87 | |
| 88 | # Checks for library functions. |
| 89 | AC_FUNC_MMAP |
| 90 | AC_FUNC_FORK |
| 91 | AC_CHECK_FUNCS([ \ |
| 92 | atexit \ |
| 93 | getcpuid \ |
| 94 | gettid \ |
| 95 | gettimeofday \ |
| 96 | memeset \ |
| 97 | memset \ |
| 98 | munmap \ |
| 99 | rand_r \ |
| 100 | sched_getcpu \ |
| 101 | strerror \ |
| 102 | strtoul \ |
| 103 | sysconf \ |
| 104 | ]) |
| 105 | |
| 106 | # AC_FUNC_MALLOC causes problems when cross-compiling. |
| 107 | #AC_FUNC_MALLOC |
| 108 | |
| 109 | # Check for headers |
| 110 | AC_HEADER_STDBOOL |
| 111 | AC_CHECK_HEADERS([ \ |
| 112 | limits.h \ |
| 113 | stddef.h \ |
| 114 | sys/param.h \ |
| 115 | sys/time.h \ |
| 116 | ]) |
| 117 | |
| 118 | AS_CASE([$host],[*-cygwin*], |
| 119 | [AM_CONDITIONAL(USE_CYGWIN, true)], |
| 120 | [AM_CONDITIONAL(USE_CYGWIN, false)] |
| 121 | ) |
| 122 | |
| 123 | AS_IF([test "$host_cpu" = "armv7l"],[ |
| 124 | AM_CFLAGS="$AM_CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1" |
| 125 | ]) |
| 126 | |
| 127 | # ARM-specific checks |
| 128 | AS_CASE([$host_cpu], [arm*], [ |
| 129 | AC_MSG_CHECKING([for dmb instruction]) |
| 130 | AC_COMPILE_IFELSE([AC_LANG_SOURCE([[ |
| 131 | int main() |
| 132 | { |
| 133 | asm volatile("dmb":::"memory"); |
| 134 | return 0; |
| 135 | } |
| 136 | ]]) |
| 137 | ],[ |
| 138 | AC_MSG_RESULT([yes]) |
| 139 | AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1]) |
| 140 | ],[ |
| 141 | AC_MSG_RESULT([no]) |
| 142 | ]) |
| 143 | ]) |
| 144 | |
| 145 | # Search for clock_gettime |
| 146 | AC_SEARCH_LIBS([clock_gettime], [rt], [ |
| 147 | AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1]) |
| 148 | config_rcu_have_clock_gettime=yes |
| 149 | ], []) |
| 150 | |
| 151 | AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"]) |
| 152 | |
| 153 | # smp-support configure option |
| 154 | AC_ARG_ENABLE([smp-support], |
| 155 | AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]), |
| 156 | [def_smp_support=$enableval], |
| 157 | [def_smp_support="yes"]) |
| 158 | AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])]) |
| 159 | |
| 160 | # RCU debugging option |
| 161 | AC_ARG_ENABLE([rcu-debug], |
| 162 | AS_HELP_STRING([--enable-rcu-debug], [Enable internal debugging |
| 163 | self-checks. Introduces a performance penalty.])) |
| 164 | AS_IF([test "x$enable_rcu_debug" = "xyes"], [ |
| 165 | AC_DEFINE([CONFIG_RCU_DEBUG], [1]) |
| 166 | ]) |
| 167 | |
| 168 | # rculfhash iterator debugging |
| 169 | AC_ARG_ENABLE([cds-lfht-iter-debug], |
| 170 | AS_HELP_STRING([--enable-cds-lfht-iter-debug], [Enable extra debugging checks for lock-free hash table iterator traversal. Alters the rculfhash ABI. Make sure to compile both library and application with matching configuration.])) |
| 171 | AS_IF([test "x$enable_cds_lfht_iter_debug" = "xyes"], [ |
| 172 | AC_DEFINE([CONFIG_CDS_LFHT_ITER_DEBUG], [1]) |
| 173 | ]) |
| 174 | |
| 175 | # From the sched_setaffinity(2)'s man page: |
| 176 | # ~~~~ |
| 177 | # The CPU affinity system calls were introduced in Linux kernel 2.5.8. |
| 178 | # The library interfaces were introduced in glibc 2.3. Initially, the |
| 179 | # glibc interfaces included a cpusetsize argument. In glibc 2.3.3, |
| 180 | # the cpuset size argument was removed, but this argument was |
| 181 | # restored in glibc 2.3.4. |
| 182 | # ~~~~ |
| 183 | |
| 184 | # In addition to that, some vendors ported the system call to 2.4 |
| 185 | # kernels. |
| 186 | |
| 187 | # Furthermore, when the function first appeared, the MASK argument was |
| 188 | # an unsigned long pointer, while later it was made into a cpu_set_t |
| 189 | # pointer. Systems that have the cpu_set_t version also should have |
| 190 | # the CPU_ZERO, CPU_SET, etc. macros. |
| 191 | |
| 192 | # All this mess means we have to cater for at least 3 different |
| 193 | # sched_setaffinity prototypes: |
| 194 | |
| 195 | # ~~~~ |
| 196 | # int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask); |
| 197 | # int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset); |
| 198 | # int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask); |
| 199 | # ~~~~ |
| 200 | |
| 201 | AC_CHECK_TYPES([cpu_set_t], |
| 202 | [have_cpu_set_t="yes"], |
| 203 | [have_cpu_set_t="no"], |
| 204 | [#include <sched.h>]) |
| 205 | |
| 206 | # Confirm that we have CPU_ZERO, and it actually works. |
| 207 | AC_MSG_CHECKING([whether CPU_ZERO works]) |
| 208 | AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works]) |
| 209 | AC_COMPILE_IFELSE([AC_LANG_SOURCE([[ |
| 210 | #include <sched.h> |
| 211 | int main() |
| 212 | { |
| 213 | cpu_set_t foo; CPU_ZERO(&foo); |
| 214 | return 0; |
| 215 | } |
| 216 | ]]) |
| 217 | ],[ |
| 218 | AC_DEFINE(HAVE_CPU_ZERO, 1) |
| 219 | AC_MSG_RESULT([yes]) |
| 220 | ],[ |
| 221 | AC_MSG_RESULT([no]) |
| 222 | ]) |
| 223 | |
| 224 | # Confirm that we have CPU_SET, and it actually works. |
| 225 | AC_MSG_CHECKING([whether CPU_SET works]) |
| 226 | AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works]) |
| 227 | AC_COMPILE_IFELSE([AC_LANG_SOURCE([[ |
| 228 | #include <sched.h> |
| 229 | int main() |
| 230 | { |
| 231 | cpu_set_t foo; CPU_SET(0, &foo); |
| 232 | return 0; |
| 233 | } |
| 234 | ]]) |
| 235 | ],[ |
| 236 | AC_DEFINE(HAVE_CPU_SET, 1) |
| 237 | AC_MSG_RESULT([yes]) |
| 238 | ],[ |
| 239 | AC_MSG_RESULT([no]) |
| 240 | ]) |
| 241 | |
| 242 | # First check if the function is available at all. |
| 243 | AC_CHECK_FUNCS([sched_setaffinity],[ |
| 244 | # Okay, we have it. Check if also have cpu_set_t. If we don't, |
| 245 | # then we have the first version using unsigned long, and no |
| 246 | # CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the |
| 247 | # version with 2 or 3 arguments. In that case, CPU_ZERO, etc., |
| 248 | # should also be present, but we confirm nonetheless. |
| 249 | |
| 250 | AS_IF([test "x$have_cpu_set_t" = "xyes"], [ |
| 251 | # We do have it. |
| 252 | # Check how many arguments does sched_setaffinity take. |
| 253 | # Should be 3 or 2. |
| 254 | AC_MSG_CHECKING([how many arguments sched_setaffinity takes]) |
| 255 | AC_COMPILE_IFELSE([AC_LANG_SOURCE([[ |
| 256 | #include <sched.h> |
| 257 | int main() |
| 258 | { |
| 259 | cpu_set_t foo; |
| 260 | sched_setaffinity(0, sizeof (foo), &foo); |
| 261 | return 0; |
| 262 | } |
| 263 | ]]) |
| 264 | ], |
| 265 | [sched_set_affinity_args=3], |
| 266 | [sched_set_affinity_args=2]) |
| 267 | AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS, |
| 268 | $sched_set_affinity_args, |
| 269 | [Defined to sched_setaffinity's number of arguments.]) |
| 270 | AC_MSG_RESULT([$sched_set_affinity_args]) |
| 271 | ],[ |
| 272 | # No cpu_set_t, always 3 args. |
| 273 | AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3) |
| 274 | ]) |
| 275 | ]) |
| 276 | |
| 277 | AM_CPPFLAGS="-include config.h" |
| 278 | AC_SUBST(AM_CPPFLAGS) |
| 279 | |
| 280 | AM_CFLAGS="-Wall -Wextra -Wno-unused-parameter $AM_CFLAGS" |
| 281 | AC_SUBST(AM_CFLAGS) |
| 282 | |
| 283 | AC_CONFIG_FILES([ |
| 284 | Makefile |
| 285 | doc/Makefile |
| 286 | doc/examples/Makefile |
| 287 | include/Makefile |
| 288 | src/Makefile |
| 289 | tests/Makefile |
| 290 | tests/common/Makefile |
| 291 | tests/unit/Makefile |
| 292 | tests/benchmark/Makefile |
| 293 | tests/regression/Makefile |
| 294 | tests/utils/Makefile |
| 295 | src/liburcu.pc |
| 296 | src/liburcu-bp.pc |
| 297 | src/liburcu-cds.pc |
| 298 | src/liburcu-qsbr.pc |
| 299 | src/liburcu-mb.pc |
| 300 | src/liburcu-signal.pc |
| 301 | ]) |
| 302 | |
| 303 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_global.tap]) |
| 304 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_percpu.tap]) |
| 305 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_perf_perthread.tap]) |
| 306 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_global.tap]) |
| 307 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_percpu.tap]) |
| 308 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_rperf_perthread.tap]) |
| 309 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_global.tap]) |
| 310 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_percpu.tap]) |
| 311 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_stress_perthread.tap]) |
| 312 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_global.tap]) |
| 313 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_percpu.tap]) |
| 314 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_bp_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_bp_uperf_perthread.tap]) |
| 315 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_global.tap]) |
| 316 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_percpu.tap]) |
| 317 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_perf_perthread.tap]) |
| 318 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_global.tap]) |
| 319 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_percpu.tap]) |
| 320 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_rperf_perthread.tap]) |
| 321 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_global.tap]) |
| 322 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_percpu.tap]) |
| 323 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_stress_perthread.tap]) |
| 324 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_global.tap]) |
| 325 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_percpu.tap]) |
| 326 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_mb_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_mb_uperf_perthread.tap]) |
| 327 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_global.tap]) |
| 328 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_percpu.tap]) |
| 329 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_perf_perthread.tap]) |
| 330 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_global.tap]) |
| 331 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_percpu.tap]) |
| 332 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_rperf_perthread.tap]) |
| 333 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_global.tap]) |
| 334 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_percpu.tap]) |
| 335 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_stress_perthread.tap]) |
| 336 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_global.tap]) |
| 337 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_percpu.tap]) |
| 338 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_membarrier_uperf_perthread.tap]) |
| 339 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_global.tap]) |
| 340 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_percpu.tap]) |
| 341 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_perf_perthread.tap]) |
| 342 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_global.tap]) |
| 343 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_percpu.tap]) |
| 344 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_rperf_perthread.tap]) |
| 345 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_global.tap]) |
| 346 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_percpu.tap]) |
| 347 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_stress_perthread.tap]) |
| 348 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_global.tap]) |
| 349 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_percpu.tap]) |
| 350 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_qsbr_uperf_perthread.tap]) |
| 351 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_global.tap]) |
| 352 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_percpu.tap]) |
| 353 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_perf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_perf_perthread.tap]) |
| 354 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_global.tap]) |
| 355 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_percpu.tap]) |
| 356 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_rperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_rperf_perthread.tap]) |
| 357 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_global.tap]) |
| 358 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_percpu.tap]) |
| 359 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_stress_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_stress_perthread.tap]) |
| 360 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_global.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_global.tap]) |
| 361 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_percpu.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_percpu.tap]) |
| 362 | AC_CONFIG_FILES([tests/regression/rcutorture_urcu_signal_uperf_perthread.tap], [chmod +x tests/regression/rcutorture_urcu_signal_uperf_perthread.tap]) |
| 363 | |
| 364 | |
| 365 | AC_OUTPUT |
| 366 | |
| 367 | # |
| 368 | # Mini-report on what will be built. |
| 369 | # |
| 370 | |
| 371 | PPRINT_INIT |
| 372 | PPRINT_SET_INDENT(1) |
| 373 | PPRINT_SET_TS(38) |
| 374 | |
| 375 | AS_ECHO |
| 376 | AS_ECHO("${PPRINT_COLOR_BLDBLU}Userspace-RCU $PACKAGE_VERSION${PPRINT_COLOR_RST}") |
| 377 | AS_ECHO |
| 378 | |
| 379 | PPRINT_SUBTITLE([Features]) |
| 380 | |
| 381 | PPRINT_PROP_STRING([Target architecture], $host_cpu) |
| 382 | |
| 383 | # SMP support enabled/disabled |
| 384 | test "x$def_smp_support" = "xyes" && value=1 || value=0 |
| 385 | PPRINT_PROP_BOOL([SMP support], $value) |
| 386 | |
| 387 | # TLS |
| 388 | test "x$def_compiler_tls" = "xyes" && value="compiler TLS" || value="pthread_getspecific()" |
| 389 | PPRINT_PROP_STRING([Thread Local Storage (TLS)], [$value]) |
| 390 | |
| 391 | # clock_gettime() available |
| 392 | test "x$config_rcu_have_clock_gettime" = "xyes" && value=1 || value=0 |
| 393 | PPRINT_PROP_BOOL([clock_gettime()], $value) |
| 394 | |
| 395 | # Require membarrier |
| 396 | test "x$def_sys_membarrier_fallback" != "xyes" && value=1 || value=0 |
| 397 | PPRINT_PROP_BOOL([Require membarrier], $value) |
| 398 | |
| 399 | # RCU debug enabled/disabled |
| 400 | test "x$enable_rcu_debug" = "xyes" && value=1 || value=0 |
| 401 | PPRINT_PROP_BOOL([Internal debugging], $value) |
| 402 | |
| 403 | # rculfhash iterator debug enabled/disabled |
| 404 | test "x$enable_cds_lfht_iter_debug" = "xyes" && value=1 || value=0 |
| 405 | PPRINT_PROP_BOOL([Lock-free hash table iterator debugging], $value) |
| 406 | |
| 407 | PPRINT_PROP_BOOL([Multi-flavor support], 1) |
| 408 | |
| 409 | report_bindir="`eval eval echo $bindir`" |
| 410 | report_libdir="`eval eval echo $libdir`" |
| 411 | |
| 412 | # Print the bindir and libdir this `make install' will install into. |
| 413 | AS_ECHO |
| 414 | PPRINT_SUBTITLE([Install directories]) |
| 415 | PPRINT_PROP_STRING([Binaries], [$report_bindir]) |
| 416 | PPRINT_PROP_STRING([Libraries], [$report_libdir]) |
| 417 | |