Commit | Line | Data |
---|---|---|
16f9d99c | 1 | dnl Version infos |
58f107eb | 2 | m4_define([V_MAJOR], [2]) |
222fa453 | 3 | m4_define([V_MINOR], [13]) |
58f107eb | 4 | m4_define([V_PATCH], [0]) |
222fa453 MJ |
5 | m4_define([V_EXTRA], [pre]) |
6 | m4_define([V_NAME], [[Codename TBD]]) | |
7 | m4_define([V_DESC], [[Description TBD]]) | |
58f107eb | 8 | |
94480b71 MJ |
9 | m4_define([V_STRING], [V_MAJOR.V_MINOR.V_PATCH]) |
10 | m4_ifdef([V_EXTRA], [m4_append([V_STRING], [-V_EXTRA])]) | |
11 | ||
90e5d8e4 | 12 | AC_PREREQ([2.69]) |
093c3f9b | 13 | AC_INIT([lttng-ust], V_STRING, [mathieu dot desnoyers at efficios dot com], [], [https://lttng.org]) |
a334646a | 14 | |
94480b71 MJ |
15 | dnl Substitute minor/major/patchlevel version numbers |
16 | AC_SUBST([MAJOR_VERSION], [V_MAJOR]) | |
17 | AC_SUBST([MINOR_VERSION], [V_MINOR]) | |
18 | AC_SUBST([PATCHLEVEL_VERSION], [V_PATCH]) | |
19 | ||
a334646a MD |
20 | # Following the numbering scheme proposed by libtool for the library version |
21 | # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html | |
41a2a9aa | 22 | # This is the library version of liblttng-ust. |
23e08412 FD |
23 | m4_define([UST_LIB_V_MAJOR], [0]) |
24 | m4_define([UST_LIB_V_MINOR], [0]) | |
25 | m4_define([UST_LIB_V_PATCH], [0]) | |
26 | ||
27 | AC_SUBST([LTTNG_UST_LIBRARY_VERSION], [UST_LIB_V_MAJOR:UST_LIB_V_MINOR:UST_LIB_V_PATCH]) | |
6be9efc1 | 28 | AC_DEFINE([CONFIG_LTTNG_UST_LIBRARY_VERSION_MAJOR], [UST_LIB_V_MAJOR], [Major SONAME number of the ust library]) |
a334646a MD |
29 | # note: remember to update tracepoint.h dlopen() to match this version |
30 | # number. TODO: eventually automate by exporting the major number. | |
31 | ||
41a2a9aa MD |
32 | # This is the library version of liblttng-ust-ctl, used internally by |
33 | # liblttng-ust, lttng-sessiond, and lttng-consumerd. | |
b2c5f61a | 34 | AC_SUBST([LTTNG_UST_CTL_LIBRARY_VERSION], [4:0:0]) |
41a2a9aa | 35 | |
fb54defd | 36 | AC_CONFIG_HEADERS([include/config.h include/lttng/ust-config.h]) |
55355fa5 | 37 | AC_CONFIG_AUX_DIR([config]) |
94480b71 MJ |
38 | AC_CONFIG_MACRO_DIR([m4]) |
39 | AC_CONFIG_SRCDIR([include/lttng/tracepoint.h]) | |
40 | ||
9441df61 PMF |
41 | AC_CANONICAL_TARGET |
42 | AC_CANONICAL_HOST | |
94480b71 | 43 | |
0f6f0e89 | 44 | AM_INIT_AUTOMAKE([1.12 foreign dist-bzip2 no-dist-gzip tar-ustar nostdinc -Wall -Wno-portability -Werror]) |
846154aa | 45 | AM_MAINTAINER_MODE([enable]) |
94480b71 | 46 | |
80268473 MJ |
47 | # Enable silent rules by default |
48 | AM_SILENT_RULES([yes]) | |
4846fadc | 49 | |
94480b71 MJ |
50 | # Checks for C compiler |
51 | AC_USE_SYSTEM_EXTENSIONS | |
52 | AC_SYS_LARGEFILE | |
53 | AC_PROG_CC | |
54 | AC_PROG_CC_STDC | |
55 | AC_PROG_CXX | |
15b385c8 | 56 | AX_CXX_COMPILE_STDCXX([11]) |
b8a1677c | 57 | RW_PROG_CXX_WORKS |
94480b71 | 58 | AM_CONDITIONAL([CXX_WORKS], [test "x$rw_cv_prog_cxx_works" = "xyes"]) |
23c8854a | 59 | |
94480b71 MJ |
60 | # Check if the compiler support weak symbols |
61 | AX_SYS_WEAK_ALIAS | |
62 | ||
63 | AS_IF([test "x${ax_cv_sys_weak_alias}" = "xno"], [ | |
64 | AC_MSG_ERROR([Your platform doesn't support weak symbols.]) | |
65 | ]) | |
161239e0 | 66 | |
94480b71 | 67 | # Checks for programs. |
8aeb3cae | 68 | AM_PROG_AR |
46a73fe4 | 69 | AC_PROG_SED |
faebb418 | 70 | AC_PROG_GREP |
85e09133 | 71 | AC_PROG_LN_S |
4c70c05c | 72 | AC_PROG_MKDIR_P |
94480b71 MJ |
73 | AC_PROG_MAKE_SET |
74 | AC_CHECK_PROG([HAVE_CMAKE], [cmake], ["yes"]) | |
75 | AM_CONDITIONAL([HAVE_CMAKE], [test "x$HAVE_CMAKE" = "xyes"]) | |
46a73fe4 | 76 | |
faebb418 | 77 | # libtool link_all_deplibs fixup. See http://bugs.lttng.org/issues/321. |
86adb855 | 78 | AC_ARG_ENABLE([libtool-linkdep-fixup], [ |
94480b71 | 79 | AS_HELP_STRING([--disable-libtool-linkdep-fixup], [disable the libtool fixup for linking all dependent libraries (link_all_deplibs)]) |
86adb855 PP |
80 | ], [ |
81 | libtool_fixup=$enableval | |
82 | ], [ | |
83 | libtool_fixup=yes | |
84 | ]) | |
85 | ||
86 | AS_IF([test "x$libtool_fixup" = "xyes"], [ | |
093c3f9b | 87 | libtool_m4="$srcdir/m4/libtool.m4" |
86adb855 PP |
88 | libtool_flag_pattern=".*link_all_deplibs\s*,\s*\$1\s*)" |
89 | AC_MSG_CHECKING([for occurence(s) of link_all_deplibs = no in $libtool_m4]) | |
90 | libtool_flag_pattern_count=$(grep -c "$libtool_flag_pattern\s*=\s*no" $libtool_m4) | |
91 | ||
92 | AS_IF([test $libtool_flag_pattern_count -ne 0], [ | |
93 | AC_MSG_RESULT([$libtool_flag_pattern_count]) | |
94 | AC_MSG_WARN([the detected libtool will not link all dependencies, forcing link_all_deplibs = unknown]) | |
94480b71 | 95 | $SED -i "s/\($libtool_flag_pattern\)\s*=\s*no/\1=unknown/g" $libtool_m4 |
86adb855 PP |
96 | ], [ |
97 | AC_MSG_RESULT([none]) | |
98 | ]) | |
99 | ]) | |
94480b71 | 100 | LT_INIT([disable-static]) |
faebb418 | 101 | |
94480b71 MJ |
102 | AC_MSG_CHECKING([whether shared libraries are enabled]) |
103 | AS_IF([test "x$enable_shared" = "xyes"], [ | |
104 | AC_MSG_RESULT([yes]) | |
105 | ], [ | |
106 | AC_MSG_RESULT([no]) | |
107 | AC_MSG_ERROR([LTTng-UST requires shared libraries to be enabled]) | |
108 | ]) | |
86adb855 | 109 | |
94480b71 MJ |
110 | # Checks for typedefs, structures, and compiler characteristics. |
111 | AC_C_INLINE | |
112 | AC_TYPE_INT8_T | |
113 | AC_TYPE_INT16_T | |
114 | AC_TYPE_INT32_T | |
115 | AC_TYPE_INT64_T | |
116 | AC_TYPE_MODE_T | |
117 | AC_TYPE_OFF_T | |
118 | AC_TYPE_PID_T | |
119 | AC_TYPE_SIZE_T | |
120 | AC_TYPE_SSIZE_T | |
121 | AC_TYPE_UID_T | |
122 | AC_TYPE_UINT8_T | |
123 | AC_TYPE_UINT16_T | |
124 | AC_TYPE_UINT32_T | |
125 | AC_TYPE_UINT64_T | |
126 | AC_CHECK_TYPES([ptrdiff_t]) | |
127 | ||
128 | AX_C___ATTRIBUTE__ | |
129 | AS_IF([test "x$ax_cv___attribute__" = "xyes"], | |
130 | [:], | |
131 | [AC_MSG_ERROR([The compiler does not support __attribute__ extensions])]) | |
86adb855 | 132 | |
d9c56a93 MJ |
133 | AX_PTHREAD(,[AC_MSG_ERROR([Could not configure pthreads support])]) |
134 | ||
94480b71 MJ |
135 | # Checks for library functions. |
136 | AC_FUNC_CHOWN | |
137 | AC_FUNC_FORK | |
138 | AC_FUNC_MMAP | |
139 | AC_FUNC_REALLOC | |
140 | AC_FUNC_STRERROR_R | |
141 | AC_FUNC_STRNLEN | |
142 | AC_CHECK_FUNCS([ \ | |
143 | atexit \ | |
144 | clock_gettime \ | |
145 | ftruncate \ | |
146 | getpagesize \ | |
147 | gettimeofday \ | |
148 | localeconv \ | |
149 | memchr \ | |
150 | memmove \ | |
151 | memset \ | |
152 | mkdir \ | |
153 | munmap \ | |
154 | realpath \ | |
155 | sched_getcpu \ | |
156 | socket \ | |
157 | strchr \ | |
158 | strdup \ | |
159 | strerror \ | |
160 | strtol \ | |
0f6f0e89 | 161 | strtoul \ |
94480b71 | 162 | sysconf \ |
86adb855 | 163 | ]) |
340f7763 | 164 | |
d9c56a93 MJ |
165 | # Check for pthread_setname_np and its signature |
166 | LTTNG_PTHREAD_SETNAME_NP | |
167 | ||
94480b71 MJ |
168 | # AC_FUNC_MALLOC causes problems when cross-compiling. |
169 | #AC_FUNC_MALLOC | |
f1d4b810 | 170 | |
94480b71 MJ |
171 | # Checks for header files. |
172 | AC_HEADER_STDBOOL | |
173 | AC_CHECK_HEADERS([ \ | |
174 | arpa/inet.h \ | |
175 | fcntl.h \ | |
176 | float.h \ | |
177 | limits.h \ | |
178 | locale.h \ | |
179 | stddef.h \ | |
180 | sys/socket.h \ | |
181 | sys/time.h \ | |
182 | wchar.h \ | |
0e7d861a | 183 | ]) |
f1d4b810 | 184 | |
c95c332a MJ |
185 | # Set architecture specific options |
186 | AS_CASE([$host_cpu], | |
187 | [i[[3456]]86], [], | |
188 | [x86_64], [], | |
189 | [amd64], [], | |
190 | [powerpc], [], | |
191 | [ppc64], [], | |
192 | [ppc64le], [], | |
193 | [powerpc64], [], | |
194 | [powerpc64le], [], | |
195 | [s390], [NO_UNALIGNED_ACCESS=1], | |
196 | [s390x], [NO_UNALIGNED_ACCESS=1], | |
197 | [arm*], [ | |
198 | NO_UNALIGNED_ACCESS=1 | |
199 | NO_NUMA=1 | |
200 | ], | |
201 | [aarch64*], [NO_UNALIGNED_ACCESS=1], | |
202 | [mips*], [NO_UNALIGNED_ACCESS=1], | |
203 | [tile*], [NO_UNALIGNED_ACCESS=1], | |
204 | [ | |
205 | UNSUPPORTED_ARCH=1 | |
206 | NO_UNALIGNED_ACCESS=1 | |
207 | ]) | |
208 | ||
37a5fa45 MJ |
209 | # Set os specific options |
210 | AS_CASE([$host_os], | |
211 | [freebsd*], [NO_NUMA=1] | |
212 | ) | |
213 | ||
94480b71 MJ |
214 | # Configuration options, which will be installed in the config.h |
215 | AH_TEMPLATE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [Use efficient unaligned access.]) | |
216 | AH_TEMPLATE([LTTNG_UST_HAVE_SDT_INTEGRATION], [SystemTap integration via sdt.h]) | |
217 | AH_TEMPLATE([LTTNG_UST_HAVE_PERF_EVENT], [Perf event integration via perf_event.h]) | |
218 | ||
b54f2130 | 219 | # Checks for libraries. |
86adb855 | 220 | AC_CHECK_LIB([dl], [dlopen], [ |
42330adc | 221 | libdl_name=dl |
9d4d2a63 | 222 | DL_LIBS="-ldl" |
86adb855 | 223 | ], [ |
c6c454ab | 224 | #libdl not found, check for dlopen in libc. |
86adb855 | 225 | AC_CHECK_LIB([c], [dlopen], [ |
42330adc | 226 | libdl_name=c |
9d4d2a63 | 227 | DL_LIBS="-lc" |
86adb855 | 228 | ], [ |
c6c454ab MD |
229 | AC_MSG_ERROR([Cannot find dlopen in libdl nor libc. Use [LDFLAGS]=-Ldir to specify their location.]) |
230 | ]) | |
231 | ]) | |
9d4d2a63 | 232 | AC_SUBST(DL_LIBS) |
86adb855 | 233 | |
42330adc JR |
234 | # Check if libdl has dlmopen support. |
235 | AH_TEMPLATE([HAVE_DLMOPEN], ["Define to 1 if dlmopen is available."]) | |
236 | AC_CHECK_LIB([$libdl_name], [dlmopen], | |
237 | [AC_DEFINE([HAVE_DLMOPEN], [1])] | |
238 | ) | |
239 | ||
f9ff7aa4 RN |
240 | # Check for dlfcn.h |
241 | AC_CHECK_HEADER([dlfcn.h]) | |
86adb855 PP |
242 | AS_IF([test "x${ac_cv_header_dlfcn_h}" = "xyes"], [ |
243 | AC_CHECK_DECLS([RTLD_DI_LINKMAP], [], [], [ | |
86adb855 PP |
244 | #include <dlfcn.h> |
245 | ]) | |
246 | ], [ | |
247 | ac_cv_have_decl_RTLD_DI_LINKMAP="no" | |
248 | ]) | |
249 | ||
f9ff7aa4 RN |
250 | AM_CONDITIONAL([HAVE_DLINFO], [test "x${ac_cv_have_decl_RTLD_DI_LINKMAP}" = "xyes"]) |
251 | ||
ff1ee9bc MJ |
252 | # Require URCU >= 0.12 for DEFINE_URCU_TLS_INIT |
253 | PKG_CHECK_MODULES([URCU], [liburcu >= 0.12]) | |
254 | PKG_CHECK_MODULES([URCU_BP], [liburcu-bp >= 0.12]) | |
255 | PKG_CHECK_MODULES([URCU_CDS], [liburcu-cds >= 0.12]) | |
4b68c31f | 256 | |
bfcda6ce | 257 | # numa.h integration |
c95c332a MJ |
258 | AS_IF([test "x$NO_NUMA" = "x1"],[ |
259 | AS_IF([test "x$enable_numa" = "x" ], [enable_numa=no]) | |
260 | ]) | |
261 | ||
bfcda6ce MD |
262 | AC_ARG_ENABLE([numa], [ |
263 | AS_HELP_STRING([--disable-numa], [disable NUMA support]) | |
264 | ], [ | |
265 | enable_numa=$enableval | |
266 | ], [ | |
267 | enable_numa=yes | |
268 | ]) | |
269 | ||
270 | AS_IF([test "x$enable_numa" = "xyes"], [ | |
271 | # numa - check that numa lib is available | |
126bf5f4 MD |
272 | AC_CHECK_LIB([numa], [numa_available], [], |
273 | [AC_MSG_ERROR([libnuma is not available. Please either install it (e.g. libnuma-dev) or use [LDFLAGS]=-Ldir to specify the right location, or use --disable-numa configure argument to disable NUMA support.])]) | |
bfcda6ce MD |
274 | have_libnuma=yes |
275 | ]) | |
276 | AM_CONDITIONAL([HAVE_LIBNUMA], [test "x$have_libnuma" = "xyes"]) | |
e3073410 | 277 | |
d58d1454 MD |
278 | # optional linux/perf_event.h |
279 | AC_CHECK_HEADERS([linux/perf_event.h], [have_perf_event=yes], []) | |
d58d1454 | 280 | |
723f78e3 MD |
281 | # Perf event counters are supported on all architectures supported by |
282 | # perf, using the read system call as fallback. | |
283 | AM_CONDITIONAL([HAVE_PERF_EVENT], [test "x$have_perf_event" = "xyes"]) | |
1113f842 | 284 | |
723f78e3 | 285 | AS_IF([test "x$have_perf_event" = "xyes"], [ |
0e7d861a PP |
286 | AC_DEFINE([LTTNG_UST_HAVE_PERF_EVENT], [1]) |
287 | ]) | |
d58d1454 | 288 | |
0e7d861a PP |
289 | AS_IF([test "x$NO_UNALIGNED_ACCESS" = "x"], [ |
290 | AC_DEFINE([LTTNG_UST_HAVE_EFFICIENT_UNALIGNED_ACCESS], [1]) | |
291 | ]) | |
2699970a | 292 | |
2b6f8df9 | 293 | # Check for JNI header files if requested |
86adb855 | 294 | AC_ARG_ENABLE([jni-interface], [ |
94480b71 | 295 | AS_HELP_STRING([--enable-jni-interface], [build JNI interface between C and Java. Needs Java include files [default=no]]) |
86adb855 PP |
296 | ], [ |
297 | jni_interface=$enableval | |
298 | ], [ | |
299 | jni_interface=no | |
300 | ]) | |
2b6f8df9 | 301 | |
b2263155 | 302 | AM_CONDITIONAL([BUILD_JNI_INTERFACE], [test "x$jni_interface" = "xyes"]) |
2b6f8df9 | 303 | |
501f6777 | 304 | |
86adb855 | 305 | AC_ARG_ENABLE([java-agent-jul], [ |
94480b71 | 306 | AS_HELP_STRING([--enable-java-agent-jul], [build the LTTng UST Java agent with JUL support [default=no]]) |
86adb855 PP |
307 | ], [ |
308 | java_agent_jul=$enableval | |
309 | ], [ | |
310 | java_agent_jul=no | |
311 | ]) | |
501f6777 | 312 | |
86adb855 | 313 | AC_ARG_ENABLE([java-agent-log4j], [ |
94480b71 | 314 | AS_HELP_STRING([--enable-java-agent-log4j], [build the LTTng UST Java agent with Log4j support [default=no]]) |
86adb855 PP |
315 | ], [ |
316 | java_agent_log4j=$enableval | |
317 | ], [ | |
318 | java_agent_log4j=no | |
319 | ]) | |
501f6777 | 320 | |
86adb855 | 321 | AC_ARG_ENABLE([java-agent-all], [ |
94480b71 | 322 | AS_HELP_STRING([--enable-java-agent-all], [build the LTTng UST Java agent with all supported backends [default=no]]) |
86adb855 PP |
323 | ], [ |
324 | java_agent_jul=$enableval | |
325 | java_agent_log4j=$enableval | |
326 | ], [:]) | |
501f6777 CB |
327 | |
328 | AM_CONDITIONAL([BUILD_JAVA_AGENT], [test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"]) | |
329 | AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_JUL], [test "x$java_agent_jul" = "xyes"]) | |
330 | AM_CONDITIONAL([BUILD_JAVA_AGENT_WITH_LOG4J], [test "x$java_agent_log4j" = "xyes"]) | |
331 | ||
0e7d861a PP |
332 | AS_IF([test "x$jni_interface" = "xyes" || test "x$java_agent_jul" = "xyes" || test "x$java_agent_log4j" = "xyes"], [ |
333 | AX_JAVA_OPTIONS | |
334 | AX_PROG_JAVAC | |
335 | AX_PROG_JAVA | |
336 | AX_PROG_JAR | |
b1035e61 | 337 | AC_ARG_VAR([CLASSPATH], [Java class path]) |
501f6777 | 338 | |
0e7d861a PP |
339 | AX_JNI_INCLUDE_DIR |
340 | for JNI_INCLUDE_DIR in $JNI_INCLUDE_DIRS | |
341 | do | |
e1c62734 | 342 | JNI_CPPFLAGS="$JNI_CPPFLAGS -I$JNI_INCLUDE_DIR" |
0e7d861a | 343 | done |
501f6777 | 344 | |
e1c62734 MJ |
345 | saved_CPPFLAGS="$CPPFLAGS" |
346 | CPPFLAGS="$CPPFLAGS $JNI_CPPFLAGS" | |
0e7d861a | 347 | AX_PROG_JAVAH |
e1c62734 | 348 | CPPFLAGS="$saved_CPPFLAGS" |
0e7d861a | 349 | ]) |
501f6777 | 350 | |
1f0418c7 MD |
351 | AM_CONDITIONAL([HAVE_JAVAH], [test "x$JAVAH" != "x"]) |
352 | ||
0e7d861a PP |
353 | AS_IF([test "x$java_agent_log4j" = "xyes"], [ |
354 | AX_CHECK_CLASSPATH | |
0e7d861a | 355 | AX_CHECK_CLASS([org.apache.log4j.Logger]) |
0e7d861a PP |
356 | AS_IF([test "x$ac_cv_class_org_apache_log4j_Logger" = "xno"], [ |
357 | AC_MSG_ERROR([The UST Java agent support for log4j was requested but the Log4j classes were not found. Please specify the location of the Log4j jar via the Java CLASSPATH e.g: export CLASSPATH="/path/to/log4j.jar"]) | |
358 | ]) | |
359 | ]) | |
501f6777 | 360 | |
c3e14096 | 361 | # Option to build the python agent |
86adb855 | 362 | AC_ARG_ENABLE([python-agent], [ |
94480b71 | 363 | AS_HELP_STRING([--enable-python-agent], [build the LTTng UST Python agent [default=no]]) |
86adb855 PP |
364 | ], [ |
365 | python_agent=$enableval | |
366 | ], [:]) | |
c3e14096 | 367 | AM_CONDITIONAL([BUILD_PYTHON_AGENT], [test "x$python_agent" = "xyes"]) |
0e7d861a | 368 | AS_IF([test "x$python_agent" = "xyes"], [ |
55c9e5ae | 369 | AM_PATH_PYTHON([2.7]) |
0e7d861a | 370 | ]) |
c3e14096 | 371 | |
4846fadc | 372 | # sdt.h integration |
86adb855 | 373 | AC_ARG_WITH([sdt], [ |
94480b71 | 374 | AS_HELP_STRING([--with-sdt], [provide SystemTap integration via sdt.h [default=no]]) |
86adb855 PP |
375 | ], [ |
376 | with_sdt=$withval | |
377 | ], [ | |
378 | with_sdt="no" | |
379 | ]) | |
4846fadc | 380 | |
86adb855 | 381 | AS_IF([test "x$with_sdt" = "xyes"], [ |
491f30fe MD |
382 | AC_MSG_CHECKING([STAP_PROBEV()]) |
383 | AC_COMPILE_IFELSE([AC_LANG_SOURCE([[ | |
86adb855 PP |
384 | #define SDT_USE_VARIADIC |
385 | #include <sys/sdt.h> | |
386 | void fct(void) | |
387 | { | |
388 | STAP_PROBEV(provider,name,1,2,3,4,5,6,7,8,9,10); | |
389 | } | |
390 | ]])], [ | |
491f30fe | 391 | AC_MSG_RESULT([yes]) |
562c813a | 392 | AC_DEFINE([LTTNG_UST_HAVE_SDT_INTEGRATION], [1]) |
86adb855 | 393 | ], [ |
491f30fe | 394 | AC_MSG_RESULT([no]) |
135987a5 | 395 | AC_MSG_ERROR([The sdt.h integration was requested but the STAP_PROBEV define cannot be used. Make sure it is installed, and up to date, or use CPPFLAGS=-I/path/ to specify a non-standard path to sys/sdt.h]) |
4846fadc AM |
396 | ]) |
397 | ]) | |
398 | ||
86adb855 | 399 | AC_ARG_WITH([lttng-system-rundir], [ |
94480b71 | 400 | AS_HELP_STRING([--with-lttng-system-rundir], [Location of the system directory where LTTng-UST expects the system-wide lttng-sessiond runtime files. The default is "/var/run/lttng".]), |
86adb855 PP |
401 | ], [ |
402 | lttng_system_rundir="$withval" | |
403 | ], [ | |
404 | lttng_system_rundir="/var/run/lttng" | |
405 | ]) | |
751d4e91 | 406 | AC_DEFINE_UNQUOTED([LTTNG_SYSTEM_RUNDIR], ["$lttng_system_rundir"], |
86adb855 | 407 | [LTTng system runtime directory]) |
751d4e91 | 408 | |
86adb855 | 409 | AC_CHECK_PROG([BUILD_GEN_TP_EXAMPLES], [python], ["yes"]) |
0d8ba43d | 410 | AM_CONDITIONAL([BUILD_GEN_TP_EXAMPLES], [test "x$BUILD_GEN_TP_EXAMPLES" = "xyes"]) |
2b90f1d3 | 411 | |
08aa9a26 PP |
412 | # Enable building examples |
413 | AC_ARG_ENABLE( | |
414 | examples, | |
415 | AS_HELP_STRING( | |
416 | [--disable-examples], | |
417 | [Do not build and install examples] | |
418 | ), | |
419 | [enable_examples=$enableval], | |
420 | [enable_examples=yes] | |
421 | ) | |
422 | ||
423 | AM_CONDITIONAL([ENABLE_EXAMPLES], [test "x$enable_examples" != "xno"]) | |
424 | ||
4ddbd0b7 PP |
425 | # Set $IN_GIT_REPO if we're in the Git repository; the `bootstrap` file |
426 | # is not distributed in tarballs. | |
427 | AS_IF([test -f "$srcdir/bootstrap"], [in_git_repo=yes], [in_git_repo=no]) | |
428 | AM_CONDITIONAL([IN_GIT_REPO], [test "x$in_git_repo" = "xyes"]) | |
429 | ||
430 | # Enable building man pages (user's intention). | |
431 | AC_ARG_ENABLE( | |
432 | man-pages, | |
433 | AS_HELP_STRING( | |
434 | [--disable-man-pages], | |
435 | [Do not build and install man pages (already built in a distributed tarball)] | |
436 | ), | |
437 | [man_pages_opt=$enableval], | |
438 | [man_pages_opt=yes] | |
439 | ) | |
440 | ||
441 | # Check for asciidoc and xmlto if we enabled building the man pages. | |
442 | have_asciidoc_xmlto=no | |
94480b71 | 443 | warn_prebuilt_man_pages=no |
4ddbd0b7 PP |
444 | |
445 | AS_IF([test "x$man_pages_opt" = "xyes"], [ | |
446 | AC_PATH_PROG([ASCIIDOC], [asciidoc], [no]) | |
447 | AC_PATH_PROG([XMLTO], [xmlto], [no]) | |
448 | ||
449 | AS_IF([test "x$ASCIIDOC" = "xno" || test "x$XMLTO" = "xno"], [ | |
450 | AS_IF([test "x$in_git_repo" = "xyes"], [ | |
451 | # This is an error because we're in the Git repo, which | |
452 | # means the man pages are not already generated for us, | |
453 | # thus asciidoc/xmlto are required because we were asked | |
454 | # to build the man pages. | |
455 | AC_MSG_ERROR([ | |
456 | Both asciidoc and xmlto are needed to build the LTTng-UST man pages. Use | |
457 | --disable-man-pages to disable building the man pages, in which case | |
458 | they will not be installed. | |
459 | ]) | |
460 | ], [ | |
461 | # Only warn here: since we're in the tarball, the man | |
462 | # pages should already be generated at this point, thus | |
463 | # asciidoc/xmlto are not strictly required. | |
94480b71 | 464 | warn_prebuilt_man_pages=yes |
4ddbd0b7 PP |
465 | ]) |
466 | ], [ | |
467 | have_asciidoc_xmlto=yes | |
468 | ]) | |
469 | ]) | |
470 | ||
471 | # Export man page build condition: build the man pages if the user | |
472 | # asked for it, and if the tools are available. | |
473 | AM_CONDITIONAL([MAN_PAGES_OPT], [test "x$man_pages_opt" != "xno"]) | |
474 | AM_CONDITIONAL([HAVE_ASCIIDOC_XMLTO], [test "x$have_asciidoc_xmlto" = "xyes"]) | |
475 | ||
2b4444ce PP |
476 | # Default values |
477 | AC_DEFUN([_AC_DEFINE_AND_SUBST], [ | |
478 | AC_DEFINE_UNQUOTED([CONFIG_$1], [$2], [$1]) | |
479 | $1="$2" | |
480 | AC_SUBST([$1]) | |
481 | ]) | |
482 | ||
483 | _AC_DEFINE_AND_SUBST([LTTNG_UST_DEFAULT_CONSTRUCTOR_TIMEOUT_MS], [3000]) | |
484 | ||
ff1ee9bc | 485 | AM_CFLAGS="-Wall $URCU_CFLAGS $PTHREAD_CFLAGS" |
e1c62734 | 486 | AC_SUBST(AM_CFLAGS) |
fb54defd | 487 | |
04022848 MJ |
488 | AM_CXXFLAGS="$AM_CFLAGS" |
489 | AC_SUBST(AM_CXXFLAGS) | |
490 | ||
fb54defd MJ |
491 | # The order in which the include folders are searched is important. |
492 | # The top_builddir should always be searched first in the event that a build | |
493 | # time generated file is included. | |
494 | AM_CPPFLAGS="-I\$(top_builddir)/include -I\$(top_srcdir)/include -include config.h" | |
495 | AC_SUBST(AM_CPPFLAGS) | |
496 | ||
e1c62734 MJ |
497 | AC_SUBST(JNI_CPPFLAGS) |
498 | ||
55355fa5 JB |
499 | AC_CONFIG_FILES([ |
500 | Makefile | |
7ccf75d3 MD |
501 | doc/Makefile |
502 | doc/examples/Makefile | |
4ddbd0b7 | 503 | doc/man/Makefile |
69400ac4 | 504 | include/Makefile |
b728d87e | 505 | include/lttng/ust-version.h |
69400ac4 | 506 | snprintf/Makefile |
4931a13e | 507 | libringbuffer/Makefile |
69400ac4 MD |
508 | liblttng-ust-comm/Makefile |
509 | liblttng-ust/Makefile | |
510 | liblttng-ust-ctl/Makefile | |
511 | liblttng-ust-fork/Makefile | |
b13d93c2 | 512 | liblttng-ust-dl/Makefile |
95e6d268 | 513 | liblttng-ust-fd/Makefile |
69400ac4 | 514 | liblttng-ust-java/Makefile |
501f6777 CB |
515 | liblttng-ust-java-agent/Makefile |
516 | liblttng-ust-java-agent/java/Makefile | |
8e6b6350 | 517 | liblttng-ust-java-agent/java/lttng-ust-agent-all/Makefile |
8e57e02f AM |
518 | liblttng-ust-java-agent/java/lttng-ust-agent-common/Makefile |
519 | liblttng-ust-java-agent/java/lttng-ust-agent-jul/Makefile | |
520 | liblttng-ust-java-agent/java/lttng-ust-agent-log4j/Makefile | |
501f6777 | 521 | liblttng-ust-java-agent/jni/Makefile |
8ab5c06b | 522 | liblttng-ust-java-agent/jni/common/Makefile |
501f6777 CB |
523 | liblttng-ust-java-agent/jni/jul/Makefile |
524 | liblttng-ust-java-agent/jni/log4j/Makefile | |
476037d9 | 525 | liblttng-ust-libc-wrapper/Makefile |
70d654f2 | 526 | liblttng-ust-cyg-profile/Makefile |
c3e14096 | 527 | liblttng-ust-python-agent/Makefile |
5b6ff569 PP |
528 | python-lttngust/Makefile |
529 | python-lttngust/setup.py | |
530 | python-lttngust/lttngust/__init__.py | |
b25c5b37 | 531 | tools/Makefile |
6dd969b5 | 532 | tests/Makefile |
dbe6ade0 MJ |
533 | tests/compile/Makefile |
534 | tests/compile/ctf-types/Makefile | |
535 | tests/compile/hello.cxx/Makefile | |
536 | tests/compile/hello/Makefile | |
537 | tests/compile/hello-many/Makefile | |
538 | tests/compile/same_line_tracepoint/Makefile | |
539 | tests/compile/test-app-ctx/Makefile | |
a44af49d | 540 | tests/benchmark/Makefile |
dbe6ade0 MJ |
541 | tests/unit/gcc-weak-hidden/Makefile |
542 | tests/unit/Makefile | |
8707de35 | 543 | tests/unit/libringbuffer/Makefile |
dbe6ade0 MJ |
544 | tests/unit/pthread_name/Makefile |
545 | tests/unit/snprintf/Makefile | |
546 | tests/unit/ust-elf/Makefile | |
9a4b88ff | 547 | tests/utils/Makefile |
74a6d87b | 548 | lttng-ust.pc |
a1acf2a6 | 549 | lttng-ust-ctl.pc |
55355fa5 | 550 | ]) |
1f9eff07 | 551 | |
bf261856 JR |
552 | # Create link for python agent for the VPATH guru. |
553 | AC_CONFIG_LINKS([ | |
5b6ff569 PP |
554 | python-lttngust/lttngust/agent.py:python-lttngust/lttngust/agent.py |
555 | python-lttngust/lttngust/cmd.py:python-lttngust/lttngust/cmd.py | |
e7bf4968 | 556 | python-lttngust/lttngust/compat.py:python-lttngust/lttngust/compat.py |
5b6ff569 PP |
557 | python-lttngust/lttngust/debug.py:python-lttngust/lttngust/debug.py |
558 | python-lttngust/lttngust/loghandler.py:python-lttngust/lttngust/loghandler.py | |
bf261856 JR |
559 | ]) |
560 | ||
dbe6ade0 | 561 | AC_CONFIG_FILES([tests/unit/ust-elf/test_ust_elf],[chmod +x tests/unit/ust-elf/test_ust_elf]) |
37b3de59 | 562 | |
1304f3df | 563 | AC_OUTPUT |
1f9eff07 | 564 | |
94480b71 MJ |
565 | |
566 | # | |
567 | # Mini-report on what will be built. | |
568 | # | |
569 | ||
570 | PPRINT_INIT | |
571 | PPRINT_SET_INDENT(1) | |
572 | PPRINT_SET_TS(38) | |
573 | ||
2770ab16 | 574 | AS_ECHO |
94480b71 | 575 | AS_ECHO("${PPRINT_COLOR_BLDBLU}LTTng-ust $PACKAGE_VERSION \"V_NAME\"$PPRINT_COLOR_RST") |
2a5b1cfe | 576 | AS_ECHO |
649282a8 | 577 | |
94480b71 MJ |
578 | AS_ECHO("V_DESC") |
579 | ||
2a5b1cfe | 580 | AS_ECHO |
94480b71 MJ |
581 | PPRINT_SUBTITLE([System]) |
582 | ||
583 | PPRINT_PROP_STRING([Target architecture], $host_cpu) | |
584 | ||
585 | test "x$NO_UNALIGNED_ACCESS" != "x1" && value=1 || value=0 | |
586 | PPRINT_PROP_BOOL([Efficient unaligned memory access], $value) | |
587 | ||
588 | AS_IF([test "x$UNSUPPORTED_ARCH" = "x1"],[ | |
589 | PPRINT_WARN([Your architecture ($host_cpu) is unsupported, using safe default of no unaligned access.]) | |
590 | ]) | |
591 | ||
592 | AS_ECHO | |
593 | PPRINT_SUBTITLE([Features]) | |
594 | PPRINT_SET_INDENT(1) | |
595 | ||
596 | test "x$with_sdt" = "xyes" && value=1 || value=0 | |
597 | PPRINT_PROP_BOOL_CUSTOM([sdt.h integration], $value, [use --with-sdt]) | |
598 | ||
599 | test "x$java_agent_jul" = xyes && value=1 || value=0 | |
600 | PPRINT_PROP_BOOL_CUSTOM([Java agent (JUL support)], $value, [use --enable-java-agent-jul]) | |
601 | ||
602 | test "x$java_agent_log4j" = xyes && value=1 || value=0 | |
603 | PPRINT_PROP_BOOL_CUSTOM([Java agent (Log4j support)], $value, [use --enable-java-agent-log4j]) | |
604 | ||
605 | test "x$jni_interface" = xyes && value=1 || value=0 | |
606 | PPRINT_PROP_BOOL_CUSTOM([JNI interface (JNI)], $value, [use --enable-jni-interface]) | |
607 | ||
608 | test "x$python_agent" = xyes && value=1 || value=0 | |
609 | PPRINT_PROP_BOOL_CUSTOM([Python agent], $value, [use --enable-python-agent]) | |
1f9eff07 | 610 | |
3207efee MJ |
611 | test "x$have_perf_event" = "xyes" && value=1 || value=0 |
612 | PPRINT_PROP_BOOL_CUSTOM([Perf event integration], $value) | |
613 | ||
bfcda6ce MD |
614 | test "x$enable_numa" = xyes && value=1 || value=0 |
615 | PPRINT_PROP_BOOL([NUMA], $value) | |
616 | ||
2a5b1cfe | 617 | AS_ECHO |
94480b71 | 618 | PPRINT_SET_INDENT(0) |
501f6777 | 619 | |
08aa9a26 PP |
620 | test "x$enable_examples" = xyes && value=1 || value=0 |
621 | PPRINT_PROP_BOOL([Build and install examples], $value, $PPRINT_COLOR_SUBTITLE) | |
622 | ||
94480b71 MJ |
623 | # man pages build enabled/disabled |
624 | m4_pushdef([build_man_pages_msg], [Build and install man pages]) | |
501f6777 | 625 | |
94480b71 MJ |
626 | AS_IF([test "x$man_pages_opt" != "xno"], [ |
627 | AS_IF([test "x$in_git_repo" = "xyes"], [ | |
628 | PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE) | |
629 | ], [ | |
630 | AS_IF([test "x$have_asciidoc_xmlto" = "xyes"], [ | |
631 | PPRINT_PROP_BOOL([build_man_pages_msg], 1, $PPRINT_COLOR_SUBTITLE) | |
632 | ], [ | |
633 | PPRINT_PROP_STRING([build_man_pages_msg], | |
634 | [${PPRINT_COLOR_BLDGRN}yes (already built)], | |
635 | $PPRINT_COLOR_SUBTITLE) | |
636 | ]) | |
637 | ]) | |
638 | ], [ | |
639 | PPRINT_PROP_BOOL([build_man_pages_msg], 0, $PPRINT_COLOR_SUBTITLE) | |
640 | ]) | |
501f6777 | 641 | |
94480b71 | 642 | m4_popdef([build_man_pages_msg]) |
1f9eff07 | 643 | |
94480b71 | 644 | PPRINT_SET_INDENT(1) |
c3e14096 | 645 | |
94480b71 MJ |
646 | report_bindir="`eval eval echo $bindir`" |
647 | report_libdir="`eval eval echo $libdir`" | |
1f9eff07 | 648 | |
94480b71 | 649 | # Print the bindir and libdir this `make install' will install into. |
2a5b1cfe | 650 | AS_ECHO |
94480b71 MJ |
651 | PPRINT_SUBTITLE([Install directories]) |
652 | PPRINT_PROP_STRING([Binaries], [$report_bindir]) | |
653 | PPRINT_PROP_STRING([Libraries], [$report_libdir]) | |
0ea8bd08 | 654 | |
94480b71 MJ |
655 | AS_ECHO |
656 | PPRINT_SUBTITLE([System directories]) | |
657 | ||
658 | PPRINT_PROP_STRING([lttng-sessiond rundir], [$lttng_system_rundir]) | |
659 | ||
660 | PPRINT_SET_INDENT(0) | |
661 | ||
662 | AS_IF([test "x$warn_prebuilt_man_pages" = "xyes" ], [ | |
663 | AS_ECHO | |
664 | PPRINT_WARN([Both asciidoc and xmlto are needed to build the LTTng-UST man pages. | |
1f9eff07 | 665 | |
94480b71 MJ |
666 | Note that the man pages are already built in this distribution tarball, |
667 | therefore asciidoc and xmlto are only needed if you intend to modify | |
668 | their sources. | |
669 | ||
670 | Use --disable-man-pages to completely disable building and installing | |
671 | the man pages.]) | |
672 | ]) |