Commit | Line | Data |
---|---|---|
074c3a1b | 1 | AC_PREREQ(2.59) |
d5edb898 | 2 | AC_INIT([userspace-rcu],[0.10.0-pre],[mathieu dot desnoyers at efficios dot com], [], [http://liburcu.org/]) |
98bc124a YB |
3 | |
4 | # Following the numbering scheme proposed by libtool for the library version | |
5 | # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html | |
9e5f4ff4 | 6 | AC_SUBST([URCU_LIBRARY_VERSION], [5:0:1]) |
98bc124a | 7 | |
6893800a | 8 | AC_CONFIG_HEADERS([include/config.h include/urcu/config.h]) |
48d848c7 | 9 | AC_CONFIG_AUX_DIR([config]) |
074c3a1b MJ |
10 | AC_CONFIG_MACRO_DIR([m4]) |
11 | ||
7d413817 MD |
12 | AC_CANONICAL_TARGET |
13 | AC_CANONICAL_HOST | |
074c3a1b | 14 | |
6893800a | 15 | AM_INIT_AUTOMAKE([foreign dist-bzip2 no-dist-gzip nostdinc]) |
35eb2d6c | 16 | AM_MAINTAINER_MODE([enable]) |
7d413817 | 17 | |
074c3a1b MJ |
18 | # Enable silent rules if available (Introduced in AM 1.11) |
19 | m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])]) | |
e72596d1 | 20 | |
02be5561 MD |
21 | AH_TEMPLATE([CONFIG_RCU_SMP], [Enable SMP support. With SMP support enabled, uniprocessors are also supported. With SMP support disabled, UP systems work fine, but the behavior of SMP systems is undefined.]) |
22 | AH_TEMPLATE([CONFIG_RCU_HAVE_FENCE], [Defined when on a system that has memory fence instructions.]) | |
23 | AH_TEMPLATE([CONFIG_RCU_HAVE_FUTEX], [Defined when on a system with futex support.]) | |
a6412536 AM |
24 | AH_TEMPLATE([CONFIG_RCU_COMPAT_ARCH], [Compatibility mode for i386 which lacks cmpxchg instruction.]) |
25 | AH_TEMPLATE([CONFIG_RCU_ARM_HAVE_DMB], [Use the dmb instruction if available for use on ARM.]) | |
a767fdc3 | 26 | AH_TEMPLATE([CONFIG_RCU_TLS], [TLS provided by the compiler.]) |
a0307b90 | 27 | AH_TEMPLATE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [clock_gettime() is detected.]) |
d8d9a340 | 28 | AH_TEMPLATE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [Require the operating system to support the membarrier system call for default and bulletproof flavors.]) |
d4e640c0 | 29 | AH_TEMPLATE([CONFIG_RCU_DEBUG], [Enable internal debugging self-checks. Introduce performance penalty.]) |
d8d9a340 MD |
30 | |
31 | # Allow requiring the operating system to support the membarrier system | |
32 | # call. Applies to default and bulletproof flavors. | |
33 | AC_ARG_ENABLE([sys-membarrier-fallback], | |
34 | AS_HELP_STRING([--disable-sys-membarrier-fallback], [Abort if sys-membarrier is needed but not available rather than using a fallback.]), | |
35 | [def_sys_membarrier_fallback=$enableval], | |
36 | [def_sys_membarrier_fallback="yes"]) | |
37 | AS_IF([test "x$def_sys_membarrier_fallback" != "xyes"], [AC_DEFINE([CONFIG_RCU_FORCE_SYS_MEMBARRIER], [1])]) | |
a767fdc3 | 38 | |
75478b32 MD |
39 | # Allow overriding storage used for TLS variables. |
40 | AC_ARG_ENABLE([compiler-tls], | |
41 | AS_HELP_STRING([--disable-compiler-tls], [Use pthread_getspecific() to emulate Thread Local Storage (TLS) variables.]), | |
42 | [def_compiler_tls=$enableval], | |
43 | [def_compiler_tls="yes"]) | |
44 | ||
45 | # If not overridden, use ax_tls.m4 to check if TLS is available. | |
46 | AS_IF([test "x$def_compiler_tls" = "xyes"], | |
47 | [AX_TLS([def_tls_detect=$ac_cv_tls], [:])], | |
48 | [:]) | |
49 | ||
50 | AS_IF([test "x$def_tls_detect" = "x"], | |
51 | [:], | |
52 | [AC_DEFINE_UNQUOTED([CONFIG_RCU_TLS], $def_tls_detect)]) | |
48d848c7 | 53 | |
074c3a1b MJ |
54 | # Checks for C compiler |
55 | AC_USE_SYSTEM_EXTENSIONS | |
48d848c7 | 56 | AC_PROG_CC |
074c3a1b MJ |
57 | AC_PROG_CC_STDC |
58 | ||
59 | # Checks for programs. | |
27d5e306 | 60 | AC_PROG_AWK |
48d848c7 | 61 | AC_PROG_MAKE_SET |
074c3a1b | 62 | AC_CHECK_PROGS(NPROC, [nproc gnproc]) |
2350bf7b MJ |
63 | AC_CHECK_PROGS(GETCONF, [getconf]) |
64 | AS_IF([test "x$NPROC" != "x"], | |
65 | [NPROC_CMD=$NPROC], | |
66 | [AS_IF([test "x$GETCONF" != "x"], | |
67 | [NPROC_CMD="$GETCONF _NPROCESSORS_ONLN"], | |
68 | [NPROC_CMD="echo 1"] | |
69 | )] | |
70 | ) | |
71 | AC_SUBST([NPROC_CMD], [$NPROC_CMD]) | |
72 | ||
b14a378a | 73 | LT_INIT |
48d848c7 PMF |
74 | |
75 | # Checks for typedefs, structures, and compiler characteristics. | |
76 | AC_C_INLINE | |
77 | AC_TYPE_PID_T | |
78 | AC_TYPE_SIZE_T | |
27d5e306 MJ |
79 | AC_TYPE_SSIZE_T |
80 | AC_TYPE_UINT16_T | |
991d28ca JR |
81 | AC_TYPE_INT32_T |
82 | AC_TYPE_UINT32_T | |
83 | AC_TYPE_UINT64_T | |
84 | AC_TYPE_UINT8_T | |
48d848c7 | 85 | |
074c3a1b MJ |
86 | AX_C___ATTRIBUTE__ |
87 | AS_IF([test "x$ax_cv___attribute__" = "xyes"], | |
88 | [:], | |
89 | [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])]) | |
90 | ||
91 | AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])]) | |
074c3a1b | 92 | |
cdadd34c MJ |
93 | AM_CFLAGS="$AM_CFLAGS $PTHREAD_CFLAGS" |
94 | ||
48d848c7 | 95 | # Checks for library functions. |
48d848c7 | 96 | AC_FUNC_MMAP |
27d5e306 MJ |
97 | AC_FUNC_FORK |
98 | AC_CHECK_FUNCS([ \ | |
99 | atexit \ | |
27d5e306 MJ |
100 | getcpuid \ |
101 | gettid \ | |
102 | gettimeofday \ | |
103 | memeset \ | |
104 | memset \ | |
105 | munmap \ | |
3e4ae45a | 106 | rand_r \ |
27d5e306 MJ |
107 | sched_getcpu \ |
108 | strerror \ | |
109 | strtoul \ | |
110 | sysconf \ | |
111 | ]) | |
48d848c7 | 112 | |
9a62b0f0 MJ |
113 | # AC_FUNC_MALLOC causes problems when cross-compiling. |
114 | #AC_FUNC_MALLOC | |
115 | ||
bb6afa9a | 116 | # Check for headers |
7dea28e7 | 117 | AC_HEADER_STDBOOL |
27d5e306 MJ |
118 | AC_CHECK_HEADERS([ \ |
119 | limits.h \ | |
120 | stddef.h \ | |
121 | sys/param.h \ | |
122 | sys/time.h \ | |
123 | ]) | |
bb6afa9a | 124 | |
48d848c7 | 125 | # Find arch type |
58e9f838 | 126 | AS_CASE([$host_cpu], |
52fe6e60 | 127 | [k1om], [ARCHTYPE="x86"], |
a6412536 AM |
128 | [i386], [ARCHTYPE="x86" && SUBARCHTYPE="x86compat"], |
129 | [i486], [ARCHTYPE="x86"], | |
130 | [i586], [ARCHTYPE="x86"], | |
131 | [i686], [ARCHTYPE="x86"], | |
132 | [amd64], [ARCHTYPE="x86"], | |
133 | [x86_64], [ARCHTYPE="x86"], | |
134 | [powerpc], [ARCHTYPE="ppc"], | |
135 | [ppc64], [ARCHTYPE="ppc"], | |
136 | [powerpc64], [ARCHTYPE="ppc"], | |
61126bd9 | 137 | [powerpc64le], [ARCHTYPE="ppc"], |
a6412536 AM |
138 | [ppc], [ARCHTYPE="ppc"], |
139 | [s390], [ARCHTYPE="s390"], | |
140 | [s390x], [ARCHTYPE="s390"], | |
171ff3a3 | 141 | [sparc], [ARCHTYPE="sparc64"], |
a6412536 AM |
142 | [sparc64], [ARCHTYPE="sparc64"], |
143 | [alpha*], [ARCHTYPE="alpha"], | |
c21a8d01 | 144 | [ia64], [ARCHTYPE="ia64"], |
a6412536 | 145 | [arm*], [ARCHTYPE="arm"], |
d1c67842 | 146 | [aarch64*], [ARCHTYPE="aarch64"], |
e1259cb1 | 147 | [mips*], [ARCHTYPE="mips"], |
859050b3 | 148 | [nios2*], [ARCHTYPE="nios2"], |
c23069c6 | 149 | [tile*], [ARCHTYPE="tile"], |
13e0bc72 | 150 | [hppa*], [ARCHTYPE="hppa"], |
a6412536 AM |
151 | [ARCHTYPE="unknown"] |
152 | ) | |
91b0650a | 153 | |
b129d5d7 SB |
154 | AS_CASE([$host],[*-cygwin*], |
155 | [AM_CONDITIONAL(USE_CYGWIN, true)], | |
156 | [AM_CONDITIONAL(USE_CYGWIN, false)] | |
157 | ) | |
158 | ||
a6412536 AM |
159 | AC_SUBST(ARCHTYPE) |
160 | AC_SUBST(SUBARCHTYPE) | |
5e626e0e | 161 | |
6893800a MJ |
162 | UATOMICSRC=include/urcu/uatomic/$ARCHTYPE.h |
163 | ARCHSRC=include/urcu/arch/$ARCHTYPE.h | |
455b809a | 164 | |
a6412536 AM |
165 | AS_IF([test "x$SUBARCHTYPE" = xx86compat],[ |
166 | AC_DEFINE([CONFIG_RCU_COMPAT_ARCH], [1]) | |
167 | ]) | |
168 | ||
58e9f838 | 169 | AS_IF([test "$host_cpu" = "armv7l"],[ |
9a79c612 | 170 | AM_CFLAGS="$AM_CFLAGS -mcpu=cortex-a9 -mtune=cortex-a9 -O1" |
a6412536 | 171 | ]) |
48d848c7 | 172 | |
a6412536 AM |
173 | # ARM-specific checks |
174 | AS_IF([test "x$ARCHTYPE" = "xarm"],[ | |
175 | AC_MSG_CHECKING([for dmb instruction]) | |
fe0707ab MD |
176 | AC_COMPILE_IFELSE([AC_LANG_SOURCE([[ |
177 | int main() | |
178 | { | |
179 | asm volatile("dmb":::"memory"); | |
180 | return 0; | |
181 | } | |
182 | ]]) | |
183 | ],[ | |
a6412536 AM |
184 | AC_MSG_RESULT([yes]) |
185 | AC_DEFINE([CONFIG_RCU_ARM_HAVE_DMB], [1]) | |
186 | ],[ | |
187 | AC_MSG_RESULT([no]) | |
188 | ]) | |
189 | ]) | |
190 | ||
274773cf SM |
191 | # Tile-specific checks |
192 | AS_IF([echo "$host_cpu" | grep "^tile"],[ | |
193 | AC_MSG_CHECKING([for Tile architecture type]) | |
194 | AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[ | |
195 | #ifndef __tilegx__ | |
196 | #error | |
197 | #endif | |
198 | ]]) | |
199 | ],[ | |
200 | AC_MSG_RESULT([ok]) | |
201 | ],[ | |
202 | AC_MSG_FAILURE([URCU has only been tested on the TileGx architecture. For other Tile* architectures, please run the tests first and report the results to the maintainer so that proper support can be added.]) | |
203 | ]) | |
204 | ]) | |
205 | ||
a6412536 AM |
206 | # x86-specific checks |
207 | AS_IF([test "x$ARCHTYPE" = "xx86"],[ | |
208 | AC_MSG_CHECKING([if architecture really supports the mfence instruction]) | |
209 | #For now, using lock; addl compatibility mode even for i686, because the | |
210 | #Pentium III is seen as a i686, but lacks mfence instruction. | |
211 | #Only using fence for x86_64. | |
8496c886 SM |
212 | # |
213 | #k1om is the name for the Intel MIC family (Xeon Phi). It is an x86_64 | |
214 | #variant but lacks fence instructions. | |
52fe6e60 | 215 | AS_IF([test "x$host_cpu" != "xi386" -a "x$host_cpu" != "xi486" -a "x$host_cpu" != "xi586" -a "x$host_cpu" != "xi686" -a "x$host_vendor" != "xk1om" -a "x$host_cpu" != "xk1om"],[ |
a6412536 AM |
216 | AC_MSG_RESULT([yes]) |
217 | AC_DEFINE([CONFIG_RCU_HAVE_FENCE], [1]) | |
628a1a72 | 218 | config_rcu_have_fence=yes |
a6412536 AM |
219 | ],[ |
220 | AC_MSG_RESULT([no]) | |
628a1a72 | 221 | config_rcu_have_fence=no |
a6412536 AM |
222 | ]) |
223 | ]) | |
224 | ||
225 | # Check if sys_futex() is available | |
226 | AC_MSG_CHECKING([for sys_futex()]) | |
fe0707ab | 227 | AC_COMPILE_IFELSE([AC_LANG_SOURCE([[ |
a6412536 | 228 | #include <sys/syscall.h> |
a6412536 AM |
229 | #ifndef __NR_futex |
230 | #error "futexes not available" | |
231 | #endif | |
fe0707ab | 232 | ]]) |
a6412536 | 233 | ],[ |
0854ccff | 234 | AC_MSG_RESULT([yes]) |
02be5561 | 235 | AC_DEFINE([CONFIG_RCU_HAVE_FUTEX], [1]) |
0854ccff | 236 | compat_futex_test=0 |
91b0650a | 237 | ],[ |
0854ccff MD |
238 | AC_MSG_RESULT([no]) |
239 | compat_futex_test=1 | |
91b0650a | 240 | ]) |
0854ccff | 241 | |
8be0fb5f | 242 | # Search for clock_gettime |
a0307b90 MD |
243 | AC_SEARCH_LIBS([clock_gettime], [rt], [ |
244 | AC_DEFINE([CONFIG_RCU_HAVE_CLOCK_GETTIME], [1]) | |
628a1a72 | 245 | config_rcu_have_clock_gettime=yes |
a0307b90 | 246 | ], []) |
8be0fb5f | 247 | |
a6412536 AM |
248 | AM_CONDITIONAL([COMPAT_FUTEX], [test "x$compat_futex_test" = "x1"]) |
249 | AM_CONDITIONAL([COMPAT_ARCH], [test "x$SUBARCHTYPE" = "xx86compat"]) | |
2f49a496 | 250 | AM_CONDITIONAL([NO_SHARED], [test "x$enable_shared" = "xno"]) |
0854ccff | 251 | |
a6412536 AM |
252 | # smp-support configure option |
253 | AC_ARG_ENABLE([smp-support], | |
254 | AS_HELP_STRING([--disable-smp-support], [Disable SMP support. Warning: only use this on uniprocessor systems. [default=enabled]]), | |
255 | [def_smp_support=$enableval], | |
256 | [def_smp_support="yes"]) | |
257 | AS_IF([test "x$def_smp_support" = "xyes"], [AC_DEFINE([CONFIG_RCU_SMP], [1])]) | |
7d413817 | 258 | |
d4e640c0 JR |
259 | # RCU debugging option |
260 | AC_ARG_ENABLE([rcu-debug], | |
261 | AS_HELP_STRING([--enable-rcu-debug], [Enable internal debugging | |
262 | self-checks. Introduce performance penalty.])) | |
263 | AS_IF([test "x$enable_rcu_debug" = "xyes"], [ | |
264 | AC_DEFINE([CONFIG_RCU_DEBUG], [1]) | |
265 | ]) | |
48d848c7 | 266 | |
d8540fc5 PA |
267 | # From the sched_setaffinity(2)'s man page: |
268 | # ~~~~ | |
269 | # The CPU affinity system calls were introduced in Linux kernel 2.5.8. | |
270 | # The library interfaces were introduced in glibc 2.3. Initially, the | |
271 | # glibc interfaces included a cpusetsize argument. In glibc 2.3.3, | |
272 | # the cpuset size argument was removed, but this argument was | |
273 | # restored in glibc 2.3.4. | |
274 | # ~~~~ | |
275 | ||
276 | # In addition to that, some vendors ported the system call to 2.4 | |
277 | # kernels. | |
278 | ||
279 | # Furthermore, when the function first appeared, the MASK argument was | |
280 | # an unsigned long pointer, while later it was made into a cpu_set_t | |
281 | # pointer. Systems that have the cpu_set_t version also should have | |
282 | # the CPU_ZERO, CPU_SET, etc. macros. | |
283 | ||
284 | # All this mess means we have to cater for at least 3 different | |
285 | # sched_setaffinity prototypes: | |
286 | ||
287 | # ~~~~ | |
288 | # int sched_setaffinity (pid_t pid, unsigned int len, unsigned long *mask); | |
289 | # int sched_setaffinity (pid_t __pid, size_t __cpusetsize, const cpu_set_t *__cpuset); | |
290 | # int sched_setaffinity (pid_t __pid, const cpu_set_t *__mask); | |
291 | # ~~~~ | |
292 | ||
b3231c17 MD |
293 | AC_CHECK_TYPES([cpu_set_t], |
294 | [have_cpu_set_t="yes"], | |
295 | [have_cpu_set_t="no"], | |
296 | [#include <sched.h>]) | |
297 | ||
298 | # Confirm that we have CPU_ZERO, and it actually works. | |
299 | AC_MSG_CHECKING([whether CPU_ZERO works]) | |
300 | AH_TEMPLATE([HAVE_CPU_ZERO], [Defined to 1 if we have CPU_ZERO and it works]) | |
301 | AC_COMPILE_IFELSE([AC_LANG_SOURCE([[ | |
b3231c17 MD |
302 | #include <sched.h> |
303 | int main() | |
304 | { | |
305 | cpu_set_t foo; CPU_ZERO(&foo); | |
306 | return 0; | |
307 | } | |
308 | ]]) | |
309 | ],[ | |
310 | AC_DEFINE(HAVE_CPU_ZERO, 1) | |
311 | AC_MSG_RESULT([yes]) | |
312 | ],[ | |
313 | AC_MSG_RESULT([no]) | |
314 | ]) | |
315 | ||
316 | # Confirm that we have CPU_SET, and it actually works. | |
317 | AC_MSG_CHECKING([whether CPU_SET works]) | |
318 | AH_TEMPLATE([HAVE_CPU_SET], [Defined to 1 if we have CPU_SET and it works]) | |
319 | AC_COMPILE_IFELSE([AC_LANG_SOURCE([[ | |
b3231c17 MD |
320 | #include <sched.h> |
321 | int main() | |
322 | { | |
323 | cpu_set_t foo, mask; CPU_SET(0, &foo); | |
324 | return 0; | |
325 | } | |
326 | ]]) | |
327 | ],[ | |
328 | AC_DEFINE(HAVE_CPU_SET, 1) | |
329 | AC_MSG_RESULT([yes]) | |
330 | ],[ | |
331 | AC_MSG_RESULT([no]) | |
332 | ]) | |
333 | ||
d8540fc5 | 334 | # First check if the function is available at all. |
a6412536 AM |
335 | AC_CHECK_FUNCS([sched_setaffinity],[ |
336 | # Okay, we have it. Check if also have cpu_set_t. If we don't, | |
337 | # then we have the first version using unsigned long, and no | |
338 | # CPU_ZERO, etc. macros. If we do have cpu_set_t, we may have the | |
339 | # version with 2 or 3 arguments. In that case, CPU_ZERO, etc., | |
340 | # should also be present, but we confirm nonetheless. | |
341 | ||
b3231c17 MD |
342 | AS_IF([test "x$have_cpu_set_t" = "xyes"], [ |
343 | # We do have it. | |
a6412536 AM |
344 | # Check how many arguments does sched_setaffinity take. |
345 | # Should be 3 or 2. | |
346 | AC_MSG_CHECKING([how many arguments sched_setaffinity takes]) | |
ec5e2d14 | 347 | AC_COMPILE_IFELSE([AC_LANG_SOURCE([[ |
a6412536 | 348 | #include <sched.h> |
fe0707ab MD |
349 | int main() |
350 | { | |
351 | cpu_set_t foo; | |
b3231c17 | 352 | sched_setaffinity(0, sizeof (foo), &foo); |
fe0707ab MD |
353 | return 0; |
354 | } | |
a6412536 AM |
355 | ]]) |
356 | ], | |
357 | [sched_set_affinity_args=3], | |
358 | [sched_set_affinity_args=2]) | |
b3231c17 MD |
359 | AC_DEFINE_UNQUOTED(SCHED_SETAFFINITY_ARGS, |
360 | $sched_set_affinity_args, | |
a6412536 AM |
361 | [Defined to sched_setaffinity's number of arguments.]) |
362 | AC_MSG_RESULT([$sched_set_affinity_args]) | |
363 | ],[ | |
364 | # No cpu_set_t, always 3 args. | |
365 | AC_DEFINE(SCHED_SETAFFINITY_ARGS, 3) | |
b3231c17 | 366 | ]) |
a6412536 | 367 | ]) |
d8540fc5 | 368 | |
9a79c612 MJ |
369 | AM_CPPFLAGS="-include config.h" |
370 | AC_SUBST(AM_CPPFLAGS) | |
371 | ||
372 | AC_SUBST(AM_CFLAGS) | |
d8540fc5 | 373 | |
455b809a | 374 | AC_CONFIG_LINKS([ |
6893800a MJ |
375 | include/urcu/arch.h:$ARCHSRC |
376 | include/urcu/uatomic.h:$UATOMICSRC | |
455b809a | 377 | ]) |
48d848c7 PMF |
378 | AC_CONFIG_FILES([ |
379 | Makefile | |
fe999c05 | 380 | doc/Makefile |
8bad63a0 | 381 | doc/examples/Makefile |
6893800a MJ |
382 | include/Makefile |
383 | src/Makefile | |
48d848c7 | 384 | tests/Makefile |
f5ab766e MD |
385 | tests/common/Makefile |
386 | tests/unit/Makefile | |
387 | tests/benchmark/Makefile | |
388 | tests/regression/Makefile | |
074c3a1b | 389 | tests/regression/regression_tests |
1b387491 | 390 | tests/utils/Makefile |
6893800a MJ |
391 | src/liburcu.pc |
392 | src/liburcu-bp.pc | |
393 | src/liburcu-cds.pc | |
394 | src/liburcu-qsbr.pc | |
395 | src/liburcu-mb.pc | |
396 | src/liburcu-signal.pc | |
48d848c7 PMF |
397 | ]) |
398 | AC_OUTPUT | |
a6412536 | 399 | |
628a1a72 MJ |
400 | # |
401 | # Mini-report on what will be built. | |
402 | # | |
403 | ||
404 | PPRINT_INIT | |
405 | PPRINT_SET_INDENT(1) | |
406 | PPRINT_SET_TS(38) | |
407 | ||
408 | AS_ECHO | |
409 | AS_ECHO("${PPRINT_COLOR_BLDBLU}Userspace-RCU $PACKAGE_VERSION${PPRINT_COLOR_RST}") | |
410 | AS_ECHO | |
411 | ||
412 | PPRINT_SUBTITLE([Features]) | |
413 | ||
414 | PPRINT_PROP_STRING([Target architecture], $host_cpu) | |
415 | ||
416 | # SMP support enabled/disabled | |
417 | test "x$def_smp_support" = "xyes" && value=1 || value=0 | |
418 | PPRINT_PROP_BOOL([SMP support], $value) | |
419 | ||
420 | # Memory fence support available | |
421 | test "x$config_rcu_have_fence" = "xyes" && value=1 || value=0 | |
422 | PPRINT_PROP_BOOL([Memory fence instructions], $value) | |
423 | ||
424 | # Futex support available | |
425 | test "x$compat_futex_test" = "x0" && value=1 || value=0 | |
426 | PPRINT_PROP_BOOL([Futex support], $value) | |
427 | ||
428 | # TLS | |
429 | test "x$def_tls_detect" = "x" && value="pthread_getspecific()" || value="$def_tls_detect" | |
430 | PPRINT_PROP_STRING([Thread Local Storage (TLS)], [$value]) | |
431 | ||
432 | # clock_gettime() available | |
433 | test "x$config_rcu_have_clock_gettime" = "xyes" && value=1 || value=0 | |
434 | PPRINT_PROP_BOOL([clock_gettime()], $value) | |
435 | ||
436 | # Require membarrier | |
437 | test "x$def_sys_membarrier_fallback" != "xyes" && value=1 || value=0 | |
438 | PPRINT_PROP_BOOL([Require membarrier], $value) | |
439 | ||
440 | # RCU debug enabled/disabled | |
441 | test "x$enable_rcu_debug" = "xyes" && value=1 || value=0 | |
442 | PPRINT_PROP_BOOL([Internal debugging], $value) | |
443 | ||
444 | report_bindir="`eval eval echo $bindir`" | |
445 | report_libdir="`eval eval echo $libdir`" | |
446 | ||
447 | # Print the bindir and libdir this `make install' will install into. | |
448 | AS_ECHO | |
449 | PPRINT_SUBTITLE([Install directories]) | |
450 | PPRINT_PROP_STRING([Binaries], [$report_bindir]) | |
451 | PPRINT_PROP_STRING([Libraries], [$report_libdir]) | |
75478b32 | 452 |