| 1 | AC_PREREQ([2.64]) |
| 2 | AC_INIT([lttng-tools],[2.8.1],[jeremie.galarneau@efficios.com],[],[https://lttng.org]) |
| 3 | |
| 4 | AC_CONFIG_HEADERS([include/config.h]) |
| 5 | AC_CONFIG_AUX_DIR([config]) |
| 6 | AC_CONFIG_MACRO_DIR([m4]) |
| 7 | |
| 8 | AC_CANONICAL_TARGET |
| 9 | AC_CANONICAL_HOST |
| 10 | |
| 11 | AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip tar-pax]) |
| 12 | AM_MAINTAINER_MODE([enable]) |
| 13 | |
| 14 | # Enable silent rules if available (Introduced in AM 1.11) |
| 15 | m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])]) |
| 16 | |
| 17 | AC_REQUIRE_AUX_FILE([tap-driver.sh]) |
| 18 | |
| 19 | # Checks for C compiler |
| 20 | AC_USE_SYSTEM_EXTENSIONS |
| 21 | AC_SYS_LARGEFILE |
| 22 | AC_PROG_CC |
| 23 | AC_PROG_CC_STDC |
| 24 | |
| 25 | # Checks for programs. |
| 26 | AC_PROG_GREP |
| 27 | AC_PROG_LEX |
| 28 | AC_PROG_MAKE_SET |
| 29 | AC_PROG_SED |
| 30 | AC_PROG_YACC |
| 31 | AC_PATH_PROG(report_fold, fold) |
| 32 | LT_INIT |
| 33 | |
| 34 | # Check for objcopy, required by the base address statedump and dynamic linker tests |
| 35 | AC_CHECK_TOOL([OBJCOPY], objcopy, no) |
| 36 | AS_IF([test "x$OBJCOPY" = xno], |
| 37 | [AC_MSG_WARN([Cannont find objcopy. The base address statedump and dynamic linker tests will be disabled. Install the binutils package to remediate this.])] |
| 38 | ) |
| 39 | AM_CONDITIONAL([HAVE_OBJCOPY], [test "x$OBJCOPY" != xno]) |
| 40 | |
| 41 | # Checks for typedefs, structures, and compiler characteristics. |
| 42 | AC_C_INLINE |
| 43 | AC_TYPE_INT32_T |
| 44 | AC_TYPE_INT64_T |
| 45 | AC_TYPE_MODE_T |
| 46 | AC_TYPE_OFF_T |
| 47 | AC_TYPE_PID_T |
| 48 | AC_TYPE_SIZE_T |
| 49 | AC_TYPE_SSIZE_T |
| 50 | AC_TYPE_UID_T |
| 51 | AC_TYPE_UINT16_T |
| 52 | AC_TYPE_UINT32_T |
| 53 | AC_TYPE_UINT64_T |
| 54 | AC_TYPE_UINT8_T |
| 55 | |
| 56 | AX_C___ATTRIBUTE__ |
| 57 | AS_IF([test "x$ax_cv___attribute__" = "xyes"], |
| 58 | [:], |
| 59 | [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])]) |
| 60 | |
| 61 | AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])]) |
| 62 | LIBS="$PTHREAD_LIBS $LIBS" |
| 63 | CFLAGS="$CFLAGS $PTHREAD_CFLAGS" |
| 64 | CC="$PTHREAD_CC" |
| 65 | |
| 66 | AX_LIB_SOCKET_NSL |
| 67 | |
| 68 | # Compute minor/major/patchlevel version numbers |
| 69 | major_version=$(echo AC_PACKAGE_VERSION | $SED 's/^\([[0-9]]\)*\.[[0-9]]*\.[[0-9]]*.*$/\1/') |
| 70 | minor_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.\([[0-9]]*\)\.[[0-9]]*.*$/\1/') |
| 71 | patchlevel_version=$(echo AC_PACKAGE_VERSION | $SED 's/^[[0-9]]*\.[[0-9]]*\.\([[0-9]]*\).*$/\1/') |
| 72 | |
| 73 | AC_SUBST([MAJOR_VERSION], [$major_version]) |
| 74 | AC_SUBST([MINOR_VERSION], [$minor_version]) |
| 75 | AC_SUBST([PATCHLEVEL_VERSION], [$patchlevel_version]) |
| 76 | AC_DEFINE_UNQUOTED([VERSION_MAJOR], $major_version, [LTTng-Tools major version number]) |
| 77 | AC_DEFINE_UNQUOTED([VERSION_MINOR], $minor_version, [LTTng-Tools minor version number]) |
| 78 | AC_DEFINE_UNQUOTED([VERSION_PATCHLEVEL], $patchlevel_version, [LTTng-Tools patchlevel version number]) |
| 79 | |
| 80 | version_name="Isseki Nicho" |
| 81 | version_description='The result of a collaboration between "Dieu du Ciel!" and Nagano-based "Shiga Kogen", Isseki Nicho is a strong Imperial Dark Saison offering a rich roasted malt flavor combined with a complex fruity finish typical of Saison yeasts.' |
| 82 | version_description_c=$(echo $version_description | $SED 's/"/\\"/g') |
| 83 | |
| 84 | AC_DEFINE_UNQUOTED([VERSION_NAME], ["$version_name"], "") |
| 85 | AC_DEFINE_UNQUOTED([VERSION_DESCRIPTION], ["$version_description_c"], "") |
| 86 | |
| 87 | # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321. |
| 88 | AC_ARG_ENABLE(libtool-linkdep-fixup, |
| 89 | AS_HELP_STRING([--disable-libtool-linkdep-fixup], |
| 90 | [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]), |
| 91 | libtool_fixup=$enableval, |
| 92 | libtool_fixup=yes) |
| 93 | |
| 94 | AS_IF([test "x$libtool_fixup" = "xyes"], |
| 95 | [ |
| 96 | libtool_m4="$srcdir/m4/libtool.m4" |
| 97 | libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)" |
| 98 | AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4]) |
| 99 | libtool_flag_pattern_count=$($GREP -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4) |
| 100 | AS_IF([test $libtool_flag_pattern_count -ne 0], |
| 101 | [ |
| 102 | AC_MSG_RESULT([$libtool_flag_pattern_count]) |
| 103 | AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown]) |
| 104 | $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4 |
| 105 | ], |
| 106 | [ |
| 107 | AC_MSG_RESULT([none]) |
| 108 | ]) |
| 109 | ]) |
| 110 | |
| 111 | AM_CONDITIONAL([NO_SHARED], [test x$enable_shared = xno]) |
| 112 | |
| 113 | AC_CHECK_HEADERS([ \ |
| 114 | sys/types.h unistd.h fcntl.h string.h pthread.h limits.h \ |
| 115 | signal.h stdlib.h sys/un.h sys/socket.h stdlib.h stdio.h \ |
| 116 | getopt.h sys/ipc.h sys/shm.h popt.h grp.h arpa/inet.h \ |
| 117 | netdb.h netinet/in.h paths.h stddef.h sys/file.h sys/ioctl.h \ |
| 118 | sys/mount.h sys/param.h sys/time.h |
| 119 | ]) |
| 120 | |
| 121 | # Basic functions check |
| 122 | AC_CHECK_FUNCS([ \ |
| 123 | atexit bzero clock_gettime dup2 fdatasync fls ftruncate \ |
| 124 | gethostbyname gethostname getpagesize localtime_r memchr memset \ |
| 125 | mkdir munmap putenv realpath rmdir socket strchr strcspn strdup \ |
| 126 | strncasecmp strndup strnlen strpbrk strrchr strstr strtol strtoul \ |
| 127 | strtoull dirfd gethostbyname2 getipnodebyname epoll_create1 \ |
| 128 | ]) |
| 129 | |
| 130 | # Babeltrace viewer check |
| 131 | AC_ARG_WITH([babeltrace-bin], |
| 132 | AS_HELP_STRING([--with-babeltrace-bin], |
| 133 | [Location of the babeltrace viewer executable (including the filename)]), |
| 134 | [BABELTRACE_BIN="$withval"], |
| 135 | [BABELTRACE_BIN='']) |
| 136 | AC_SUBST([BABELTRACE_BIN]) |
| 137 | |
| 138 | # lttv-gui |
| 139 | AC_ARG_WITH([lttv-gui-bin], |
| 140 | AS_HELP_STRING([--with-lttv-gui-bin], |
| 141 | [Location of the lttv GUI viewer executable (including the filename)]), |
| 142 | [LTTV_GUI_BIN="$withval"], |
| 143 | [LTTV_GUI_BIN='']) |
| 144 | AC_SUBST([LTTV_GUI_BIN]) |
| 145 | |
| 146 | AC_ARG_WITH([consumerd32-bin], |
| 147 | AS_HELP_STRING([--with-consumerd32-bin], |
| 148 | [Location of the 32-bit consumerd executable (including the filename)]), |
| 149 | [CONSUMERD32_BIN="$withval"], |
| 150 | [CONSUMERD32_BIN='']) |
| 151 | AC_SUBST([CONSUMERD32_BIN]) |
| 152 | |
| 153 | AC_ARG_WITH([consumerd64-bin], |
| 154 | AS_HELP_STRING([--with-consumerd64-bin], |
| 155 | [Location of the 64-bit consumerd executable (including the filename)]), |
| 156 | [CONSUMERD64_BIN="$withval"], |
| 157 | [CONSUMERD64_BIN='']) |
| 158 | AC_SUBST([CONSUMERD64_BIN]) |
| 159 | |
| 160 | AC_ARG_WITH([consumerd32-libdir], |
| 161 | AS_HELP_STRING([--with-consumerd32-libdir], |
| 162 | [Directory containing the 32-bit consumerd libraries]), |
| 163 | [CONSUMERD32_LIBDIR="$withval"], |
| 164 | [CONSUMERD32_LIBDIR='']) |
| 165 | AC_SUBST([CONSUMERD32_LIBDIR]) |
| 166 | |
| 167 | AC_ARG_WITH([consumerd64-libdir], |
| 168 | AS_HELP_STRING([--with-consumerd64-libdir], |
| 169 | [Directory containing the 64-bit consumerd libraries]), |
| 170 | [CONSUMERD64_LIBDIR="$withval"], |
| 171 | [CONSUMERD64_LIBDIR='']) |
| 172 | AC_SUBST([CONSUMERD64_LIBDIR]) |
| 173 | |
| 174 | AC_ARG_WITH([sessiond-bin], |
| 175 | AS_HELP_STRING([--with-sessiond-bin], |
| 176 | [Location of the sessiond executable (including the filename)]), |
| 177 | [SESSIOND_BIN="$withval"], |
| 178 | [SESSIOND_BIN='']) |
| 179 | AC_SUBST([SESSIOND_BIN]) |
| 180 | |
| 181 | AC_ARG_WITH([lttng-system-rundir], |
| 182 | AS_HELP_STRING([--with-lttng-system-rundir], |
| 183 | [Location of the system directory where the system-wide lttng-sessiond runtime files are kept. The default is "/var/run/lttng".]), |
| 184 | [LTTNG_SYSTEM_RUNDIR="$withval"], |
| 185 | [LTTNG_SYSTEM_RUNDIR="/var/run/lttng"]) |
| 186 | AC_SUBST([LTTNG_SYSTEM_RUNDIR]) |
| 187 | |
| 188 | AC_ARG_ENABLE([test-java-agent-jul], |
| 189 | [AS_HELP_STRING([--enable-test-java-agent-jul],[enable the LTTng UST Java agent JUL tests [default=no]])], |
| 190 | [test_java_agent_jul=$enableval], |
| 191 | [test_java_agent_jul=no] |
| 192 | ) |
| 193 | |
| 194 | AC_ARG_ENABLE([test-java-agent-log4j], |
| 195 | [AS_HELP_STRING([--enable-test-java-agent-log4j],[enable the LTTng UST Java agent Log4j tests [default=no]])], |
| 196 | [test_java_agent_log4j=$enableval], |
| 197 | [test_java_agent_log4j=no] |
| 198 | ) |
| 199 | |
| 200 | AC_ARG_ENABLE([test-java-agent-all], |
| 201 | [AS_HELP_STRING([--enable-test-java-agent-all],[enable all the LTTng UST Java agent tests [default=no]])], |
| 202 | [test_java_agent_jul=$enableval |
| 203 | test_java_agent_log4j=$enableval], |
| 204 | [:] |
| 205 | ) |
| 206 | |
| 207 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_BIN], "$CONSUMERD32_BIN", [Location of the 32-bit consumerd executable.]) |
| 208 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_BIN], "$CONSUMERD64_BIN", [Location of the 64-bit consumerd executable]) |
| 209 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD32_LIBDIR], "$CONSUMERD32_LIBDIR", [Search for consumerd 32-bit libraries in this location.]) |
| 210 | AC_DEFINE_UNQUOTED([CONFIG_CONSUMERD64_LIBDIR], "$CONSUMERD64_LIBDIR", [Search for consumerd 64-bit libraries in this location.]) |
| 211 | AC_DEFINE_UNQUOTED([CONFIG_BABELTRACE_BIN], "$BABELTRACE_BIN", [Location of the babeltrace viewer executable.]) |
| 212 | AC_DEFINE_UNQUOTED([CONFIG_LTTV_GUI_BIN], "$LTTV_GUI_BIN", [Location of the lttv GUI viewer executable.]) |
| 213 | AC_DEFINE_UNQUOTED([CONFIG_SESSIOND_BIN], "$SESSIOND_BIN", [Location of the sessiond executable.]) |
| 214 | AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_RUNDIR], ["$LTTNG_SYSTEM_RUNDIR"], [LTTng system runtime directory]) |
| 215 | |
| 216 | AC_DEFUN([_AC_DEFINE_AND_SUBST], [ |
| 217 | AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1]) |
| 218 | $1="$2" |
| 219 | AC_SUBST([$1]) |
| 220 | ]) |
| 221 | |
| 222 | AC_DEFUN([_AC_DEFINE_QUOTED_AND_SUBST], [ |
| 223 | AC_DEFINE_UNQUOTED([CONFIG_$1], ["$2"], [$1]) |
| 224 | $1="$2" |
| 225 | AC_SUBST([$1]) |
| 226 | ]) |
| 227 | |
| 228 | # Default values |
| 229 | m4_define([_DEFAULT_CHANNEL_SUBBUF_SIZE], [4096]) |
| 230 | m4_define([_DEFAULT_CHANNEL_SUBBUF_NUM], [4]) |
| 231 | m4_define([_DEFAULT_CHANNEL_SWITCH_TIMER], [0]) |
| 232 | m4_define([_DEFAULT_CHANNEL_LIVE_TIMER], [0]) |
| 233 | m4_define([_DEFAULT_CHANNEL_READ_TIMER], [200000]) |
| 234 | _AC_DEFINE_AND_SUBST([DEFAULT_AGENT_TCP_PORT], [5345]) |
| 235 | _AC_DEFINE_AND_SUBST([DEFAULT_APP_SOCKET_RW_TIMEOUT], [5]) |
| 236 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE]) |
| 237 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_COUNT], [0]) |
| 238 | _AC_DEFINE_AND_SUBST([DEFAULT_CHANNEL_TRACEFILE_SIZE], [0]) |
| 239 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| 240 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_READ_TIMER], [_DEFAULT_CHANNEL_READ_TIMER]) |
| 241 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| 242 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SUBBUF_SIZE], [262144]) |
| 243 | _AC_DEFINE_AND_SUBST([DEFAULT_KERNEL_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| 244 | _AC_DEFINE_AND_SUBST([DEFAULT_LTTNG_LIVE_TIMER], [1000000]) |
| 245 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_CACHE_SIZE], [4096]) |
| 246 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_READ_TIMER], [0]) |
| 247 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_NUM], [2]) |
| 248 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SUBBUF_SIZE], [4096]) |
| 249 | _AC_DEFINE_AND_SUBST([DEFAULT_METADATA_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| 250 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_CONTROL_PORT], [5342]) |
| 251 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_DATA_PORT], [5343]) |
| 252 | _AC_DEFINE_AND_SUBST([DEFAULT_NETWORK_VIEWER_PORT], [5344]) |
| 253 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| 254 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_READ_TIMER], [0]) |
| 255 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| 256 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SUBBUF_SIZE], [_DEFAULT_CHANNEL_SUBBUF_SIZE]) |
| 257 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_PID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| 258 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_LIVE_TIMER], [_DEFAULT_CHANNEL_LIVE_TIMER]) |
| 259 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_READ_TIMER], [0]) |
| 260 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_NUM], [_DEFAULT_CHANNEL_SUBBUF_NUM]) |
| 261 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SUBBUF_SIZE], [131072]) |
| 262 | _AC_DEFINE_AND_SUBST([DEFAULT_UST_UID_CHANNEL_SWITCH_TIMER], [_DEFAULT_CHANNEL_SWITCH_TIMER]) |
| 263 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_AGENT_BIND_ADDRESS], [localhost]) |
| 264 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_CONTROL_BIND_ADDRESS], [0.0.0.0]) |
| 265 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_DATA_BIND_ADDRESS], [0.0.0.0]) |
| 266 | _AC_DEFINE_QUOTED_AND_SUBST([DEFAULT_NETWORK_VIEWER_BIND_ADDRESS], [localhost]) |
| 267 | |
| 268 | # Command short descriptions |
| 269 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ADD_CONTEXT], [Add context fields to a channel]) |
| 270 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CALIBRATE], [Quantify LTTng overhead]) |
| 271 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_CREATE], [Create a tracing session]) |
| 272 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DESTROY], [Tear down tracing sessions]) |
| 273 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_CHANNEL], [Disable tracing channels]) |
| 274 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_DISABLE_EVENT], [Disable event rules]) |
| 275 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_CHANNEL], [Create or enable tracing channels]) |
| 276 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_ENABLE_EVENT], [Create or enable event rules]) |
| 277 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_HELP], [Display help information about a command]) |
| 278 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LIST], [List tracing sessions, domains, channels, and events]) |
| 279 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_LOAD], [Load tracing session configurations]) |
| 280 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_METADATA], [Manage an LTTng tracing session's metadata generation]) |
| 281 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SAVE], [Save tracing session configurations]) |
| 282 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SET_SESSION], [Set current tracing session]) |
| 283 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_SNAPSHOT], [Snapshot buffers of current tracing session]) |
| 284 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_START], [Start tracing]) |
| 285 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STATUS], [Get the status of the current tracing session]) |
| 286 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_STOP], [Stop tracing]) |
| 287 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_TRACK], [Track specific system resources]) |
| 288 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_UNTRACK], [Untrack specific system resources]) |
| 289 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VERSION], [Show version information]) |
| 290 | _AC_DEFINE_QUOTED_AND_SUBST([CMD_DESCR_VIEW], [Start trace viewer]) |
| 291 | |
| 292 | if test "x$prefix" = "xNONE"; then |
| 293 | prefix=$ac_default_prefix |
| 294 | fi |
| 295 | CONFDIR=`eval echo $sysconfdir` |
| 296 | AC_SUBST(CONFDIR) |
| 297 | AC_DEFINE_UNQUOTED([CONFIG_LTTNG_SYSTEM_CONFIGDIR],"$CONFDIR", [LTTng system configuration directory.]) |
| 298 | |
| 299 | AC_DEFINE_DIR([CONFIG_LTTNG_SYSTEM_DATADIR],[datadir], [LTTng system data directory.]) |
| 300 | |
| 301 | # |
| 302 | # Check for pthread |
| 303 | AC_CHECK_LIB([pthread], [pthread_create], [], |
| 304 | [AC_MSG_ERROR([Cannot find libpthread. Use LDFLAGS=-Ldir to specify its location.])] |
| 305 | ) |
| 306 | |
| 307 | # Check libpopt |
| 308 | PKG_CHECK_MODULES([POPT], [popt], |
| 309 | [LIBS="$LIBS $POPT_LIBS"], |
| 310 | [ |
| 311 | AC_MSG_WARN([pkg-config was unable to find a valid .pc for libpopt. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location]) |
| 312 | AC_MSG_WARN([Finding libpopt without pkg-config.]) |
| 313 | AC_CHECK_LIB([popt], |
| 314 | [poptGetContext], |
| 315 | [], |
| 316 | [ |
| 317 | AC_MSG_ERROR([Cannot find libpopt. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location]) |
| 318 | ] |
| 319 | ) |
| 320 | ] |
| 321 | ) |
| 322 | |
| 323 | AM_PATH_XML2(2.7.6, true, AC_MSG_ERROR(No supported version of libxml2 found.)) |
| 324 | |
| 325 | # Check for libuuid |
| 326 | PKG_CHECK_MODULES([UUID], [uuid], |
| 327 | [ |
| 328 | LIBS="$LIBS $UUID_LIBS" |
| 329 | AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.]) |
| 330 | have_libuuid=yes |
| 331 | ], |
| 332 | [ |
| 333 | AC_MSG_WARN([pkg-config was unable to find a valid .pc for libuuid. Set PKG_CONFIG_PATH to specify the pkgconfig configuration file location]) |
| 334 | AC_MSG_WARN([Finding libuuid without pkg-config.]) |
| 335 | AC_CHECK_LIB([uuid], |
| 336 | [uuid_generate], |
| 337 | [ |
| 338 | AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBUUID], 1, [Has libuuid support.]) |
| 339 | have_libuuid=yes |
| 340 | ], |
| 341 | [ |
| 342 | # libuuid not found, check for uuid_create in libc. |
| 343 | AC_CHECK_LIB([c], |
| 344 | [uuid_create], |
| 345 | [ |
| 346 | AC_DEFINE_UNQUOTED([LTTNG_HAVE_LIBC_UUID], 1, [Has libc uuid support.]) |
| 347 | have_libc_uuid=yes |
| 348 | ], |
| 349 | [ |
| 350 | AC_MSG_ERROR([Cannot find libuuid uuid_generate nor libc uuid_create. Either set PKG_CONFIG_PATH to the configuration file location or use LDFLAGS=-Ldir to specify the library location]) |
| 351 | ] |
| 352 | ) |
| 353 | ] |
| 354 | ) |
| 355 | ]) |
| 356 | AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBUUID], [test "x$have_libuuid" = "xyes"]) |
| 357 | AM_CONDITIONAL([LTTNG_BUILD_WITH_LIBC_UUID], [test "x$have_libc_uuid" = "xyes"]) |
| 358 | |
| 359 | # URCU library version needed or newer |
| 360 | m4_define([WRONG_LIBURCU_MSG], [Userspace RCU (liburcu) >= 0.8.0 is needed]) |
| 361 | |
| 362 | # Check liburcu needed function calls |
| 363 | AC_CHECK_DECL([cds_list_add], [], |
| 364 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/list.h>]]) |
| 365 | AC_CHECK_DECL([cds_wfcq_init], [], |
| 366 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]]) |
| 367 | AC_CHECK_DECL([cds_wfcq_dequeue_blocking], [], |
| 368 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/wfcqueue.h>]]) |
| 369 | AC_CHECK_DECL([futex_async], [], |
| 370 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu/futex.h>]]) |
| 371 | AC_CHECK_DECL([rcu_thread_offline], [], |
| 372 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]) |
| 373 | AC_CHECK_DECL([rcu_thread_online], [], |
| 374 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]) |
| 375 | AC_CHECK_DECL([caa_likely], [], |
| 376 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]]) |
| 377 | AC_CHECK_LIB([urcu-cds], [_cds_lfht_new], [], |
| 378 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])]) |
| 379 | |
| 380 | #Function added in urcu 0.7.0 |
| 381 | AC_CHECK_DECL([cmm_smp_mb__before_uatomic_or], [], |
| 382 | [AC_MSG_ERROR([WRONG_LIBURCU_MSG])], [[#include <urcu.h>]] |
| 383 | ) |
| 384 | |
| 385 | # Check kmod library |
| 386 | AC_ARG_WITH(kmod-prefix, |
| 387 | AS_HELP_STRING([--with-kmod-prefix=PATH], |
| 388 | [Specify the installation prefix of the kmod library. |
| 389 | Headers must be in PATH/include; libraries in PATH/lib.]), |
| 390 | [ |
| 391 | CPPFLAGS="$CPPFLAGS -I${withval}/include" |
| 392 | LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib" |
| 393 | ]) |
| 394 | |
| 395 | AC_ARG_ENABLE(kmod, |
| 396 | AS_HELP_STRING([--disable-kmod],[build without kmod support]), |
| 397 | kmod_support=$enableval, kmod_support=yes) |
| 398 | |
| 399 | AS_IF([test "x$kmod_support" = "xyes"], [ |
| 400 | AC_CHECK_LIB([kmod], [kmod_module_probe_insert_module], |
| 401 | [ |
| 402 | AC_DEFINE([HAVE_KMOD], [1], [has kmod support]) |
| 403 | LIBS="$LIBS -lkmod" |
| 404 | kmod_found=yes |
| 405 | ], |
| 406 | kmod_found=no |
| 407 | ) |
| 408 | ]) |
| 409 | AM_CONDITIONAL([HAVE_KMOD], [test "x$kmod_found" = xyes]) |
| 410 | |
| 411 | AC_ARG_WITH(lttng-ust-prefix, |
| 412 | AS_HELP_STRING([--with-lttng-ust-prefix=PATH], |
| 413 | [Specify the installation prefix of the lttng-ust library. |
| 414 | Headers must be in PATH/include; libraries in PATH/lib.]), |
| 415 | [ |
| 416 | CPPFLAGS="$CPPFLAGS -I${withval}/include" |
| 417 | LDFLAGS="$LDFLAGS -L${withval}/lib64 -L${withval}/lib" |
| 418 | ]) |
| 419 | |
| 420 | # Check liblttng-ust-ctl library |
| 421 | AC_ARG_WITH(lttng-ust, |
| 422 | AS_HELP_STRING([--without-lttng-ust],[build without LTTng-UST (Userspace Tracing) support]), |
| 423 | lttng_ust_support=$withval, lttng_ust_support=yes) |
| 424 | |
| 425 | AS_IF([test "x$lttng_ust_support" = "xyes"], [ |
| 426 | AC_CHECK_LIB([lttng-ust-ctl], [ustctl_recv_channel_from_consumer], |
| 427 | [ |
| 428 | AC_DEFINE([HAVE_LIBLTTNG_UST_CTL], [1], [has LTTng-UST control support]) |
| 429 | lttng_ust_ctl_found=yes |
| 430 | ], |
| 431 | [AC_MSG_ERROR([Cannot find LTTng-UST >= 2.2.x. Use --with-lttng-ust-prefix=PREFIX to specify its location, or specify --without-lttng-ust to build lttng-tools without LTTng-UST support.])], |
| 432 | [-lurcu-common -lurcu-bp -lurcu-cds -lrt -ldl] |
| 433 | ) |
| 434 | ]) |
| 435 | AM_CONDITIONAL([HAVE_LIBLTTNG_UST_CTL], [test "x$lttng_ust_ctl_found" = xyes]) |
| 436 | AC_CHECK_FUNCS([sched_getcpu sysconf sync_file_range]) |
| 437 | |
| 438 | # check for dlopen |
| 439 | AC_CHECK_LIB([dl], [dlopen], |
| 440 | [ |
| 441 | have_libdl=yes |
| 442 | ], |
| 443 | [ |
| 444 | #libdl not found, check for dlopen in libc. |
| 445 | AC_CHECK_LIB([c], [dlopen], |
| 446 | [ |
| 447 | have_libc_dl=yes |
| 448 | ], |
| 449 | [ |
| 450 | AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.]) |
| 451 | ]) |
| 452 | ]) |
| 453 | AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBDL], [test "x$have_libdl" = "xyes"]) |
| 454 | AM_CONDITIONAL([LTTNG_TOOLS_BUILD_WITH_LIBC_DL], [test "x$have_libc_dl" = "xyes"]) |
| 455 | |
| 456 | # Check for fmemopen |
| 457 | AC_CHECK_LIB([c], [fmemopen], |
| 458 | [ |
| 459 | AC_DEFINE_UNQUOTED([LTTNG_HAVE_FMEMOPEN], 1, [Has fmemopen support.]) |
| 460 | ] |
| 461 | ) |
| 462 | |
| 463 | # Check for open_memstream |
| 464 | AC_CHECK_LIB([c], [open_memstream], |
| 465 | [ |
| 466 | AC_DEFINE_UNQUOTED([LTTNG_HAVE_OPEN_MEMSTREAM], 1, [Has open_memstream support.]) |
| 467 | ] |
| 468 | ) |
| 469 | |
| 470 | AC_ARG_ENABLE([git-version], |
| 471 | [AC_HELP_STRING([--disable-git-version], |
| 472 | [Do not use the git version for the build])], |
| 473 | [have_git_version=$enableval], [have_git_version=yes] |
| 474 | ) |
| 475 | |
| 476 | AM_CONDITIONAL([LTTNG_TOOLS_BUILD_GIT_SOURCE], |
| 477 | [test "x${have_git_version}" = "xyes"]) |
| 478 | |
| 479 | # For Python |
| 480 | # SWIG version needed or newer: |
| 481 | swig_version=2.0.0 |
| 482 | |
| 483 | AC_ARG_ENABLE([python-bindings], |
| 484 | [AC_HELP_STRING([--enable-python-bindings], |
| 485 | [compile Python bindings])], |
| 486 | [enable_python_binding=$enableval], [enable_python_binding=no]) |
| 487 | |
| 488 | AM_CONDITIONAL([PYTHON_BINDING], [test "x$enable_python_binding" = xyes]) |
| 489 | |
| 490 | if test "x$enable_python_binding" = xyes; then |
| 491 | AX_PKG_SWIG($swig_version, [], [ AC_MSG_ERROR([SWIG $swig_version or newer is needed]) ]) |
| 492 | AS_IF([test x$enable_shared = xno], [ AC_MSG_ERROR([Python bindings require shared libraries.]) ]) |
| 493 | AM_PATH_PYTHON([3.0]) |
| 494 | |
| 495 | AC_ARG_VAR([PYTHON_INCLUDE], [Include flags for python, bypassing python-config]) |
| 496 | AC_ARG_VAR([PYTHON_CONFIG], [Path to python-config]) |
| 497 | AS_IF([test -z "$PYTHON_INCLUDE"], [ |
| 498 | AS_IF([test -z "$PYTHON_CONFIG"], [ |
| 499 | AC_PATH_PROGS([PYTHON_CONFIG], |
| 500 | [python$PYTHON_VERSION-config python-config], |
| 501 | [no], |
| 502 | [`dirname $PYTHON`]) |
| 503 | AS_IF([test "$PYTHON_CONFIG" = no], [AC_MSG_ERROR([cannot find python-config for $PYTHON. Do you have python-dev installed?])]) |
| 504 | ]) |
| 505 | AC_MSG_CHECKING([python include flags]) |
| 506 | PYTHON_INCLUDE=`$PYTHON_CONFIG --includes` |
| 507 | AC_MSG_RESULT([$PYTHON_INCLUDE]) |
| 508 | ]) |
| 509 | |
| 510 | else |
| 511 | AC_MSG_NOTICE([You may configure with --enable-python-bindings ]dnl |
| 512 | [if you want Python bindings.]) |
| 513 | |
| 514 | fi |
| 515 | |
| 516 | # Epoll check. If not present, the build will fallback on poll() API |
| 517 | AX_HAVE_EPOLL( |
| 518 | [AX_CONFIG_FEATURE_ENABLE(epoll)], |
| 519 | [AX_CONFIG_FEATURE_DISABLE(epoll)] |
| 520 | ) |
| 521 | AX_CONFIG_FEATURE( |
| 522 | [epoll], [This platform supports epoll(7)], |
| 523 | [HAVE_EPOLL], [This platform supports epoll(7).], |
| 524 | [enable_epoll="yes"], [enable_epoll="no"] |
| 525 | ) |
| 526 | AM_CONDITIONAL([COMPAT_EPOLL], [ test "$enable_epoll" = "yes" ]) |
| 527 | |
| 528 | AM_CONDITIONAL([TEST_JAVA_JUL_AGENT], [test "x$test_java_agent_jul" = "xyes"]) |
| 529 | AM_CONDITIONAL([TEST_JAVA_LOG4J_AGENT], [test "x$test_java_agent_log4j" = "xyes"]) |
| 530 | |
| 531 | if test "x$test_java_agent_jul" = "xyes" || test "x$test_java_agent_log4j" = "xyes"; then |
| 532 | AX_JAVA_OPTIONS |
| 533 | AX_PROG_JAVAC |
| 534 | AX_PROG_JAVA |
| 535 | AX_PROG_JAR |
| 536 | |
| 537 | AX_CHECK_CLASSPATH |
| 538 | |
| 539 | # Check for Java UST agent common class first |
| 540 | AX_CHECK_CLASS(org.lttng.ust.agent.AbstractLttngAgent) |
| 541 | if test "x$ac_cv_class_org_lttng_ust_agent_AbstractLttngAgent" = "xno"; then |
| 542 | AC_MSG_ERROR([The UST Java agent common class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-common.jar"]) |
| 543 | fi |
| 544 | |
| 545 | if test "x$test_java_agent_jul" = "xyes"; then |
| 546 | # Check for JUL agent class |
| 547 | AX_CHECK_CLASS(org.lttng.ust.agent.jul.LttngLogHandler) |
| 548 | if test "x$ac_cv_class_org_lttng_ust_agent_jul_LttngLogHandler" = "xno"; then |
| 549 | AC_MSG_ERROR([The UST Java agent JUL class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-jul.jar"]) |
| 550 | fi |
| 551 | fi |
| 552 | |
| 553 | if test "x$test_java_agent_log4j" = "xyes"; then |
| 554 | # Check for Log4j agent class |
| 555 | AX_CHECK_CLASS(org.lttng.ust.agent.log4j.LttngLogAppender) |
| 556 | if test "x$ac_cv_class_org_lttng_ust_agent_log4j_LttngLogAppender" = "xno"; then |
| 557 | AC_MSG_ERROR([The UST Java agent Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/lttng-ust-agent-log4j.jar"]) |
| 558 | fi |
| 559 | |
| 560 | # Check for Log4j class |
| 561 | AX_CHECK_CLASS(org.apache.log4j.Logger) |
| 562 | if test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"; then |
| 563 | AC_MSG_ERROR([The Log4j class was not found. Please specify the location of the jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"]) |
| 564 | fi |
| 565 | fi |
| 566 | fi |
| 567 | |
| 568 | # set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file |
| 569 | # is not distributed in tarballs |
| 570 | AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no]) |
| 571 | AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"]) |
| 572 | |
| 573 | # enable building man pages (user's intention) |
| 574 | AC_ARG_ENABLE( |
| 575 | man-pages, |
| 576 | AS_HELP_STRING( |
| 577 | [--disable-man-pages], |
| 578 | [Do not build and install man pages (already built in a distributed tarball)] |
| 579 | ), |
| 580 | [man_pages_opt=$enableval], |
| 581 | [man_pages_opt=yes] |
| 582 | ) |
| 583 | |
| 584 | # check for asciidoc and xmlto if we enabled building the man pages |
| 585 | have_asciidoc_xmlto=no |
| 586 | |
| 587 | AS_IF([test "x$man_pages_opt" = "xyes"], [ |
| 588 | AC_PATH_PROG([ASCIIDOC], [asciidoc], [no]) |
| 589 | AC_PATH_PROG([XMLTO], [xmlto], [no]) |
| 590 | |
| 591 | AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [ |
| 592 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| 593 | # this is an error because we're in the Git repo, which |
| 594 | # means the man pages are not already generated for us, |
| 595 | # thus asciidoc/xmlto are required because we were asked |
| 596 | # to build the man pages |
| 597 | AC_MSG_ERROR([ |
| 598 | Both asciidoc and xmlto are needed to build the LTTng man pages. Use |
| 599 | --disable-man-pages to disable building the man pages, in which case |
| 600 | they will not be installed. |
| 601 | ]) |
| 602 | ], [ |
| 603 | # only warn here: since we're in the tarball, the man |
| 604 | # pages should already be generated at this point, thus |
| 605 | # asciidoc/xmlto are not strictly required |
| 606 | AC_MSG_WARN([ |
| 607 | Both asciidoc and xmlto are needed to build the LTTng man pages. Note |
| 608 | that the man pages are already built in this distribution tarball, so |
| 609 | asciidoc and xmlto are only needed if you intend to modify their |
| 610 | sources. Use --disable-man-pages to completely disable building |
| 611 | and installing the man pages. |
| 612 | ]) |
| 613 | ]) |
| 614 | ], [ |
| 615 | have_asciidoc_xmlto=yes |
| 616 | ]) |
| 617 | ]) |
| 618 | |
| 619 | # export man page build condition: build the man pages if the user |
| 620 | # asked for it, and if the tools are available |
| 621 | AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"]) |
| 622 | AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"]) |
| 623 | |
| 624 | AC_DEFINE_UNQUOTED([MANPATH], ["`eval eval echo $mandir`"], [Path to man pages.]) |
| 625 | |
| 626 | # Python agent test |
| 627 | UST_PYTHON_AGENT="lttngust" |
| 628 | |
| 629 | AC_ARG_ENABLE(test-python2-agent, |
| 630 | AS_HELP_STRING([--enable-test-python2-agent], |
| 631 | [enable tests for python2 agent. Python2 interpreter path can be overridden by setting the PYTHON2 environment variable. Default: Autodetect] |
| 632 | ),[:],[test_python2_agent_autodetect=yes] |
| 633 | ) |
| 634 | |
| 635 | AC_ARG_ENABLE(test-python3-agent, |
| 636 | AS_HELP_STRING([--enable-test-python3-agent], |
| 637 | [enable tests for python3 agent. Python3 interpreter path can be overridden by setting the PYTHON3 environment variable. Default: Autodetect] |
| 638 | ),[:],[test_python3_agent_autodetect=yes] |
| 639 | ) |
| 640 | |
| 641 | AC_ARG_ENABLE(test-python-agent-all, |
| 642 | AS_HELP_STRING([--enable-test-python-agent-all], |
| 643 | [enable test for all python{2/3} agent.] |
| 644 | ), |
| 645 | ) |
| 646 | |
| 647 | AS_IF([test ! -z "$enable_test_python_agent_all"], [ |
| 648 | unset test_python2_agent_autodetect |
| 649 | unset test_python3_agent_autodetect |
| 650 | ]) |
| 651 | |
| 652 | AS_IF([test "x$enable_test_python_agent_all" = "xyes"], [ |
| 653 | enable_test_python2_agent=yes |
| 654 | enable_test_python3_agent=yes |
| 655 | ]) |
| 656 | |
| 657 | AS_IF([test "x$enable_test_python_agent_all" = "xno"], [ |
| 658 | enable_test_python2_agent=no |
| 659 | enable_test_python3_agent=no |
| 660 | ]) |
| 661 | |
| 662 | |
| 663 | AS_IF([test "x$enable_test_python2_agent" = "xyes" -o "x$test_python2_agent_autodetect" = "xyes" ], [ |
| 664 | AS_IF([test -z "$PYTHON2"], [ |
| 665 | PYTHON2=python2 |
| 666 | ], [ |
| 667 | AC_MSG_WARN([Using user-defined PYTHON2 ($PYTHON2) for lttng-ust python2 agent check]) |
| 668 | ]) |
| 669 | |
| 670 | AC_PATH_PROG([PYTHON2_BIN],[$PYTHON2]) |
| 671 | AS_IF([test -z "$PYTHON2_BIN"], [ |
| 672 | AS_IF([test -z "$test_python2_agent_autodetect"],[ |
| 673 | AC_MSG_ERROR([No python2 interpreter found. PYTHON2 can be set to override default interpreter path]) |
| 674 | ]) |
| 675 | ], [ |
| 676 | AC_MSG_CHECKING([for python2 lttng-ust agent]) |
| 677 | AS_IF([$PYTHON2_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [ |
| 678 | PYTHON2_AGENT=$PYTHON2_BIN |
| 679 | AC_MSG_RESULT([yes]) |
| 680 | RUN_PYTHON_AGENT_TEST=yes |
| 681 | ], [ |
| 682 | AC_MSG_RESULT([no]) |
| 683 | AS_IF([test -z "$test_python2_agent_autodetect"],[ |
| 684 | AC_MSG_ERROR([No python2 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.]) |
| 685 | ]) |
| 686 | ]) |
| 687 | |
| 688 | ]) |
| 689 | |
| 690 | ]) |
| 691 | |
| 692 | AS_IF([test "x$enable_test_python3_agent" = "xyes" -o "x$test_python3_agent_autodetect" = "xyes" ], [ |
| 693 | AS_IF([test -z "$PYTHON3"], [ |
| 694 | PYTHON3=python3 |
| 695 | ], [ |
| 696 | AC_MSG_WARN([Using user-defined PYTHON3 ($PYTHON3) for lttng-ust python3 agent check]) |
| 697 | ]) |
| 698 | |
| 699 | AC_PATH_PROG([PYTHON3_BIN],[$PYTHON3]) |
| 700 | AS_IF([test -z "$PYTHON3_BIN"], [ |
| 701 | AS_IF([test -z "$test_python3_agent_autodetect"],[ |
| 702 | AC_MSG_ERROR([No python3 interpreter found. PYTHON3 can be set to override default interpreter path]) |
| 703 | ]) |
| 704 | ], [ |
| 705 | AC_MSG_CHECKING([for python3 lttng-ust agent]) |
| 706 | AS_IF([$PYTHON3_BIN -c "import $UST_PYTHON_AGENT" 2>/dev/null], [ |
| 707 | PYTHON3_AGENT=$PYTHON3_BIN |
| 708 | AC_MSG_RESULT([yes]) |
| 709 | RUN_PYTHON_AGENT_TEST=yes |
| 710 | ], [ |
| 711 | AC_MSG_RESULT([no]) |
| 712 | AS_IF([test -z "$test_python3_agent_autodetect"],[ |
| 713 | AC_MSG_ERROR([No python3 agent found. The path to the agent can be specified by setting the PYTHONPATH environment variable.]) |
| 714 | ]) |
| 715 | ]) |
| 716 | |
| 717 | ]) |
| 718 | ]) |
| 719 | AC_SUBST([RUN_PYTHON_AGENT_TEST]) |
| 720 | AC_SUBST([PYTHON2_AGENT]) |
| 721 | AC_SUBST([PYTHON3_AGENT]) |
| 722 | |
| 723 | # Arguments for binaries build exclusion |
| 724 | AC_ARG_ENABLE([bin-lttng], AS_HELP_STRING([--disable-bin-lttng],[Disable the build of lttng binaries])) |
| 725 | AC_ARG_ENABLE([bin-lttng-consumerd], AS_HELP_STRING([--disable-bin-lttng-consumerd], |
| 726 | [Disable the build of lttng-consumerd binaries])) |
| 727 | AC_ARG_ENABLE([bin-lttng-crash], AS_HELP_STRING([--disable-bin-lttng-crash],[Disable the build of lttng-crash binaries])) |
| 728 | AC_ARG_ENABLE([bin-lttng-relayd], AS_HELP_STRING([--disable-bin-lttng-relayd], |
| 729 | [Disable the build of lttng-relayd binaries])) |
| 730 | AC_ARG_ENABLE([bin-lttng-sessiond], AS_HELP_STRING([--disable-bin-lttng-sessiond], |
| 731 | [Disable the build of lttng-sessiond binaries])) |
| 732 | AC_ARG_ENABLE([extras], AS_HELP_STRING([--disable-extras], |
| 733 | [Disable the build of the extra components])) |
| 734 | |
| 735 | |
| 736 | # Always build libconfig since it a dependency of libcommon |
| 737 | build_lib_config=yes |
| 738 | |
| 739 | build_lib_compat=no |
| 740 | build_lib_consumer=no |
| 741 | build_lib_hashtable=no |
| 742 | build_lib_health=no |
| 743 | build_lib_index=no |
| 744 | build_lib_kernel_consumer=no |
| 745 | build_lib_kernel_ctl=no |
| 746 | build_lib_lttng_ctl=no |
| 747 | build_lib_relayd=no |
| 748 | build_lib_sessiond_comm=no |
| 749 | build_lib_testpoint=no |
| 750 | build_lib_ust_consumer=no |
| 751 | |
| 752 | # There is an overlap for enabled dependencies, but this makes everything |
| 753 | # simpler. libcommon and libconfig are always compiled so they are not repeated |
| 754 | # here. |
| 755 | |
| 756 | # Enable binary dependencies. |
| 757 | AS_IF([test x$enable_bin_lttng != xno], |
| 758 | [ |
| 759 | build_lib_lttng_ctl=yes |
| 760 | ] |
| 761 | ) |
| 762 | |
| 763 | AS_IF([test x$enable_bin_lttng_consumerd != xno], |
| 764 | [ |
| 765 | build_lib_consumer=yes |
| 766 | build_lib_sessiond_comm=yes |
| 767 | build_lib_index=yes |
| 768 | build_lib_health=yes |
| 769 | build_lib_testpoint=yes |
| 770 | ] |
| 771 | ) |
| 772 | |
| 773 | AS_IF([test x$enable_bin_lttng_crash != xno], |
| 774 | # Do nothing since libconfig and libcommon are built by default. |
| 775 | [] |
| 776 | ) |
| 777 | |
| 778 | AS_IF([test x$enable_bin_lttng_relayd != xno], |
| 779 | [ |
| 780 | build_lib_lttng_ctl=yes |
| 781 | build_lib_sessiond_comm=yes |
| 782 | build_lib_hashtable=yes |
| 783 | build_lib_compat=yes |
| 784 | build_lib_index=yes |
| 785 | build_lib_health=yes |
| 786 | build_lib_testpoint=yes |
| 787 | ] |
| 788 | ) |
| 789 | AS_IF([test x$enable_bin_lttng_sessiond != xno], |
| 790 | [ |
| 791 | build_lib_lttng_ctl=yes |
| 792 | build_lib_sessiond_comm=yes |
| 793 | build_lib_kernel_ctl=yes |
| 794 | build_lib_hashtable=yes |
| 795 | build_lib_compat=yes |
| 796 | build_lib_relayd=yes |
| 797 | build_lib_testpoint=yes |
| 798 | build_lib_health=yes |
| 799 | build_lib_health=yes |
| 800 | ] |
| 801 | ) |
| 802 | |
| 803 | # Libraries dependencies enabling |
| 804 | AS_IF([test x$build_lib_lttng_ctl = xyes], |
| 805 | [ |
| 806 | build_lib_sessiond_comm=yes |
| 807 | build_lib_hashtable=yes |
| 808 | ] |
| 809 | ) |
| 810 | |
| 811 | AS_IF([test x$build_lib_consumer = xyes], |
| 812 | [ |
| 813 | build_lib_sessiond_comm=yes |
| 814 | build_lib_kernel_consumer=yes |
| 815 | build_lib_hashtable=yes |
| 816 | build_lib_compat=yes |
| 817 | build_lib_relayd=yes |
| 818 | AS_IF([test x$lttng_ust_ctl_found = xyes],[build_lib_ust_consumer=yes]) |
| 819 | ] |
| 820 | ) |
| 821 | |
| 822 | AS_IF([test x$build_lib_kernel_consumer = xyes], |
| 823 | [ |
| 824 | build_lib_kernel_ctl=yes |
| 825 | build_lib_relayd=yes |
| 826 | ] |
| 827 | ) |
| 828 | |
| 829 | AS_IF([test x$build_lib_relayd = xyes], |
| 830 | [ |
| 831 | build_lib_sessiond_comm=yes |
| 832 | ] |
| 833 | ) |
| 834 | |
| 835 | |
| 836 | # Export binaries build conditions. |
| 837 | AM_CONDITIONAL([BUILD_BIN_LTTNG], [test x$enable_bin_lttng != xno]) |
| 838 | AM_CONDITIONAL([BUILD_BIN_LTTNG_CONSUMERD], [test x$enable_bin_lttng_consumerd != xno]) |
| 839 | AM_CONDITIONAL([BUILD_BIN_LTTNG_CRASH], [test x$enable_bin_lttng_crash != xno]) |
| 840 | AM_CONDITIONAL([BUILD_BIN_LTTNG_RELAYD], [test x$enable_bin_lttng_relayd != xno]) |
| 841 | AM_CONDITIONAL([BUILD_BIN_LTTNG_SESSIOND], [test x$enable_bin_lttng_sessiond != xno]) |
| 842 | |
| 843 | # Export the tests and extras build conditions. |
| 844 | AS_IF([\ |
| 845 | test "x$enable_bin_lttng" != "xno" && \ |
| 846 | test "x$enable_bin_lttng_consumerd" != "xno" && \ |
| 847 | test "x$enable_bin_lttng_crash" != "xno" && \ |
| 848 | test "x$enable_bin_lttng_relayd" != "xno" && \ |
| 849 | test "x$enable_bin_lttng_sessiond" != "xno"], |
| 850 | [build_tests=yes], |
| 851 | [build_tests=no] |
| 852 | ) |
| 853 | |
| 854 | AM_CONDITIONAL([BUILD_TESTS], [test x$build_tests = xyes]) |
| 855 | AM_CONDITIONAL([BUILD_EXTRAS], [test x$enable_extras != xno]) |
| 856 | |
| 857 | # Export libraries build conditions. |
| 858 | AM_CONDITIONAL([BUILD_LIB_COMPAT], [test x$build_lib_compat = xyes]) |
| 859 | AM_CONDITIONAL([BUILD_LIB_CONFIG], [test x$build_lib_config = xyes]) |
| 860 | AM_CONDITIONAL([BUILD_LIB_CONSUMER], [test x$build_lib_consumer = xyes]) |
| 861 | AM_CONDITIONAL([BUILD_LIB_HASHTABLE], [test x$build_lib_hashtable = xyes]) |
| 862 | AM_CONDITIONAL([BUILD_LIB_HEALTH], [test x$build_lib_health = xyes]) |
| 863 | AM_CONDITIONAL([BUILD_LIB_INDEX], [test x$build_lib_index = xyes]) |
| 864 | AM_CONDITIONAL([BUILD_LIB_KERNEL_CONSUMER], [test x$build_lib_kernel_consumer = xyes]) |
| 865 | AM_CONDITIONAL([BUILD_LIB_KERNEL_CTL], [test x$build_lib_kernel_ctl = xyes]) |
| 866 | AM_CONDITIONAL([BUILD_LIB_LTTNG_CTL], [test x$build_lib_lttng_ctl = xyes]) |
| 867 | AM_CONDITIONAL([BUILD_LIB_RELAYD], [test x$build_lib_relayd = xyes]) |
| 868 | AM_CONDITIONAL([BUILD_LIB_SESSIOND_COMM], [test x$build_lib_sessiond_comm = xyes]) |
| 869 | AM_CONDITIONAL([BUILD_LIB_TESTPOINT], [test x$build_lib_testpoint = xyes]) |
| 870 | AM_CONDITIONAL([BUILD_LIB_UST_CONSUMER], [test x$build_lib_ust_consumer = xyes]) |
| 871 | |
| 872 | # check for pgrep |
| 873 | AC_PATH_PROG([PGREP], [pgrep], [no]) |
| 874 | AM_CONDITIONAL([HAS_PGREP], [test "x$PGREP" != "xno"]) |
| 875 | |
| 876 | # check for bison |
| 877 | have_bison=yes |
| 878 | |
| 879 | AS_IF([test "x$(basename "$YACC")" != "xbison -y"], [have_bison=no]) |
| 880 | AC_PATH_PROG([BISON], [bison]) |
| 881 | AX_PROG_BISON_VERSION([2.4], [], [have_bison=no]) |
| 882 | |
| 883 | AS_IF([test "x$have_bison" = "xno"], [ |
| 884 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| 885 | AC_MSG_ERROR([Bison >= 2.4 is required when building from the Git repository.]) |
| 886 | ], [ |
| 887 | AC_MSG_WARN([ |
| 888 | Missing Bison >= 2.4. Note that the parser files are already built in |
| 889 | this distribution tarball, so Bison is only needed if you intend to |
| 890 | modify their sources. |
| 891 | ]) |
| 892 | ]) |
| 893 | ]) |
| 894 | |
| 895 | # export bison condition |
| 896 | AM_CONDITIONAL([HAVE_BISON], [test "x$have_bison" = "xyes"]) |
| 897 | |
| 898 | # check for flex |
| 899 | have_flex=yes |
| 900 | |
| 901 | AS_IF([test "x$LEX" != "xflex"], [have_flex=no]) |
| 902 | AC_PATH_PROG([FLEX], [flex]) |
| 903 | AX_PROG_FLEX_VERSION([2.5.35], [], [have_flex=no]) |
| 904 | |
| 905 | AS_IF([test "x$have_flex" = "xno"], [ |
| 906 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| 907 | AC_MSG_ERROR([Flex >= 2.5.35 is required when building from the Git repository.]) |
| 908 | ], [ |
| 909 | AC_MSG_WARN([ |
| 910 | Missing Flex >= 2.5.35. Note that the lexer files are already built in |
| 911 | this distribution tarball, so Flex is only needed if you intend to |
| 912 | modify their sources. |
| 913 | ]) |
| 914 | ]) |
| 915 | ]) |
| 916 | |
| 917 | # export flex condition |
| 918 | AM_CONDITIONAL([HAVE_FLEX], [test "x$have_flex" = "xyes"]) |
| 919 | |
| 920 | CFLAGS="-Wall $CFLAGS -g -fno-strict-aliasing" |
| 921 | |
| 922 | DEFAULT_INCLUDES="-I\$(top_srcdir) -I\$(top_builddir) -I\$(top_builddir)/src -I\$(top_builddir)/include -include config.h" |
| 923 | |
| 924 | lttngincludedir="${includedir}/lttng" |
| 925 | |
| 926 | AC_SUBST(lttngincludedir) |
| 927 | AC_SUBST(DEFAULT_INCLUDES) |
| 928 | |
| 929 | lttnglibexecdir="${libdir}/lttng/libexec" |
| 930 | AC_SUBST(lttnglibexecdir) |
| 931 | |
| 932 | AC_CONFIG_FILES([ |
| 933 | Makefile |
| 934 | doc/Makefile |
| 935 | doc/man/Makefile |
| 936 | doc/man/asciidoc-attrs.conf |
| 937 | include/Makefile |
| 938 | extras/Makefile |
| 939 | extras/bindings/Makefile |
| 940 | extras/bindings/swig/Makefile |
| 941 | extras/bindings/swig/python/Makefile |
| 942 | extras/core-handler/Makefile |
| 943 | src/Makefile |
| 944 | src/common/Makefile |
| 945 | src/common/kernel-ctl/Makefile |
| 946 | src/common/kernel-consumer/Makefile |
| 947 | src/common/consumer/Makefile |
| 948 | src/common/ust-consumer/Makefile |
| 949 | src/common/hashtable/Makefile |
| 950 | src/common/sessiond-comm/Makefile |
| 951 | src/common/compat/Makefile |
| 952 | src/common/relayd/Makefile |
| 953 | src/common/testpoint/Makefile |
| 954 | src/common/index/Makefile |
| 955 | src/common/health/Makefile |
| 956 | src/common/config/Makefile |
| 957 | src/lib/Makefile |
| 958 | src/lib/lttng-ctl/Makefile |
| 959 | src/lib/lttng-ctl/filter/Makefile |
| 960 | src/lib/lttng-ctl/lttng-ctl.pc |
| 961 | src/bin/Makefile |
| 962 | src/bin/lttng-consumerd/Makefile |
| 963 | src/bin/lttng-sessiond/Makefile |
| 964 | src/bin/lttng-relayd/Makefile |
| 965 | src/bin/lttng/Makefile |
| 966 | src/bin/lttng-crash/Makefile |
| 967 | tests/Makefile |
| 968 | tests/destructive/Makefile |
| 969 | tests/regression/Makefile |
| 970 | tests/regression/kernel/Makefile |
| 971 | tests/regression/tools/Makefile |
| 972 | tests/regression/tools/streaming/Makefile |
| 973 | tests/regression/tools/filtering/Makefile |
| 974 | tests/regression/tools/health/Makefile |
| 975 | tests/regression/tools/tracefile-limits/Makefile |
| 976 | tests/regression/tools/snapshots/Makefile |
| 977 | tests/regression/tools/live/Makefile |
| 978 | tests/regression/tools/exclusion/Makefile |
| 979 | tests/regression/tools/save-load/Makefile |
| 980 | tests/regression/tools/mi/Makefile |
| 981 | tests/regression/tools/wildcard/Makefile |
| 982 | tests/regression/tools/crash/Makefile |
| 983 | tests/regression/tools/metadata-regen/Makefile |
| 984 | tests/regression/ust/Makefile |
| 985 | tests/regression/ust/nprocesses/Makefile |
| 986 | tests/regression/ust/high-throughput/Makefile |
| 987 | tests/regression/ust/low-throughput/Makefile |
| 988 | tests/regression/ust/before-after/Makefile |
| 989 | tests/regression/ust/buffers-pid/Makefile |
| 990 | tests/regression/ust/periodical-metadata-flush/Makefile |
| 991 | tests/regression/ust/multi-session/Makefile |
| 992 | tests/regression/ust/overlap/Makefile |
| 993 | tests/regression/ust/overlap/demo/Makefile |
| 994 | tests/regression/ust/linking/Makefile |
| 995 | tests/regression/ust/daemon/Makefile |
| 996 | tests/regression/ust/exit-fast/Makefile |
| 997 | tests/regression/ust/fork/Makefile |
| 998 | tests/regression/ust/libc-wrapper/Makefile |
| 999 | tests/regression/ust/baddr-statedump/Makefile |
| 1000 | tests/regression/ust/ust-dl/Makefile |
| 1001 | tests/regression/ust/java-jul/Makefile |
| 1002 | tests/regression/ust/java-log4j/Makefile |
| 1003 | tests/regression/ust/python-logging/Makefile |
| 1004 | tests/regression/ust/getcpu-override/Makefile |
| 1005 | tests/regression/ust/clock-override/Makefile |
| 1006 | tests/regression/ust/type-declarations/Makefile |
| 1007 | tests/regression/ust/rotation-destroy-flush/Makefile |
| 1008 | tests/stress/Makefile |
| 1009 | tests/unit/Makefile |
| 1010 | tests/unit/ini_config/Makefile |
| 1011 | tests/utils/Makefile |
| 1012 | tests/utils/tap/Makefile |
| 1013 | tests/utils/testapp/Makefile |
| 1014 | tests/utils/testapp/gen-ust-events/Makefile |
| 1015 | tests/utils/testapp/gen-ust-nevents/Makefile |
| 1016 | tests/utils/testapp/gen-ust-tracef/Makefile |
| 1017 | ]) |
| 1018 | |
| 1019 | # Inject variable into python test script. |
| 1020 | AC_CONFIG_FILES([tests/regression/ust/python-logging/test_python_logging],[chmod +x tests/regression/ust/python-logging/test_python_logging]) |
| 1021 | |
| 1022 | AC_OUTPUT |
| 1023 | |
| 1024 | # |
| 1025 | # Mini-report on what will be built. |
| 1026 | # |
| 1027 | |
| 1028 | PPRINT_INIT |
| 1029 | PPRINT_SET_INDENT(1) |
| 1030 | PPRINT_SET_TS(38) |
| 1031 | |
| 1032 | AS_ECHO |
| 1033 | AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-tools $PACKAGE_VERSION \"$version_name\"$PPRINT_COLOR_RST") |
| 1034 | AS_ECHO |
| 1035 | |
| 1036 | AS_IF([test -n "$report_fold"], [ |
| 1037 | AS_ECHO("`AS_ECHO("$version_description") | $report_fold -s`") |
| 1038 | ], [ |
| 1039 | AS_ECHO("$version_description") |
| 1040 | ]) |
| 1041 | |
| 1042 | AS_ECHO |
| 1043 | PPRINT_SUBTITLE([Features]) |
| 1044 | |
| 1045 | # Target architecture we're building for. |
| 1046 | target_arch=$host_cpu |
| 1047 | [ |
| 1048 | for f in $CFLAGS; do |
| 1049 | if test $f = "-m32"; then |
| 1050 | target_arch="32-bit" |
| 1051 | elif test $f = "-m64"; then |
| 1052 | target_arch="64-bit" |
| 1053 | fi |
| 1054 | done |
| 1055 | ] |
| 1056 | PPRINT_PROP_STRING([Target architecture], $target_arch) |
| 1057 | |
| 1058 | # kmod enabled/disabled |
| 1059 | test "x$kmod_found" = "xyes" && value=1 || value=0 |
| 1060 | PPRINT_PROP_BOOL([libkmod support], $value) |
| 1061 | |
| 1062 | # LTTng-UST enabled/disabled |
| 1063 | test "x$lttng_ust_support" = "xyes" && value=1 || value=0 |
| 1064 | PPRINT_PROP_BOOL([LTTng-UST support], $value) |
| 1065 | |
| 1066 | AS_ECHO |
| 1067 | PPRINT_SUBTITLE([Binaries]) |
| 1068 | |
| 1069 | # List binaries to be built |
| 1070 | test x$enable_bin_lttng != xno && value=1 || value=0 |
| 1071 | PPRINT_PROP_BOOL([lttng], $value) |
| 1072 | |
| 1073 | test x$enable_bin_lttng_consumerd != xno && value=1 || value=0 |
| 1074 | PPRINT_PROP_BOOL([lttng-consumerd], $value) |
| 1075 | |
| 1076 | test x$enable_bin_lttng_crash != xno && value=1 || value=0 |
| 1077 | PPRINT_PROP_BOOL([lttng-crash], $value) |
| 1078 | |
| 1079 | test x$enable_bin_lttng_relayd != xno && value=1 || value=0 |
| 1080 | PPRINT_PROP_BOOL([lttng-relayd], $value) |
| 1081 | |
| 1082 | test x$enable_bin_lttng_sessiond != xno && value=1 || value=0 |
| 1083 | PPRINT_PROP_BOOL([lttng-sessiond], $value) |
| 1084 | |
| 1085 | # Extras |
| 1086 | test x$enable_extras != xno && value=1 || value=0 |
| 1087 | AS_ECHO |
| 1088 | PPRINT_SET_INDENT(0) |
| 1089 | PPRINT_PROP_BOOL([Extras], $value, $PPRINT_COLOR_SUBTITLE) |
| 1090 | PPRINT_SET_INDENT(1) |
| 1091 | |
| 1092 | AS_ECHO |
| 1093 | PPRINT_SUBTITLE([Tests]) |
| 1094 | |
| 1095 | # Print clear message that tests won't be built |
| 1096 | AS_IF([test "x$build_tests" = "xno"],[ |
| 1097 | PPRINT_WARN([Tests won't be built since some binaries were disabled]) |
| 1098 | ]) |
| 1099 | |
| 1100 | # LTTng UST Java agent JUL tests enabled/disabled |
| 1101 | test "x$test_java_agent_jul" = "xyes" && value=1 || value=0 |
| 1102 | PPRINT_PROP_BOOL([LTTng-UST Java agent JUL tests], $value) |
| 1103 | |
| 1104 | # LTTng UST Java agent Log4j tests enabled/disabled |
| 1105 | test "x$test_java_agent_log4j" = "xyes" && value=1 || value=0 |
| 1106 | PPRINT_PROP_BOOL([LTTng-UST Java agent Log4j tests], $value) |
| 1107 | |
| 1108 | test ! -z "$PYTHON2_AGENT" && value=1 || value=0 |
| 1109 | PPRINT_PROP_BOOL([LTTng-UST Python2 agent tests], $value) |
| 1110 | |
| 1111 | test ! -z "$PYTHON3_AGENT" && value=1 || value=0 |
| 1112 | PPRINT_PROP_BOOL([LTTng-UST Python3 agent tests], $value) |
| 1113 | |
| 1114 | #Python binding enabled/disabled |
| 1115 | test "x$enable_python_binding" = xyes && value=1 || value=0 |
| 1116 | AS_ECHO |
| 1117 | PPRINT_SET_INDENT(0) |
| 1118 | PPRINT_PROP_BOOL([Python binding], $value, $PPRINT_COLOR_SUBTITLE) |
| 1119 | |
| 1120 | # man pages build enabled/disabled |
| 1121 | m4_pushdef([build_man_pages_msg], [Build and install man pages]) |
| 1122 | |
| 1123 | AS_IF([test "x$man_pages_opt" != "xno"], [ |
| 1124 | AS_IF([test "x$in_git_repo" = "xyes"], [ |
| 1125 | PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE) |
| 1126 | ], [ |
| 1127 | AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [ |
| 1128 | PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE) |
| 1129 | ], [ |
| 1130 | PPRINT_PROP_STRING([build_man_pages_msg], |
| 1131 | [${PPRINT_COLOR_BLDGRN}yes (already built)], |
| 1132 | $PPRINT_COLOR_SUBTITLE) |
| 1133 | ]) |
| 1134 | ]) |
| 1135 | ], [ |
| 1136 | PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE) |
| 1137 | ]) |
| 1138 | |
| 1139 | m4_popdef([build_man_pages_msg]) |
| 1140 | |
| 1141 | PPRINT_SET_INDENT(1) |
| 1142 | |
| 1143 | report_bindir="`eval eval echo $bindir`" |
| 1144 | report_libdir="`eval eval echo $libdir`" |
| 1145 | |
| 1146 | # Print the bindir and libdir this `make install' will install into. |
| 1147 | AS_ECHO |
| 1148 | PPRINT_SUBTITLE([Install directories]) |
| 1149 | PPRINT_PROP_STRING([Binaries], [$report_bindir]) |
| 1150 | PPRINT_PROP_STRING([Libraries], [$report_libdir]) |
| 1151 | |
| 1152 | AS_ECHO |
| 1153 | PPRINT_SUBTITLE([Search directories]) |
| 1154 | |
| 1155 | # If we build the sessiond, print the paths it will use |
| 1156 | AS_IF([test "$SESSIOND_BIN" = ""],[ |
| 1157 | path="$report_bindir/lttng-sessiond" |
| 1158 | ],[ |
| 1159 | path="$SESSIOND_BIN" |
| 1160 | ]) |
| 1161 | PPRINT_PROP_STRING([lttng-sessiond executable], [$path]) |
| 1162 | |
| 1163 | AS_IF([test "$CONSUMERD32_BIN" = ""],[ |
| 1164 | path="`eval eval echo $lttnglibexecdir`/lttng-consumerd" |
| 1165 | ],[ |
| 1166 | path="$CONSUMERD32_BIN" |
| 1167 | ]) |
| 1168 | PPRINT_PROP_STRING([32-bit lttng-consumerd executable], [$path]) |
| 1169 | |
| 1170 | AS_IF([test "$CONSUMERD32_LIBDIR" = ""],[ |
| 1171 | path="`eval eval echo $libdir`" |
| 1172 | ],[ |
| 1173 | path="$CONSUMERD32_LIBDIR" |
| 1174 | ]) |
| 1175 | PPRINT_PROP_STRING([32-bit consumer libraries], [$path]) |
| 1176 | |
| 1177 | AS_IF([test "$CONSUMERD64_BIN" = ""],[ |
| 1178 | path="`eval eval echo $lttnglibexecdir`/lttng-consumerd" |
| 1179 | ],[ |
| 1180 | path="$CONSUMERD64_BIN" |
| 1181 | ]) |
| 1182 | PPRINT_PROP_STRING([64-bit lttng-consumerd executable], [$path]) |
| 1183 | |
| 1184 | AS_IF([test "$CONSUMERD64_LIBDIR" = ""],[ |
| 1185 | path="`eval eval echo $libdir`" |
| 1186 | ],[ |
| 1187 | path="$CONSUMERD64_LIBDIR" |
| 1188 | ]) |
| 1189 | PPRINT_PROP_STRING([64-bit consumer libraries], [$path]) |